Udhëzuesi shpjegon lidhjet dhe bulonat e funksioneve të Excel MONTH dhe EOMONTH. Ju do të gjeni një sërë shembujsh formulash që tregojnë se si të nxirrni muajin nga data në Excel, të merrni ditën e parë dhe të fundit të muajit, të konvertoni emrin e muajit në numër dhe më shumë.

Në artikullin e mëparshëm, ne kemi eksploruar një sërë formulash për të llogaritur ditët e javës. Sot, ne do të operojmë në një njësi më të madhe kohore dhe do të mësojmë funksionet që Microsoft Excel ofron për muaj të tërë.

Në këtë tutorial, do të mësoni:

Excel Funksioni MONTH - sintaksa dhe përdor

Microsoft Excel ofron një funksion të veçantë MUAJ për të nxjerrë një muaj nga data, i cili kthen numrin e muajit që varion nga 1 (janar) deri në 12 (dhjetor).

Funksioni MONTH mund të përdoret në të gjitha versionet e Excel 2016 - 2000 dhe sintaksa e tij është aq e thjeshtë sa mund të jetë:

Ku serial_number është çdo datë e vlefshme e muajit që po përpiqeni të gjeni.

Për punën e saktë të formulave të Excel MUAJ, duhet të futet një datë duke përdorur funksionin DATE (viti, muaji, ditë). Për shembull, formula =MONTH(DATE(2015,3,1)) kthen 3 pasi DATE përfaqëson ditën e 1 marsit 2015.

Formulat si =MONTH("1-Mar-2015") gjithashtu funksionojnë mirë, megjithëse mund të shfaqen probleme në skenarë më komplekse nëse datat futen si tekst.

Në praktikë, në vend që të specifikoni një datë brenda funksionit MUAJ, është më e përshtatshme t'i referoheni një qelize me një datë oseFunksionet MUAJ dhe EOMONTH për të kryer llogaritje të ndryshme në fletët tuaja të punës, mund të bëni një hap më tej dhe të përmirësoni paraqitjen vizuale. Për këtë, ne do të përdorim aftësitë e formatimit të kushtëzuar të Excel për datat.

Përveç shembujve të dhënë në artikullin e lartpërmendur, tani do t'ju tregoj se si mund t'i nënvizoni shpejt të gjitha qelizat ose rreshtat e tëra lidhur me një muaj të caktuar.

Shembulli 1. Theksoni datat brenda muajit aktual

Në tabelën nga shembulli i mëparshëm, supozoni se dëshironi të nënvizoni të gjitha rreshtat me datat e muajit aktual.

Së pari, ju nxjerrni numrat e muajve nga datat në kolonën A duke përdorur formulën më të thjeshtë =MONTH($A2). Dhe më pas, ju i krahasoni ato numra me muajin aktual të kthyer nga =MONTH(TODAY()). Si rezultat, ju keni formulën e mëposhtme që kthen TRUE nëse numrat e muajve përputhen, FALSE ndryshe:

=MONTH($A2)=MONTH(TODAY())

Krijoni një rregull të formatimit të kushtëzuar të Excel bazuar në këtë formulë dhe rezultati juaj mund të ngjajnë me pamjen e mëposhtme të ekranit (artikulli është shkruar në prill, kështu që të gjitha datat e prillit janë të theksuara).

Shembulli 2. Theksimi i datave sipas muajit dhe ditës

Dhe këtu është një sfidë tjetër. Supozoni se dëshironi të nënvizoni festat kryesore në fletën tuaj të punës pavarësisht nga viti. Le të themi ditët e Krishtlindjeve dhe Vitit të Ri. Si do t'i qaseni kësaj detyre?

Thjesht përdorni funksionin Excel DAY për tënxirrni ditën e muajit (1 - 31) dhe funksionin MUAJ për të marrë numrin e muajit, dhe më pas kontrolloni nëse DITA është e barabartë me 25 ose 31, dhe nëse MUAJI është i barabartë me 12:

