Dalam tutorial ini, Anda akan belajar cara membuat rentang bernama dinamis di Excel dan cara menggunakannya dalam rumus agar data baru disertakan dalam penghitungan secara otomatis.

Dalam tutorial minggu lalu, kami melihat berbagai cara untuk menentukan rentang bernama statis di Excel. Nama statis selalu mengacu pada sel yang sama, artinya Anda harus memperbarui referensi rentang secara manual setiap kali Anda menambahkan data baru atau menghapus data yang ada.

Jika Anda bekerja dengan kumpulan data yang terus berubah, Anda mungkin ingin membuat rentang bernama Anda dinamis sehingga secara otomatis meluas untuk mengakomodasi entri yang baru ditambahkan atau berkontraksi untuk mengecualikan data yang dihapus. Lebih lanjut dalam tutorial ini, Anda akan menemukan panduan langkah demi langkah yang mendetail tentang cara melakukan ini.

Cara membuat rentang bernama dinamis di Excel

Sebagai permulaan, mari kita buat rentang bernama dinamis yang terdiri dari satu kolom dan sejumlah baris variabel. Untuk menyelesaikannya, lakukan langkah-langkah ini:

1. Pada Rumus tab, di tab Nama yang Ditetapkan kelompok, klik Tentukan Nama Atau, tekan Ctrl + F3 untuk membuka Excel Name Manger, dan klik tombol Baru... tombol.
2. Apa pun itu, yang Nama Baru kotak dialog akan terbuka, di mana Anda menentukan detail berikut ini:
   • Dalam Nama kotak, ketikkan nama untuk rentang dinamis Anda.
   • Dalam Ruang Lingkup tarik-turun, atur cakupan nama. Buku Kerja (default) direkomendasikan dalam kebanyakan kasus.
   • Dalam Mengacu pada kotak, masukkan rumus OFFSET COUNTA atau INDEX COUNTA.
3. Klik OK. Selesai!

Dalam tangkapan layar berikut ini, kita mendefinisikan rentang bernama dinamis item yang mengakomodasi semua sel dengan data dalam kolom A, kecuali untuk baris header:

Rumus OFFSET untuk menentukan rentang bernama dinamis Excel

Rumus umum untuk membuat rentang bernama dinamis di Excel adalah sebagai berikut:

Di mana:

• first_cell - item pertama yang akan dimasukkan ke dalam rentang yang disebutkan, misalnya $ A $ 2.
• kolom - referensi absolut ke kolom seperti $A:$A.

Pada inti rumus ini, Anda menggunakan fungsi COUNTA untuk mendapatkan jumlah sel yang tidak kosong dalam kolom yang diinginkan. Angka itu langsung masuk ke tinggi argumen dari fungsi OFFSET (referensi, baris, cols, [tinggi], [lebar]) yang memberitahukan berapa banyak baris yang akan dikembalikan.

Di luar itu, ini adalah rumus Offset biasa, di mana:

• referensi adalah titik awal dari mana Anda mendasarkan offset (first_cell).
• barisan dan cols keduanya 0, karena tidak ada kolom atau baris yang harus diimbangi.
• lebar sama dengan 1 kolom.

Misalnya, untuk membuat rentang bernama dinamis untuk kolom A di Sheet3, dimulai di sel A2, kami menggunakan rumus ini:

=OFFSET(Sheet3!$A$2, 0, 0, COUNTA(Sheet3!$A:$A), 1)

Catatan. Jika Anda mendefinisikan rentang dinamis di lembar kerja saat ini, Anda tidak perlu menyertakan nama lembar dalam referensi, Excel akan melakukannya untuk Anda secara otomatis. Jika Anda membuat rentang untuk beberapa lembar lain, awali referensi sel atau rentang dengan nama lembar diikuti dengan tanda seru (seperti pada contoh rumus di atas).

Rumus INDEX untuk membuat rentang bernama dinamis di Excel

Cara lain untuk membuat rentang dinamis Excel menggunakan COUNTA yang dikombinasikan dengan fungsi INDEX.

Formula ini terdiri atas dua bagian:

• Di sisi kiri operator range (:), Anda meletakkan referensi awal yang dikodekan dengan keras seperti $A$2.
• Di sisi kanan, Anda menggunakan fungsi INDEX(larik, row_num, [column_num]) untuk mencari referensi akhir. Di sini, Anda menyediakan seluruh kolom A untuk larik dan menggunakan COUNTA untuk mendapatkan nomor baris (yaitu jumlah sel yang bukan entri di kolom A).

Untuk dataset sampel kami (silakan lihat tangkapan layar di atas), rumusnya adalah sebagai berikut:

=$A$2:INDEX($A:$A, COUNTA($A:$A))

Karena ada 5 sel yang tidak kosong di kolom A, termasuk tajuk kolom, COUNTA mengembalikan 5. Akibatnya, INDEX mengembalikan $ A $ 5, yang merupakan sel yang terakhir digunakan di kolom A (biasanya rumus Indeks mengembalikan nilai, tetapi operator referensi memaksanya untuk mengembalikan referensi). Dan karena kami telah menetapkan $ A $ 2 sebagai titik awal, hasil akhir dari rumus tersebut adalah kisaran $ A $ 2: $ A $ 5.

Untuk menguji rentang dinamis yang baru dibuat, Anda dapat meminta COUNTA mengambil jumlah item:

=COUNTA(Item)

