Kui oled selle blogi regulaarne külastaja, siis oled ilmselt märganud paari artiklit, mis käsitlevad Exceli tingimusliku vormindamise erinevaid aspekte. Ja nüüd kasutame neid teadmisi ära ja loome tabelid, mis eristavad nädalapäevad ja nädalavahetused, tõstavad esile riigipühad ja näitavad saabuvat tähtaega või viivitust. Teisisõnu, me rakendame Exceli tingimuslikku vormindamist kuupäevadele.

Kui teil on mõningad algteadmised Exceli valemitest, siis olete tõenäoliselt tuttav mõne kuupäeva- ja ajafunktsiooniga, nagu NOW, TODAY, DATE, WEEKDAY jne. Selles õpetuses läheme selle funktsiooniga sammu võrra edasi, et Exceli kuupäevade tingimuslik vorming nii, nagu soovite.

Exceli kuupäevade tingimuslik vormindamine (sisseehitatud reeglid)

Microsoft Excel pakub 10 võimalust valitud lahtrite vormindamiseks praeguse kuupäeva alusel.

1. Vormindamise kohaldamiseks tuleb lihtsalt minna menüüsse Kodu tab> Tingimuslik vormindamine> Raku esiletõstmise reeglid ja valige Toimuv kuupäev .

   

2. Valige üks järgmistest kuupäeva valikud akna vasakpoolses rippmenüüst, alates eelmisest kuust kuni järgmise kuuni.
3. Lõpuks valige üks etteantud vormingutest või seadistage oma kohandatud vorming, valides erinevaid valikuid valikul Font , Piiril ja Täitke Kui Exceli standardpaleest ei piisa, võite alati klõpsata nuppu Rohkem värve... nupp.

   

4. Klõpsake OK ja nautige tulemust! : )

   

Sellel kiirel ja lihtsal viisil on aga kaks olulist piirangut - 1) see töötab ainult valitud lahtritele ja 2) tingimuslik vorming rakendub alati praeguse kuupäeva alusel.

Exceli kuupäevade tingimuslikud vorminguvormelid

Kui soovite esile tõsta lahtreid või terveid ridu teise lahtri kuupäeva alusel , või luua reeglid suuremad ajavahemikud (st rohkem kui kuu aega alates praegusest kuupäevast), peate looma oma tingimusliku vormindamise reegli, mis põhineb valemil. Allpool leiate mõned näited minu lemmikutest Exceli tingimuslikest vormingutest kuupäevade jaoks.

Kuidas Excelis nädalavahetusi esile tõsta

Kahjuks ei ole Microsoft Excelil sisseehitatud kalendrit, mis oleks sarnane Outlooki omaga. Noh, vaatame, kuidas saate üsna vähese vaevaga luua omaenda automatiseeritud kalendri.

Exceli kalendri kujundamisel saate nädalapäevade kuvamiseks kasutada funktsiooni =DATE(aasta,kuu,kuupäev). Sisestage lihtsalt aasta ja kuu number kuskile oma arvutustabeli ja viita nendele lahtritele valemis. Loomulikult võite numbrid otse valemisse sisestada, kuid see ei ole väga tõhus lähenemine, sest peate valemi iga kuu jaoks kohandama.

Allpool olev ekraanipilt näitab DATE funktsiooni toimimist. Ma kasutasin valemit =DATE($B$2,$B$1,B$4) mis on kopeeritud üle 5. rea.

Vihje. Kui soovite kuvada ainult nädalapäevi, nagu näete ülaltoodud pildil, valige lahtrid valemiga (meie puhul rida 5), tehke paremklõps ja valige Format Cells.> Number> Custom Valige rippmenüüst Tüüp , valige kas dddd või ddd näidata vastavalt päevade täisnimesid või lühendatud nimesid.

Teie Exceli kalender on peaaegu valmis ja teil on vaja ainult nädalavahetuste värvi muuta. Loomulikult ei kavatse te lahtreid käsitsi värvida. Laseme Excelil vormindada nädalavahetused automaatselt, luues tingimusliku vormindamise reegli, mis põhineb NÄDALA valemiga.