=AND(OR(DAY($A2)=25, DAY($A2)=31), MONTH(A2)=12)

Kështu funksionon funksioni MUAJ në Excel. Duket se është shumë më i gjithanshëm nga sa duket, apo jo?

Në disa postime të ardhshme, ne do të llogarisim javët dhe vitet dhe shpresojmë se do të mësoni disa truke më të dobishme. Nëse jeni të interesuar për njësi më të vogla kohore, ju lutemi shikoni pjesët e mëparshme të serisë sonë të Data Excel (do të gjeni lidhjet më poshtë). Ju falënderoj që lexoni dhe shpresoj të shihemi javën tjetër!

=MONTH(A1) - kthen muajin e një date në qelizën A1.

=MONTH(TODAY()) - kthen numrin e muajit aktual.

Në pamje të parë, MUAJI Excel funksioni mund të duket i thjeshtë. Por shikoni shembujt e mëposhtëm dhe do të habiteni kur të dini se sa gjëra të dobishme mund të bëjë në të vërtetë.

Si të merrni numrin e muajit nga data në Excel

Ka disa mënyra për të marrë muajin nga data në Excel. Cilin të zgjidhni varet saktësisht nga rezultati që po përpiqeni të arrini.

Funksioni MUAJ në Excel - merrni numrin e muajit nga data

Ky është më i dukshëm dhe më i lehtë mënyra për të kthyer datën në muaj në Excel. Për shembull:

• =MONTH(A2) - kthen muajin e një date në qelizën A2.
• =MONTH(DATE(2015,4,15)) - kthen 4 që korrespondon me prillin.
• =MONTH("15-Apr-2015") - padyshim, kthen numrin 4 gjithashtu.

Funksioni TEXT në Excel - nxjerr muajin si varg teksti

Një mënyrë alternative për të marrë një numër muaji nga një datë Excel është përdorimi i Funksioni TEXT:

• =TEXT(A2, "m") - kthen një numër muaji pa një zero të parë, si 1 - 12.
• =TEXT(A2,"mm") - kthen një numër muaji me një zero të parë, si 01 - 12.

Ju lutemi të jeni shumë të kujdesshëm kur përdorni formulat TEXT, sepse ato gjithmonë kthejnë numrat e muajve si vargje teksti. Pra, nëse planifikoni të kryeni disa llogaritje të mëtejshme ose të përdorni numrat e kthyer në formula të tjera, është më mirë t'i përmbaheni MUAJIT të Excelfunksioni.

Pamja e mëposhtme e ekranit tregon rezultatet e kthyera nga të gjitha formulat e mësipërme. Ju lutemi vini re shtrirjen e djathtë të numrave të kthyer nga funksioni MONTH (qelizat C2 dhe C3) në krahasim me vlerat e tekstit të rreshtuara majtas të kthyera nga funksionet TEXT (qelizat C4 dhe C5).

Si të nxirrni emrin e muajit nga data në Excel

Në rast se dëshironi të merrni një emër muaji në vend të një numri, ju përdorni përsëri funksionin TEXT, por me një kod tjetër të datës:

• =TEXT(A2, "mmm") - kthen një emër muaji të shkurtuar, si Jan - Dhjetor
• =TEXT(A2,"mmmm") - kthen një emër të plotë muaji, si Janar - Dhjetor.

Nëse në fakt nuk dëshironi të konvertoni datën në muaj në fletën tuaj të punës në Excel, thjesht dëshironi të shfaqni emrin e muajit vetëm në vend të datës së plotë, atëherë nuk dëshironi çdo formula.

