Udhëzuesi ofron një numër shembujsh të formulës "Excel nëse përmban" që tregojnë se si të kthehet diçka në një kolonë tjetër nëse një qelizë e synuar përmban një vlerë të kërkuar, si të kërkoni me përputhje të pjesshme dhe të testoni kritere të shumta me OR si si dhe logjika DHE.

Një nga detyrat më të zakonshme në Excel është kontrollimi nëse një qelizë përmban një vlerë interesi. Çfarë lloj vlere mund të jetë kjo? Vetëm çdo tekst ose numër, tekst specifik ose ndonjë vlerë fare (jo qelizë boshe).

Ekzistojnë disa variacione të formulës "Nëse qeliza përmban" në Excel, në varësi të saktësisht se çfarë vlerash dëshironi të gjeni. Në përgjithësi, ju do të përdorni funksionin IF për të bërë një test logjik dhe do të ktheni një vlerë kur kushti plotësohet (qeliza përmban) dhe/ose një vlerë tjetër kur kushti nuk plotësohet (qeliza nuk përmban). Shembujt e mëposhtëm mbulojnë skenarët më të shpeshtë.

Nëse qeliza përmban ndonjë vlerë, atëherë

Për fillim, le të shohim se si të gjejmë qeliza që përmbajnë ndonjë gjë fare: ndonjë teksti, numri ose data. Për këtë, ne do të përdorim një formulë të thjeshtë IF që kontrollon për qeliza jo bosh.

Për shembull, për të kthyer "Jo bosh" në kolonën B nëse qeliza e kolonës A në të njëjtin rresht përmban ndonjë vlerë, futni formulën e mëposhtme në B2 dhe më pas klikoni dy herë katrorin e vogël jeshil në këndin e poshtëm djathtas për të kopjuar formulën poshtë tëkolona:

=IF(A2"", "Not blank", "")

Rezultati do të duket i ngjashëm me këtë:

Nëse qeliza përmban tekst, atëherë

Nëse dëshironi të gjeni vetëm qeliza me vlera teksti që shpërfillin numrat dhe datat, atëherë përdorni IF në kombinim me funksionin ISTEXT. Këtu është formula e përgjithshme për të kthyer një vlerë në një qelizë tjetër nëse një qelizë e synuar përmban çdo tekst :

Supozojmë se dëshironi të futni fjalën "po" në kolonën B nëse një qelizë në kolonën A përmban tekst. Për ta bërë këtë, vendosni formulën e mëposhtme në B2:

=IF(ISTEXT(A2), "Yes", "")

Nëse qeliza përmban numër, atëherë

Në mënyrë të ngjashme , mund të identifikoni qelizat me vlera numerike (numrat dhe datat). Për këtë, përdorni funksionin IF së bashku me ISNUMBER:

Formula e mëposhtme kthen "po" në kolonë B nëse një qelizë përkatëse në kolonën A përmban ndonjë numër:

=IF(ISNUMBER(A2), "Yes", "")

Nëse qeliza përmban tekst specifik

Gjeni qelizat që përmbajnë tekst të caktuar (ose numrat ose datat) është e lehtë. Ju shkruani një formulë të rregullt IF që kontrollon nëse një qelizë e synuar përmban tekstin e dëshiruar dhe shkruani tekstin për t'u kthyer në argumentin value_if_true .

Për shembull, për të zbuluar nëse qeliza A2 përmban "mollë", përdorni këtë formulë:

=IF(A2="apples", "Yes", "")

Nëse qeliza nuk përmban specifiktekst

Nëse po kërkoni rezultatin e kundërt, d.m.th. ktheni një vlerë në një kolonë tjetër nëse një qelizë e synuar nuk përmban tekstin e specifikuar ("mollët"), atëherë bëni një nga sa vijon.

0>Furnizoni një varg bosh ("") në argumentin value_if_true dhe tekst për t'u kthyer në argumentin value_if_false :

=IF(A2="apples", "", "Not apples")

Ose , vendosni operatorin "jo e barabartë me" në logjik_test dhe tekstin për ta kthyer në value_if_true:

=IF(A2"apples", "Not apples", "")

Sido që të jetë, formula do të prodhojë ky rezultat:

Nëse qeliza përmban tekst: formulë e ndjeshme ndaj shkronjave

Për të detyruar formulën tuaj të bëjë dallimin midis shkronjave të mëdha dhe të vogla, përdorni funksionin EXACT që kontrollon nëse dy vargje teksti janë saktësisht të barabarta, duke përfshirë shkronjat:

=IF(EXACT(A2,"APPLES"), "Yes", "")