1. Alustad oma Exceli kalendri valimisega, kus soovid nädalavahetusi varjutada. Meie puhul on see vahemik $B$4:$AE$10. Kindlasti alusta valiku tegemist tähisega 1. kuupäeva veerg - Selles näites on veerus B.
2. On Kodu vahekaart, klõpsake Tingimuslik vormingu menüü> Uus reegel .
3. Looge uus tingimusliku vormingu reegel, mis põhineb valemil, nagu on selgitatud eespool lingitud juhendis.
4. In " Vormindage väärtused, kus see valem on tõene" sisestage järgmine valem WEEKDAY, mis määrab kindlaks, millised lahtrid on laupäevad ja pühapäevad: =WEEKDAY(B$5,2)>5
5. Klõpsake nuppu Formaat... nuppu ja seadistage oma kohandatud vorming, lülitades vahel ümber Font , Piiril ja Täitke vahekaardid ja mängides erinevate vormindusvalikutega. Kui olete valmis, klõpsake nuppu OK nuppu reegli eelvaates.

Lubage mul nüüd lühidalt selgitada WEEKDAY(serial_number,[return_type]) valemit, et saaksite seda kiiresti kohandada oma arvutustabelite jaoks.

• The serial_number parameeter tähistab kuupäeva, mida püütakse leida. Sa sisestad viite oma esimesele lahtrisse, kus on kuupäev, meie puhul B$5.
• The [return_type] parameeter määrab nädala tüübi (nurksulgudes tähendab, et see on valikuline). 2 sisestate tagastustüübiks nädala, mis algab esmaspäevast (1) kuni pühapäevani (7). Täieliku loetelu saadavalolevatest tagastustüüpidest leiate siit.
• Lõpuks kirjutate>5, et rõhutada ainult laupäevi (6) ja pühapäevi (7).

Allpool olev ekraanipilt näitab tulemust Excel 2013-s - nädalavahetused on esile toodud punase värviga.

Näpunäited:

• Kui teie ettevõttes on mittestandardsed nädalavahetused, nt reeded ja laupäevad, siis tuleb valemit muuta nii, et arvestus algab pühapäevast (1) ja toob esile päevad 6 (reede) ja 7 (laupäev) -. WEEKDAY(B$5,1)>5 .
• Kui te loote horisontaalset (maastikuline) kalendrit, kasutage lahtriviites suhtelist veergu (ilma $) ja absoluutset rida (koos $-ga), sest peate lukustama rea viite - ülaltoodud näites on see rida 5, seega sisestasime B$5. Kui aga kujundate kalendrit vertikaalses orientatsioonis, peaksite tegema vastupidi, st kasutama absoluutset veergu ja suhtelist rida, nt $B5, nagu näete dokumendisalloleval ekraanipildil:

Kuidas Excelis puhkuste esiletõstmine

Et oma Exceli kalendrit veelgi täiustada, saate varjutada ka riigipühad. Selleks peate samas või mõnes teises tabelis loetlema pühad, mida soovite esile tõsta.

Näiteks olen lisanud veergu A järgmised pühad ($A$14:$A$17). Loomulikult ei ole kõik neist tõelised pühad, kuid demonstratsiooniks piisab neist : )

Jällegi, te avate Tingimuslik vormindamine > Uus reegel Puhkuste puhul kasutate kas MATCH või COUNTIF funktsioon:

• =COUNTIF($A$14:$A$17,B$5)>0
• =MATCH(B$5,$A$14:$A$17,0)

Märkus. Kui olete valinud pühade jaoks teise värvi, tuleb riigipühade reegel viia reeglistiku tippu reeglite kaudu Tingimuslik vormindamine> Reeglite haldamine...

Järgneval pildil on esitatud tulemus Excel 2013:

Tingimuslik lahtri vormindamine, kui väärtus muutub kuupäevaks

Ei ole suur probleem, kui lahtrit tingimuslikult vormindada, kui sellesse lahtrisse või mõnda teise sama rea lahtrisse lisatakse kuupäev, kui muud väärtustüüpi ei ole lubatud. Sellisel juhul võiksite lihtsalt kasutada valemit, et rõhutada mitte tühikuid, nagu on kirjeldatud Excelis tingimuslikes valemites tühikute ja mitte tühikute jaoks. Aga mis siis, kui nendes lahtrites on juba mõned väärtused, nt tekst, ja te soovite muutataustavärvi, kui tekst muudetakse kuupäevaks?