Zgjidhni një qelizë me data, shtypni Ctrl+1 për të hapur dialogun Formatoni qelizat . Në skedën Numri , zgjidhni Personalizuar dhe shkruani "mmm" ose "mmmm" në kutinë Lloji për të shfaqur përkatësisht emrat e shkurtuar ose të plotë të muajve. Në këtë rast, shënimet tuaja do të mbeten plotësisht funksionale datat e Excel që mund t'i përdorni në llogaritjet dhe formulat e tjera. Për më shumë detaje rreth ndryshimit të formatit të datës, ju lutemi shihni Krijimi i një formati të personalizuar të datës në Excel.

Si të konvertoni numrin e muajit në emrin e muajit në Excel

Supozoni, ju keni një listë me numra (1 deri në 12)në fletën tuaj të punës në Excel që dëshironi ta konvertoni në emra muajsh. Për ta bërë këtë, mund të përdorni ndonjë nga formulat e mëposhtme:

Për të kthyer një emër të shkurtuar muaji (Jan - Dhjetor):

=TEXT(A2*28, "mmm")

=TEXT(DATE(2015, A2, 1), "mmm")

Për të kthyer një emër të plotë muaji (janar - dhjetor):

=TEXT(A2*28, "mmmm")

=TEXT(DATE(2015, A2, 1), "mmmm")

Në të gjitha formulat e mësipërme, A2 është një qelizë me një numër muaji. Dhe i vetmi ndryshim i vërtetë midis formulave është kodet e muajit:

• "mmm" - shkurtesa me 3 shkronja e muajit, si p.sh. janar - dhjetor
• "mmmm" - muaj shkruar plotësisht
• "mmmmm" - germa e parë e emrit të muajit

Si funksionojnë këto formula

Kur përdoren së bashku me kodet e formatit të muajit si "mmmm" dhe "mmmm", Excel e konsideron numrin 1 si Ditën 1 në Janar 1900. Duke shumëzuar 1, 2, 3 etj. me 28, ju merrni Ditët 28, 56, 84, etj. të vitit 1900, të cilat janë në janar, shkurt, mars etj. Kodi i formatit "mmmm" ose "mmmm" shfaq vetëm emrin e muajit.

Si të konvertohet emri i muajit në numër në Excel

Ka dy funksione të Excel që mund t'ju ndihmojnë të konvertoni emrat e muajve në numra - DATEVALUE dhe MONTH. Funksioni DATEVALUE i Excel konverton një datë të ruajtur si tekst në një numër serial që Microsoft Excel e njeh si datë. Dhe më pas, funksioni MONTH nxjerr një numër muaji nga ajo datë.

Formula e plotë është si më poshtë:

=MONTH(DATEVALUE(A2 & "1"))

Ku A2 në një qelizë që përmban emrin e muajitju dëshironi të shndërroheni në një numër (&"1" është shtuar për funksionin DATEVALUE për të kuptuar se është një datë).

Si të merrni ditën e fundit të muajit në Excel (funksioni EOMONTH)

Funksioni EOMONTH në Excel përdoret për të kthyer ditën e fundit të muajit bazuar në datën e specifikuar të fillimit. Ai ka argumentet e mëposhtme, të cilat kërkohen të dyja:

• Data_fillimi - data e fillimit ose një referencë për një qelizë me datën e fillimit.
• Muj - numri i muajve para ose pas datës së fillimit. Përdorni një vlerë pozitive për datat e ardhshme dhe një vlerë negative për datat e kaluara.

Këtu janë disa shembuj të formulës EOMONTH:

=EOMONTH(A2, 1) - kthen ditën e fundit të muajit, një muaj pas datën në qelizën A2.

=EOMONTH(A2, -1) - kthen ditën e fundit të muajit, një muaj para datës në qelizën A2.

Në vend të referencës së qelizës, mund të kodoni një datë në kodin tuaj Formula EOMONTH. Për shembull, të dyja formulat e mëposhtme kthehen në ditën e fundit të prillit.

=EOMONTH("15-Apr-2015", 0)

=EOMONTH(DATE(2015,4,15), 0)