Mund të futni gjithashtu vargun e tekstit të modelit në disa qeliza (të themi në C1), rregulloni referencën e qelizës me shenjën $ ($C$1) dhe krahasoni qelizën e synuar me atë qelizë:

=IF(EXACT(A2,$C$1), "Yes", "")

Nëse qeliza përmban varg teksti specifik (përputhje e pjesshme)

Kemi mbaruar me detyra të parëndësishme dhe kalojmë në ato më sfiduese dhe interesante :) Në këtë shembull, duhen tre funksione të ndryshme për të zbuluar nëse një karakter ose nënvarg i caktuar është pjesë e qelizës përmbajtjet:

Po funksionon nga brenda jashtë , ja çfarë bën formula:

• TheFunksioni SEARCH kërkon një varg teksti dhe nëse gjendet vargu, kthen pozicionin e karakterit të parë, #VALUE! gabim ndryshe.
• Funksioni ISNUMBER kontrollon nëse SEARCH pati sukses apo dështoi. Nëse SEARCH ka kthyer ndonjë numër, ISNUMBER kthen TË VËRTETË. Nëse SEARCH rezulton në një gabim, ISNUMBER kthen FALSE.
• Më në fund, funksioni IF kthen vlerën e specifikuar për qelizat që kanë TRUE në testin logjik, një varg bosh ("") përndryshe.

Dhe tani, le të shohim se si funksionon kjo formulë e përgjithshme në fletët e punës në jetën reale.

Nëse qeliza përmban tekst të caktuar, vendosni një vlerë në një qelizë tjetër

Duke supozuar se keni një listë të urdhrat në kolonën A dhe dëshironi të gjeni porosi me një identifikues specifik, thoni "A-". Detyra mund të realizohet me këtë formulë:

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

Në vend të kodimit të fortë të vargut në formulë, mund ta futni atë në një qelizë të veçantë (E1), referencën e asaj qelize në formulën tuaj :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

Që formula të funksionojë si duhet, sigurohuni që të kyçni adresën e qelizës që përmban vargun me shenjën $ (referencë absolute e qelizës).

Nëse qeliza përmban tekst specifik, kopjojeni atë në një kolonë tjetër

Nëse dëshironi të kopjoni përmbajtjen e qelizave të vlefshme diku tjetër, thjesht jepni adresën e qelizës së vlerësuar (A2) në argumentin value_if_true :

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

Pastroja më poshtë tregon rezultatet:

Nëseqeliza përmban tekst specifik: formula e ndjeshme ndaj shkronjave të vogla

Në të dy shembujt e mësipërm, formulat janë të pandjeshme ndaj shkronjave. Në situatat kur punoni me të dhëna të ndjeshme ndaj shkronjave, përdorni funksionin FIND në vend të SEARCH për të dalluar shkronjat.

Për shembull, formula e mëposhtme do të identifikojë vetëm urdhrat me shkronja të mëdha "A-" duke injoruar shkronjat e vogla " a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

Nëse qeliza përmban një nga shumë vargjet e tekstit (OR logjikë)

Për të identifikuar qelizat që përmbajnë të paktën një nga shumë gjëra që po kërkoni, përdorni një nga formulat e mëposhtme.

Formula IF OSE ISNUM SEARCH

Qasja më e dukshme do të ishte të kontrolloni çdo nënvarg individualisht dhe të keni funksionin OR ktheni TRUE në testin logjik të formulës IF nëse gjendet të paktën një nënvarg:

Duke supozuar se keni një listë të SKU-ve në kolonën A dhe ju dëshironi të gjeni ato që përfshijnë ose "fustan" ose "fund". Ju mund ta bëni këtë duke përdorur këtë formulë:

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

Formula funksionon mjaft mirë për disa artikuj, por sigurisht që nuk është mënyra për të shkoni nëse doni të kontrolloni për shumë gjëra. Në këtë rast, një qasje më e mirë do të ishte përdorimi i funksionit SUMPRODUCT siç tregohet në shembullin vijues.

Formula e KËRKIMIT TË NUMRIVE TË SUMPRODUCT

Nëse jeniduke u marrë me vargje të shumta teksti, kërkimi i secilit varg individualisht do ta bënte formulën tuaj shumë të gjatë dhe të vështirë për t'u lexuar. Një zgjidhje më elegante do të ishte futja e kombinimit ISNUMBER SEARCH në funksionin SUMPRODUCT dhe shikoni nëse rezultati është më i madh se zero:

Për shembull, për të zbuluar nëse A2 përmban ndonjë nga fjalët e dhëna në qelizat D2:D4, përdorni këtë formulë:

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

Në mënyrë alternative, mund të krijoni një gamë të emërtuar që përmban vargjet për të kërkuar, ose të jepni fjalët drejtpërdrejt në formulën:

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

