Tha an oideachadh a’ mìneachadh na cnothan is na buillean ann an gnìomhan Excel MONTH agus EOMONTH. Lorgaidh tu sreath de eisimpleirean foirmle a sheallas mar a tharraing thu mìos bhon cheann-latha ann an Excel, faigh a’ chiad latha agus an latha mu dheireadh den mhìos, atharraich ainm mìos gu àireamh agus barrachd.

San artaigil roimhe, rannsaich sinn grunn fhoirmlean gus làithean seachdaineach obrachadh a-mach. An-diugh, tha sinn gu bhith ag obair air aonad ùine nas motha agus ionnsaichidh sinn na gnìomhan a bheir Microsoft Excel seachad airson mìosan.

San oideachadh seo, ionnsaichidh tu:

Excel Gnìomh MIS - co-chòrdadh agus cleachdadh

Tha Microsoft Excel a’ toirt seachad gnìomh MIS sònraichte gus mìos a thoirt a-mach às a’ cheann-latha, a thilleas àireamh na mìos eadar 1 (Faoilleach) gu 12 (Dùbhlachd).

An Faodar gnìomh MIS a chleachdadh anns a h-uile tionndadh de Excel 2016 - 2000 agus tha an co-chòrdadh aige cho sìmplidh 's as urrainn dha a bhith:

Far a bheil serial_number na cheann-latha dligheach sam bith den mhìos a tha thu a 'feuchainn ri lorg.

Airson an obair cheart air foirmlean Excel MIS, bu chòir ceann-latha a chuir a-steach le bhith a’ cleachdadh an gnìomh DATE (bliadhna, mìos, latha). Mar eisimpleir, tha am foirmle =MONTH(DATE(2015,3,1)) a’ tilleadh 3 leis gu bheil DATE a’ riochdachadh 1d latha den Mhàrt, 2015.

Bidh foirmlean mar =MONTH("1-Mar-2015") cuideachd ag obair gu math, ged a dh’ fhaodadh duilgheadasan èirigh ann an suidheachaidhean nas iom-fhillte ma thèid cinn-latha a chuir a-steach mar theacsa.

Ann an cleachdadh, an àite ceann-latha a shònrachadh taobh a-staigh gnìomh MIS, tha e nas fhasa iomradh a thoirt air cealla le ceann-latha nognìomhan MONTH agus EOMONTH gus diofar àireamhachadh a dhèanamh anns na duilleagan-obrach agad, faodaidh tu ceum nas fhaide a ghabhail agus an taisbeanadh lèirsinneach adhartachadh. Airson seo, tha sinn gu bhith a’ cleachdadh comasan fòrmatadh cumhach Excel airson cinn-latha.

A bharrachd air na h-eisimpleirean anns an artaigil gu h-àrd, seallaidh mi dhut a-nis mar as urrainn dhut a h-uile cealla no sreath slàn a shoilleireachadh gu sgiobalta. co-cheangailte ri mìos sònraichte.

Eisimpleir 1. Comharraich cinn-latha taobh a-staigh na mìosa seo

Sa chlàr bhon eisimpleir roimhe, saoil gu bheil thu airson gach sreath a chomharrachadh le cinn-latha na mìosa làithreach.<3

An toiseach dheth, bheir thu a-mach àireamhan nam mìos à cinn-latha ann an colbh A a’ cleachdadh na foirmle as sìmplidhe =MONTH($A2). Agus an uairsin, bidh thu a’ dèanamh coimeas eadar na h-àireamhan sin agus a’ mhìos a th’ air a thilleadh le = MIS (TODAY()). Mar thoradh air an sin, tha am foirmle a leanas agad a thilleas TRUE ma tha àireamhan nam mìosan a’ maidseadh, FALSE air dhòigh eile:

=MONTH($A2)=MONTH(TODAY())

Cruthaich riaghailt cruth cumhach Excel stèidhichte air an fhoirmle seo, agus faodaidh an toradh agad coltach ris an dealbh-sgrìn gu h-ìosal (chaidh an artaigil a sgrìobhadh sa Ghiblean, agus mar sin tha cinn-latha Giblean air fad air an comharrachadh).

