Αυτό το σεμινάριο εξηγεί τη διαφορά μεταξύ των συναρτήσεων SUMIF και SUMIFS όσον αφορά τη σύνταξη και τη χρήση τους και παρέχει μια σειρά παραδειγμάτων τύπων για την άθροιση τιμών με πολλαπλά κριτήρια AND / OR στο Excel 365, 2021, 2019, 2016, 2013, 2010 και χαμηλότερα.

Όπως όλοι γνωρίζουν, το Microsoft Excel παρέχει μια σειρά από συναρτήσεις για την εκτέλεση διαφόρων υπολογισμών με δεδομένα. Πριν από μερικά άρθρα, εξερευνήσαμε τις COUNTIF και COUNTIFS, οι οποίες έχουν σχεδιαστεί για την καταμέτρηση κελιών με βάση μια μόνο συνθήκη και πολλές συνθήκες, αντίστοιχα. Την περασμένη εβδομάδα καλύψαμε την Excel SUMIF που προσθέτει τιμές που πληρούν τα καθορισμένα κριτήρια. Τώρα ήρθε η ώρα να εξετάσουμε την πληθυντική έκδοση τηςSUMIF - Excel SUMIFS που επιτρέπει την άθροιση τιμών με πολλαπλά κριτήρια.

Όσοι είναι εξοικειωμένοι με τη συνάρτηση SUMIF μπορεί να σκεφτούν ότι η μετατροπή της σε SUMIFS απαιτεί απλώς ένα επιπλέον "S" και μερικά επιπλέον κριτήρια. Αυτό θα φαινόταν αρκετά λογικό... αλλά "λογικό" δεν είναι πάντα όταν έχουμε να κάνουμε με τη Microsoft : )

Συνάρτηση Excel SUMIF - σύνταξη & χρήση

Η συνάρτηση SUMIF χρησιμοποιείται για να αθροίζει υπό όρους τιμές με βάση μια ενιαία κριτήρια Συζητήσαμε λεπτομερώς τη σύνταξη SUMIF στο προηγούμενο άρθρο, και εδώ είναι μια σύντομη υπενθύμιση.

• εύρος - το εύρος των κελιών που θα αξιολογηθούν με βάση τα κριτήριά σας, απαιτείται.
• κριτήρια - η προϋπόθεση που πρέπει να πληρούται, απαιτείται.
• sum_range - τα κελιά που θα αθροιστούν εάν πληρούται η συνθήκη, προαιρετικά.

Όπως βλέπετε, η σύνταξη της συνάρτησης Excel SUMIF επιτρέπει μόνο μία συνθήκη. Και παρόλα αυτά, λέμε ότι η Excel SUMIF μπορεί να χρησιμοποιηθεί για την άθροιση τιμών με πολλαπλά κριτήρια. Πώς μπορεί να γίνει αυτό; Με την πρόσθεση των αποτελεσμάτων πολλών συναρτήσεων SUMIF και με τη χρήση τύπων SUMIF με κριτήρια συστοιχίας, όπως φαίνεται στα παραδείγματα που ακολουθούν.

Συνάρτηση SUMIFS του Excel - σύνταξη και χρήση

Χρησιμοποιείτε το SUMIFS στο Excel για να εύρεση ενός υπό όρους αθροίσματος τιμών με βάση πολλαπλά κριτήρια Η συνάρτηση SUMIFS εισήχθη στο Excel 2007 και είναι διαθέσιμη σε όλες τις επόμενες εκδόσεις του Excel 2010, 2013, 2016, 2019, 2021 και Excel 365.

Σε σύγκριση με το SUMIF, η σύνταξη του SUMIFS είναι λίγο πιο σύνθετη:

Τα 3 πρώτα ορίσματα είναι υποχρεωτικά, οι πρόσθετες περιοχές και τα σχετικά κριτήρια είναι προαιρετικά.

• sum_range - ένα ή περισσότερα κελιά προς άθροιση, υποχρεωτικά. Αυτό μπορεί να είναι ένα μεμονωμένο κελί, μια περιοχή κελιών ή μια ονομαστική περιοχή. Μόνο τα κελιά με αριθμούς αθροίζονται- οι κενές τιμές και οι τιμές κειμένου αγνοούνται.
• criteria_range1 - το πρώτο εύρος που πρέπει να αξιολογηθεί με τα σχετικά κριτήρια, απαιτείται.
• κριτήρια1 - η πρώτη συνθήκη που πρέπει να ικανοποιείται, απαιτείται. Μπορείτε να παρέχετε τα κριτήρια με τη μορφή αριθμού, λογικής έκφρασης, αναφοράς κελιού, κειμένου ή άλλης συνάρτησης του Excel. Για παράδειγμα, μπορείτε να χρησιμοποιήσετε κριτήρια όπως 10, ">=10", A1, "cherries" ή TODAY().
• criteria_range2, criteria2, ... - πρόκειται για πρόσθετες περιοχές και κριτήρια που σχετίζονται με αυτές, προαιρετικά. Μπορείτε να χρησιμοποιήσετε έως και 127 ζεύγη περιοχών/κριτηρίων στους τύπους SUMIFS.