Jika semua dilakukan dengan benar, hasil rumus akan berubah setelah Anda menambahkan atau menghapus item ke/dari daftar:

Catatan. Dua rumus yang dibahas di atas menghasilkan hasil yang sama, namun ada perbedaan kinerja yang harus Anda waspadai. OFFSET adalah fungsi volatile yang menghitung ulang dengan setiap perubahan pada lembar. Pada mesin modern yang kuat dan kumpulan data berukuran cukup, ini seharusnya tidak menjadi masalah. Pada mesin berkapasitas rendah dan kumpulan data yang besar, ini dapat memperlambat Excel Anda. Dalam hal ini, Anda akanlebih baik menggunakan rumus INDEX untuk membuat rentang bernama dinamis.

Cara membuat rentang dinamis dua dimensi di Excel

Untuk membangun rentang bernama dua dimensi, di mana tidak hanya jumlah baris tetapi juga jumlah kolomnya dinamis, gunakan modifikasi rumus INDEX COUNTA berikut:

Dalam rumus ini, Anda memiliki dua fungsi COUNTA untuk mendapatkan baris terakhir yang tidak kosong dan kolom terakhir yang tidak kosong ( row_num dan column_num argumen dari fungsi INDEX, masing-masing). Di dalam array argumen, Anda memberi makan seluruh lembar kerja (1048576 baris di Excel 2016 - 2007; 65535 baris di Excel 2003 dan yang lebih rendah).

Dan sekarang, mari kita definisikan satu lagi kisaran dinamis untuk kumpulan data kita: kisaran bernama penjualan yang mencakup angka penjualan selama 3 bulan (Jan hingga Mar) dan menyesuaikan secara otomatis saat Anda menambahkan item baru (baris) atau bulan (kolom) ke tabel.

Dengan data penjualan dimulai pada kolom B, baris 2, rumusnya berbentuk sebagai berikut:

=$B$2:INDEX($1:$1048576,COUNTA($B:$B),COUNTA($2:$2))

Untuk memastikan dynamic range Anda berfungsi sebagaimana mestinya, masukkan rumus berikut ini di suatu tempat pada sheet:

=SUM(penjualan)

=SUM(B2:D5)

Seperti yang bisa Anda lihat pada tangkapan layar di bawah ini, kedua rumus mengembalikan total yang sama. Perbedaannya terlihat pada saat Anda menambahkan entri baru ke dalam tabel: rumus pertama (dengan rentang nama dinamis) akan diperbarui secara otomatis, sedangkan rumus kedua harus diperbarui secara manual dengan setiap perubahan. Itu membuat perbedaan besar, eh?

Cara menggunakan rentang bernama dinamis dalam rumus Excel

Di bagian sebelumnya dari tutorial ini, Anda telah melihat beberapa rumus sederhana yang menggunakan rentang dinamis. Sekarang, mari kita coba membuat sesuatu yang lebih bermakna yang menunjukkan nilai sebenarnya dari rentang bernama dinamis Excel.

Untuk contoh ini, kita akan mengambil rumus INDEX MATCH klasik yang melakukan Vlookup di Excel:

...dan lihat bagaimana kita bisa membuat formula ini lebih kuat lagi dengan penggunaan rentang bernama dinamis.

Seperti yang ditunjukkan pada screenshot di atas, kita mencoba untuk membangun dashboard, di mana pengguna memasukkan nama item di H1 dan mendapatkan total penjualan untuk item tersebut di H2. Tabel sampel kami yang dibuat untuk tujuan demonstrasi hanya berisi 4 item, tetapi dalam lembar kehidupan nyata Anda bisa ada ratusan bahkan ribuan baris. Selain itu, item baru dapat ditambahkan setiap hari, jadi menggunakan referensi bukanlah hal yangkarena Anda harus memperbarui rumus berulang-ulang. Saya terlalu malas untuk itu! :)

Untuk memaksa formula meluas secara otomatis, kita akan mendefinisikan 3 nama: 2 rentang dinamis, dan 1 sel bernama statis:

Lookup_range: =$A$2:INDEX($A:$A, COUNTA($A:$A))

Return_range: =$E$2:INDEX($E:$E, COUNTA($E:$E))

Lookup_value: =$H$1

Excel akan menambahkan nama sheet saat ini ke semua referensi, jadi sebelum membuat nama pastikan untuk membuka sheet dengan data sumber Anda.

Sekarang, mulailah mengetik rumus di H1. Ketika sampai pada argumen pertama, ketik beberapa karakter nama yang ingin Anda gunakan, dan Excel akan menampilkan semua nama yang cocok yang tersedia. Klik dua kali nama yang sesuai, dan Excel akan segera memasukkannya ke dalam rumus:

Rumus lengkapnya terlihat sebagai berikut:

=INDEX(Return_range, MATCH(Lookup_value, Lookup_range, 0))

Dan bekerja dengan sempurna!

Segera setelah Anda menambahkan catatan baru ke tabel, mereka akan dimasukkan dalam perhitungan Anda sekaligus, tanpa Anda harus membuat satu perubahan pun pada rumusnya! Dan jika Anda perlu memindahkan rumus ke file Excel lain, cukup buat nama yang sama di buku kerja tujuan, salin / tempel rumus, dan segera kerjakan.

Tip Selain membuat rumus lebih tahan lama, rentang dinamis berguna untuk membuat daftar dropdown dinamis.

Untuk melihat lebih dekat rumus-rumus yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh contoh Excel Dynamic Named Range Workbook kami. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!