Eisimpleir 2. A’ comharrachadh cinn-latha a rèir mìos is latha

Agus seo dùbhlan eile. Seach gu bheil thu airson na prìomh shaor-làithean a chomharrachadh air an duilleag-obrach agad ge bith dè a’ bhliadhna. Canaidh sinn làithean na Nollaige agus na Bliadhn’ Ùire. Ciamar a dhèiligeadh tu ris a’ ghnìomh seo?

Dìreach cleachd an gnìomh Excel DAY guthoir a-mach latha na mìos (1 - 31) agus an gnìomh MIS gus àireamh na mìos fhaighinn, agus an uairsin dèan cinnteach a bheil an LATHA co-ionann ri 25 no 31, agus ma tha a’ MHIS co-ionann ri 12:

=AND(OR(DAY($A2)=25, DAY($A2)=31), MONTH(A2)=12)

Seo mar a tha gnìomh MIS ann an Excel ag obair. Tha e coltach gu bheil e fada nas ioma-chruthach na tha e a’ coimhead, huh?

Ann an ath phost no dhà, tha sinn gu bhith a’ tomhas seachdainean is bliadhnaichean agus an dòchas gun ionnsaich thu beagan chleasan feumail eile. Ma tha ùidh agad ann an aonadan ùine nas lugha, thoir sùil air na pàirtean roimhe seo den t-sreath Excel Dates againn (gheibh thu na ceanglaichean gu h-ìosal). Tha mi a’ toirt taing dhut airson an leughadh agus an dòchas ur faicinn an ath sheachdain!

=MONTH(A1) - a' tilleadh mìos ceann-latha ann an ceal A1.

=MONTH(TODAY()) - a' tilleadh àireamh na mìos làithreach.

Aig a' chiad sealladh, an Excel MONTH faodaidh gnìomh coimhead soilleir. Ach seall tro na h-eisimpleirean gu h-ìosal agus bidh iongnadh ort cia mheud rud feumail as urrainn dha a dhèanamh.

Mar a gheibh thu àireamh mìos bhon cheann-latha ann an Excel

Tha grunn dhòighean ann mìos fhaighinn bhon cheann-latha ann an Excel. Bidh am fear a thaghas tu an urra ri dè dìreach an toradh a tha thu a’ feuchainn ri choileanadh.

Gnìomh MIS ann an Excel - faigh àireamh mìos bhon cheann-latha

Seo am fear as fhollaisiche agus as fhasa dòigh air ceann-latha atharrachadh gu mìos ann an Excel. Mar eisimpleir:

• =MONTH(A2) - tilleadh mìos ceann-latha ann an ceal A2.
• =MONTH(DATE(2015,4,15)) - tilleadh 4 a' freagairt ris a' Ghiblean.
• =MONTH("15-Apr-2015") - gu follaiseach, tillidh an àireamh 4 cuideachd.

Gnìomh TEXT ann an Excel - thoir a-mach mìos mar shreang teacsa

Tha dòigh eile air àireamh mìos fhaighinn bho cheann-latha Excel a’ cleachdadh an Gnìomh TEXT:

• =TEXT(A2, "m") - tilleadh àireamh mìos gun phrìomh neoni, mar 1 - 12.
• =TEXT(A2,"mm") - tilleadh àireamh mìos le prìomh neoni, mar 01 - 12.

Feuch gum bi thu faiceallach nuair a bhios tu a’ cleachdadh foirmlean TEXT, oir bidh iad an-còmhnaidh a’ tilleadh àireamhan mìos mar shreathan teacsa. Mar sin, ma tha thu an dùil beagan àireamhachadh a bharrachd a dhèanamh no na h-àireamhan a chaidh a thilleadh a chleachdadh ann am foirmlean eile, b’ fheàrr dhut cumail ris an Excel MONTHfunction.

