Pokud jste pravidelnými návštěvníky tohoto blogu, pravděpodobně jste zaznamenali několik článků zabývajících se různými aspekty podmíněného formátování aplikace Excel. A nyní tyto znalosti využijeme a vytvoříme tabulky, které budou rozlišovat mezi pracovními dny a víkendy, zvýrazňovat státní svátky a zobrazovat blížící se termín nebo zpoždění. Jinými slovy, budeme aplikovat podmíněné formátování aplikace Excel na data.

Pokud máte základní znalosti vzorců Excelu, pak pravděpodobně znáte některé funkce data a času, jako jsou TEĎ, DNES, DATUM, TÝDEN atd. V tomto kurzu se chystáme posunout tuto funkci o krok dále a podmíněně formátovat data aplikace Excel tak, jak si přejete.

Podmíněné formátování aplikace Excel pro data (vestavěná pravidla)

Aplikace Microsoft Excel nabízí 10 možností formátování vybraných buněk na základě aktuálního data.

1. Chcete-li formátování použít, jednoduše přejděte do složky Home karta> Pravidla podmíněného formátování> zvýraznění buněk a vyberte Nastávající datum .

   

2. Vyberte jednu z těchto možností možnosti data z rozevíracího seznamu v levé části okna, a to v rozsahu od minulého měsíce po následující měsíc.
3. Nakonec si vyberte jeden z předdefinovaných formátů nebo si nastavte vlastní formát výběrem různých možností v okně. Písmo , Hranice a Naplňte Pokud vám standardní paleta Excelu nestačí, můžete vždy kliknout na tlačítko Více barev... tlačítko.

   

4. Klikněte na OK a užijte si výsledek! : )

   

Tento rychlý a jednoduchý způsob má však dvě podstatná omezení - 1) funguje pouze pro vybrané buňky a 2) podmíněný formát se vždy použije na základě aktuálního data.

Vzorce podmíněného formátování aplikace Excel pro data

Pokud chcete zvýraznit buňky nebo celé řádky. na základě data v jiné buňce nebo vytvořit pravidla pro větší časové intervaly (tj. více než měsíc od aktuálního data), budete muset vytvořit vlastní pravidlo podmíněného formátování založené na vzorci. Níže najdete několik příkladů mých oblíbených podmíněných formátů Excelu pro data.

Jak zvýraznit víkendy v aplikaci Excel

Microsoft Excel bohužel nemá vestavěný kalendář podobný kalendáři v aplikaci Outlook. Podívejme se, jak si můžete vytvořit vlastní automatizovaný kalendář s poměrně malým úsilím.

Při tvorbě kalendáře v aplikaci Excel můžete k zobrazení dnů v týdnu použít funkci =DATE(rok,měsíc,datum). Stačí zadat rok a číslo měsíce někde v tabulce a ve vzorci se na tyto buňky odkázat. Samozřejmě byste mohli zadat čísla přímo do vzorce, ale to není příliš efektivní přístup, protože byste museli vzorec upravovat pro každý měsíc.

Níže uvedený obrázek ukazuje funkci DATE v akci. Použil jsem vzorec =DATE($B$2,$B$1,B$4) který je zkopírován přes řádek 5.

Tip: Pokud chcete zobrazit pouze dny v týdnu, jak vidíte na obrázku výše, vyberte buňky se vzorcem (v našem případě řádek 5), klikněte pravým tlačítkem myši a vyberte možnost Formátování buněk.> Číslo> Vlastní . Z rozevíracího seznamu v části Typ , vyberte buď dddd nebo ddd pro zobrazení plných názvů dnů nebo zkrácených názvů.

Váš kalendář v Excelu je téměř hotový, zbývá jen změnit barvu víkendů. Samozřejmě nebudete buňky obarvovat ručně. Necháme Excel automaticky formátovat víkendy vytvořením pravidla podmíněného formátování na základě parametru TÝDEN vzorec.

