Encontrará una serie de ejemplos de fórmulas que demuestran cómo extraer el mes de una fecha en Excel, obtener el primer y último día del mes, convertir el nombre del mes en número y mucho más.

En el artículo anterior, exploramos una variedad de fórmulas para calcular los días de la semana. Hoy, vamos a operar con una unidad de tiempo mayor y aprender las funciones que Microsoft Excel proporciona para los meses.

En este tutorial aprenderás:

Función MES de Excel - sintaxis y usos

Microsoft Excel proporciona una función especial MES para extraer un mes de la fecha, que devuelve el número de mes que va del 1 (enero) al 12 (diciembre).

La función MES se puede utilizar en todas las versiones de Excel 2016 - 2000 y su sintaxis es lo más sencilla posible:

Dónde número_de_serie es cualquier fecha válida del mes que está intentando encontrar.

Para que las fórmulas MES de Excel funcionen correctamente, debe introducirse una fecha utilizando la función FECHA(año, mes, día). Por ejemplo, la fórmula =MONTH(DATE(2015,3,1)) devuelve 3 ya que DATE representa el día 1 de marzo de 2015.

Fórmulas como = MES("1-Mar-2015") también funcionan bien, aunque pueden surgir problemas en escenarios más complejos si las fechas se introducen como texto.

En la práctica, en lugar de especificar una fecha dentro de la función MES, es más conveniente hacer referencia a una celda con una fecha o suministrar una fecha devuelta por alguna otra función. Por ejemplo:

= MES(A1) - devuelve el mes de una fecha en la celda A1.

=MES(HOY()) - devuelve el número del mes actual.

A primera vista, la función MES de Excel puede parecer sencilla, pero si echa un vistazo a los siguientes ejemplos se sorprenderá de la cantidad de cosas útiles que puede hacer.

Cómo obtener el número de mes a partir de la fecha en Excel

Hay varias formas de obtener el mes a partir de la fecha en Excel. La que elija dependerá exactamente del resultado que esté intentando conseguir.

Función MES en Excel - obtener el número de mes a partir de una fecha

Esta es la forma más obvia y sencilla de convertir fecha a mes en Excel. Por ejemplo:

• = MES(A2) - devuelve el mes de una fecha en la celda A2.
• =MONTH(DATE(2015,4,15)) - devuelve 4 correspondientes a abril.
• =MONTH("15-Apr-2015") - obviamente, también devuelve el número 4.

Función TEXT en Excel - extraer el mes como una cadena de texto

Una forma alternativa de obtener un número de mes a partir de una fecha de Excel es utilizar la función TEXTO:

• =TEXT(A2, "m") - devuelve un número de mes sin un cero a la izquierda, como 1 - 12.
• =TEXT(A2, "mm") - devuelve un número de mes con un cero a la izquierda, como 01 - 12.

Tenga mucho cuidado al utilizar fórmulas TEXTO, ya que siempre devuelven los números de mes como cadenas de texto. Por lo tanto, si tiene previsto realizar otros cálculos o utilizar los números devueltos en otras fórmulas, será mejor que utilice la función MES de Excel.

La siguiente captura de pantalla muestra los resultados devueltos por todas las fórmulas anteriores. Observe la alineación a la derecha de los números devueltos por la función MES (celdas C2 y C3) en contraposición a los valores de texto alineados a la izquierda devueltos por las funciones TEXTO (celdas C4 y C5).

Cómo extraer el nombre del mes de la fecha en Excel

En caso de que desee obtener el nombre de un mes en lugar de un número, utilice de nuevo la función TEXTO, pero con un código de fecha diferente:

• =TEXT(A2, "mmm") - devuelve un nombre de mes abreviado, como Ene - Dic.
• =TEXT(A2, "mmmm") - devuelve un nombre de mes completo, como enero - diciembre.

Si en realidad no desea convertir la fecha a mes en su hoja de cálculo de Excel, sólo desea mostrar el nombre de un mes en lugar de la fecha completa, entonces no querrá ninguna fórmula.

