Tuturuan ka ng tutorial kung paano maghanap ng average sa Excel na mayroon o walang mga formula at bilugan ang mga resulta sa pinakamaraming decimal na lugar hangga't gusto mo.

Sa Microsoft Excel mayroong isang ilang iba't ibang mga function para sa pagkalkula ng average para sa isang hanay ng mga numeric na halaga. Bukod dito, mayroong isang instant na hindi formula na paraan. Sa pahinang ito, makikita mo ang isang mabilis na pangkalahatang-ideya ng lahat ng mga pamamaraan na inilalarawan sa mga halimbawa ng paggamit at pinakamahusay na kagawian. Ang lahat ng mga function na tinalakay sa tutorial na ito ay gumagana sa anumang bersyon ng Excel 365 hanggang Excel 2007.

Ano ang average?

Sa pang-araw-araw na buhay, ang average ay isang numero na nagpapahayag ang karaniwang halaga sa isang dataset ng data. Halimbawa, kung ang ilang mga atleta ay nagpatakbo ng 100m sprint, maaaring gusto mong malaman ang average na resulta - ibig sabihin, kung gaano katagal ang inaasahan ng karamihan sa mga sprinter upang makumpleto ang karera.

Sa matematika, ang average ay ang gitna o gitnang halaga sa isang hanay ng mga numero, na kinakalkula sa pamamagitan ng paghahati ng kabuuan ng lahat ng mga halaga sa kanilang numero.

Sa halimbawa sa itaas, sa pag-aakalang ang unang atleta ay sumakop sa distansya sa loob ng 10.5 segundo, ang pangalawa ay kailangan 10.7 segundo, at ang pangatlo ay tumagal ng 11.2 segundo, ang average na oras ay magiging 10.8 segundo:

(10.5+10.7+11.2)/3 = 10.8

Paano makakuha ng average sa Excel walang mga formula

Sa mga worksheet ng Excel, hindi mo kailangang magsagawa ng mga manu-manong kalkulasyon - gagawin ng mga makapangyarihang function ng Excel ang lahatfunction na kinakalkula ang isang arithmetic mean ng mga numero na binabalewala ang mga lohikal na halaga.

Paano i-round average sa Excel

Kapag nagkalkula ng average sa Excel, ang resulta ay madalas na isang numero na may maraming decimal na lugar . Kung sakaling gusto mong magpakita ng mas kaunting decimal na digit o i-round ang average sa isang integer, gamitin ang isa sa mga sumusunod na solusyon.

Bawasan ang pagpipiliang Decimal

Upang i-round lamang ang ipinapakitang average nang hindi binabago ang pinagbabatayan na halaga, ang pinakamabilis na paraan ay ang paggamit ng command na Decrease Decimal sa tab na Home , sa grupong Number :

Format Cells dialog box

Ang bilang ng mga decimal place ay maaari ding tukuyin sa Format Cells dialog box. Upang magawa ito, piliin ang formula cell at pindutin ang Ctrl + 1 upang buksan ang dialog na Format Cells . Pagkatapos, lumipat sa tab na Number , at i-type ang bilang ng mga lugar na gusto mong ipakita sa kahon na Decimal na lugar .

Tulad ng nakaraang paraan, nagbabago lang ito ang format ng pagpapakita. Kapag tinutukoy ang average na cell sa iba pang mga formula, ang orihinal na hindi bilugan na halaga ay gagamitin sa lahat ng mga kalkulasyon.

Para sa buong detalye, pakitingnan ang mga Round number sa pamamagitan ng pagpapalit ng format ng cell.

I-round ang average gamit ang isang formula

Para i-round ang mismong kinakalkula na halaga, balutin ang iyong average formula sa isa sa Excel rounding function.

Sa karamihan ng mga sitwasyon, gagamitin mo angROUND function na sumusunod sa pangkalahatang mga panuntunan sa matematika para sa rounding. Sa 1st argument ( number ), ilagay ang AVERAGE, AVERAGEIF o AVERAGEIFS function. Sa 2nd argument ( num_digits ), tukuyin ang bilang ng mga decimal na lugar kung saan ibi-round ang average.