1. Začněte tím, že vyberete kalendář Excelu, ve kterém chcete stínovat víkendy. V našem případě je to rozsah $B$4:$AE$10. Nezapomeňte začít výběr znakem 1. sloupec s datem - Sloupec B v tomto příkladu.
2. Na Home klikněte na kartu Nabídka podmíněného formátování> Nové pravidlo .
3. Vytvořte nové pravidlo podmíněného formátování založené na vzorci, jak je vysvětleno ve výše uvedeném odkazovaném průvodci.
4. V " Formátování hodnot, kde je tento vzorec pravdivý" zadejte následující vzorec WEEKDAY, který určí, které buňky jsou soboty a neděle: =WEEKDAY(B$5,2)>5
5. Klikněte na Formát... a nastavte vlastní formát přepínáním mezi tlačítky Písmo , Hranice a Naplňte a hrát si s různými možnostmi formátování. Po dokončení klikněte na tlačítko OK pro zobrazení náhledu pravidla.

Nyní mi dovolte, abych stručně vysvětlil WEEKDAY(serial_number,[return_type]) vzorec, abyste jej mohli rychle upravit pro své vlastní tabulky.

• Na stránkách serial_number Parametr představuje datum, které se snažíte najít. Zadáte odkaz na první buňku s datem, v našem případě B$5.
• Na stránkách [return_type] Parametr určuje typ týdne (hranaté závorky naznačují, že je nepovinný). Jako typ návratu zadáte 2 pro týden začínající pondělím (1) až nedělí (7). Úplný seznam dostupných typů návratu najdete zde.
• Nakonec napíšete>5, abyste zvýraznili pouze soboty (6) a neděle (7).

Níže uvedený snímek obrazovky ukazuje výsledek v aplikaci Excel 2013 - víkendy jsou zvýrazněny červenou barvou.

Tipy:

• Pokud máte ve firmě nestandardní víkendy, např. pátky a soboty, pak byste museli vzorec upravit tak, aby se počítal od neděle (1) a zvýraznil dny 6 (pátek) a 7 (sobota) -. WEEKDAY(B$5,1)>5 .
• Pokud vytváříte kalendář ve vodorovné orientaci (na šířku), použijte v odkazu na buňku relativní sloupec (bez $) a absolutní řádek (s $), protože byste měli uzamknout odkaz na řádek - ve výše uvedeném příkladu je to řádek 5, takže jsme zadali B$5. Pokud však vytváříte kalendář ve svislé orientaci, měli byste postupovat opačně, tj. použít absolutní sloupec a relativní řádek, např. $B5, jak vidíte na obrázkuníže uvedený snímek obrazovky:

Jak zvýraznit svátky v aplikaci Excel

Chcete-li svůj kalendář v aplikaci Excel dále vylepšit, můžete zastínit i státní svátky. K tomu budete muset ve stejné nebo jiné tabulce uvést svátky, které chcete zvýraznit.

Do sloupce A jsem například přidal následující svátky ($A$14:$A$17). Samozřejmě ne všechny jsou skutečnými svátky, ale pro demonstrační účely postačí : )

Opět otevřete Podmíněné formátování > Nové pravidlo . V případě dovolené použijete buď MATCH nebo COUNTIF funkce:

• =COUNTIF($A$14:$A$17,B$5)>0
• =MATCH(B$5,$A$14:$A$17,0)

Poznámka: Pokud jste pro svátky zvolili jinou barvu, je třeba přesunout pravidlo pro státní svátky na začátek seznamu pravidel prostřednictvím položky Podmíněné formátování> Správa pravidel...

Následující obrázek ukazuje výsledek v aplikaci Excel 2013:

Podmíněné formátování buňky při změně hodnoty na datum

