Obsah
Tento návod vysvetľuje rozdiel medzi funkciami SUMIF a SUMIFS z hľadiska ich syntaxe a použitia a poskytuje niekoľko príkladov vzorcov na sčítanie hodnôt s viacerými kritériami AND/OR v aplikáciách Excel 365, 2021, 2019, 2016, 2013, 2010 a nižších.
Ako každý vie, Microsoft Excel poskytuje celý rad funkcií na vykonávanie rôznych výpočtov s údajmi. Pred niekoľkými článkami sme sa venovali funkciám COUNTIF a COUNTIFS, ktoré sú určené na počítanie buniek na základe jednej podmienky, resp. viacerých podmienok. Minulý týždeň sme sa zaoberali funkciou Excel SUMIF, ktorá sčítava hodnoty spĺňajúce zadané kritériá. Teraz je čas prejsť si verziu množného číslaSUMIF - Excel SUMIFS, ktorý umožňuje sčítanie hodnôt podľa viacerých kritérií.
Tí, ktorí poznajú funkciu SUMIF, by si mohli myslieť, že jej prevod na SUMIFS vyžaduje len ďalšie písmeno "S" a niekoľko ďalších kritérií. Zdá sa to celkom logické... ale "logické" to nie je vždy, keď máte do činenia so spoločnosťou Microsoft : )
Funkcia Excel SUMIF - syntax & použitie
Funkcia SUMIF sa používa na podmienečné sčítanie hodnôt na základe Jednotlivé kritériá Syntaxou SUMIF sme sa podrobne zaoberali v predchádzajúcom článku a tu si ju len v krátkosti pripomenieme.
SUMIF(rozsah, kritériá, [sum_range])- rozsah - rozsah buniek, ktoré sa majú vyhodnotiť podľa vašich kritérií, požadované.
- kritériá - podmienka, ktorá musí byť splnená, požadovaná.
- sum_range - bunky, ktoré sa majú sčítať, ak je splnená podmienka, nepovinné.
Ako vidíte, syntax funkcie Excel SUMIF umožňuje len jednu podmienku. A napriek tomu hovoríme, že funkciu Excel SUMIF možno použiť na sčítanie hodnôt s viacerými kritériami. Ako je to možné? Sčítaním výsledkov viacerých funkcií SUMIF a použitím vzorcov SUMIF s kritériami poľa, ako je to demonštrované v nasledujúcich príkladoch.
Funkcia Excel SUMIFS - syntax & použitie
SUMIFS sa v programe Excel používa na nájsť podmienený súčet hodnôt na základe viacerých kritérií Funkcia SUMIFS bola zavedená v programe Excel 2007 a je k dispozícii vo všetkých nasledujúcich verziách programov Excel 2010, 2013, 2016, 2019, 2021 a Excel 365.
V porovnaní so SUMIF je syntax SUMIFS trochu zložitejšia:
SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)Prvé 3 argumenty sú povinné, ďalšie rozsahy a súvisiace kritériá sú nepovinné.
sum_range- jedna alebo viac buniek, ktoré sa majú sčítať, povinné. Môže to byť jedna bunka, rozsah buniek alebo pomenovaný rozsah. Sčítajú sa len bunky s číslami; prázdne a textové hodnoty sa ignorujú.kritérium_rozsah1- prvý rozsah, ktorý sa má vyhodnotiť podľa príslušných kritérií, požadované.kritériá1- prvá podmienka, ktorá musí byť splnená, povinná. Kritérium môžete zadať vo forme čísla, logického výrazu, odkazu na bunku, textu alebo inej funkcie programu Excel. Môžete napríklad použiť kritériá ako 10, ">=10", A1, "čerešne" alebo TODAY().criteria_range2, criteria2, ...- sú to ďalšie rozsahy a k nim priradené kritériá, nepovinné. Vo vzorcoch SUMIFS môžete použiť až 127 dvojíc rozsahov/kritérií.
Poznámky:
- Aby vzorec SUMIFS fungoval správne, všetky criteria_range argumenty musia mať rovnaký rozmer ako sum_range , t. j. rovnaký počet riadkov a stĺpcov.
- Funkcia SUMIFS pracuje s logikou AND, čo znamená, že bunka v rozsahu súčtu sa sčíta len vtedy, ak spĺňa všetky zadané kritériá, t. j. všetky kritériá sú pre danú bunku pravdivé.
Základný vzorec SUMIFS
A teraz sa pozrime na vzorec Excel SUMIFS s dvoma podmienkami. Predpokladajme, že máte tabuľku so zoznamom dodávok ovocia od rôznych dodávateľov. V stĺpci A máte názvy ovocia, v stĺpci B názvy dodávateľov a v stĺpci C množstvo. Chcete zistiť súčet množstiev týkajúcich sa daného ovocia a dodávateľa, napr. všetkých jabĺk dodaných Petom.
Keď sa učíte niečo nové, vždy je dobré začať s jednoduchými vecami. Takže na začiatok definujme všetky argumenty pre náš vzorec SUMIFS:
- sum_range - C2:C9
- kritérium_rozsah1 - A2:A9
- kritérium1 - "jablká"
- kritérium_rozsah2 - B2:B9
- kritériá2 - "Pete"
Teraz zostavte vyššie uvedené parametre a dostanete nasledujúci vzorec SUMIFS:
=SUMIFS(C2:C9, A2:A9, "jablká", B2:B9, "Pete")
Ak chcete vzorec ďalej spresniť, môžete nahradiť textové kritériá "jablká" a "Pete" odkazmi na bunky. V tomto prípade nebudete musieť vzorec meniť, aby ste vypočítali množstvo iného ovocia od iného dodávateľa:
=SUMIFS(C2:C9, A2:A9, F1, B2:B9, F2)
Poznámka: Funkcie SUMIF aj SUMIFS vo svojej podstate nerozlišujú veľké a malé písmená. Ak chcete, aby rozpoznávali veľké a malé písmená textu, pozrite si časť Rozlišovanie veľkých a malých písmen vzorca SUMIF a SUMIFS v programe Excel.
SUMIF vs. SUMIFS v programe Excel
Keďže cieľom tohto návodu je pokryť všetky možné spôsoby sčítania hodnôt podľa viacerých podmienok, budeme rozoberať príklady vzorcov s oboma funkciami - Excel SUMIFS a SUMIF s viacerými kritériami. Aby ste ich mohli správne používať, musíte jasne pochopiť, čo majú tieto dve funkcie spoločné a v čom sa líšia.
Zatiaľ čo spoločná časť je jasná (podobný účel a parametre), rozdiely nie sú také zrejmé, hoci sú veľmi podstatné.
Medzi SUMIF a SUMIFS sú 4 hlavné rozdiely:
- Počet podmienok . SUMIF môže vyhodnotiť len jednu podmienku naraz, zatiaľ čo SUMIFS môže kontrolovať viacero kritérií.
- Syntax Pomocou funkcie SUMIF sa sum_range je posledný a nepovinný argument - ak nie je definovaný, hodnoty v rozsah argument sú sčítané. Pomocou SUMIFS, sum_range je prvý a povinný argument.
- Veľkosť rozsahov. Vo vzorcoch SUMIF, sum_range nemusí mať nevyhnutne rovnakú veľkosť a tvar ako rozsah , pokiaľ máte ľavú hornú bunku vpravo. V programe Excel SUMIFS je každá criteria_range musí obsahovať rovnaký počet riadkov a stĺpcov ako sum_range argument.
Napríklad SUMIF(A2:A9,F1,C2:C18) vráti správny výsledok, pretože najľavejšia bunka sum_range argument (C2) je správny. Takže Excel vykoná opravu automaticky a zahrnie toľko stĺpcov a riadkov v sum_range ako sú v rozsah .
Vzorec SUMIFS s nerovnako veľkými rozsahmi vráti chybu #VALUE!.
- Dostupnosť . súčet SUMIF je k dispozícii vo všetkých verziách programu Excel od 365 po 2000. súčet SUMIFS je k dispozícii v programe Excel 2007 a vyšších.
Dobre, dosť bolo stratégie (t. j. teórie), poďme na taktiku (t. j. príklady vzorcov : )
Ako používať SUMIFS v programe Excel - príklady vzorcov
Pred chvíľou sme sa venovali jednoduchému vzorcu SUMIFS s dvoma textovými kritériami. Rovnakým spôsobom môžete použiť vzorec Excel SUMIFS s viacerými kritériami vyjadrenými číslami, dátumami, logickými výrazmi a inými funkciami programu Excel.
Príklad 1. Excel SUMIFS s operátormi porovnávania
Predpokladajme, že v našej tabuľke dodávateľov ovocia chcete zrátať všetky dodávky podľa Mikea s množstvom 200 alebo viac. Na tento účel použijete v kritériu2 operátor porovnania "väčšie alebo rovné" (>=) a získate nasledujúci vzorec SUMIFS:
=SUMIFS(C2:C9,B2:B9,"Mike",C2:C9,">=200")
Poznámka: Dbajte na to, že vo vzorcoch Excel SUMIFS by logické výrazy s operátormi porovnávania mali byť vždy uzavreté v dvojitých úvodzovkách ("").
Všetky možné operátory porovnávania sme podrobne rozobrali pri funkcii SUMIF programu Excel, rovnaké operátory možno použiť aj v kritériu SUMIFS. Napríklad nasledujúci vzorec vráti súčet všetkých hodnôt v bunkách C2:C9, ktoré sú väčšie alebo rovné 200 a menšie alebo rovné 300.
=SUMIFS(C2:C9, C2:C9,">=200", C2:C9,"<=300")
Príklad 2. Použitie programu Excel SUMIFS s dátumami
V prípade, že chcete sčítať hodnoty s viacerými kritériami na základe aktuálneho dátumu, použite v kritériu SUMIFS funkciu TODAY(), ako je uvedené nižšie. Nasledujúci vzorec sčíta hodnoty v stĺpci D, ak príslušný dátum v stĺpci C spadá do posledných 7 dní vrátane dnešného dňa:
=SUMIFS(D2:D10, C2:C10,">="&TODAY()-7, C2:C10,"<="&TODAY())
Poznámka: Ak v kritériách použijete inú funkciu programu Excel spolu s logickým operátorom, musíte použiť ampersand (&) na spojenie reťazca, napríklad "<="&TODAY().
Podobným spôsobom môžete použiť funkciu SUMIF aplikácie Excel na sčítanie hodnôt v danom rozsahu dátumov. Napríklad nasledujúci vzorec SUMIFS sčíta hodnoty v bunkách C2:C9, ak dátum v stĺpci B spadá do obdobia od 1. októbra 2014 do 31. októbra 2014 vrátane.
=SUMIFS(C2:C9, B2:B9, ">=10/1/2014", B2:B9, "<=10/31/2014")
Rovnaký výsledok sa dá dosiahnuť výpočtom rozdielu dvoch funkcií SUMIF, ako je ukázané v tomto príklade - Ako použiť SUMIF na sčítanie hodnôt v danom rozsahu dátumov. Excel SUMIFS je však oveľa jednoduchší a zrozumiteľnejší, však?
Príklad 3. Excel SUMIFS s prázdnymi a neprázdnymi bunkami
Pri analýze zostáv a iných údajov môžete často potrebovať sčítať hodnoty zodpovedajúce prázdnym alebo neprázdnym bunkám.
| Kritériá | Popis | Príklad vzorca | |
|---|---|---|---|
| Prázdne bunky | "=" | Súčet hodnôt zodpovedajúcich prázdnym bunkám, ktoré neobsahujú absolútne nič - žiadny vzorec, žiadny reťazec nulovej dĺžky. | =SUMIFS(C2:C10, A2:A10, "=", B2:B10, "=") |
Súčet hodnôt v bunkách C2:C10, ak sú príslušné bunky v stĺpcoch A a B úplne prázdne.
Súčet hodnôt v bunkách C2:C10 s rovnakými podmienkami ako vo vyššie uvedenom vzorci, ale zahŕňa prázdne reťazce.
Súčet hodnôt v bunkách C2:C10, ak príslušné bunky v stĺpcoch A a B nie sú prázdne, vrátane buniek s prázdnymi reťazcami.
alebo
SUM / LEN
=SUM((C2:C10) * (LEN(A2:A10)>0)*(LEN(B2:B10)>0))
Súčet hodnôt v bunkách C2:C10, ak zodpovedajúce bunky v stĺpcoch A a B nie sú prázdne, bunky s nulovou dĺžkou reťazcov sa nezapočítavajú.
A teraz sa pozrime, ako môžete použiť vzorec SUMIFS s kritériami "prázdne" a "neprázdne" na reálnych údajoch.
Predpokladajme, že v stĺpci B máte dátum objednávky, v stĺpci C dátum dodania a v stĺpci D množstvo. Ako zistíte súčet výrobkov, ktoré ešte neboli dodané? To znamená, že chcete zistiť súčet hodnôt zodpovedajúcich neprázdnym bunkám v stĺpci B a prázdnym bunkám v stĺpci C.
Riešením je použitie vzorca SUMIFS s 2 kritériami:
=SUMIFS(D2:D10, B2:B10,"", C2:C10,"=")
Používanie funkcie SUMIF programu Excel s viacerými kritériami OR
Ako bolo uvedené na začiatku tohto návodu, funkcia SUMIFS je navrhnutá s logikou AND. Čo však v prípade, ak potrebujete sčítať hodnoty s viacerými kritériami OR, t. j. keď je splnená aspoň jedna z podmienok?
Príklad 1. SUMIF + SUMIF
Najjednoduchším riešením je sčítanie výsledkov vrátených niekoľkými funkciami SUMIF. Napríklad nasledujúci vzorec ukazuje, ako zistiť súčet výrobkov dodaných Mikom a Johnom:
=SUMIF(C2:C9, "Mike",D2:D9) + SUMIF(C2:C9, "John",D2:D9)
Ako vidíte, prvá funkcia SUMIF sčíta množstvá zodpovedajúce "Mikeovi", druhá funkcia SUMIF vráti množstvá týkajúce sa "Johna" a potom tieto dve čísla sčítate.
Príklad 2. SUM & SUMIF s argumentom poľa
Vyššie uvedené riešenie je veľmi jednoduché a môže byť rýchlo hotové, ak existuje len niekoľko kritérií. Ale vzorec SUMIF + SUMIF môže veľmi narásť, ak chcete sčítať hodnoty s viacerými podmienkami OR. V tomto prípade je lepším prístupom použitie kritériá poľa Argument vo funkcii SUMIF. Preskúmame teraz tento prístup.
Môžete začať tým, že vypíšete všetky podmienky oddelené čiarkami a výsledný zoznam oddelený čiarkami uzavriete do {vlnitých zátvoriek}, čo sa odborne nazýva pole.
Ak chcete v predchádzajúcom príklade zhrnúť produkty dodané Johnom, Mikom a Petom, vaše kritériá poľa budú vyzerať takto {"John", "Mike", "Pete"}. A kompletná funkcia SUMIF je SUMIF(C2:C9, {"John", "Mike", "Pete"} ,D2:D9) .
Argument poľa pozostávajúci z 3 hodnôt núti váš vzorec SUMIF vrátiť tri samostatné výsledky, ale keďže sme vzorec zapísali do jednej bunky, vrátil by len prvý výsledok - t. j. súčet výrobkov dodaných Jánom. Aby tento prístup založený na kritériách poľa fungoval, musíte použiť ešte jeden malý trik - uzavrieť vzorec SUMIF do funkcie SUM, napríklad takto:
=SUM(SUMIF(C2:C9, {"John", "Mike", "Pete"} , D2:D9))
Ako vidíte, vďaka kritériám poľa je vzorec v porovnaní so SUMIF + SUMIF oveľa kompaktnejší a umožňuje pridať do poľa ľubovoľný počet hodnôt.
Tento prístup funguje s číslami aj s textovými hodnotami. Napríklad, ak by ste namiesto názvov dodávateľov v stĺpci C mali ID dodávateľov ako 1, 2, 3 atď., potom by váš vzorec SUMIF vyzeral podobne:
=SUM(SUMIF(C2:C9, {1,2,3} , D2:D9))
Na rozdiel od textových hodnôt nemusia byť čísla v argumentoch poľa uzavreté v dvojitých úvodzovkách.
Príklad 3. SUMPRODUCT & SUMIF
V prípade, že uprednostňujete zoznam kritérií v niektorých bunkách namiesto ich priameho zadania vo vzorci, môžete použiť funkciu SUMIF v spojení s funkciou SUMPRODUCT, ktorá vynásobí zložky v daných poliach a vráti súčet týchto súčinov.
=SUMPRODUCT(SUMIF(C2:C9, G2:G4, D2:D9))
Kde G2:G4 sú bunky obsahujúce vaše kritériá, v našom prípade názvy dodávateľov, ako je znázornené na obrázku nižšie.
Ale samozrejme, nič vám nebráni v tom, aby ste v prípade potreby vypisovali hodnoty v kritériách poľa funkcie SUMIF:
=SUMPRODUCT(SUMIF(C2:C9, {"Mike", "John", "Pete"}, D2:D9))
Výsledok vrátený oboma vzorcami bude totožný s tým, ktorý vidíte na obrázku:
Excel SUMIFS s viacerými kritériami OR
Ak chcete v programe Excel podmienečne sčítavať hodnoty nie jednoducho pomocou viacerých podmienok OR, ale pomocou viacerých súborov podmienok, budete musieť namiesto SUMIF použiť SUMIFS. Vzorce budú veľmi podobné tomu, čo sme práve prebrali.
Ako zvyčajne, na lepšiu ilustráciu môže pomôcť príklad. V našej tabuľke dodávateľov ovocia pridajme dátum dodania (stĺpec E) a zistime celkové množstvo dodané Mikom, Johnom a Petom v októbri.
Príklad 1. SUMIFS + SUMIFS
Vzorec vytvorený týmto prístupom obsahuje veľa opakovaní a vyzerá ťažkopádne, ale je ľahko pochopiteľný a hlavne funguje : )
=SUMIFS(D2:D9,C2:C9, "Mike", E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014") +
SUMIFS(D2:D9, C2:C9, "John", E2:E9, ">=10/1/2014", E2:E9, "<=10/31/2014") +
SUMIFS(D2:D9, C2:C9, "Pete", E2:E9, ">=10/1/2014" ,E2:E9, "<=10/31/2014")
Ako vidíte, pre každého dodávateľa napíšete samostatnú funkciu SUMIFS a uvediete dve podmienky - rovná sa alebo je väčšia ako 1. október (">=10/1/2014",) a menšia alebo sa rovná 31. októbru ("<=10/31/2014"), a potom výsledky spočítate.
Príklad 2. SUM & SUMIFS s argumentom poľa
Podstatu tohto prístupu som sa snažil vysvetliť v príklade SUMIF, takže teraz môžeme tento vzorec jednoducho skopírovať, zmeniť poradie argumentov (ako si pamätáte, v SUMIF a SUMIFS je odlišné) a pridať ďalšie kritériá. Výsledný vzorec je kompaktnejší ako SUMIFS + SUMIFS:
=SUM(SUMIFS(D2:D9,C2:C9, {"Mike", "John", "Pete"}, E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014"))
Výsledok vrátený týmto vzorcom je presne taký istý, ako vidíte na obrázku vyššie.
Príklad 3. SUMPRODUCT &; SUMIFS
Ako si pamätáte, prístup SUMPRODUCT sa od predchádzajúcich dvoch líši tým, že každé z kritérií zadávate do samostatnej bunky, a nie priamo do vzorca. V prípade viacerých súborov kritérií vám funkcia SUMPRODUCT nebude stačiť a budete musieť použiť aj funkcie ISNUMBER a MATCH.
Takže za predpokladu, že názvy dodávok sú v bunkách H1:H3, dátum začiatku je v bunke H4 a dátum konca v bunke H5, náš vzorec SUMPRODUCT má nasledujúci tvar:
=SUMPRODUCT(--(E2:E9>=H4), --(E2:E9<=H5), --(ISNUMBER(MATCH(C2:C9, H1:H3,0))), D2:D9)
Mnohí ľudia sa čudujú, prečo vo vzorcoch SUMPRODUCT používať dvojitú pomlčku (--). Ide o to, že Excel SUMPRODUCT ignoruje všetky hodnoty okrem číselných, zatiaľ čo operátory porovnávania v našom vzorci vracajú logické hodnoty (TRUE / FALSE), ktoré nie sú číselné. Na prevod týchto logických hodnôt na 1 a 0 sa používa dvojitý znak mínus, ktorý sa odborne nazýva dvojitý unárny operátor. Prvý unárny operátor núkaTRUE/FALSE na -1/0. Druhý unárny znak neguje hodnoty, t. j. obracia znamienko a mení ich na +1 a 0, čomu funkcia SUMPRODUCT rozumie.
Dúfam, že vyššie uvedené vysvetlenie dáva zmysel. A aj keby nie, zapamätajte si toto pravidlo - pri používaní operátorov porovnávania vo vzorcoch SUMPRODUCT používajte dvojitý unárny operátor (--).
Používanie súčtu Excelu vo vzorcoch polí
Ako si pamätáte, spoločnosť Microsoft implementovala funkciu SUMIFS v programe Excel 2007. Ak niekto stále používa program Excel 2003, 2000 alebo staršie verzie, na sčítanie hodnôt s viacerými kritériami AND bude musieť použiť vzorec SUM v poli. Tento postup samozrejme funguje aj v moderných verziách programu Excel 2013 - 2007 a možno ho považovať za staromódnu obdobu funkcie SUMIFS.
Vo vyššie uvedených vzorcoch SUMIF ste už použili argumenty poľa, ale vzorec poľa je niečo iné.
Príklad 1. Súčet s viacerými kritériami AND v programe Excel 2003 a starších
Vráťme sa k prvému príkladu, v ktorom sme zistili súčet súm týkajúcich sa daného ovocia a dodávateľa:
Ako už viete, táto úloha sa dá ľahko vykonať pomocou obyčajného vzorca SUMIFS:
=SUMIFS(C2:C9, A2:A9, "jablká", B2:B9, "Pete")
A teraz sa pozrime, ako sa dá rovnaká úloha splniť v prvých verziách Excelu "bez SUMIFS". Najprv si zapíšete všetky podmienky, ktoré majú byť splnené, v tvare range="condition". V tomto príklade máme dve dvojice range/condition:
Podmienka 1: A2:A9="jablká"
Podmienka 2: B2:B9="Pete"
Potom napíšete vzorce SUM, ktoré "vynásobia" všetky vaše dvojice rozsah/podmienka, pričom každá z nich je uzavretá v zátvorkách. Posledným násobiteľom je rozsah súčtu, v našom prípade C2:C9:
=SUM((A2:A9="jablká") * ( B2:B9="Pete") * ( C2:C9))
Ako je znázornené na nasledujúcej snímke obrazovky, vzorec dokonale funguje v najnovšej verzii aplikácie Excel 2013.
Poznámka: Pri zadávaní akéhokoľvek vzorca poľa musíte stlačiť klávesovú skratku Ctrl + Shift + Enter . Keď to urobíte, vzorec sa uzavrie do {vlnitých zátvoriek}, čo je vizuálna indikácia, že vzorec poľa je zadaný správne. Ak sa pokúsite zadať zátvorky ručne, vzorec sa prevedie na textový reťazec a nebude fungovať.
Príklad 2. Vzorce poľa SUM v moderných verziách programu Excel
Ani v moderných verziách programu Excel by sa nemala podceňovať sila funkcie SUM. Vzorec SUM nie je len gymnastikou mysle, ale má praktickú hodnotu, ako ukazuje nasledujúci príklad.
Predpokladajme, že máte dva stĺpce, B a C, a potrebujete spočítať, koľkokrát je stĺpec C väčší ako stĺpec B, keď je hodnota v stĺpci C väčšia alebo rovná 10. Okamžité riešenie, ktoré vás napadne, je použitie vzorca SUM v poli:
=SUM((C1:C10>=10) * (C1:C10>B1:B10))
Nevidíte praktické využitie uvedeného vzorca? Zamyslite sa nad ním iným spôsobom : )
Predpokladajme, že máte zoznam objednávok, ako je znázornené na snímke obrazovky nižšie, a chcete zistiť, koľko výrobkov nebolo dodaných v plnom rozsahu k danému dátumu. Preložené do jazyka Excelu máme tieto podmienky:
Podmienka 1: Hodnota v stĺpci B (Usporiadané položky) je väčšia ako 0
Podmienka 2: Hodnota v stĺpci C (Dodané) je nižšia ako v stĺpci B
Podmienka 3: Dátum v stĺpci D (Dátum splatnosti) je nižší ako 1.11.2014.
Spojením týchto troch dvojíc rozsah/podmienka získate nasledujúci vzorec:
=SUM((B2:B10>=0)*(B2:B10>C2:C10)*(D2:D10
Príklady vzorcov uvedené v tomto návode len poodhalili povrch toho, čo funkcie SUMIFS a SUMIF v programe Excel skutočne dokážu. Dúfame však, že vám pomohli nasmerovať vás správnym smerom a teraz môžete sčítavať hodnoty vo svojich zošitoch programu Excel bez ohľadu na to, koľko zložitých podmienok musíte zohľadniť.