Halimbawa, upang i-round off ang average sa pinakamalapit na integer , ang formula ay:

=ROUND(AVERAGE(B3:B15), 0)

Upang i-round ang average sa isang decimal place , ito ang formula na gagamitin:

=ROUND(AVERAGE(B3:B15), 1)

Upang i-round ang average sa dalawang decimal na lugar , gagana ang isang ito:

=ROUND(AVERAGE(B3:B15), 2)

Tip. Para sa pag-round up, gamitin ang ROUNDUP function; para sa pag-round down - ang ROUNDDOWN function.

Iyan ay kung paano mo magagawa ang average sa Excel. Sa ibaba ay may mga link sa mga kaugnay na tutorial na tumatalakay sa mas partikular na mga kaso ng average, sana ay matulungan mo ang mga ito. Salamat sa pagbabasa!

Magsanay ng workbook para sa pag-download

Kalkulahin ang average sa Excel - mga halimbawa (.xlsx file)

ang gawain sa likod ng mga eksena at ihatid ang resulta sa walang oras. Bago tuklasin nang detalyado ang mga espesyal na function, alamin natin ang isang mabilis at kamangha-manghang simpleng paraan na hindi formula.

Upang mabilis na makahanap ng average na walang formula, gamitin ang status bar ng Excel:

1. Piliin ang mga cell o hanay na gusto mong i-average. Para sa mga hindi magkadikit na seleksyon, gamitin ang Ctrl key.
2. Tingnan ang status bar sa ibaba ng Excel window, na nagbibigay ng mahahalagang impormasyon tungkol sa kasalukuyang napiling mga cell. Isa sa mga value na awtomatikong kinakalkula ng Excel ay ang average.

Ang resulta ay ipinapakita sa larawan sa ibaba:

Paano manu-manong kalkulahin ang average

Sa matematika, upang mahanap ang arithmetic mean ng isang listahan ng mga numero, kailangan mong magdagdag ng lahat ng mga halaga, at pagkatapos ay hatiin ang kabuuan sa kung gaano karaming mga numero ang nasa listahan. Sa Excel, maaari itong gawin gamit ang SUM at COUNT function, ayon sa pagkakabanggit:

SUM( range )/COUNT( range )

Para sa hanay ng mga numero sa ibaba, ang formula ay sumusunod:

=SUM(B3:B12)/COUNT(B3:B12)

Gaya ng nakikita mo, ang resulta ng formula ay eksaktong tumutugma sa average na halaga sa status bar.

Sa pagsasagawa, hindi mo na kakailanganing gumawa ng manual average sa iyong mga worksheet. Gayunpaman, maaaring kapaki-pakinabang na muling suriin ang resulta ng iyong average na formula kung sakaling may pagdududa.

At ngayon, tingnan natin kung paano mo magagawa ang average sa Excel gamit ang mga function na espesyal.idinisenyo para sa layunin.

AVERAGE function - kalkulahin ang average ng mga numero

Ginagamit mo ang Excel AVERAGE function para makakuha ng average ng lahat ng numero sa tinukoy na mga cell o range.

AVERAGE(number1, [number2], …)

Kung saan ang number1, number2 , … ay mga numerong halaga kung saan mo gustong hanapin ang average. Hanggang 255 na argumento ang maaaring isama sa isang formula. Ang mga argumento ay maaaring ibigay bilang mga numero, sanggunian, o pinangalanang hanay.

Ang AVERAGE ay isa sa mga pinakasimple at madaling gamitin na function sa Excel.

Upang kalkulahin ang average ng mga numero, maaari mong direktang i-type ang mga ito sa isang formula o ibigay ang katumbas na cell o range reference.

Halimbawa, sa average na 2 range at 1 indibidwal na cell sa ibaba, ang formula ay:

=AVERAGE(B4:B6, B8:B10, B12)

Bukod sa mga numero, ang Excel AVERAGE function ay makakahanap ng average ng iba pang mga numeric na halaga gaya ng mga porsyento at oras.

Excel AVERAGE formula - mga tala sa paggamit

Gaya ng nakita mo lang, ang paggamit ng AVERAGE function sa Excel ay madali. Gayunpaman, upang makakuha ng tamang resulta, kailangan mong malinaw na maunawaan kung anong mga value ang kasama sa average at kung ano ang binabalewala.