Není velký problém podmíněně formátovat buňku, když je do ní nebo do jiné buňky ve stejném řádku přidáno datum, pokud není povolen jiný typ hodnoty. V takovém případě můžete jednoduše použít vzorec pro zvýraznění neprázdných míst, jak je popsáno v článku Podmíněné vzorce Excelu pro prázdná a neprázdná místa. Co když ale tyto buňky již obsahují nějaké hodnoty, např. text, a vy chcete změnit hodnotubarva pozadí při změně textu na datum?

Tento úkol může znít poněkud složitě, ale řešení je velmi jednoduché.

1. Nejprve je třeba určit kód formátu data. Zde je jen několik příkladů:
   • D1: dd-mmm-yy nebo d-mmm-yy
   • D2: dd-mmm nebo d-mmm
   • D3: mmm-yy
   • D4: mm/dd/rr nebo m/d/rr nebo m/d/rr h:mm

   Úplný seznam datových kódů najdete v tomto článku.

2. Vyberte sloupec, ve kterém chcete změnit barvu buněk, nebo celou tabulku v případě, že chcete zvýraznit řádky.
3. A nyní vytvořte pravidlo podmíněného formátování pomocí vzorce podobného tomuto: =CELL("format",$A2)="D1" Ve vzorci je A sloupec s daty a D1 je formát data.

   Pokud tabulka obsahuje data ve dvou nebo více formátech, použijte operátor OR, např. =OR(buňka("format", $A2)="D1", buňka("format",$A2)="D2", buňka("format", $A2)="D3")

   Následující obrázek ukazuje výsledek takového pravidla podmíněného formátování pro data.

   

Jak zvýraznit řádky na základě určitého data v určitém sloupci

Předpokládejme, že máte velkou tabulku aplikace Excel, která obsahuje dva sloupce s daty (B a C). Chcete zvýraznit každý řádek, který má ve sloupci C určité datum, například 13. května-14.

Chcete-li použít podmíněné formátování aplikace Excel na určité datum, musíte najít jeho název. číselná hodnota Za prvé. Jak pravděpodobně víte, Microsoft Excel ukládá data jako pořadová čísla počínaje 1. lednem 1900. 1. leden 1900 je tedy uložen jako 1, 2. leden 1900 je uložen jako 2... a 13. květen 14 jako 41772.

Chcete-li zjistit číslo data, klikněte pravým tlačítkem myši na buňku, vyberte možnost Formátování buněk> Číslo a vyberte Obecné formát. Zapište si číslo, které vidíte, a klikněte na tlačítko Zrušit protože ve skutečnosti nechcete měnit formát data.

To byla vlastně hlavní část práce a nyní stačí vytvořit pravidlo podmíněného formátování pro celou tabulku pomocí tohoto velmi jednoduchého vzorce: =$C2=41772 Vzorec předpokládá, že vaše tabulka má záhlaví a řádek 2 je první řádek s daty.

Alternativním způsobem je použití DATEVALUE vzorec, který převede datum na formát čísla, ve kterém je uloženo, např. =$C2=DATEVALUE("5/13/2014")

Ať už použijete jakýkoli vzorec, bude mít stejný účinek:

Podmíněné formátování dat v aplikaci Excel na základě aktuálního data

Jak pravděpodobně víte, Microsoft Excel poskytuje TODAY() funkce pro různé výpočty na základě aktuálního data. Zde je jen několik příkladů, jak je můžete použít k podmíněnému formátování dat v aplikaci Excel.

Příklad 1. Zvýrazněte data, která se rovnají, jsou větší nebo menší než dnešní.

Chcete-li podmíněně formátovat buňky nebo celé řádky na základě dnešního data, použijte funkci TODAY následujícím způsobem:

Stejně jako dnes: =$B2=TODAY()

Větší než dnes: =$B2>TODAY()

Méně než dnes: =$B2

Níže uvedený snímek obrazovky ukazuje výše uvedená pravidla v akci. Upozorňujeme, že v době psaní tohoto článku byl den 12. června 2014.

Příklad 2. Podmíněné formátování dat v aplikaci Excel na základě několika podmínek