Seallaidh an dealbh-sgrìn a leanas na toraidhean a thàinig air ais leis na foirmlean gu h-àrd uile. Thoir an aire gu bheil co-thaobhadh ceart nan àireamhan air an tilleadh leis a’ ghnìomh MONTH (ceallan C2 agus C3) an taca ri luachan teacsa co-thaobhadh clì air an tilleadh leis na gnìomhan TEXT (ceallan C4 agus C5).

Mar a bheir thu a-mach ainm mìos bhon cheann-latha ann an Excel

Air eagal gu bheil thu airson ainm mìos seach àireamh fhaighinn, cleachdaidh tu an gnìomh TEXT a-rithist, ach le còd ceann-latha eile:

• =TEXT(A2, "mmm") - a' tilleadh ainm mìos giorraichte, mar Faoilleach - Dùbhlachd
• =TEXT(A2,"mmmm") - a' tilleadh ainm mìos slàn, mar Faoilleach - Dùbhlachd.

Mura h-eil thu dha-rìribh ag iarraidh ceann-latha atharrachadh gu mìos anns an duilleag-obrach Excel agad, tha thu dìreach airson ainm mìos a thaisbeanadh a-mhàin an àite a’ cheann-latha slàn, mar sin chan eil thu ag iarraidh foirmlean sam bith.

Tagh ceal(an) le cinn-latha, brùth Ctrl+1 gus an còmhradh Format Cells fhosgladh. Air an taba Àireamh , tagh Custom agus taidhp an dàrna cuid “mmm” no “mmmm” sa bhogsa Type gus ainmean giorraichte no làn mhìos a thaisbeanadh, fa leth. Anns a 'chùis seo, bidh na h-inntrigidhean agad fhathast nan cinn-latha Excel làn-ghnìomhach as urrainn dhut a chleachdadh ann an àireamhachadh agus foirmlean eile. Airson tuilleadh fiosrachaidh mu bhith ag atharrachadh cruth ceann-latha, faic Cruthachadh cruth ceann-latha àbhaisteach ann an Excel. Osbarr, tha liosta àireamhan agad (1 tro 12)anns an duilleag-obrach Excel agad a tha thu airson a thionndadh gu ainmean mìos. Gus seo a dhèanamh, faodaidh tu gin dhe na foirmlean a leanas a chleachdadh:

Gus ainm mìos giorraichte (Faoilleach - Dùbhlachd) a thilleadh:

=TEXT(A2*28, "mmm")

=TEXT(DATE(2015, A2, 1), "mmm")

Gus ainm mìos slàn a thilleadh (Faoilleach - Dùbhlachd):

=TEXT(A2*28, "mmmm")

=TEXT(DATE(2015, A2, 1), "mmmm")

Anns na foirmlean gu h-àrd uile, A2 tha e na chill le àireamh mìos. Agus is e an aon fhìor eadar-dhealachadh eadar na foirmlean còdan na mìosa:

• "mmm" - giorrachadh 3-litir den mhìos, leithid Faoilleach - Dùbhlachd
• "mmmm" - mìos air a litreachadh gu tur
• "mmmmm" - a' chiad litir dhen ainm mìos

Mar a tha na foirmlean seo ag obair

Nuair a thèid an cleachdadh còmhla ri còdan cruth mìos mar “mmm” agus “mmmm”, tha Excel a’ beachdachadh air an àireamh 1 mar Latha 1 san Fhaoilleach 1900. Ag iomadachadh 1, 2, 3 msaa le 28, tha thu a’ faighinn Làithean 28, 56, 84, msaa. den bhliadhna 1900, a tha san Fhaoilleach, sa Ghearran, sa Mhàrt, msaa. Chan eil an còd cruth "mmm" no "mmmm" a' sealltainn ach ainm na mìos.

Mar a dh'atharraicheas tu ainm na mìos gu àireamh ann an Excel