Kasama:

• Mga cell na may mga zero na halaga (0)
• Ang mga lohikal na halaga na TRUE at FALSE ay direktang na-type sa listahan ng mga argumento. Halimbawa, ang formula na AVERAGE(TRUE, FALSE) ay nagbabalik ng 0.5, na siyang mean ng 1 at 0.

Binalewala:

• Walang lamanmga cell
• Mga string ng text
• Mga cell na naglalaman ng mga Boolean na halaga na TRUE at FALSE

Para sa higit pang impormasyon, pakitingnan ang Paano gamitin ang AVERAGE function sa Excel.

AVERAGEA function - average ang lahat ng hindi blangko na cell

Ang Excel AVERAGEA function ay katulad ng AVERAGE dahil kinakalkula nito ang arithmetic mean ng mga value sa mga argumento nito. Ang pagkakaiba ay ang AVERAGEA ay kinabibilangan ng lahat ng walang laman na mga cell sa isang kalkulasyon, naglalaman man ang mga ito ng mga numero, text, lohikal na halaga, o walang laman na string na ibinalik ng iba pang mga function.

AVERAGEA(value1, [value2], …)

Kung saan ang value1, value2, … ay mga value, array, cell reference o range na gusto mong i-average. Kinakailangan ang unang argumento, ang iba (hanggang 255) ay opsyonal.

Excel AVERAGEA formula - mga tala sa paggamit

Gaya ng nabanggit sa itaas, ang AVERAGEA function ay nagpoproseso ng iba't ibang uri ng halaga gaya ng mga numero, mga string ng teksto at mga lohikal na halaga. At narito kung paano sinusuri ang mga ito:

Kasama:

• Nasusuri ang mga halaga ng teksto bilang 0.
• Ang mga string na walang haba ("") ay sinusuri bilang 0.
• Ang boolean value na TRUE ay sinusuri bilang 1 at FALSE bilang 0.

Binalewala:

• Empty cells

Halimbawa, ang Ang formula sa ibaba ay nagbabalik ng 1, na siyang average ng 2 at 0.

=AVERAGEA(2, FALSE)

Ang sumusunod na formula ay nagbabalik ng 1.5, na siyang average ng 2 at 1.

=AVERAGEA(2, TRUE)

Ang larawan sa ibaba ay nagpapakita ng AVERAGE at AVERAGEA na mga formula na inilapat saparehong listahan ng mga value at iba't ibang resulta ang ibinabalik nila:

AVERAGEIF function - makakuha ng average na may kundisyon

Upang makuha ang average ng lahat ng mga cell sa tinukoy na hanay na nakakatugon sa isang partikular na kundisyon, gamitin ang AVERAGEIF function .

AVERAGEIF(range, criteria, [average_range])

Ang AVERAGEIF function ay may mga sumusunod na argumento:

• Range (kinakailangan) - ang hanay ng mga cell hanggang pagsubok laban sa isang ibinigay na pamantayan.
• Mga Pamantayan (kinakailangan) - ang kundisyon na dapat matugunan.
• Average_range (opsyonal) - ang mga cell sa karaniwan. Kung tinanggal, ang range ay na-average.

Ang AVERAGEIF function ay available sa Excel 2007 - Excel 365. Sa mga naunang bersyon, maaari kang bumuo ng sarili mong AVERAGE IF na formula.

At ngayon, tingnan natin kung paano mo magagamit ang Excel AVERAGEIF function sa average na mga cell batay sa kundisyon na iyong tinukoy.

Ipagpalagay na mayroon kang mga marka para sa iba't ibang mga paksa sa C3:C15 at nais mong makahanap ng average na marka sa matematika. Magagawa ito gamit ang sumusunod na formula:

=AVERAGEIF(B3:B15, "math", C3:C15)

Sa halip na "hardcoding" ang kundisyon nang direkta sa isang formula, maaari mo itong i-type sa isang hiwalay na cell (F3) at sumangguni sa cell na iyon sa pamantayan:

=AVERAGEIF(B3:B15, F3, C3:C15)