Për të kthyer ditën e fundit të muajit aktual , ju përdorni funksionin TODAY() në argumentin e parë të formulës suaj EOMONTH në mënyrë që data e sotme të merret si data e fillimit. Dhe, ju vendosni 0 në argumentin months sepse nuk dëshironi të ndryshoni muajin në asnjë mënyrë.

=EOMONTH(TODAY(), 0)

Shënim. Meqenëse funksioni Excel EOMONTH kthen numrin serial që përfaqëson datën, ju kenipër të aplikuar formatin e datës në një qelizë me formulat tuaja. Ju lutemi shihni Si të ndryshoni formatin e datës në Excel për hapat e detajuar.

Dhe këtu janë rezultatet e kthyera nga formulat e Excel EOMONTH të diskutuara më sipër:

Nëse doni të llogaritni sa ditë kanë mbetur deri në fund të muajit aktual, ju thjesht zbrisni datën e kthyer nga TODAY() nga data e kthyer nga EOMONTH dhe aplikoni formatin e Përgjithshëm në një qelizë:

=EOMONTH(TODAY(), 0)-TODAY()

Si të gjeni ditën e parë të muajit në Excel

Siç e dini tashmë, Microsoft Excel ofron vetëm një funksion për të kthyer ditën e fundit të muajit (EOMONTH). Kur bëhet fjalë për ditën e parë të muajit, ka më shumë se një mënyrë për ta marrë atë.

Shembulli 1. Merrni ditën e parë të muajit sipas numrit të muajit

Nëse keni numrin e muajit, më pas përdorni një formulë të thjeshtë DATE si kjo:

Për shembull, =DATE(2015, 4, 1) do të kthehet 1-prill-15.

Nëse numrat tuaj janë të vendosur në një kolonë të caktuar, le të themi në kolonën A, mund të shtoni një referencë qelize direkt në formulën:

=DATE(2015, B2, 1)

Shembulli 2. Merrni ditën e parë të muajit nga një datë

Nëse dëshironi të llogarisni ditën e parë të muajit bazuar në një datë, mund të përdorni sërish funksionin Excel DATE, por këtë herë do t'ju duhet edhe funksioni MONTH për të nxjerrë numrin e muajit:

Përshembull, formula e mëposhtme do të kthejë ditën e parë të muajit bazuar në datën në qelizën A2:

=DATE(2015,MONTH(A2),1)

Shembulli 3. Gjeni ditën e parë e muajit bazuar në datën aktuale

Kur llogaritjet tuaja bazohen në datën e sotme, përdorni një ndërlidhës të funksioneve Excel EOMONTH dhe TODAY:

=EOMONTH(TODAY(),0) +1 - kthen të 1-tën ditën e muajit pasardhës.

Siç e mbani mend, ne kemi përdorur tashmë një formulë të ngjashme EOMONTH për të marrë ditën e fundit të muajit aktual. Dhe tani, ju thjesht shtoni 1 në atë formulë për të marrë ditën e parë të muajit të ardhshëm.

Në mënyrë të ngjashme, ju mund të merrni ditën e parë të muajit të mëparshëm dhe aktual:

=EOMONTH(TODAY(),-2) +1 - kthen ditën e parë të muajit të mëparshëm.

=EOMONTH(TODAY(),-1) +1 - kthen ditën e parë të muajit aktual.

Mund të përdorni gjithashtu funksionin Excel DATE për të trajtuar kjo detyrë, megjithëse formulat do të ishin pak më të gjata. Për shembull, mendoni se çfarë bën formula e mëposhtme?

=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)

Po, ajo kthehet në ditën e parë të muajit aktual.

Dhe si e detyroni atë të kthejë ditën e parë të muajit vijues apo të mëparshëm? Duart poshtë :) Thjesht shtoni ose hiqni 1 në/nga muaji aktual:

Për të kthyer ditën e parë të muajit vijues:

=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)

Për të kthyer ditën e parë të muajit të kaluar:

=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)

Si të llogarisni numrin e ditëve në një muaj