Tha dà ghnìomh Excel ann a chuidicheas tu gus ainmean mìos a thionndadh gu àireamhan - DATEVALUE agus MIS. Bidh gnìomh DATEVALUE aig Excel ag atharrachadh ceann-latha a tha air a stòradh mar theacsa gu àireamh sreathach a dh’ aithnicheas Microsoft Excel mar cheann-latha. Agus an uairsin, bidh an gnìomh MIS a’ toirt a-mach àireamh mìos bhon cheann-latha sin.

Tha am foirmle iomlan mar a leanas:

=MONTH(DATEVALUE(A2 & "1"))

Far a bheil A2 ann an cealla anns a bheil ainm na mìostha thu airson àireamh a thionndadh (tha &"1" air a chur ris airson an gnìomh DATEVALUE gus tuigsinn gur e ceann-latha a th’ ann).

Mar a gheibh thu an latha mu dheireadh dhen mhìos ann Excel (gnìomh EOMONTH)

Tha an gnìomh EOMONTH ann an Excel air a chleachdadh gus an latha mu dheireadh den mhìos a thilleadh stèidhichte air a’ cheann-latha tòiseachaidh ainmichte. Tha na h-argamaidean a leanas aige, agus tha an dà chuid a dhìth:

• Start_date - an ceann-latha tòiseachaidh no iomradh air cealla air a bheil an ceann-latha tòiseachaidh.
• Mìosan - an àireamh de mhìosan ron cheann-latha tòiseachaidh no às a dhèidh. Cleachd luach dearbhach airson cinn-latha san àm ri teachd agus luach àicheil airson cinn-latha a dh’ fhalbh.

Seo beagan eisimpleirean de fhoirmle EOMONTH:

=EOMONTH(A2, 1) - a’ tilleadh an latha mu dheireadh den mhìos, mìos às deidh sin an ceann-latha ann an ceal A2.

=EOMONTH(A2, -1) - tilleadh an latha mu dheireadh den mhìos, mìos ron cheann-latha ann an ceal A2.

An àite iomradh cill, is urrainn dhut ceann-latha a chòdachadh gu cruaidh nad Foirmle EOMONTH. Mar eisimpleir, tillidh an dà fhoirmle gu h-ìosal an latha mu dheireadh sa Ghiblean.

=EOMONTH("15-Apr-2015", 0)

=EOMONTH(DATE(2015,4,15), 0)

Gus an latha mu dheireadh den mhìos làithreach a thilleadh , bidh thu a’ cleachdadh a’ ghnìomh TODAY() anns a’ chiad argamaid den fhoirmle EOMONTH agad gus an tèid ceann-latha an latha an-diugh a ghabhail mar an ceann-latha tòiseachaidh. Agus, chuir thu 0 anns an argamaid months a chionn 's nach eil thu airson a' mhìos atharrachadh an dara dòigh.

=EOMONTH(TODAY(), 0)

An aire. Leis gu bheil gnìomh Excel EOMONTH a’ tilleadh an àireamh sreathach a tha a’ riochdachadh a’ chinn-latha, tha agadgus cruth ceann-latha a chuir an sàs ann an cealla(an) leis na foirmlean agad. Faic mar a dh’ atharraicheas tu cruth ceann-latha ann an Excel airson na ceumannan mionaideach.

Agus seo na toraidhean a thill na foirmlean Excel EOMONTH air an deach beachdachadh gu h-àrd:

Ma tha thu airson obrachadh a-mach cia mheud latha a tha air fhàgail gu deireadh na mìos seo, tha thu dìreach a’ toirt air falbh an ceann-latha air a thilleadh le TODAY() bhon cheann-latha a thill EOMONTH agus a’ cur an cruth Coitcheann gu cealla:

=EOMONTH(TODAY(), 0)-TODAY()

Mar a lorgas tu a’ chiad latha den mhìos ann an Excel<7

Mar a tha fios agad mu thràth, tha Microsoft Excel a’ toirt seachad dìreach aon ghnìomh gus an latha mu dheireadh den mhìos (EOMONTH) a thilleadh. Nuair a thig e chun a' chiad latha dhen mhìos, tha barrachd air aon dòigh air fhaighinn.