Ülesanne võib tunduda veidi keerulisena, kuid lahendus on väga lihtne.

1. Kõigepealt peate kindlaks määrama oma kuupäeva vormingukoodi. Siin on vaid mõned näited:
   • D1: dd-mmm-yy või d-mmm-yy
   • D2: dd-mmm või d-mmm
   • D3: mmm-yy
   • D4: mm/dd/yy või m/d/yy või m/d/yy h:mm

   Täieliku kuupäevakoodide loetelu leiate sellest artiklist.

2. Valige veerg, kus soovite muuta lahtrite värvi, või kogu tabel, kui soovite ridu esile tõsta.
3. Ja nüüd looge tingimusliku vormingu reegel, kasutades sarnast valemit: =CELL("format",$A2)="D1" Valemis on A veerus kuupäevad ja D1 on kuupäeva formaat.

   Kui teie tabel sisaldab kuupäevi kahes või enamas formaadis, siis kasutage OR-operaatorit, nt. =OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")

   Allpool olev ekraanipilt näitab sellise kuupäevade tingimusliku vormindamise reegli tulemust.

   

Kuidas rõhutada ridu teatud kuupäeva alusel teatud veerus olevasse veergu

Oletame, et teil on suur Exceli tabel, mis sisaldab kahte kuupäeva veergu (B ja C). Te soovite esile tõsta iga rea, mille veerus C on teatud kuupäev, näiteks 13. mai 14.

Exceli tingimusliku vormingu kohaldamiseks teatud kuupäevale peate leidma selle numbriline väärtus esiteks. Nagu te ilmselt teate, salvestab Microsoft Excel kuupäevad järjestikuste järjekorranumbritena, alustades 1. jaanuarist 1900. Seega, 1-Jan-1900 salvestatakse kui 1, 2-Jan-1900 salvestatakse kui 2... ja 13-May-14 kui 41772.

Kuupäeva numbri leidmiseks klõpsake lahtril paremklõpsuga, valige Formaat lahtrid> Number ja valida Üldine formaat. Kirjutage number, mida näete, ja klõpsake Tühista sest te ei taha tegelikult kuupäeva formaati muuta.

See oli tegelikult suurem osa tööst ja nüüd on vaja ainult luua tingimuslik vormindamise reegel kogu tabeli jaoks selle väga lihtsa valemiga: =$C2=41772 Valem eeldab, et teie tabelis on päised ja rida 2 on teie esimene rida andmetega.

Alternatiivne võimalus on kasutada DATEVALUE valem, mis teisendab kuupäeva numbrivormingusse, milles see on salvestatud, nt. =$C2=DATEVALUE("5/13/2014")

Ükskõik, millist valemit te kasutate, on sellel sama mõju:

Kuupäevade tingimuslik vormindamine Excelis praeguse kuupäeva alusel

Nagu te ilmselt teate, pakub Microsoft Excel TODAY() funktsioonid erinevate arvutuste jaoks, mis põhinevad jooksval kuupäeval. Siin on vaid mõned näited, kuidas saate seda kasutada kuupäevade tingimuslikuks vormindamiseks Excelis.

Näide 1. Rõhutage kuupäevad, mis on võrdsed, suuremad või väiksemad kui täna.

Selleks, et vormindada lahtreid või terveid ridu tänase kuupäeva alusel, kasutate funktsiooni TODAY järgmiselt:

Võrdne tänapäevaga: =$B2=TODAY()

Suurem kui täna: =$B2>TODAY()

Vähem kui täna: =$B2

Allpool olev ekraanipilt näitab ülaltoodud reeglite toimimist. Pange tähele, et kirjutamise hetkel oli TODAY 12-Jun-2014.

Näide 2. Kuupäevade tingimuslik vormindamine Excelis mitme tingimuse alusel

Samamoodi saate kasutada funktsiooni TODAY koos teiste Exceli funktsioonidega, et käsitleda keerulisemaid stsenaariume. Näiteks võite soovida, et teie Exceli tingimusliku vormingu kuupäeva valemiga värvitakse Arve veerus, kui Tarnekuupäev on võrdne või suurem kui täna, MUTTA soovite, et vorming kaoks, kui sisestate arve numbri.