Σημειώσεις:

• Για να λειτουργήσει σωστά ένας τύπος SUMIFS, όλες οι criteria_range τα ορίσματα πρέπει να έχουν την ίδια διάσταση με sum_range , δηλαδή τον ίδιο αριθμό γραμμών και στηλών.
• Η συνάρτηση SUMIFS λειτουργεί με τη λογική AND, πράγμα που σημαίνει ότι ένα κελί στην περιοχή αθροίσματος αθροίζεται μόνο εάν πληροί όλα τα καθορισμένα κριτήρια, δηλαδή όλα τα κριτήρια είναι αληθή για το συγκεκριμένο κελί.

Βασικός τύπος SUMIFS

Και τώρα, ας ρίξουμε μια ματιά στον τύπο SUMIFS του Excel με δύο συνθήκες. Ας υποθέσουμε ότι έχετε έναν πίνακα με τις αποστολές φρούτων από διάφορους προμηθευτές. Έχετε τα ονόματα των φρούτων στη στήλη Α, τα ονόματα των προμηθευτών στη στήλη Β και την ποσότητα στη στήλη Γ. Αυτό που θέλετε είναι να βρείτε ένα άθροισμα των ποσών που αφορούν ένα συγκεκριμένο φρούτο και έναν συγκεκριμένο προμηθευτή, π.χ. όλα τα μήλα που προμηθεύτηκε ο Pete.

Όταν μαθαίνετε κάτι καινούργιο, είναι πάντα καλή ιδέα να ξεκινάτε με απλά πράγματα. Έτσι, για αρχή, ας ορίσουμε όλα τα επιχειρήματα για τον τύπο SUMIFS:

• sum_range - C2:C9
• criteria_range1 - A2:A9
• criteria1 - "μήλα"
• criteria_range2 - B2:B9
• criteria2 - "Pete"

Συγκεντρώστε τώρα τις παραπάνω παραμέτρους και θα λάβετε τον ακόλουθο τύπο SUMIFS:

=SUMIFS(C2:C9, A2:A9, "apples", B2:B9, "Pete")

Για να βελτιώσετε περαιτέρω τον τύπο, μπορείτε να αντικαταστήσετε τα κριτήρια κειμένου "μήλα" και "Pete" με αναφορές κελιών. Σε αυτή την περίπτωση, δεν θα χρειαστεί να αλλάξετε τον τύπο για να υπολογίσετε την ποσότητα άλλων φρούτων από διαφορετικό προμηθευτή:

=SUMIFS(C2:C9, A2:A9, F1, B2:B9, F2)

Σημείωση. Οι συναρτήσεις SUMIF και SUMIFS είναι από τη φύση τους μη ευαίσθητες στην πεζότητα. Για να τις κάνετε να αναγνωρίζουν την πεζότητα του κειμένου, ανατρέξτε στην ενότητα Τύπος SUMIF και SUMIFS με ευαισθησία στην πεζότητα στο Excel.

SUMIF vs. SUMIFS στο Excel

Δεδομένου ότι ο στόχος αυτού του σεμιναρίου είναι να καλύψει όλους τους πιθανούς τρόπους άθροισης τιμών με βάση πολλές συνθήκες, θα συζητήσουμε παραδείγματα τύπων και με τις δύο συναρτήσεις - Excel SUMIFS και SUMIF με πολλαπλά κριτήρια. Για να τις χρησιμοποιήσετε σωστά, πρέπει να κατανοήσετε με σαφήνεια τι κοινό έχουν αυτές οι δύο συναρτήσεις και σε τι διαφέρουν.

Ενώ το κοινό μέρος είναι σαφές (παρόμοιος σκοπός και παράμετροι), οι διαφορές δεν είναι τόσο προφανείς, αν και πολύ ουσιαστικές.

Υπάρχουν 4 βασικές διαφορές μεταξύ των SUMIF και SUMIFS:

