Kazalo
V tem učbeniku je razložena razlika med funkcijama SUMIF in SUMIFS glede njune sintakse in uporabe ter podani številni primeri formul za seštevanje vrednosti z več merili AND / OR v Excelu 365, 2021, 2019, 2016, 2013, 2010 in nižjih.
Kot vsi vemo, Microsoft Excel ponuja vrsto funkcij za izvajanje različnih izračunov s podatki. Pred nekaj članki smo raziskali COUNTIF in COUNTIFS, ki sta namenjena štetju celic na podlagi enega pogoja oziroma več pogojev. Prejšnji teden smo obravnavali Excelov SUMIF, ki sešteva vrednosti, ki izpolnjujejo določena merila. Zdaj je čas, da pregledamo množinsko različico funkcijeSUMIF - Excelov SUMIFS, ki omogoča seštevanje vrednosti po več merilih.
Tisti, ki poznajo funkcijo SUMIF, morda mislijo, da je za njeno pretvorbo v SUMIFS potreben le dodaten "S" in nekaj dodatnih meril. To se zdi povsem logično... vendar "logično" ni vedno tako, ko imamo opravka z Microsoftom : )
Funkcija Excel SUMIF - sintaksa in uporaba
Funkcija SUMIF se uporablja za pogojno seštevanje vrednosti na podlagi enotno merilo . Sintakso SUMIF smo podrobno obravnavali v prejšnjem članku, tukaj pa jo bomo na kratko osvežili.
SUMIF(razpon, merila, [sum_razpon])- obseg - območje celic, ki jih je treba oceniti po vaših merilih, obvezno.
- merila - pogoj, ki mora biti izpolnjen, zahtevan.
- sum_range - celice za seštevek, če je pogoj izpolnjen, neobvezno.
Kot vidite, sintaksa funkcije Excel SUMIF omogoča le en pogoj. Kljub temu pa pravimo, da lahko funkcijo Excel SUMIF uporabimo za seštevanje vrednosti z več merili. Kako je to mogoče? Z dodajanjem rezultatov več funkcij SUMIF in z uporabo formul SUMIF z merili polja, kot je prikazano v naslednjih primerih.
Funkcija Excel SUMIFS - sintaksa in primerjava; uporaba
SUMIFS v Excelu uporabljate za iskanje pogojne vsote vrednosti na podlagi več meril Funkcija SUMIFS je bila uvedena v Excelu 2007 in je na voljo v vseh naslednjih različicah Excel 2010, 2013, 2016, 2019, 2021 in Excel 365.
V primerjavi s sintakso SUMIF je sintaksa SUMIFS nekoliko bolj zapletena:
SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)Prvi trije argumenti so obvezni, dodatni razponi in z njimi povezana merila so neobvezni.
sum_range- ena ali več celic za seštevanje, obvezno. To je lahko ena celica, niz celic ali poimenovani niz. Seštevajo se samo celice s številkami; prazne in besedilne vrednosti se ne upoštevajo.kriterij_razpon1- prvo območje, ki ga je treba ovrednotiti s povezanimi merili, obvezno.merila1- prvi pogoj, ki mora biti izpolnjen, obvezen. Merila lahko podate v obliki števila, logičnega izraza, reference na celico, besedila ali druge funkcije Excel-a. Uporabite lahko na primer merila, kot so 10, ">=10", A1, "češnje" ali TODAY().criteria_range2, criteria2, ...- to so dodatna območja in z njimi povezana merila, ki niso obvezna. V formulah SUMIFS lahko uporabite do 127 parov območij/meril.
Opombe:
- Za pravilno delovanje formule SUMIFS morajo biti vsi kriterij_območje argumenti morajo imeti enako dimenzijo kot sum_range , tj. enako število vrstic in stolpcev.
- Funkcija SUMIFS deluje z logiko AND, kar pomeni, da se celica v območju seštevanja sešteje le, če izpolnjuje vsa določena merila, tj. če so vsa merila resnična za to celico.
Osnovna formula SUMIFS
Zdaj si oglejmo Excelovo formulo SUMIFS z dvema pogojema. Predpostavimo, da imate tabelo s seznamom pošiljk sadja od različnih dobaviteljev. Imena sadja so v stolpcu A, imena dobaviteljev v stolpcu B, količina pa v stolpcu C. Želite ugotoviti vsoto zneskov, ki se nanašajo na določeno sadje in dobavitelja, npr. vsa jabolka, ki jih je dobavil Pete.
Ko se učite nekaj novega, je vedno dobro začeti s preprostimi stvarmi. Zato za začetek definirajmo vse argumente za našo formulo SUMIFS:
- sum_range - C2:C9
- kriterij_razpon1 - A2:A9
- kriterij1 - "jabolka"
- kriterij_razpon2 - B2:B9
- kriterij2 - "Pete"
Zdaj sestavite zgornje parametre in dobili boste naslednjo formulo SUMIFS:
=SUMIFS(C2:C9, A2:A9, "jabolka", B2:B9, "Pete")
Če želite formulo še bolj izpopolniti, lahko besedilni merili "jabolka" in "Pete" nadomestite z referencami na celice. V tem primeru vam ne bo treba spreminjati formule za izračun količine drugega sadja od drugega dobavitelja:
=SUMIFS(C2:C9, A2:A9, F1, B2:B9, F2)
Opomba: Funkciji SUMIF in SUMIFS sta po naravi neobčutljivi na velikost črk. Če želite, da prepoznata velikost besedila, glejte poglavje Formula SUMIF in SUMIFS v Excelu, ki je občutljiva na velikost črk.
SUMIF proti SUMIFS v Excelu
Ker je cilj tega učbenika zajeti vse možne načine seštevanja vrednosti po več pogojih, bomo obravnavali primere formul z obema funkcijama - Excelovo SUMIFS in SUMIF z več merili. Za pravilno uporabo morate jasno razumeti, kaj imata ti dve funkciji skupnega in v čem se razlikujeta.
Medtem ko je skupni del jasen (podoben namen in parametri), razlike niso tako očitne, čeprav so zelo pomembne.
Med SUMIF in SUMIFS so štiri glavne razlike:
- Število pogojev . SUMIF lahko hkrati oceni le en pogoj, medtem ko lahko SUMIFS preveri več meril.
- Sintaksa . S SUMIF se sum_range je zadnji in neobvezen argument - če ni določen, se vrednosti v obseg argumenta se seštejejo. S SUMIFS, sum_range je prvi in obvezni argument.
- Velikost območij. V formulah SUMIF, sum_range ni nujno, da ima enako velikost in obliko kot obseg , če je leva zgornja celica desno. V Excelovih SUMIFS je vsaka kriterij_območje mora vsebovati enako število vrstic in stolpcev kot sum_range argument.
Na primer, SUMIF(A2:A9,F1,C2:C18) bo dal pravilen rezultat, ker je skrajna leva celica v sum_range (C2) je pravilen. Excel bo samodejno izvedel popravek in vključil toliko stolpcev in vrstic v sum_range kot so v obseg .
Formula SUMIFS z neenako velikimi območji bo vrnila napako #VALUE!.
- Razpoložljivost SUMIF je na voljo v vseh različicah programa Excel, od 365 do 2000. SUMIFS je na voljo v programu Excel 2007 in novejših.
V redu, dovolj je strategije (tj. teorije), pojdimo k taktiki (tj. primerom formul : )
Kako uporabljati SUMIFS v Excelu - primeri formul
Pred trenutkom smo obravnavali preprosto formulo SUMIFS z dvema besedilnima kriterijema. Na enak način lahko Excelovo formulo SUMIFS uporabite z več kriteriji, izraženimi s številkami, datumi, logičnimi izrazi in drugimi funkcijami programa Excel.
Primer 1. Excelov SUMIFS s primerjalnimi operatorji
V naši preglednici dobaviteljev sadja, recimo, želite sešteti vse dobave po Mikeu s količino 200 ali več. V ta namen uporabite primerjalni operator "večji ali enak" (>=) v merilu2 in dobite naslednjo formulo SUMIFS:
=SUMIFS(C2:C9,B2:B9,"Mike",C2:C9,">=200")
Opomba: Bodite pozorni, da morajo biti v Excelovih formulah SUMIFS logični izrazi s primerjalnimi operatorji vedno zaprti v dvojne narekovaje ("").
Pri obravnavi Excelove funkcije SUMIF smo podrobno obravnavali vse možne primerjalne operatorje, iste operatorje pa lahko uporabimo tudi v merilih SUMIFS. Naslednja formula na primer vrne vsoto vseh vrednosti v celicah C2:C9, ki so večje ali enake 200 in manjše ali enake 300.
=SUMIFS(C2:C9, C2:C9,">=200", C2:C9,"<=300")
Primer 2. Uporaba Excelovega SUMIFS z datumi
Če želite sešteti vrednosti z več merili na podlagi trenutnega datuma, v merilu SUMIFS uporabite funkcijo TODAY(), kot je prikazano spodaj. Naslednja formula sešteje vrednosti v stolpcu D, če ustrezen datum v stolpcu C pade v zadnjih 7 dneh, vključno z današnjim:
=SUMIFS(D2:D10, C2:C10,">="&TODAY()-7, C2:C10,"<="&TODAY())
Opomba: Ko v merilih uporabite drugo funkcijo Excel skupaj z logičnim operatorjem, morate uporabiti ampersand (&) za združevanje niza, na primer "<="&TODAY().
Podobno lahko uporabite Excelovo funkcijo SUMIF za seštevanje vrednosti v danem datumskem območju. Naslednja formula SUMIFS na primer sešteje vrednosti v celicah C2:C9, če datum v stolpcu B pade med 1. oktobrom 2014 in vključno 31. oktobrom 2014.
=SUMIFS(C2:C9, B2:B9, ">=10/1/2014", B2:B9, "<=10/31/2014")
Enak rezultat lahko dosežete z izračunom razlike dveh funkcij SUMIF, kot je prikazano v tem primeru - Kako uporabiti SUMIF za seštevanje vrednosti v danem datumskem območju. Vendar je Excelova funkcija SUMIFS veliko lažja in bolj razumljiva, kajne?
Primer 3. Excelov SUMIFS s praznimi in nepraznimi celicami
Pri analizi poročil in drugih podatkov boste pogosto morali sešteti vrednosti, ki ustrezajo praznim ali nepraznim celicam.
| Merila | Opis | Primer formule | |
|---|---|---|---|
| Prazne celice | "=" | Vrednosti vsote, ki ustrezajo praznim celicam, ki ne vsebujejo ničesar - nobene formule, nobenega niza z ničelno dolžino. | =SUMIFS(C2:C10, A2:A10, "=", B2:B10, "=") |
Vrednosti v celicah C2:C10 seštejete, če so ustrezne celice v stolpcih A in B popolnoma prazne.
Vrednosti v celicah C2:C10 seštejete pod enakimi pogoji kot zgornja formula, vendar vključuje prazne nize.
Vrednosti v celicah C2:C10 seštejte, če ustrezne celice v stolpcih A in B niso prazne, vključno s celicami s praznimi nizi.
ali
SUM / LEN
=SUM((C2:C10) * (LEN(A2:A10)>0)*(LEN(B2:B10)>0))
Vrednosti v celicah C2:C10 seštejete, če ustrezne celice v stolpcih A in B niso prazne, celice z ničelno dolžino niza niso vključene.
Zdaj pa si poglejmo, kako lahko formulo SUMIFS z merili "prazno" in "neprazno" uporabite za prave podatke.
Predpostavimo, da imate datum naročila v stolpcu B, datum dostave v stolpcu C in količino v stolpcu D. Kako ugotoviti vsoto izdelkov, ki še niso bili dostavljeni? To pomeni, da želite izvedeti vsoto vrednosti, ki ustrezajo nepraznim celicam v stolpcu B in praznim celicam v stolpcu C.
Rešitev je uporaba formule SUMIFS z 2 merili:
=SUMIFS(D2:D10, B2:B10,"", C2:C10,"=")
Uporaba Excelovega SUMIF z več merili OR
Kot je navedeno na začetku tega priročnika, je funkcija SUMIFS zasnovana z logiko AND. Kaj pa, če morate sešteti vrednosti z več kriteriji OR, tj. če je izpolnjen vsaj eden od pogojev?
Primer 1. SUMIF + SUMIF
Najpreprostejša rešitev je seštevanje rezultatov, ki jih vrne več funkcij SUMIF. Naslednja formula na primer prikazuje, kako ugotoviti vsoto izdelkov, ki sta jih dostavila Mike in John:
=SUMIF(C2:C9, "Mike",D2:D9) + SUMIF(C2:C9, "John",D2:D9)
Kot vidite, prva funkcija SUMIF sešteje količine, ki ustrezajo "Mikeu", druga funkcija SUMIF vrne količine, ki ustrezajo "Johnu", nato pa seštejete ti dve številki.
Primer 2. SUM & amp; SUMIF z argumentom polja
Zgornja rešitev je zelo preprosta in lahko hitro opravi delo, če je na voljo le nekaj meril. Toda formula SUMIF + SUMIF se lahko zelo poveča, če želite sešteti vrednosti z več pogoji OR. V tem primeru je boljši pristop uporaba merila za polja argument v funkciji SUMIF. Preučimo ta pristop.
Najprej lahko naštejete vse svoje pogoje, ločene z vejicami, nato pa seznam, ločen z vejicami, zaprete v {vijugaste oklepaje}, kar se tehnično imenuje polje.
Če želite v prejšnjem primeru sešteti izdelke, ki so jih dostavili John, Mike in Pete, bo vaše merilo v obliki polja videti kot {"John", "Mike", "Pete"}. Celotna funkcija SUMIF je SUMIF(C2:C9, {"John", "Mike", "Pete"} ,D2:D9) .
Zaradi argumenta polja, sestavljenega iz treh vrednosti, mora formula SUMIF vrniti tri ločene rezultate, ker pa smo formulo zapisali v eno samo celico, bi vrnila samo prvi rezultat, tj. skupno število izdelkov, ki jih je dostavil John. Da bi ta pristop z merili polja deloval, morate uporabiti še en majhen trik - formulo SUMIF vključite v funkcijo SUM, kot je ta:
=SUM(SUMIF(C2:C9, {"John", "Mike", "Pete"} , D2:D9))
Kot vidite, je formula zaradi merila matrike v primerjavi s formulo SUMIF + SUMIF veliko bolj kompaktna in omogoča dodajanje poljubnega števila vrednosti v matriko.
Ta pristop deluje tako pri številkah kot pri besedilnih vrednostih. Če bi na primer namesto imen dobaviteljev v stolpcu C imeli ID dobavitelja, kot so 1, 2, 3 itd., bi bila vaša formula SUMIF videti podobno:
=SUM(SUMIF(C2:C9, {1,2,3} , D2:D9))
V nasprotju z besedilnimi vrednostmi številk v argumentih polja ni treba zapreti v dvojne narekovaje.
Primer 3. SUMPRODUCT &; SUMIF
Če vam je ljubši način seznam meril v nekaterih celicah, namesto da bi jih navedli neposredno v formuli, lahko uporabite SUMIF v povezavi s funkcijo SUMPRODUCT, ki pomnoži sestavine v danih poljih in vrne vsoto teh zmnožkov.
=SUMPRODUKT(SUMIF(C2:C9, G2:G4, D2:D9))
Pri tem so G2:G4 celice, ki vsebujejo vaša merila, v našem primeru imena dobaviteljev, kot je prikazano na spodnji sliki zaslona.
Seveda pa vam nič ne preprečuje, da bi po želji vrednosti v funkciji SUMIF navajali v merilih polja:
=SUMPRODUCT(SUMIF(C2:C9, {"Mike", "John", "Pete"}, D2:D9))
Rezultat, ki ga vrneta obe formuli, bo enak tistemu, ki ga vidite na sliki zaslona:
Excel SUMIFS z več merili OR
Če želite v Excelu pogojno seštevati vrednosti ne le z več pogoji OR, temveč z več sklopi pogojev, boste morali namesto SUMIF uporabiti SUMIFS. Formule bodo zelo podobne tistim, ki smo jih pravkar obravnavali.
Kot običajno lahko to bolje ponazorimo s primerom. V naši tabeli dobaviteljev sadja dodamo datum dobave (stolpec E) in ugotovimo skupno količino, ki so jo Mike, John in Pete dobavili v oktobru.
Primer 1. SUMIFS + SUMIFS
Formula, ki jo dobimo s tem pristopom, vsebuje veliko ponavljanja in je videti okorna, vendar jo je enostavno razumeti in, kar je najpomembneje, deluje : )
=SUMIFS(D2:D9,C2:C9, "Mike", E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014") +
SUMIFS(D2:D9, C2:C9, "John", E2:E9, ">=10/1/2014", E2:E9, "<=10/31/2014") +
SUMIFS(D2:D9, C2:C9, "Pete", E2:E9, ">=10/1/2014" ,E2:E9, "<=10/31/2014")
Kot vidite, za vsakega od dobaviteljev napišete ločeno funkcijo SUMIFS in vključite dva pogoja - enak ali večji od 1. oktobra (">=10/1/2014",) in manjši ali enak 31. oktobru ("<=10/31/2014"), nato pa seštejete rezultate.
Primer 2. SUM & amp; SUMIFS z argumentom polja
Bistvo tega pristopa sem poskušal razložiti v primeru SUMIF, zato lahko zdaj preprosto kopiramo to formulo, spremenimo vrstni red argumentov (kot se spomnite, je ta pri SUMIF in SUMIFS različen) in dodamo dodatna merila. Nastala formula je bolj kompaktna kot SUMIFS + SUMIFS:
=SUM(SUMIFS(D2:D9,C2:C9, {"Mike", "John", "Pete"}, E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014"))
Rezultat, ki ga vrne ta formula, je popolnoma enak kot na zgornji sliki zaslona.
Primer 3. SUMPRODUCT &; SUMIFS
Kot ste se spomnili, se pristop SUMPRODUCT od prejšnjih dveh razlikuje po tem, da vsako merilo vnesete v ločeno celico in ga ne navedete neposredno v formuli. V primeru več nizov meril funkcija SUMPRODUCT ne bo zadostovala in boste morali uporabiti tudi funkciji ISNUMBER in MATCH.
Ob predpostavki, da so imena zalog v celicah H1:H3, datum začetka v celici H4 in datum konca v celici H5, ima naša formula SUMPRODUCT naslednjo obliko:
=SUMPRODUCT(--(E2:E9>=H4), --(E2:E9<=H5), --(ISNUMBER(MATCH(C2:C9, H1:H3,0)))), D2:D9)
Veliko ljudi se sprašuje, zakaj v formulah SUMPRODUCT uporabljati dvojni pomišljaj (--). Gre za to, da Excelova formula SUMPRODUCT ne upošteva vseh vrednosti razen številčnih, medtem ko primerjalni operatorji v naši formuli vračajo logične vrednosti (TRUE / FALSE), ki niso številčne. Za pretvorbo teh logičnih vrednosti v 1 in 0 uporabite dvojni znak minus, ki se strokovno imenuje dvojni unarni operator. Prvi unarni operator prisiljujeTRUE/FALSE na -1/0. Drugi enopomenskik vrednosti zanikuje, tj. obrne znak in jih spremeni v +1 in 0, kar funkcija SUMPRODUCT razume.
Upam, da je zgornja razlaga smiselna, in tudi če ni, si zapomnite to pravilo - pri uporabi primerjalnih operatorjev v formulah SUMPRODUCT uporabljajte dvojni enojni operator (--).
Uporaba Excelove vsote v formulah polja
Kot se spomnite, je Microsoft funkcijo SUMIFS uvedel v Excelu 2007. Če kdo še vedno uporablja Excel 2003, 2000 ali starejše različice, bo moral za seštevanje vrednosti z več merili AND uporabiti formulo polja SUM. Seveda ta pristop deluje tudi v sodobnih različicah Excel 2013 - 2007 in ga lahko štejemo za staromodno ustreznico funkcije SUMIFS.
V zgoraj obravnavanih formulah SUMIF ste že uporabili argumente v obliki polja, vendar je formula v obliki polja nekaj drugega.
Primer 1. Vsota z več merili AND v Excelu 2003 in prejšnjih različicah
Vrnimo se k prvemu primeru, v katerem smo ugotovili vsoto zneskov za določeno sadje in dobavitelja:
Kot že veste, to nalogo zlahka opravite z navadno formulo SUMIFS:
=SUMIFS(C2:C9, A2:A9, "jabolka", B2:B9, "Pete")
Zdaj pa si poglejmo, kako lahko isto nalogo opravimo v zgodnjih različicah programa Excel brez SUMIFS-a. Najprej zapišemo vse pogoje, ki morajo biti izpolnjeni, v obliki range="condition". V tem primeru imamo dva para range/condition:
Pogoj 1: A2:A9="jabolka"
Pogoj 2: B2:B9="Pete"
Nato napišite formulo SUM, ki "pomnoži" vse vaše pare obseg/pogoj, od katerih je vsak zaprt v oklepaju. Zadnji množitelj je obseg vsote, v našem primeru C2:C9:
=SUM((A2:A9="jabolka") * ( B2:B9="Pete") * ( C2:C9))
Kot je prikazano na spodnji sliki zaslona, formula odlično deluje v najnovejši različici programa Excel 2013.
Opomba: Pri vnosu katere koli formule za polje morate pritisniti kombinacijo tipk Ctrl + Shift + Enter . Ko to storite, se formula zapre v {vijugaste oklepaje}, kar je vizualni znak, da je formula za polje pravilno vnesena. Če poskušate oklepaje vnesti ročno, bo vaša formula pretvorjena v besedilni niz in ne bo delovala.
Primer 2. Formule polja SUM v sodobnih različicah programa Excel
Tudi v sodobnih različicah programa Excel ne smemo podcenjevati moči funkcije SUM. Formula SUM ni le telovadba uma, temveč ima praktično vrednost, kot je prikazano v naslednjem primeru.
Recimo, da imate dva stolpca, B in C, in morate prešteti, kolikokrat je stolpec C večji od stolpca B, kadar je vrednost v stolpcu C večja ali enaka 10. Takoj vam pride na misel rešitev z uporabo formule SUM array:
=SUM((C1:C10>=10) * (C1:C10>B1:B10))
Ne vidite praktične uporabe zgornje formule? Razmislite o njej na drug način : )
Recimo, da imate seznam naročil, kot je prikazan na spodnji sliki zaslona, in želite vedeti, koliko izdelkov ni bilo v celoti dobavljenih do določenega datuma. Prevedeno v jezik programa Excel imamo naslednje pogoje:
Pogoj 1: Vrednost v stolpcu B (Urejene postavke) je večja od 0
Pogoj 2: Vrednost v stolpcu C (Dobavljeno) je manjša od vrednosti v stolpcu B
Pogoj 3: Datum v stolpcu D (datum zapadlosti) je krajši od 1. 11. 2014.
Če združite tri pare obseg/pogoj, dobite naslednjo formulo:
=SUM((B2:B10>=0)*(B2:B10>C2:C10)*(D2:D10
Primeri formul, obravnavani v tem priročniku, so le poškropili površino tega, kar funkcije Excel SUMIFS in SUMIF v resnici zmorejo. Upamo, da so vam pomagali pri usmerjanju v pravo smer in zdaj lahko seštejete vrednosti v delovnih zvezkih Excel ne glede na to, koliko zapletenih pogojev je treba upoštevati.