Eisimpleir 1. Faigh a' chiad latha dhen mhìos a rèir àireamh na mìosa

Ma tha an àireamh mìos, an uairsin cleachd foirmle DATE sìmplidh mar seo:

Mar eisimpleir, =DATE(2015, 4, 1) tillidh e 1-Apr-15.

Ma tha na h-àireamhan agad suidhichte ann an colbh sònraichte, abair ann an colbh A, faodaidh tu iomradh cealla a chuir gu dìreach san fhoirmle:

=DATE(2015, B2, 1)

Eisimpleir 2. Faigh a’ chiad latha dhen mhìos bho cheann-latha

Ma tha thu airson a’ chiad latha den mhìos obrachadh a-mach stèidhichte air ceann-latha, faodaidh tu cleachd an gnìomh Excel DATE a-rithist, ach an turas seo bidh feum agad air a’ ghnìomh MIS cuideachd gus àireamh na mìos a thoirt a-mach:

Airsonmar eisimpleir, tillidh am foirmle a leanas a' chiad latha dhen mhìos stèidhichte air a' cheann-là ann an ceal A2:

=DATE(2015,MONTH(A2),1)

Eisimpleir 3. Lorg a' chiad latha den mhìos stèidhichte air a’ cheann-latha làithreach

Nuair a bhios an àireamhachadh agad stèidhichte air ceann-latha an latha an-diugh, cleachd ceangal de na gnìomhan Excel EOMONTH agus AN-DIUGH:

=EOMONTH(TODAY(),0) +1 - tillidh tu an 1d latha dhen ath mhìos.

Mar a chuimhnicheas tu, chleachd sinn foirmle coltach ri EOMONTH mu thràth airson an latha mu dheireadh den mhìos seo fhaighinn. Agus a-nis, cha leig thu leas ach 1 a chur ris an fhoirmle sin gus a’ chiad latha den ath mhìos fhaighinn.

San aon dòigh, gheibh thu a’ chiad latha den mhìos roimhe agus an-dràsta:

=EOMONTH(TODAY(),-2) +1 - tilleadh a' chiad latha dhen mhìos roimhe.

=EOMONTH(TODAY(),-1) +1 - tilleadh a' chiad latha dhen mhìos seo chaidh.

Dh'fhaodadh tu cuideachd an gnìomh Excel DATE a chleachdadh gus a làimhseachadh an obair seo, ged a bhiodh na foirmlean beagan nas fhaide. Mar eisimpleir, dèan tomhas dè tha am foirmle a leanas a’ dèanamh?

=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)

Seadh, bidh e a’ tilleadh a’ chiad latha den mhìos seo.

Agus ciamar a bheir thu air am faidhle a thilleadh a’ chiad latha den ath mhìos no den mhìos roimhe? Làmhan sìos :) Dìreach cuir ris no thoir air falbh 1 gu/bhon mhìos làithreach:

Gus a’ chiad latha den ath mhìos a thilleadh:

=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)

Airson a’ chiad latha a thilleadh den mhìos roimhe:

=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)

Mar a nì thu obrachadh a-mach an àireamh de làithean ann am mìos

Ann am Microsoft Excel, tha grunn ghnìomhan ann airson obrachadh le cinn-latha agusamannan. Ach, chan eil gnìomh aige airson obrachadh a-mach an àireamh de làithean ann am mìos sònraichte. Mar sin, feumaidh sinn dèanamh suas airson an dearmad sin leis na foirmlean againn fhèin.

Eisimpleir 1. Airson àireamh nan làithean fhaighinn stèidhichte air àireamh na mìos

Mas aithne dhut àireamh na mìosa, tillidh am foirmle DAY/DATE a leanas an àireamh de làithean sa mhìos sin:

Anns an fhoirmle gu h-àrd, bidh an gnìomh DATE a’ tilleadh a’ chiad latha den ath mhìos, às an toir thu air falbh 1 gus an latha mu dheireadh den mhìos a tha thu ag iarraidh fhaighinn. Agus an uairsin, bidh gnìomh DAY ag atharrachadh a’ chinn-latha gu àireamh latha.