Selle ülesande jaoks oleks vaja täiendavat veergu järgmise valemiga (kus E on teie valem). Kohaletoimetamine veerg ja F veerg Arve veerg):

=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)

Kui tarnekuupäev on suurem või võrdne praeguse kuupäevaga ja veerus Arve puudub number, annab valem 1, vastasel juhul 0.

Pärast seda loote lihtsa tingimusliku vormindamise reegli jaoks Arve veerus valemiga =$G2=1 kus G on teie täiendav veerg. Loomulikult saate selle veeru hiljem ära peita.

Näide 3. Rõhutage eelseisvaid kuupäevi ja viivitusi

Oletame, et teil on Excelis projekti ajakava, milles on loetletud ülesanded, nende alguskuupäevad ja kestus. Te soovite, et iga ülesande lõppkuupäev arvutataks automaatselt. Täiendav väljakutse on see, et valem peaks arvestama ka nädalavahetusi. Näiteks kui alguskuupäev on 13-Jun-2014 ja tööpäevade arv (kestus) on 2, peaks lõppkuupäevaks saama 17-Jun-2014,sest 14. ja 15. juuni on laupäev ja pühapäev.

Selleks kasutame me WORKDAY.INTL(alguskuupäev,päevad,[nädalavahetus],[pühad]) funktsioon, täpsemalt =WORKDAY.INTL(B2,C2,1) .

Valemis sisestame 3. parameetriks 1, kuna see näitab laupäeva ja pühapäeva kui pühi. Võite kasutada mõnda muud väärtust, kui teie nädalavahetused on erinevad, näiteks R ja L. Täielik nimekiri nädalavahetuste väärtustest on saadaval siin. Valikuliselt võite kasutada ka 4. parameetrit [pühad], mis on kuupäevade kogum (lahtrite vahemik), mis tuleks tööpäevakalendrist välja jätta.

Ja lõpuks võite rõhutada ridu sõltuvalt sellest, kui kaugel on tähtaeg. Näiteks järgmistel 2 valemil põhinevate tingimuslike vormindusreeglitega tõstetakse esile vastavalt eelseisvad ja hiljutised lõppkuupäevad:

• =AND($D2-TODAY()>=0,$D2-TODAY()<=7) - tõsta esile kõik read, kus lõppkuupäev (veerg D) on jooksul järgmised 7 päeva See valem on tõesti mugav, kui tegemist on eelseisvate aegumiskuupäevade või maksete jälgimisega.
• =AND(TODAY()-$D2>=0,TODAY()-$D2<=7) - tõsta esile kõik read, kus lõppkuupäev (veerg D) on jooksul viimased 7 päeva Selle valemi abil saate jälgida viimaseid makseviivitusi ja muid viivitusi.

Siin on veel mõned valemite näited, mida saab rakendada ülaltoodud tabelis:

=$D2 - toob esile kõik möödunud kuupäevad (st kuupäevad, mis on lühemad kui praegune kuupäev). Saab kasutada aegunud tellimuste, makseviivituste jne. vormistamiseks.

=$D2>TODAY() - toob esile kõik tulevased kuupäevad (st kuupäevad, mis on suuremad kui praegune kuupäev). Seda saate kasutada eelseisvate sündmuste esiletõstmiseks.

Loomulikult võib ülaltoodud valemitest olla lõputuid variante, sõltuvalt teie konkreetsest ülesandest. Näiteks:

=$D2-TODAY()>=6 - toob esile kuupäevad, mis toimuvad 6 või enama päeva pärast.

=$D2=TODAY()-14 - rõhutab täpselt 2 nädalat tagasi toimunud kuupäevi.

Kuidas tõsta kuupäevad kuupäevade vahemikus esile

Kui teie töölehel on pikk nimekiri kuupäevadest, võite ka soovida esile tõsta lahtrid või read, mis jäävad teatud kuupäevade vahemikku, st tõsta esile kõik kuupäevad, mis jäävad kahe antud kuupäeva vahele.

