Šajā pamācībā uzzināsiet, kā programmā Excel izveidot dinamisku nosaukumu diapazonu un kā to izmantot formulās, lai aprēķinos automātiski iekļautu jaunus datus.

Pagājušās nedēļas pamācībā mēs aplūkojām dažādus veidus, kā Excel programmā definēt statisku nosaukumu diapazonu. Statisks nosaukums vienmēr attiecas uz tām pašām šūnām, kas nozīmē, ka jums būtu manuāli jāatjaunina diapazona atsauce ikreiz, kad pievienojat jaunus vai dzēšat esošos datus.

Ja strādājat ar nepārtraukti mainīgu datu kopu, iespējams, vēlēsieties izveidot savu nosaukto diapazonu dinamisku, lai tas automātiski paplašinātos, iekļaujot jaunus pievienotos ierakstus, vai sašaurinātos, izslēdzot no tā noņemtos datus. Tālāk šajā pamācībā atradīsiet detalizētus norādījumus soli pa solim, kā to izdarīt.

Kā izveidot dinamisku nosaukumu diapazonu programmā Excel

Vispirms izveidosim dinamisku nosaukumu diapazonu, kas sastāv no vienas kolonnas un mainīga rindu skaita. Lai to izdarītu, izpildiet šādas darbības:

1. Par Formula cilnē Definētie nosaukumi grupu, noklikšķiniet uz Definēt nosaukumu . Vai arī nospiediet taustiņus Ctrl + F3, lai atvērtu programmu Excel Name Manger, un noklikšķiniet uz Jauns... pogu.
2. Jebkurā gadījumā Jauns nosaukums tiks atvērts dialoglodziņš, kurā norādiet šādu informāciju:
   • In the Nosaukums ievadiet dinamiskā diapazona nosaukumu.
   • In the Darbības joma nolaižamajā logā iestatiet nosaukuma darbības jomu. Darba burtnīca (noklusējuma iestatījums) vairumā gadījumu ir ieteicama.
   • In the Attiecas uz ievadiet OFFSET COUNTA vai INDEX COUNTA formulu.
3. Noklikšķiniet uz Labi. Gatavs!

Tālāk redzamajā ekrānšāviņā mēs definējam dinamisku nosaukumu diapazons preces kas ietver visus šūnas ar datiem A slejā, izņemot virsraksta rindu:

OFFSET formula, lai definētu Excel dinamisko nosaukumu diapazonu

Vispārējā formula dinamiska nosaukuma diapazona izveidei programmā Excel ir šāda:

Kur:

• first_cell - pirmais vienums, kas jāiekļauj nosauktajā diapazonā, piemēram, $A$2.
• sleja - absolūta atsauce uz kolonnu, piemēram, $A:$A.

Šīs formulas pamatā ir funkcija COUNTA, lai iegūtu to šūnu skaitu, kas nav tukšas, interesējošajā slejā. Šis skaitlis tiek tieši ievadīts formulā. augstums OFFSET(atsauce, rindas, cols, [augstums], [platums]) arguments, kas norāda, cik daudz rindu jāatgriež.

Papildus tam tā ir parasta ieskaita formula, kurā:

• atsauce ir sākumpunkts, no kura sākas nobīde (first_cell).
• rindas un Cols abas ir 0, jo nav ne kolonnu, ne rindu, kas būtu jānokompensē.
• platums ir vienāds ar 1 kolonnu.

Piemēram, lai izveidotu dinamisku nosaukto diapazonu A slejā 3. lapā, sākot no šūnas A2, mēs izmantojam šo formulu:

=OFFSET(Sheet3!$A$2, 0, 0, COUNTA(Sheet3!$A:$A), 1)

Piezīme. Ja definējat dinamisko diapazonu pašreizējā darblapā, jums nav jānorāda lapas nosaukums, Excel to izdarīs automātiski. Ja veidojat diapazonu kādai citai lapai, pirms šūnas vai diapazona atsauces norādiet lapas nosaukumu, kam seko izsaukuma punkts (kā formulas piemērā iepriekš).