Para sa higit pang mga halimbawa ng formula, pakitingnan ang Excel AVERAGEIF function.

AVERAGEIFS function - average na may maraming pamantayan

Upang gawin ang average na may dalawa o higit pang kundisyon, gamitin ang pangmaramihang katapat ng AVERAGEIF -ang AVERAGEIFS function.

AVERAGEIFS(average_range, criteria_range1, criteria1, [criteria_range2, criteria2], …)

Ang function ay may sumusunod na syntax:

• Average_range ( kinakailangan) - ang saklaw sa average.
• Criteria_range (kinakailangan) - ang hanay na susuriin laban sa pamantayan .
• Mga Pamantayan (kinakailangan) - ang kundisyong tumutukoy kung aling mga cell ang i-average. Maaari itong ibigay sa anyo ng isang numero, lohikal na expression, text value, o cell reference.

1 hanggang 127 criteria_range / criteria ang mga pares ay maaaring maibigay. Ang unang pares ay kinakailangan, ang mga kasunod ay opsyonal.

Sa esensya, ginagamit mo ang AVERAGEIFS na katulad ng AVERAGEIF, maliban na higit sa isang kundisyon ang maaaring masuri sa loob ng iisang formula.

Ipagpalagay na ilang mag-aaral hindi kumuha ng mga pagsusulit sa ilang mga asignatura at may mga zero na marka. Nilalayon mong makahanap ng average na marka sa isang partikular na paksa na binabalewala ang mga zero.

Para magawa ang gawain, bubuo ka ng AVERAGEIFS formula na may dalawang pamantayan:

• Tukuyin ang hanay sa average (C3 :C15).
• Tukuyin ang hanay na susuriin laban sa unang kundisyon (B3:B15 - mga item).
• Ipahayag ang unang kundisyon ("math" o F3 - ang target na item na nakapaloob sa quotation mga marka o reference sa cell na naglalaman ng item).
• Tukuyin ang hanay na susuriin laban sa ika-2 kundisyon (C3:C15 - mga marka).
• Ipahayag ang ika-2 kundisyon (">0"- higit sa zero).

Sa pamamagitan ng pagsasama-sama ng mga bahagi sa itaas, nakukuha natin ang sumusunod na formula:

=AVERAGEIFS(C3:C15, B3:B15, "math", C3:C15, ">0")

O

=AVERAGEIFS(C3:C15, B3:B15, F3, C3:C15, ">0")

Nilinaw ng larawan sa ibaba na dalawang cell lamang (C6 at C10) ang nakakatugon sa parehong kundisyon, at samakatuwid ang mga cell na ito lamang ang naa-average.

Para sa higit pang impormasyon, tingnan ang Excel AVERAGEIFS function.

AVERAGEIF at AVERAGEIFS na mga formula - mga tala sa paggamit

Ang Excel AVERAGEIF at AVERAGEIFS function ay may magkapareho, lalo na kung aling mga halaga ang mga ito kalkulahin at hindi binabalewala:

• Sa average na hanay, ang mga walang laman na cell, mga text value, mga logical value na TRUE/FALSE ay binabalewala.
• Sa pamantayan, ang mga walang laman na cell ay itinuturing bilang mga zero na halaga.
• Maaaring gamitin ang mga wildcard na character gaya ng tandang pananong (?) at asterisk (*) sa pamantayan para sa bahagyang tugma.
• Kung walang cell na nakakatugon sa lahat ng tinukoy na pamantayan, isang #DIV0! nagkakaroon ng error.

AVERAGEIF vs. AVERAGEIFS - mga pagkakaiba

Sa mga tuntunin ng functionality, ang pinakamahalagang pagkakaiba ay ang AVERAGEIF ay maaari lamang humawak ng isang kundisyon habang ang AVERAGEIFS ay isa o higit pang pamantayan. Gayundin, mayroong ilang teknikal na pagkakaiba na nauugnay sa average_range .