Podobným způsobem můžete funkci TODAY použít v kombinaci s dalšími funkcemi aplikace Excel pro řešení složitějších scénářů. Například můžete chtít, aby vzorec pro podmíněné formátování data v aplikaci Excel obarvil datum. Faktura sloupec, když Datum dodání se rovná nebo je větší než dnes, ALE chcete, aby formátování při zadávání čísla faktury zmizelo.

Pro tento úkol byste potřebovali další sloupec s následujícím vzorcem (kde E je váš vzorec) Dodávka sloupec a F Faktura sloupec):

=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)

Pokud je datum dodání větší nebo rovno aktuálnímu datu a ve sloupci Faktura není žádné číslo, vzorec vrátí 1, jinak 0.

Poté vytvoříte jednoduché pravidlo podmíněného formátování pro pole Faktura sloupec se vzorcem =$G2=1 kde G je váš další sloupec. Tento sloupec samozřejmě budete moci později skrýt.

Příklad 3. Zvýraznění nadcházejících termínů a zpoždění

Předpokládejme, že máte v Excelu harmonogram projektu, který obsahuje seznam úkolů, jejich počáteční data a doby trvání. Chcete, aby se datum ukončení každého úkolu vypočítalo automaticky. Další výzvou je, že vzorec by měl zohlednit také víkendy. Například pokud je počáteční datum 13. června 2014 a počet pracovních dnů (doba trvání) je 2, datum ukončení by mělo být 17. června 2014,protože 14. a 15. června jsou sobota a neděle.

K tomu použijeme příkaz WORKDAY.INTL(start_date,days,[weekend],[holidays]) funkce, přesněji řečeno =WORKDAY.INTL(B2,C2,1) .

Ve vzorci zadáme jako 3. parametr hodnotu 1, protože označuje sobotu a neděli jako svátky. Pokud máte jiné víkendy, například pá a so, můžete použít jinou hodnotu. Úplný seznam hodnot víkendů je k dispozici zde. Volitelně můžete použít také 4. parametr [svátky], což je sada dat (rozsah buněk), která mají být vyloučena z kalendáře pracovních dnů.

A nakonec můžete chtít zvýraznit řádky v závislosti na tom, jak daleko je termín uzávěrky. Například pravidla podmíněného formátování založená na následujících 2 vzorcích zvýrazní blížící se, resp. nedávné termíny uzávěrky:

• =AND($D2-TODAY()>=0,$D2-TODAY()<=7) - zvýraznit všechny řádky, ve kterých je Datum ukončení (sloupec D) v rozmezí příštích 7 dní . Tento vzorec je opravdu užitečný, pokud jde o sledování blížících se dat vypršení platnosti nebo plateb.
• =AND(TODAY()-$D2>=0,TODAY()-$D2<=7) - zvýraznit všechny řádky, ve kterých je Datum ukončení (sloupec D) v rozmezí posledních 7 dní . Pomocí tohoto vzorce můžete sledovat poslední opožděné platby a další zpoždění.

Zde je několik dalších příkladů vzorců, které lze aplikovat na výše uvedenou tabulku:

=$D2 - zvýrazní všechna prošlá data (tj. data kratší než aktuální datum). Lze použít k formátování prošlých předplatných, opožděných plateb atd.

=$D2>TODAY() - zvýrazní všechna budoucí data (tj. data, která jsou delší než aktuální datum). Můžete ji použít ke zvýraznění nadcházejících událostí.

Výše uvedené vzorce mohou samozřejmě existovat v nekonečném množství variant, v závislosti na konkrétním úkolu. Například:

=$D2-TODAY()>=6 - zvýrazňuje data, která se vyskytují za 6 a více dní.

=$D2=TODAY()-14 - upozorňuje na data, která se vyskytla přesně před 2 týdny.

Jak zvýraznit data v rámci rozsahu dat