INDEX formula, lai izveidotu dinamisku nosaukumu diapazonu programmā Excel

Vēl viens veids, kā izveidot Excel dinamisko diapazonu, ir izmantot funkciju COUNTA kopā ar funkciju INDEX.

Šī formula sastāv no divām daļām:

• Diapazona operatora (:) kreisajā pusē ievietojiet grūti kodētu sākuma atsauci, piemēram, $A$2.
• Labajā pusē, lai noskaidrotu beigu atsauci, izmantojiet funkciju INDEX(array, row_num, [column_num]). Šajā gadījumā jūs sniedzat visu A sleju masīvam un izmantojat COUNTA, lai iegūtu rindas numuru (t. i., A slejā esošo šūnu skaitu, kas nav ievades).

Mūsu parauga datu kopai (skatiet ekrānšāviņas attēlā) formula ir šāda:

=$A$2:INDEX($A:$A, COUNTA($A:$A))

Tā kā A slejā ir 5 tukšas šūnas, ieskaitot slejas virsrakstu, COUNTA atgriež 5. Līdz ar to INDEX atgriež $A$5, kas ir pēdējā izmantotā A slejas šūna (parasti indeksa formula atgriež vērtību, bet atsauces operators liek atgriezt atsauci). Un, tā kā par sākuma punktu esam iestatījuši $A$2, formulas gala rezultāts ir diapazons $A$2:$A$5.

Lai pārbaudītu jaunizveidoto dinamisko diapazonu, varat palūgt COUNTA iegūt elementu skaitu:

=COUNTA(Preces)

Ja viss ir izdarīts pareizi, formulas rezultāts mainīsies, tiklīdz sarakstā pievienosiet vai no tā noņemsiet vienumus:

Piezīme. Abas iepriekš aplūkotās formulas dod vienu un to pašu rezultātu, tomēr ir atšķirība veiktspējas ziņā, kas jums būtu jāņem vērā. OFFSET ir gaistoša funkcija, kas tiek pārrēķināta pēc katrām izmaiņām lapā. Ja ir jaudīgi mūsdienu datori un samērīga izmēra datu kopas, tas neradīs problēmas. Ja ir mazjaudas datori un lielas datu kopas, tas var palēnināt Excel darbību. Tādā gadījumā jums vajadzētulabāk izmantot INDEX formulu, lai izveidotu dinamisku nosaukumu diapazonu.

Kā izveidot divdimensiju dinamisko diapazonu programmā Excel

Lai izveidotu divdimensiju nosaukumu diapazonu, kurā dinamisks ir ne tikai rindu, bet arī kolonnu skaits, izmantojiet šādu INDEX COUNTA formulas modifikāciju:

Šajā formulā ir divas COUNTA funkcijas, lai iegūtu pēdējo nepilno rindu un pēdējo nepilno kolonnu ( rindu_num un column_num INDEX funkcijas argumenti). masīvs argumentu, tiek ievadīta visa darblapa (1048576 rindas programmā Excel 2016 - 2007; 65535 rindas programmā Excel 2003 un jaunākās versijās).

Un tagad definēsim vēl vienu dinamisko diapazonu mūsu datu kopai: diapazonu ar nosaukumu pārdošana kas ietver pārdošanas rādītājus par 3 mēnešiem (no janvāra līdz martam) un automātiski pielāgojas, kad tabulai tiek pievienotas jaunas preces (rindas) vai mēneši (kolonnas).

Ja pārdošanas dati sākas B slejas 2. rindā, formula ir šāda:

=$B$2:INDEX($1:$1048576,COUNTA($B:$B),COUNTA($2:$2))

Lai pārliecinātos, ka dinamiskais diapazons darbojas, kā paredzēts, ievadiet lapas lappusē šādas formulas:

=SUM(pārdošanas apjoms)

=SUM(B2:D5)

Kā redzams zemāk redzamajā ekrānšāviņā, abas formulas atgriež vienu un to pašu kopsummu. Atšķirība atklājas brīdī, kad tabulā pievienojat jaunus ierakstus: pirmā formula (ar dinamisko nosaukumu diapazonu) atjaunināsies automātiski, bet otrā formula būs jāatjaunina manuāli ar katru izmaiņu. Tas ir milzīga atšķirība, vai ne?

Kā Excel formulās izmantot dinamiskos nosauktos diapazonus

Šīs pamācības iepriekšējās sadaļās jau esat redzējuši dažas vienkāršas formulas, kurās izmantoti dinamiskie diapazoni. Tagad mēģināsim izdomāt kaut ko jēgpilnāku, kas parāda Excel dinamiskā nosaukuma diapazona reālo vērtību.

Šajā piemērā mēs izmantosim klasisko INDEX MATCH formulu, kas Excel programmā veic Vlookup:

...un skatiet, kā mēs varam padarīt formulu vēl jaudīgāku, izmantojot dinamiskos nosaukumu diapazonus.

Kā parādīts iepriekš redzamajā ekrānšāviņas attēlā, mēs mēģinām izveidot paneli, kurā lietotājs H1 ieraksta preces nosaukumu, bet H2 saņem šīs preces kopējo pārdošanas apjomu. Mūsu parauga tabulā, kas izveidota demonstrācijas nolūkos, ir tikai 4 preces, bet jūsu reālās dzīves tabulās var būt simtiem un pat tūkstošiem rindu. Turklāt jaunas preces var tikt pievienotas katru dienu, tāpēc atsauču izmantošana nav lietderīga.iespēja, jo būtu atkal un atkal jāatjaunina formula. Es esmu pārāk slinks, lai to darītu! :)

Lai piespiestu formulu automātiski izvērsties, mēs definēsim 3 nosaukumus: 2 dinamiskos diapazonus un 1 statisku šūnas nosaukumu:

Lookup_range: =$A$2:INDEX($A:$A, COUNTA($A:$A))

Return_range: =$E$2:INDEX($E:$E, COUNTA($E:$E))

Lookup_value: =$H$1

Piezīme. Excel visām atsaucēm pievienos pašreizējās lapas nosaukumu, tāpēc pirms nosaukumu izveides noteikti atveriet lapu ar avota datiem.

Tagad sāciet rakstīt formulu H1. Kad nonāksiet pie pirmā argumenta, ierakstiet dažas vēlamā nosaukuma rakstzīmes, un Excel parādīs visus pieejamos atbilstošos nosaukumus. Divreiz noklikšķiniet uz atbilstošā nosaukuma, un Excel to uzreiz ievietos formulā:

Pabeigtā formula izskatās šādi:

=INDEX(Return_range, MATCH(Lookup_value, Lookup_range, 0))

Un darbojas perfekti!

Tiklīdz tabulai pievienosiet jaunus ierakstus, tie uzreiz tiks iekļauti aprēķinos, neveicot nevienu formulas izmaiņu! Un, ja jums kādreiz būs nepieciešams pārnest formulu uz citu Excel failu, vienkārši izveidojiet tādus pašus nosaukumus galamērķa darbgrāmatā, kopējiet/ielīmējiet formulu un nekavējoties sāciet to izmantot.

Padoms. Dinamiskie diapazoni ne tikai padara formulas noturīgākas, bet arī ir noderīgi, lai izveidotu dinamiskus izlaižamos sarakstus.

Tas ir veids, kā izveidot un izmantot dinamiskos nosauktos diapazonus programmā Excel. Lai tuvāk aplūkotu šajā pamācībā aplūkotās formulas, aicinām lejupielādēt mūsu Excel dinamisko nosaukto diapazonu darbgrāmatas paraugu. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu emuārā!