Seleccione una(s) celda(s) con fechas, pulse Ctrl+1 para abrir la pantalla Formatear celdas En el Número seleccione A medida y escriba "mmm" o "mmmm" en el campo Tipo para mostrar nombres de mes abreviados o completos, respectivamente. En este caso, las entradas seguirán siendo fechas de Excel totalmente funcionales que podrá utilizar en cálculos y otras fórmulas. Para obtener más información sobre cómo cambiar el formato de fecha, consulte Creación de un formato de fecha personalizado en Excel.

Cómo convertir el número de mes en nombre de mes en Excel

Suponga que tiene una lista de números (del 1 al 12) en su hoja de cálculo de Excel que desea convertir en nombres de mes. Para ello, puede utilizar cualquiera de las siguientes fórmulas:

Para devolver un nombre de mes abreviado (Ene - Dic):

=TEXT(A2*28, "mmm")

=TEXT(DATE(2015, A2, 1), "mmm")

Para devolver un nombre de mes completo (enero - diciembre):

=TEXT(A2*28, "mmmm")

=TEXT(DATE(2015, A2, 1), "mmmm")

En todas las fórmulas anteriores, A2 es una celda con un número de mes. Y la única diferencia real entre las fórmulas son los códigos de mes:

• "mmm" - abreviatura de 3 letras del mes, como Ene - Dic
• "mmmm" - mes deletreado completamente
• "mmmmm" - la primera letra del nombre del mes

Cómo funcionan estas fórmulas

Cuando se utiliza junto con códigos de formato de mes como "mmm" y "mmmm", Excel considera el número 1 como el Día 1 de enero de 1900. Multiplicando 1, 2, 3, etc. por 28, se obtienen los Días 28, 56, 84, etc. del año 1900, que corresponden a enero, febrero, marzo, etc. El código de formato "mmm" o "mmmm" sólo muestra el nombre del mes.

Cómo convertir el nombre del mes en número en Excel

Hay dos funciones de Excel que pueden ayudarte a convertir los nombres de los meses en números: DATEVALUE y MONTH. La función DATEVALUE de Excel convierte una fecha almacenada como texto en un número de serie que Microsoft Excel reconoce como una fecha. Y luego, la función MONTH extrae un número de mes de esa fecha.

La fórmula completa es la siguiente:

=MONTH(DATEVALUE(A2 & "1"))

Donde A2 en una celda que contenga el nombre del mes que quieres convertir en un número (& "1" se añade para que la función DATEVALUE entienda que es una fecha).

Cómo obtener el último día del mes en Excel (función EOMONTH)

La función EOMONTH en Excel se utiliza para devolver el último día del mes basado en la fecha de inicio especificada. Tiene los siguientes argumentos, ambos obligatorios:

• Fecha_inicio - la fecha de inicio o una referencia a una celda con la fecha de inicio.
• Meses - el número de meses anteriores o posteriores a la fecha de inicio. Utilice un valor positivo para fechas futuras y negativo para fechas pasadas.

Aquí tienes algunos ejemplos de fórmulas EOMONTH:

=EOMONTH(A2, 1) - devuelve el último día del mes, un mes después de la fecha de la celda A2.

=EOMONTH(A2, -1) - devuelve el último día del mes, un mes antes de la fecha de la celda A2.

En lugar de una referencia de celda, puede codificar una fecha en la fórmula EOMONTH. Por ejemplo, las dos fórmulas siguientes devuelven el último día de abril.

=EOMONTH("15-Abr-2015", 0)

=EOMONTH(FECHA(2015,4,15), 0)

Para devolver el último día del mes en curso utiliza la función TODAY() en el primer argumento de la fórmula EOMONTH para que la fecha de hoy se tome como fecha de inicio y pone 0 en el argumento meses argumento porque no quieres cambiar el mes de ninguna manera.

=EOMONTH(HOY(), 0)

Nota. Dado que la función EOMONTH de Excel devuelve el número de serie que representa la fecha, tiene que aplicar el formato de fecha a una(s) celda(s) con sus fórmulas. Consulte Cómo cambiar el formato de fecha en Excel para ver los pasos detallados.

Y aquí están los resultados devueltos por las fórmulas EOMONTH de Excel comentadas anteriormente:

Si desea calcular cuántos días faltan para que finalice el mes en curso, sólo tiene que restar la fecha devuelta por TODAY() de la fecha devuelta por EOMONTH y aplicar el formato General a una celda:

=EOMONTH(HOY(), 0)-HOY()

Cómo encontrar el primer día del mes en Excel

Como ya sabes, Microsoft Excel sólo proporciona una función para devolver el último día del mes (EOMONTH). Cuando se trata del primer día del mes, hay más de una forma de obtenerlo.

Ejemplo 1. Obtener el primer día del mes por el número de mes

Si tiene el número de mes, utilice una fórmula DATE sencilla como ésta:

Por ejemplo, =DATE(2015, 4, 1) devolverá 1-Abr-15.

Si sus números se encuentran en una columna determinada, por ejemplo en la columna A, puede añadir una referencia de celda directamente en la fórmula:

=FECHA(2015, B2, 1)

Ejemplo 2. Obtener el primer día del mes a partir de una fecha

Si desea calcular el primer día del mes basándose en una fecha, puede utilizar de nuevo la función FECHA de Excel, pero esta vez necesitará también la función MES para extraer el número del mes:

Por ejemplo, la siguiente fórmula devolverá el primer día del mes basándose en la fecha de la celda A2:

=DATE(2015,MONTH(A2),1)

Ejemplo 3. Buscar el primer día del mes basándose en la fecha actual

Cuando sus cálculos se basen en la fecha de hoy, utilice un enlace del programa Excel EOMONTH y funciones HOY:

=EOMONTH(HOY(),0) +1 - vuelve el día 1 del mes siguiente.

Como recordará, ya utilizamos una fórmula EOMONTH similar para obtener el último día del mes actual. Y ahora, basta con añadir 1 a esa fórmula para obtener el primer día del mes siguiente.

De forma similar, puede obtener el primer día del mes anterior y del mes en curso:

=EOMONTH(HOY(),-2) +1 - devuelve el día 1 del mes anterior.

=EOMONTH(HOY(),-1) +1 - devuelve el día 1 del mes en curso.

También puede utilizar el programa Excel FECHA para manejar esta tarea, aunque las fórmulas serían un poco más largas. Por ejemplo, ¿adivina qué hace la siguiente fórmula?

=FECHA(AÑO(HOY()), MES(HOY()), 1)

Sí, devuelve el primer día del mes en curso.

¿Y cómo se fuerza a que devuelva el primer día del mes siguiente o anterior? Sin duda :) Basta con sumar o restar 1 al/del mes actual:

A devolver el primer día del mes siguiente:

=FECHA(AÑO(HOY()), MES(HOY())+1, 1)

Para volver al primer día del mes anterior:

=FECHA(AÑO(HOY()), MES(HOY())-1, 1)

Cómo calcular el número de días de un mes

En Microsoft Excel existen diversas funciones para trabajar con fechas y horas. Sin embargo, carece de una función para calcular el número de días de un mes determinado, por lo que tendremos que suplir esa omisión con nuestras propias fórmulas.

Ejemplo 1. Obtener el número de días en función del número de mes

Si conoce el número del mes, la siguiente fórmula DÍA / FECHA le devolverá el número de días de ese mes:

En la fórmula anterior, la función FECHA devuelve el primer día del mes siguiente, al que se le resta 1 para obtener el último día del mes deseado y, a continuación, la función DÍA convierte la fecha en un número de día.

Por ejemplo, la siguiente fórmula devuelve el número de días de abril (el 4º mes del año).

=DÍA(FECHA(2015, 4 +1, 1) -1)

Ejemplo 2. Obtener el número de días de un mes en función de la fecha

Si no conoce el número de un mes pero tiene una fecha cualquiera dentro de ese mes, puede utilizar las funciones AÑO y MES para extraer el número de año y mes de la fecha. Sólo tiene que incrustarlos en la fórmula DÍA / FECHA comentada en el ejemplo anterior, y le dirá cuántos días contiene un mes determinado:

=DÍA(FECHA(AÑO(A2), MES(A2) +1, 1) -1)

Donde A2 es la celda con una fecha.