Selle ülesande saate täita, kasutades taas funktsiooni TODAY(). Peate lihtsalt koostama veidi keerulisemaid valemeid, nagu on näidatud allpool toodud näidetes.

Valemid mineviku kuupäevade esiletõstmiseks

• Rohkem kui 30 päeva tagasi: =TODAY()-$A2>30
• Alates 30 kuni 15 päeva tagasi, kaasa arvatud: =AND(TODAY()-$A2>=15, TODAY()-$A2<=30)
• Vähem kui 15 päeva tagasi: =AND(TODAY()-$A2>=1, TODAY()-$A2<15)

Praegune kuupäev ja tulevased kuupäevad ei ole värvitud.

Valemid tulevaste kuupäevade esiletõstmiseks

• Toimub rohkem kui 30 päeva pärast: =$A2-TODAY()>30
• 30 kuni 15 päeva jooksul, kaasa arvatud: =AND($A2-TODAY()>=15, $A2-TODAY()<=30)
• Vähem kui 15 päeva jooksul: =AND($A2-TODAY()>=1, $A2-TODAY()<15)

Praegune kuupäev ja mis tahes varasemad kuupäevad ei ole värvitud.

Kuidas varjutada lüngad ja ajavahed

Selles viimases näites kasutame veel ühte Exceli kuupäeva funktsiooni - DATEDIF(alguskuupäev, lõppkuupäev, intervall) See funktsioon arvutab kahe kuupäeva vahe, mis põhineb määratud ajavahemikul. See funktsioon erineb kõigist teistest funktsioonidest, mida me selles õpetuses oleme käsitlenud, selle poolest, et see võimaldab teil ignoreerida kuud või aastad ja arvutada ainult päevade või kuude vahe, olenevalt sellest, mida te valite.

Ei näe, kuidas see võiks teie jaoks toimida? Mõelge selle peale teistmoodi... Oletame, et teil on nimekiri teie pereliikmete ja sõprade sünnipäevadest. Kas te tahaksite teada, mitu päeva on nende järgmise sünnipäevani? Lisaks, mitu päeva täpselt on jäänud teie pulma-aastapäevani ja muudesse sündmustesse, millest te ei tahaks ilma jääda? Lihtsalt!

Vajalik valem on järgmine (kus A on teie Kuupäev veerg):

=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")

Valemi lõpus olevat intervallitüüpi "yd" kasutatakse aastate ignoreerimiseks ja ainult päevade erinevuse arvutamiseks. Täieliku loetelu saadavalolevatest intervallitüüpidest leiate siit.

Vihje. Kui juhtub, et unustad või paned selle keerulise valemi valesti, võid selle asemel kasutada seda lihtsat valemit: =365-DATEDIF($A2,TODAY(), "yd") See annab täpselt sama tulemuse, lihtsalt ärge unustage asendada 365 366-ga hüppeaastatel : )

Ja nüüd loome Exceli tingimusliku vormindamise reegli, et toonida erinevad lüngad eri värvidega. Sel juhul on mõistlikum kasutada Exceli värviskaalasid, mitte luua iga perioodi jaoks eraldi reeglit.

Allpool olev ekraanipilt näitab tulemust Excelis - gradientne 3-värviline skaala, mille toonid ulatuvad rohelisest punase ja kollase vahel.

"Päevad järgmise sünnipäevani" Exceli veebirakendus

Oleme loonud selle Exceli veebirakenduse, et näidata teile ülaltoodud valemit praktikas. Lihtsalt sisestage oma sündmused 1. veergu ja muutke vastavaid kuupäevi 2. veerus, et katsetada tulemust.

Märkus. Sisseehitatud töövihiku vaatamiseks lubage turundusküpsiseid.

Kui olete uudishimulik teada, kuidas luua selliseid interaktiivseid Exceli tabeleid, vaadake seda artiklit, kuidas teha veebipõhiseid Exceli tabeleid.

Loodetavasti on vähemalt üks selles artiklis käsitletud Exceli kuupäevade tingimuslikest vormingutest teile kasulikuks osutunud. Kui otsite lahendust mõnele teisele ülesandele, siis olete väga oodatud kommentaari kirjutama. Täname lugemise eest!