Në Microsoft Excel, ekzistojnë një sërë funksionesh për të punuar me datat dheherë. Megjithatë, atij i mungon një funksion për llogaritjen e numrit të ditëve në një muaj të caktuar. Pra, do të na duhet ta plotësojmë atë lëshim me formulat tona.

Shembulli 1. Për të marrë numrin e ditëve bazuar në numrin e muajit

Nëse e dini numrin e muajit, formula e mëposhtme DAY / DATE do të kthejë numrin e ditëve në atë muaj:

Në formulën e mësipërme, funksioni DATE kthen ditën e parë të muajit pasardhës, nga i cili zbrisni 1 për të marrë ditën e fundit të muajit që dëshironi. Dhe më pas, funksioni DAY e konverton datën në një numër dite.

Për shembull, formula e mëposhtme kthen numrin e ditëve në prill (muaji i 4-të i vitit).

=DAY(DATE(2015, 4 +1, 1) -1)

Shembulli 2. Për të marrë numrin e ditëve në një muaj bazuar në datën

Nëse nuk e dini një numër muaji, por keni ndonjë datë brenda atij muaji, mund të përdorni VITIN dhe MUAJIN funksionet për të nxjerrë numrin e vitit dhe muajit nga data. Thjesht futini ato në formulën DAY / DATE të diskutuar në shembullin e mësipërm dhe do t'ju tregojë se sa ditë përmban një muaj i caktuar:

=DAY(DATE(YEAR(A2), MONTH(A2) +1, 1) -1)

Ku A2 është qeliza me një datë.

Përndryshe, ju mund të përdorni një formulë shumë më të thjeshtë DAY / EOMUAJ. Siç e mbani mend, funksioni Excel EOMONTH kthen ditën e fundit të muajit, kështu që nuk keni nevojë për ndonjë llogaritje shtesë:

=DAY(EOMONTH(A1, 0))

Pamja e mëposhtme e ekranit tregonrezultatet e kthyera nga të gjitha formulat, dhe siç e shihni ato janë identike:

Si të mblidhni të dhënat sipas muajve në Excel

Në një tabelë të madhe me shumë të dhëna, shpesh mund t'ju duhet të merrni një shumë vlerash për një muaj të caktuar. Dhe ky mund të jetë një problem nëse të dhënat nuk janë futur në rend kronologjik.

Zgjidhja më e lehtë është të shtoni një kolonë ndihmëse me një formulë të thjeshtë Excel MUAJI që do të konvertojë datat në numrat e muajve. Thuaj, nëse datat tuaja janë në kolonën A, ju përdorni =MUAJ(A2).

Dhe tani, shkruani një listë numrash (nga 1 në 12, ose vetëm ato numra muajsh që ju interesojnë ) në një kolonë të zbrazët dhe vlerat e shumës për çdo muaj duke përdorur një formulë SUMIF të ngjashme me këtë:

=SUMIF(C2:C15, E2, B2:B15)

Ku E2 është numri i muajit.

Pamja e mëposhtme e ekranit tregon rezultati i llogaritjeve:

Nëse nuk dëshironi të shtoni një kolonë ndihmëse në fletën tuaj të Excel, nuk ka problem, mund të bëni pa të. Funksioni pak më i ndërlikuar SUMPRODUCT do të funksionojë:

=SUMPRODUCT((MONTH($A$2:$A$15)=$E2) * ($B$2:$B$15))

Aty ku kolona A përmban data, kolona B përmban vlerat për të mbledhur dhe E2 është numri i muajit.

Shënim. Ju lutemi mbani në mend se të dyja zgjidhjet e mësipërme mbledhin të gjitha vlerat për një muaj të caktuar pavarësisht nga viti. Pra, nëse fleta juaj e punës në Excel përmban të dhëna për disa vite, të gjitha do të përmblidhen.

Si të formatoni me kusht datat në bazë të muajit

Tani që dini se si të përdorni Excel