Como alternativa, puede utilizar una fórmula DAY / EOMONTH mucho más sencilla. Como recordará, la función EOMONTH de Excel devuelve el último día del mes, por lo que no necesita ningún cálculo adicional:

=DÍA(EOMONTH(A1, 0))

La siguiente captura de pantalla muestra los resultados devueltos por todas las fórmulas, y como puede ver son idénticos:

Cómo sumar datos por mes en Excel

En una tabla grande con muchos datos, a menudo puede ser necesario obtener la suma de los valores de un mes determinado. Y esto puede ser un problema si los datos no se introdujeron en orden cronológico.

La solución más sencilla es añadir una columna de ayuda con una sencilla fórmula de Excel MES que convertirá las fechas en números de mes. Por ejemplo, si las fechas están en la columna A, utilice = MES(A2).

Y ahora, escriba una lista de números (del 1 al 12, o sólo los números de los meses que le interesen) en una columna vacía, y sume los valores de cada mes utilizando una fórmula SUMIF similar a ésta:

=SUMIF(C2:C15, E2, B2:B15)

Donde E2 es el número de mes.

La siguiente captura de pantalla muestra el resultado de los cálculos:

Si prefiere no añadir una columna de ayuda a su hoja Excel, no hay problema, puede prescindir de ella. Una función SUMPRODUCT un poco más complicada funcionará a las mil maravillas:

=SUMPRODUCTO((MES($A$2:$A$15)=$E2) * ($B$2:$B$15))

Donde la columna A contiene fechas, la columna B contiene los valores a sumar y E2 es el número de mes.

Nota: tenga en cuenta que las dos soluciones anteriores suman todos los valores de un mes determinado, independientemente del año. Por lo tanto, si su hoja de cálculo de Excel contiene datos de varios años, se sumarán todos.

Cómo formatear condicionalmente fechas en función del mes

Ahora que ya sabe cómo utilizar las funciones MES y EOMESTRE de Excel para realizar diversos cálculos en sus hojas de cálculo, puede dar un paso más y mejorar la presentación visual. Para ello, vamos a utilizar las capacidades del formato condicional de Excel para las fechas.

Además de los ejemplos proporcionados en el artículo mencionado anteriormente, ahora le mostraré cómo puede resaltar rápidamente todas las celdas o filas enteras relacionadas con un mes determinado.

Ejemplo 1. Resaltar fechas del mes en curso

En la tabla del ejemplo anterior, supongamos que desea resaltar todas las filas con las fechas del mes en curso.

En primer lugar, se extraen los números de mes de las fechas de la columna A utilizando la fórmula más sencilla =MONTH($A2). A continuación, se comparan esos números con el mes actual devuelto por =MONTH(TODAY()). Como resultado, se obtiene la siguiente fórmula que devuelve TRUE si los números de los meses coinciden, FALSE en caso contrario:

=MES($A2)=MES(HOY())

Cree una regla de formato condicional de Excel basada en esta fórmula, y su resultado puede parecerse a la captura de pantalla siguiente (el artículo se escribió en abril, por lo que todas las fechas de abril aparecen resaltadas).

Ejemplo 2. Resaltar fechas por mes y día

Y he aquí otro reto. Supongamos que quieres destacar en tu hoja de cálculo los días festivos más importantes independientemente del año. Pongamos los días de Navidad y Año Nuevo. ¿Cómo enfocarías esta tarea?

Simplemente utilice la función DÍA de Excel para extraer el día del mes (1 - 31) y la función MES para obtener el número del mes, y luego compruebe si el DÍA es igual a 25 o 31, y si el MES es igual a 12:

=AND(OR(DÍA($A2)=25, DÍA($A2)=31), MES(A2)=12)

Así funciona la función MES en Excel. Parece ser mucho más versátil de lo que parece, ¿eh?

En un par de los próximos posts, vamos a calcular semanas y años y espero que aprendas algunos trucos útiles más. Si te interesan las unidades de tiempo más pequeñas, consulta las partes anteriores de nuestra serie Fechas en Excel (encontrarás los enlaces más abajo). Te doy las gracias por leer y ¡espero verte la semana que viene!