Pokud máte v pracovním listu dlouhý seznam dat, můžete také chtít zvýraznit buňky nebo řádky, které spadají do určitého rozsahu dat, tj. zvýraznit všechna data, která jsou mezi dvěma danými daty.

Tuto úlohu můžete splnit opět pomocí funkce TODAY(). Jen budete muset sestavit trochu složitější vzorce, jak je ukázáno v příkladech níže.

Vzorce pro zvýraznění minulých dat

• Před více než 30 dny: =TODAY()-$A2>30
• Před 30 až 15 dny včetně: =AND(TODAY()-$A2>=15, TODAY()-$A2<=30)
• Před méně než 15 dny: =AND(TODAY()-$A2>=1, TODAY()-$A2<15)

Aktuální datum a případná budoucí data nejsou barevně vyznačena.

Vzorce pro zvýraznění budoucích dat

• Nastane za více než 30 dní: =$A2-TODAY()>30
• Za 30 až 15 dní včetně: =AND($A2-TODAY()>=15, $A2-TODAY()<=30)
• Za méně než 15 dní: =AND($A2-TODAY()>=1, $A2-TODAY()<15)

Aktuální datum ani žádná minulá data nejsou podbarvena.

Jak odstínit mezery a časové intervaly

V tomto posledním příkladu použijeme další funkci Excelu pro datum - DATEDIF(start_date, end_date, interval) . Tato funkce vypočítá rozdíl mezi dvěma daty na základě zadaného intervalu. Od všech ostatních funkcí, které jsme v tomto kurzu probrali, se liší tím, že umožňuje ignorovat měsíce nebo roky a vypočítat pouze rozdíl mezi dny nebo měsíci, podle toho, co si vyberete.

Nechápete, jak by vám to mohlo vyhovovat? Přemýšlejte o tom jinak... Předpokládejme, že máte seznam narozenin svých rodinných příslušníků a přátel. Chtěli byste vědět, kolik dní zbývá do jejich dalších narozenin? A navíc, kolik přesně dní zbývá do výročí vaší svatby a dalších událostí, které byste nechtěli zmeškat? Snadno!

Vzorec, který potřebujete, je následující (kde A je vaše Datum sloupec):

=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")

Typ intervalu "yd" na konci vzorce slouží k ignorování let a výpočtu rozdílu pouze mezi dny. Úplný seznam dostupných typů intervalů naleznete zde.

Tip: Pokud se vám stane, že zapomenete nebo ztratíte složitý vzorec, můžete použít tento jednoduchý: =365-DATEDIF($A2,TODAY(), "yd") . Výsledek je naprosto stejný, jen nezapomeňte v přestupných letech nahradit 365 číslem 366 : )

A nyní vytvoříme pravidlo podmíněného formátování aplikace Excel, které odstíní různé mezery různými barvami. V tomto případě má větší smysl využít barevné škály aplikace Excel než vytvářet samostatné pravidlo pro každou tečku.

Níže uvedený obrázek ukazuje výsledek v aplikaci Excel - gradientní tříbarevnou stupnici s odstíny od zelené přes červenou až po žlutou.

Webová aplikace Excel "Dny do příštích narozenin"

Vytvořili jsme tuto webovou aplikaci Excelu, která vám ukáže výše uvedený vzorec v akci. Stačí zadat události do 1. sloupce a změnit odpovídající data ve 2. sloupci a experimentovat s výsledkem.

Poznámka: Chcete-li zobrazit vložený pracovní sešit, povolte prosím marketingové soubory cookie.

Pokud vás zajímá, jak takové interaktivní tabulky Excelu vytvořit, přečtěte si tento článek o tom, jak vytvořit webové tabulky Excelu.

Doufejme, že se vám alespoň jeden z podmíněných formátů Excelu pro data popsaných v tomto článku osvědčil. Pokud hledáte řešení nějaké jiné úlohy, budete vítáni v komentářích. Děkujeme za přečtení!