1. Αριθμός συνθηκών Το SUMIF μπορεί να αξιολογήσει μόνο μία συνθήκη κάθε φορά, ενώ το SUMIFS μπορεί να ελέγξει πολλαπλά κριτήρια.
2. Σύνταξη Με την SUMIF, η sum_range είναι το τελευταίο και προαιρετικό όρισμα - αν δεν οριστεί, οι τιμές στο πεδίο εύρος αθροίζονται. Με το SUMIFS, sum_range είναι το πρώτο και απαιτούμενο όρισμα.
3. Μέγεθος των σειρών. Σε τύπους SUMIF, sum_range δεν είναι απαραίτητο να έχει το ίδιο μέγεθος και σχήμα με το εύρος , αρκεί να έχετε το πάνω αριστερό κελί δεξιά. Στο Excel SUMIFS, κάθε criteria_range πρέπει να περιέχει τον ίδιο αριθμό γραμμών και στηλών με το αρχείο sum_range επιχείρημα.

   Για παράδειγμα, το SUMIF(A2:A9,F1,C2:C18) θα επιστρέψει το σωστό αποτέλεσμα επειδή το αριστερότερο κελί στο sum_range Το επιχείρημα (C2) είναι σωστό. Έτσι, το Excel θα κάνει τη διόρθωση αυτόματα και θα συμπεριλάβει τόσες στήλες και γραμμές στο sum_range όπως υπάρχουν σε εύρος .

   Ένας τύπος SUMIFS με άνισου μεγέθους περιοχές θα επιστρέψει σφάλμα #VALUE!.

   Δείτε επίσης: Πώς να καταγράψετε μια μακροεντολή στο Excel
4. Διαθεσιμότητα Το SUMIF είναι διαθέσιμο σε όλες τις εκδόσεις του Excel, από το 365 έως το 2000. Το SUMIFS είναι διαθέσιμο στο Excel 2007 και νεότερες εκδόσεις.

Εντάξει, αρκετά με τη στρατηγική (δηλ. τη θεωρία), ας περάσουμε στην τακτική (δηλ. παραδείγματα τύπων : )

Πώς να χρησιμοποιήσετε το SUMIFS στο Excel - παραδείγματα τύπων

Πριν από λίγο, συζητήσαμε έναν απλό τύπο SUMIFS με δύο κριτήρια κειμένου. Με τον ίδιο τρόπο, μπορείτε να χρησιμοποιήσετε το Excel SUMIFS με πολλαπλά κριτήρια που εκφράζονται από αριθμούς, ημερομηνίες, λογικές εκφράσεις και άλλες συναρτήσεις του Excel.

Παράδειγμα 1. Excel SUMIFS με τελεστές σύγκρισης

Στον πίνακα προμηθευτών φρούτων, ας υποθέσουμε ότι θέλετε να αθροίσετε όλες τις παραδόσεις ανά Mike με Qty. 200 ή περισσότερο. Για να το κάνετε αυτό, χρησιμοποιείτε τον τελεστή σύγκρισης "μεγαλύτερο από ή ίσο με" (>=) στο criteria2 και λαμβάνετε τον ακόλουθο τύπο SUMIFS:

=SUMIFS(C2:C9,B2:B9,"Mike",C2:C9,">=200")

Σημείωση. Προσέξτε ότι στους τύπους SUMIFS του Excel, οι λογικές εκφράσεις με τελεστές σύγκρισης πρέπει πάντα να περικλείονται σε διπλά εισαγωγικά ("").

Καλύψαμε λεπτομερώς όλους τους πιθανούς τελεστές σύγκρισης όταν συζητήσαμε τη συνάρτηση SUMIF του Excel, οι ίδιοι τελεστές μπορούν να χρησιμοποιηθούν στα κριτήρια SUMIFS. Για παράδειγμα, ο ακόλουθος τύπος επιστρέφει το άθροισμα όλων των τιμών στα κελιά C2:C9 που είναι μεγαλύτερες ή ίσες με 200 και μικρότερες ή ίσες με 300.

=SUMIFS(C2:C9, C2:C9,">=200", C2:C9,"<=300")

Παράδειγμα 2. Χρήση του Excel SUMIFS με ημερομηνίες

Σε περίπτωση που θέλετε να αθροίσετε τιμές με πολλαπλά κριτήρια βάσει της τρέχουσας ημερομηνίας, χρησιμοποιήστε τη συνάρτηση TODAY() στα κριτήρια SUMIFS, όπως φαίνεται παρακάτω. Ο ακόλουθος τύπος αθροίζει τις τιμές στη στήλη D εάν μια αντίστοιχη ημερομηνία στη στήλη C εμπίπτει στις τελευταίες 7 ημέρες, συμπεριλαμβανομένης της σημερινής:

=SUMIFS(D2:D10, C2:C10,">="&TODAY()-7, C2:C10,"<="&TODAY())

Σημείωση. Όταν χρησιμοποιείτε μια άλλη συνάρτηση του Excel μαζί με έναν λογικό τελεστή στα κριτήρια, πρέπει να χρησιμοποιήσετε την τελεία (&) για να συνδέσετε μια συμβολοσειρά, για παράδειγμα "<="&TODAY().

Με παρόμοιο τρόπο, μπορείτε να χρησιμοποιήσετε τη συνάρτηση SUMIF του Excel για να αθροίσετε τιμές σε ένα συγκεκριμένο εύρος ημερομηνιών. Για παράδειγμα, ο ακόλουθος τύπος SUMIFS προσθέτει τις τιμές στα κελιά C2:C9 εάν μια ημερομηνία στη στήλη B εμπίπτει μεταξύ 1-Oct-2014 και 31-Oct-2014, συμπεριλαμβανομένων.

=SUMIFS(C2:C9, B2:B9, ">=10/1/2014", B2:B9, "<=10/31/2014")

Το ίδιο αποτέλεσμα μπορεί να επιτευχθεί με τον υπολογισμό της διαφοράς δύο συναρτήσεων SUMIF, όπως παρουσιάζεται σε αυτό το παράδειγμα - Πώς να χρησιμοποιήσετε τη SUMIF για να αθροίσετε τιμές σε ένα συγκεκριμένο εύρος ημερομηνιών. Ωστόσο, το Excel SUMIFS είναι πολύ πιο εύκολο και πιο κατανοητό, έτσι δεν είναι;

Παράδειγμα 3. Excel SUMIFS με κενά και μη κενά κελιά

Κατά την ανάλυση αναφορών και άλλων δεδομένων, μπορεί συχνά να χρειαστεί να αθροίσετε τιμές που αντιστοιχούν είτε σε κενά είτε σε μη κενά κελιά.

Αθροίστε τις τιμές στα κελιά C2:C10 εάν τα αντίστοιχα κελιά στις στήλες A και B είναι απολύτως κενά. "" Αθροίζει τιμές που αντιστοιχούν σε "οπτικά" κενά κελιά, συμπεριλαμβανομένων εκείνων που περιέχουν κενές συμβολοσειρές που επιστρέφονται από κάποια άλλη συνάρτηση του Excel (για παράδειγμα, κελιά με τύπο όπως). =SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Άθροισμα τιμών στα κελιά C2:C10 με τις ίδιες συνθήκες με τον παραπάνω τύπο, αλλά περιλαμβάνει κενές συμβολοσειρές. Μη τυφλά κύτταρα "" Αθροίζει τις τιμές που αντιστοιχούν σε μη κενά κελιά, συμπεριλαμβανομένων των συμβολοσειρών μηδενικού μήκους. =SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

Αθροίζει τις τιμές στα κελιά C2:C10 εάν τα αντίστοιχα κελιά στις στήλες A και B δεν είναι κενά, συμπεριλαμβανομένων των κελιών με κενές συμβολοσειρές. SUM-SUMIF

ή

SUM / LEN Άθροισμα τιμών που αντιστοιχούν σε μη κενά κελιά, χωρίς να περιλαμβάνονται συμβολοσειρές μηδενικού μήκους. =SUM(C2:C10) - SUMIFS(C2:C10, A2:A10, "", B2:B10, "")

=SUM((C2:C10) * (LEN(A2:A10)>0)*(LEN(B2:B10)>0))

Αθροίστε τις τιμές στα κελιά C2:C10 εάν τα αντίστοιχα κελιά στις στήλες Α και Β δεν είναι κενά, τα κελιά με μηδενικού μήκους συμβολοσειρές δεν περιλαμβάνονται.

Και τώρα, ας δούμε πώς μπορείτε να χρησιμοποιήσετε έναν τύπο SUMIFS με κριτήρια "κενό" και "μη κενό" σε πραγματικά δεδομένα.

Ας υποθέσουμε ότι έχετε ημερομηνία παραγγελίας στη στήλη Β, ημερομηνία παράδοσης στη στήλη Γ και Ποσότητα στη στήλη Δ. Πώς μπορείτε να βρείτε το σύνολο των προϊόντων που δεν έχουν παραδοθεί ακόμη; Δηλαδή, θέλετε να μάθετε το άθροισμα των τιμών που αντιστοιχούν στα μη κενά κελιά της στήλης Β και στα κενά κελιά της στήλης Γ.