• Sa AVERAGEIF, average_range ang huli at opsyonal na argumento. Sa mga formula ng AVERAGEIFS, ito ang una at kinakailangang argumento.
• Sa AVERAGEIF, ang average_range ay hindi kailangang kasing laki ng range dahil ang aktwal na mga cell na ia-average ay tinutukoy ng laki ng range argument - ang kaliwang itaas na cell ng average_range ay kinuha bilang panimulang punto, at dahil maraming mga cell ang na-average bilang kasama sa range argument. Ang AVERAGEIFS ay nangangailangan ng bawat criteria_range na may parehong laki at hugis bilang average_range , kung hindi ay isang #VALUE! nagkakaroon ng error.

AVERAGE IF OR formula sa Excel

Dahil ang Excel AVERAGEIFS function ay palaging gumagana sa AND logic (lahat ng pamantayan ay dapat TOTOO), kakailanganin mong bumuo ng sarili mong formula sa average na mga cell na may OR logic (anumang solong criterion ay dapat na TRUE).

Narito ang generic na formula sa average kung ang cell ay X o Y.

AVERAGE(IF(ISNUMBER(MATCH( ) range , { criteria1 , criteria2 ,…}, 0)), average_range ))

Ngayon, tingnan natin kung paano ito gumagana sa pagsasanay . Sa talahanayan sa ibaba, ipagpalagay na gusto mong makahanap ng average na marka ng dalawang paksa, Biology at Chemistry , na input sa mga cell F3 at F4. Magagawa ito gamit ang sumusunod na array formula:

=AVERAGE(IF(ISNUMBER(MATCH(B3:B15, {"biology", "chemistry"}, 0)), C3:C15))

Isinalin sa wika ng tao, ang formula ay nagsasabing: average na mga cell sa C3:C15 kung ang katumbas na cell sa B3:B15 ay alinman sa " Biology" o "Chemistry".

Sa halip na ang hardcoded na pamantayan, maaari kang gumamit ng range reference (F3:F4 sa aming kaso):

=AVERAGE(IF(ISNUMBER(MATCH(B3:B15, F3:F4, 0)), C3:C15))

Para sa formula upang gumana nang tama,mangyaring tandaan na pindutin ang Ctrl + Shift + Enter sa Excel 2019 at mas mababa. Sa dynamic array Excel (365 at 2021), sapat na ang regular na Enter hit:

Paano gumagana ang formula na ito:

Para sa aming mausisa at maalalahanin na mga mambabasa na nais hindi lamang para gumamit ng formula ngunit maunawaan kung ano ang kanilang ginagawa, narito ang isang detalyadong paliwanag ng lohika.

Sa core ng formula, tinutukoy ng IF function kung aling mga value sa source range ang tumutugma sa alinman sa mga tinukoy na pamantayan at pumasa ang mga halagang iyon sa AVERAGE function. Ganito:

Ginagamit ng MATCH function ang mga pangalan ng paksa sa B3:B15 bilang mga value ng lookup at inihahambing ang bawat isa sa mga value na iyon laban sa lookup array sa F3:F4 (aming mga target na paksa). Ang ika-3 argumento ( match_type ) ay nakatakda sa 0 upang maghanap ng eksaktong tugma:

MATCH(B3:B15, F3:F4, 0)

Kapag may nakitang tugma, ibinabalik ng MATCH ang relatibong posisyon nito sa lookup array , kung hindi ay isang #N/A error:

{1;2;1;#N/A;1;#N/A;2;#N/A;1;2;2;1;#N/A}

Ang ISNUMBER function ay nagko-convert ng mga numero sa TRUE at mga error sa FALSE:

{TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE}

Ang array na ito ay napupunta sa lohikal na pagsubok ng IF. Sa buong anyo, ang lohikal na pagsubok ay dapat na nakasulat tulad nito:

IF(ISNUMBER(MATCH(B3:B15, F3:F4, 0))=TRUE

Para sa kaiklian, tinanggal namin ang =TRUE na bahagi dahil ito ay ipinahiwatig.

Ni itinatakda ang argumentong value_if_true sa C3:C15, sasabihin mo sa IF function na palitan ang TRUE ng mga aktwal na halaga mula sa C3:C15:

{89;78;75;FALSE;64;FALSE;62;FALSE;78;56;93;88;FALSE}

Ang panghuling array na ito ay ibinigay hanggang sa AVERAGE