Sidoqoftë, rezultati do të jetë i ngjashëm me këtë:

Për ta bërë rezultatin më miqësor për përdoruesit, mund të futni formulën e mësipërme në funksionin IF dhe të ktheni tekstin tuaj në vend të vlerave TRUE/FALSE:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

Si funksionon kjo formulë

Në thelb, ju përdorni ISNUMBER së bashku me SEARCH siç shpjegohet në shembullin e mëparshëm. Në këtë rast, rezultatet e kërkimit paraqiten në formën e një grupi si {TRUE;FALSE;FALSE}. Nëse një qelizë përmban të paktën një nga nënvargjet e specifikuara, do të jetë TRUE në grup. Operatori i dyfishtë unar (--) detyron vlerat TRUE / FALSE në 1 dhe 0, përkatësisht, dhe jep një grup si {1;0;0}. Së fundi, funksioni SUMPRODUCT mbledh numrat dhe ne zgjedhim qelizat ku rezultati është më i madh se zero.

Nëseqeliza përmban disa vargje (AND logjikë)

Në situatat kur dëshironi të gjeni qeliza që përmbajnë të gjitha vargjet e specifikuara të tekstit, përdorni kombinimin tashmë të njohur ISNUMBER SEARCH së bashku me IF AND:

Për shembull, mund të gjeni SKU që përmbajnë "dress" dhe "blu" me këtë formulë:

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

Ose, mund të shkruani vargjet në qeliza të veçanta dhe referojini ato qeliza në formulën tuaj:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

Si një zgjidhje alternative, mund të numëroni dukuritë e çdo vargu dhe të kontrolloni nëse çdo numërim është më i madh se zero:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

Rezultati do të jetë saktësisht siç tregohet në pamjen e mësipërme.

Si të ktheni rezultate të ndryshme bazuar në vlerën e qelizës

Në rast se dëshironi të krahasoni secilën qelizë në kolonën e synuar me një listë tjetër artikujsh dhe të ktheni një vlerë të ndryshme për secilën përputhje, përdorni një nga metodat e mëposhtme.

Të ndërlidhura. IFs

Logjika e formulës IF të ndërlidhur është kaq e thjeshtë sa kjo: ju përdorni një funksion të veçantë IF për të testuar çdo kusht dhe ktheni vlera të ndryshme në varësi të rezultateve të atyre testeve.

Duke supozuar se keni një listë artikujsh në kolonën A dhe dëshironi të keni shkurtesat e tyre në kolonën B. Për ta bërë këtë, përdorni formulën e mëposhtme:

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

Për detaje të plota në lidhje me sintaksën dhe logjikën e IF të mbivendosur, ju lutemi shikoni IF të mbivendosur në Excel - kushte të shumta në një formulë të vetme.

Formula e kërkimit

Nëse po kërkoni më shumë formulë kompakte dhe më e kuptueshme, përdorni funksionin LOOKUP me vlerat e kërkimit dhe të kthimit të ofruara si konstante të grupit vertikal:

Për rezultate të sakta, sigurohuni që të listoni vlerat e kërkimit sipas rendit alfabetik , nga A në Z.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

Krahasuar me IF-të e ndërlidhura, formula e kërkimit ka një avantazh më shumë - ajo kupton karakteret e egër dhe për këtë arsye mund të identifikojë përputhjet e pjesshme.

Për shembull, nëse kolona A përmban disa lloje e bananeve, mund të kërkoni "*banane*" dhe të keni të njëjtën shkurtesë ("B") për të gjitha qelizat e tilla:

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

Për më shumë informacion, ju lutemi shikoni formulën e kërkimit si një alternativë ndaj IF-ve të ndërlidhura.

Formula e Vlookup-it

Kur punoni me një grup të dhënash të ndryshueshme, mund të jetë më e përshtatshme të futni një listë të përputhjeve veçmas qelizat dhe i rifitoni ato duke përdorur një formulë Vlookup,p.sh.:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

Për më shumë informacion, ju lutemi shikoni tutorialin e Excel VLOOKUP për fillestarët.

Kjo është mënyra se si kontrolloni nëse një qelizë përmban ndonjë vlerë ose tekst specifik në Excel. Javën e ardhshme, ne do të vazhdojmë të shikojmë qelizën If të Excel-it përmban formula dhe do të mësojmë se si të numërojmë ose të përmbledhim qelizat përkatëse, të kopjojmë ose heqim rreshta të tëra që përmbajnë ato qeliza dhe më shumë. Ju lutemi qëndroni të sintonizuar!

Praktikoni librin e punës

Excel nëse qeliza përmban - shembuj formulash (skedari .xlsx)