Η λύση είναι η χρήση του τύπου SUMIFS με 2 κριτήρια:

=SUMIFS(D2:D10, B2:B10,"", C2:C10,"=")

Χρήση του Excel SUMIF με πολλαπλά κριτήρια OR

Όπως σημειώθηκε στην αρχή αυτού του σεμιναρίου, η συνάρτηση SUMIFS έχει σχεδιαστεί με τη λογική AND. Τι γίνεται όμως αν πρέπει να αθροίσετε τιμές με πολλαπλά κριτήρια OR, δηλαδή όταν ικανοποιείται τουλάχιστον μία από τις συνθήκες;

Παράδειγμα 1. SUMIF + SUMIF

Η απλούστερη λύση είναι να αθροίσετε τα αποτελέσματα που επιστρέφονται από διάφορες συναρτήσεις SUMIF. Για παράδειγμα, ο ακόλουθος τύπος δείχνει πώς να βρείτε το σύνολο των προϊόντων που παραδόθηκαν από τον Mike και τον John:

=SUMIF(C2:C9, "Mike",D2:D9) + SUMIF(C2:C9, "John",D2:D9)

Όπως βλέπετε, η πρώτη συνάρτηση SUMIF προσθέτει τις ποσότητες που αντιστοιχούν στον "Mike", η άλλη συνάρτηση SUMIF επιστρέφει τα ποσά που αφορούν τον "John" και στη συνέχεια προσθέτετε αυτούς τους 2 αριθμούς.

Παράδειγμα 2. SUM & SUMIF με όρισμα πίνακα

Η παραπάνω λύση είναι πολύ απλή και μπορεί να κάνει γρήγορα τη δουλειά όταν υπάρχουν μόνο μερικά κριτήρια. Αλλά ένας τύπος SUMIF + SUMIF μπορεί να μεγαλώσει πάρα πολύ αν θέλετε να αθροίσετε τιμές με πολλαπλές συνθήκες OR. Σε αυτή την περίπτωση, μια καλύτερη προσέγγιση είναι η χρήση ενός κριτήρια συστοιχίας Ας εξετάσουμε αυτή την προσέγγιση τώρα.

Μπορείτε να ξεκινήσετε απαριθμώντας όλες τις συνθήκες σας χωρισμένες με κόμματα και στη συνέχεια να περιβάλλετε την προκύπτουσα λίστα με διαχωρισμένα κόμματα σε {καμπύλες αγκύλες}, η οποία τεχνικά ονομάζεται πίνακας.

Στο προηγούμενο παράδειγμα, αν θέλετε να αθροίσετε τα προϊόντα που παραδόθηκαν από τους John, Mike και Pete, τα κριτήρια του πίνακα σας θα είναι {"John", "Mike", "Pete"}. Και η πλήρης συνάρτηση SUMIF είναι SUMIF(C2:C9, {"John", "Mike", "Pete"} ,D2:D9) .

Το όρισμα του πίνακα που αποτελείται από 3 τιμές αναγκάζει τον τύπο SUMIF να επιστρέψει τρία ξεχωριστά αποτελέσματα, αλλά αφού γράφουμε τον τύπο σε ένα μόνο κελί, θα επιστρέψει μόνο το πρώτο αποτέλεσμα - δηλαδή το σύνολο των προϊόντων που παραδόθηκαν από τον John. Για να λειτουργήσει αυτή η προσέγγιση με βάση τα κριτήρια του πίνακα, πρέπει να χρησιμοποιήσετε ένα ακόμη μικρό τέχνασμα - να συμπεριλάβετε τον τύπο SUMIF σε μια συνάρτηση SUM, όπως εδώ:

=SUM(SUMIF(C2:C9, {"John", "Mike", "Pete"} , D2:D9))

Όπως βλέπετε, τα κριτήρια ενός πίνακα κάνουν τον τύπο πολύ πιο συμπαγή σε σύγκριση με το SUMIF + SUMIF και σας επιτρέπουν να προσθέσετε όσες τιμές θέλετε στον πίνακα.

Αυτή η προσέγγιση λειτουργεί τόσο με αριθμούς όσο και με τιμές κειμένου. Για παράδειγμα, αν αντί για τα ονόματα των προμηθευτών στη στήλη C, είχατε αναγνωριστικά προμηθευτών όπως 1, 2, 3 κ.λπ., τότε ο τύπος SUMIF θα έμοιαζε με τον ακόλουθο:

=SUM(SUMIF(C2:C9, {1,2,3} , D2:D9))

Σε αντίθεση με τις τιμές κειμένου, οι αριθμοί δεν χρειάζεται να περικλείονται σε διπλά εισαγωγικά στα ορίσματα του πίνακα.

Παράδειγμα 3. SUMPRODUCT & SUMIF

Σε περίπτωση που ο τρόπος που προτιμάτε είναι να απαριθμήσετε τα κριτήρια σε ορισμένα κελιά αντί να τα προσδιορίσετε απευθείας στον τύπο, μπορείτε να χρησιμοποιήσετε τη συνάρτηση SUMIF σε συνδυασμό με τη συνάρτηση SUMPRODUCT που πολλαπλασιάζει τα στοιχεία στους δεδομένους πίνακες και επιστρέφει το άθροισμα αυτών των προϊόντων.

=SUMPRODUCT(SUMIF(C2:C9, G2:G4, D2:D9))

Όπου G2:G4 είναι τα κελιά που περιέχουν τα κριτήριά σας, τα ονόματα των προμηθευτών στην περίπτωσή μας, όπως φαίνεται στο παρακάτω στιγμιότυπο.

Αλλά φυσικά, τίποτα δεν σας εμποδίζει να παραθέσετε τις τιμές σε έναν πίνακα κριτηρίων της συνάρτησης SUMIF, αν το θέλετε:

=SUMPRODUCT(SUMIF(C2:C9, {"Mike", "John", "Pete"}, D2:D9))

Το αποτέλεσμα που επιστρέφεται και από τους δύο τύπους θα είναι πανομοιότυπο με αυτό που βλέπετε στο στιγμιότυπο οθόνης:

Excel SUMIFS με πολλαπλά κριτήρια OR

Εάν θέλετε να αθροίσετε υπό όρους τιμές στο Excel όχι απλώς με πολλαπλές συνθήκες OR, αλλά με πολλά σύνολα συνθηκών, θα πρέπει να χρησιμοποιήσετε το SUMIFS αντί του SUMIF. Οι τύποι θα είναι πολύ παρόμοιοι με αυτούς που μόλις συζητήσαμε.

Ως συνήθως, ένα παράδειγμα θα μπορούσε να βοηθήσει στην καλύτερη κατανόηση του θέματος. Στον πίνακά μας με τους προμηθευτές φρούτων, ας προσθέσουμε την ημερομηνία παράδοσης (στήλη Ε) και ας βρούμε τη συνολική ποσότητα που παρέδωσαν οι Mike, John και Pete τον Οκτώβριο.

Παράδειγμα 1. SUMIFS + SUMIFS

Ο τύπος που παράγεται από αυτή την προσέγγιση περιλαμβάνει πολλές επαναλήψεις και φαίνεται δυσκίνητος, αλλά είναι εύκολα κατανοητός και, το σημαντικότερο, λειτουργεί : )