Mar eisimpleir, tha an fhoirmle a leanas a’ tilleadh an àireamh de làithean sa Ghiblean (an 4mh mìos sa bhliadhna).

=DAY(DATE(2015, 4 +1, 1) -1)

Eisimpleir 2. Airson an àireamh de làithean ann am mìos fhaighinn stèidhichte air a' cheann-latha

Mura h-eil fios agad air àireamh mìos ach gu bheil ceann-latha sam bith agad taobh a-staigh na mìos sin, faodaidh tu BLIADHNA agus MIS a chleachdadh gnìomhan gus an àireamh bliadhna is mìos a thoirt a-mach às a’ cheann-latha. Dìreach cuir a-steach iad san fhoirmle DAY / DATE air a bheilear a’ beachdachadh san eisimpleir gu h-àrd, agus innsidh e dhut cia mheud latha anns a’ mhìos a chaidh a thoirt seachad:

=DAY(DATE(YEAR(A2), MONTH(A2) +1, 1) -1)

Far a bheil A2 na chealla le ceann-latha.

Air an làimh eile, faodaidh tu foirmle DAY / EOMONTH tòrr nas sìmplidh a chleachdadh. Mar a chuimhnicheas tu, tillidh an gnìomh Excel EOMONTH an latha mu dheireadh den mhìos, agus mar sin cha bhith feum agad air àireamhachadh a bharrachd:

=DAY(EOMONTH(A1, 0))

Tha an dealbh-sgrìn a leanas a’ sealltainn antoraidhean air an tilleadh leis na foirmlean gu lèir, agus mar a chì thu tha iad co-ionann:

Mar a nì thu suim dàta a rèir mìos ann an Excel

Ann an clàr mòr le tòrr dàta, is dòcha gu feum thu gu tric suim luachan fhaighinn airson mìos sònraichte. Agus dh'fhaodadh seo a bhith na dhuilgheadas mura deach an dàta a chur a-steach ann an òrdugh a rèir eachdraidh.

'S e am fuasgladh as fhasa colbh cuideachaidh a chur ris le foirmle sìmplidh Excel MONTH a dh'atharraicheas cinn-latha gu àireamhan mìos. Abair, ma tha na cinn-latha agad ann an colbh A, bidh thu a’ cleachdadh =MONTH(A2).

Agus a-nis, sgrìobh sìos liosta àireamhan (bho 1 gu 12, no dìreach na h-àireamhan mìos sin anns a bheil ùidh agad). ) ann an colbh falamh, agus luachan sùim airson gach mìos a’ cleachdadh foirmle SUMIF coltach ri seo:

=SUMIF(C2:C15, E2, B2:B15)

Càit a bheil E2 àireamh na mìos.

Tha an dealbh-sgrìn a leanas a’ sealltainn toradh an àireamhachaidh:

Mura bheil thu airson colbh cuideachaidh a chur ris an duilleag Excel agad, gun duilgheadas sam bith, faodaidh tu sin a dhèanamh às aonais. Obraichidh gnìomh SUMPRODUCT beagan nas duilghe:

=SUMPRODUCT((MONTH($A$2:$A$15)=$E2) * ($B$2:$B$15))

Far a bheil cinn-latha ann an colbh A, tha na luachan ann an colbh B gu suim agus is e E2 àireamh na mìos.

Thoir an aire. Feuch an cuimhnich thu gu bheil an dà fhuasgladh gu h-àrd a’ cur suas a h-uile luach airson mìos sònraichte ge bith dè a’ bhliadhna. Mar sin, ma tha dàta anns an duilleag-obrach Excel agad airson grunn bhliadhnaichean, thèid a h-uile càil a thoirt seachad.

Mar a chuireas tu cinn-latha ann an cruth cumhach stèidhichte air mìos

A-nis gu bheil fios agad mar a chleachdas tu an Excel