=SUMIFS(D2:D9,C2:C9, "Mike", E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014") +

SUMIFS(D2:D9, C2:C9, "John", E2:E9, ">=10/1/2014", E2:E9, "<=10/31/2014") +

SUMIFS(D2:D9, C2:C9, "Pete", E2:E9, ">=10/1/2014" ,E2:E9, "<=10/31/2014")

Όπως βλέπετε, γράφετε μια ξεχωριστή συνάρτηση SUMIFS για κάθε έναν από τους προμηθευτές και περιλαμβάνετε δύο συνθήκες - ίση ή μεγαλύτερη από την 1η Οκτωβρίου (">=10/1/2014",) και μικρότερη ή ίση από την 31η Οκτωβρίου ("<=10/31/2014"), και στη συνέχεια αθροίζετε τα αποτελέσματα.

Παράδειγμα 2. SUM & SUMIFS με όρισμα πίνακα

Προσπάθησα να εξηγήσω την ουσία αυτής της προσέγγισης στο παράδειγμα SUMIF, οπότε τώρα μπορούμε απλά να αντιγράψουμε αυτόν τον τύπο, να αλλάξουμε τη σειρά των επιχειρημάτων (όπως θυμάστε είναι διαφορετική στο SUMIF και στο SUMIFS) και να προσθέσουμε πρόσθετα κριτήρια. Ο τύπος που προκύπτει είναι πιο συμπαγής από το SUMIFS + SUMIFS:

=SUM(SUMIFS(D2:D9,C2:C9, {"Mike", "John", "Pete"}, E2:E9,">=10/1/2014", E2:E9,"<=10/31/2014"))

Το αποτέλεσμα που επιστρέφει αυτός ο τύπος είναι ακριβώς το ίδιο με αυτό που βλέπετε στο παραπάνω στιγμιότυπο.

Παράδειγμα 3. SUMPRODUCT & SUMIFS

Όπως θυμάστε, η προσέγγιση SUMPRODUCT διαφέρει από τις δύο προηγούμενες στον τρόπο με τον οποίο εισάγετε κάθε ένα από τα κριτήριά σας σε ξεχωριστό κελί αντί να τα καθορίσετε απευθείας στον τύπο. Σε περίπτωση πολλών συνόλων κριτηρίων, η συνάρτηση SUMPRODUCT δεν αρκεί και θα πρέπει να χρησιμοποιήσετε και τις ISNUMBER και MATCH.

Έτσι, υποθέτοντας ότι τα ονόματα των προμηθειών βρίσκονται στα κελιά H1:H3, η ημερομηνία έναρξης στο κελί H4 και η ημερομηνία λήξης στο κελί H5, ο τύπος SUMPRODUCT παίρνει την ακόλουθη μορφή:

=SUMPRODUCT(--(E2:E9>=H4), --(E2:E9<=H5), --(ISNUMBER(MATCH(C2:C9, H1:H3,0))), D2:D9)

Πολλοί άνθρωποι αναρωτιούνται γιατί να χρησιμοποιούμε διπλή παύλα (--) στους τύπους SUMPRODUCT. Το θέμα είναι ότι το Excel SUMPRODUCT αγνοεί όλες τις τιμές εκτός από τις αριθμητικές, ενώ οι τελεστές σύγκρισης στον τύπο μας επιστρέφουν τιμές Boolean (TRUE / FALSE), οι οποίες δεν είναι αριθμητικές. Για να μετατρέψετε αυτές τις τιμές Boolean σε 1 και 0, χρησιμοποιείτε το διπλό σύμβολο μείον, το οποίο τεχνικά ονομάζεται διπλός μοναδιαίος τελεστής. Ο πρώτος μοναδιαίος τελεστής εξαναγκάζει σεΤο δεύτερο μονόπλευρο αναιρεί τις τιμές, δηλαδή αντιστρέφει το πρόσημο, μετατρέποντάς τες σε +1 και 0, κάτι που μπορεί να κατανοήσει η συνάρτηση SUMPRODUCT.

Ελπίζω η παραπάνω εξήγηση να βγάζει νόημα. Και ακόμη και αν δεν βγάζει, απλά θυμηθείτε αυτόν τον κανόνα - χρησιμοποιήστε τον διπλό μοναδιαίο τελεστή (--) όταν χρησιμοποιείτε τελεστές σύγκρισης στους τύπους SUMPRODUCT.

Χρήση του Excel SUM σε τύπους συστοιχίας

Όπως θυμάστε, η Microsoft εφάρμοσε τη συνάρτηση SUMIFS στο Excel 2007. Αν κάποιος εξακολουθεί να χρησιμοποιεί το Excel 2003, 2000 ή παλαιότερα, θα πρέπει να χρησιμοποιήσει έναν τύπο πίνακα SUM για να προσθέσει τιμές με πολλαπλά κριτήρια AND. Φυσικά, αυτή η προσέγγιση λειτουργεί και στις σύγχρονες εκδόσεις του Excel 2013 - 2007 και μπορεί να θεωρηθεί ως ένα παλιομοδίτικο αντίστοιχο της συνάρτησης SUMIFS.

Στους τύπους SUMIF που συζητήθηκαν παραπάνω, έχετε ήδη χρησιμοποιήσει ορίσματα πίνακα, αλλά ένας τύπος πίνακα είναι κάτι διαφορετικό.

Παράδειγμα 1. Άθροισμα με πολλαπλά κριτήρια AND στο Excel 2003 και παλαιότερα

Ας επιστρέψουμε στο πρώτο παράδειγμα όπου βρήκαμε ένα άθροισμα ποσών που αφορούν ένα συγκεκριμένο φρούτο και έναν συγκεκριμένο προμηθευτή:

Όπως ήδη γνωρίζετε, αυτή η εργασία μπορεί εύκολα να επιτευχθεί με τη χρήση ενός συνηθισμένου τύπου SUMIFS:

=SUMIFS(C2:C9, A2:A9, "apples", B2:B9, "Pete")

Και τώρα, ας δούμε πώς μπορεί να εκπληρωθεί η ίδια εργασία στις πρώτες εκδόσεις του Excel χωρίς "SUMIFS". Αρχικά, γράφετε όλες τις συνθήκες που πρέπει να πληρούνται με τη μορφή range="condition". Σε αυτό το παράδειγμα, έχουμε δύο ζεύγη range/condition:

Προϋπόθεση 1: A2:A9="μήλα"

Προϋπόθεση 2: B2:B9="Pete"

Στη συνέχεια, γράφετε έναν τύπο SUM που "πολλαπλασιάζει" όλα τα ζεύγη εύρους/προϋποθέσεων, το καθένα από τα οποία περικλείεται σε αγκύλες. Ο τελευταίος πολλαπλασιαστής είναι το εύρος του αθροίσματος, C2:C9 στην περίπτωσή μας:

=SUM((A2:A9="μήλα") * ( B2:B9="Πιτ") * ( C2:C9))

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, ο τύπος λειτουργεί τέλεια στην τελευταία έκδοση του Excel 2013.

Σημείωση: Κατά την εισαγωγή οποιουδήποτε τύπου συστοιχίας, πρέπει να πατήσετε Ctrl + Shift + Enter . Μόλις το κάνετε αυτό, ο τύπος σας περικλείεται σε {καμπύλες αγκύλες}, το οποίο είναι μια οπτική ένδειξη ότι ένας τύπος συστοιχίας έχει εισαχθεί σωστά. Αν προσπαθήσετε να πληκτρολογήσετε τις αγκύλες χειροκίνητα, ο τύπος σας θα μετατραπεί σε συμβολοσειρά κειμένου και δεν θα λειτουργήσει.

Παράδειγμα 2. Τύποι συστοιχίας SUM στις σύγχρονες εκδόσεις του Excel

Ακόμη και στις σύγχρονες εκδόσεις του Excel, η δύναμη της συνάρτησης SUM δεν πρέπει να υποτιμάται. Ο τύπος του πίνακα SUM δεν είναι απλώς γυμναστική του μυαλού, αλλά έχει πρακτική αξία, όπως αποδεικνύεται στο ακόλουθο παράδειγμα.

Ας υποθέσουμε ότι έχετε δύο στήλες, B και C, και πρέπει να μετρήσετε πόσες φορές η στήλη C είναι μεγαλύτερη από τη στήλη B, όταν μια τιμή στη στήλη C είναι μεγαλύτερη ή ίση με 10. Μια άμεση λύση που σας έρχεται στο μυαλό είναι η χρήση του τύπου του πίνακα SUM:

=SUM((C1:C10>=10) * (C1:C10>B1:B10))

Δεν βλέπετε καμία πρακτική εφαρμογή στον παραπάνω τύπο; Σκεφτείτε το με έναν άλλο τρόπο : )

Ας υποθέσουμε ότι έχετε τη λίστα παραγγελιών όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης και θέλετε να μάθετε πόσα προϊόντα δεν έχουν παραδοθεί πλήρως μέχρι μια δεδομένη ημερομηνία. Μεταφρασμένα στη γλώσσα του Excel, έχουμε τις ακόλουθες συνθήκες:

Προϋπόθεση 1: Μια τιμή στη στήλη Β (Διατεταγμένα στοιχεία) είναι μεγαλύτερη από 0

Προϋπόθεση 2: Η τιμή στη στήλη Γ (Παραδοτέα) είναι μικρότερη από τη στήλη Β.

Προϋπόθεση 3: Μια ημερομηνία στη στήλη Δ (Ημερομηνία λήξης) είναι μικρότερη από την 11/1/2014.

Συνδυάζοντας τα τρία ζεύγη εύρους/προϋποθέσεων, λαμβάνετε τον ακόλουθο τύπο:

=SUM((B2:B10>=0)*(B2:B10>C2:C10)*(D2:D10

Λοιπόν, τα παραδείγματα τύπων που συζητήθηκαν σε αυτό το σεμινάριο έχουν μόνο ξύσει την επιφάνεια του τι μπορούν πραγματικά να κάνουν οι συναρτήσεις SUMIFS και SUMIF του Excel. Αλλά ελπίζουμε ότι σας βοήθησαν να οδηγηθείτε προς τη σωστή κατεύθυνση και τώρα μπορείτε να αθροίζετε τιμές στα βιβλία εργασίας του Excel, ανεξάρτητα από το πόσες περίπλοκες συνθήκες πρέπει να λάβετε υπόψη.