Cuprins
Veți găsi o serie de exemple de formule care demonstrează cum să extrageți luna din data în Excel, să obțineți prima și ultima zi a lunii, să convertiți numele lunii în număr și multe altele.
În articolul precedent, am explorat o varietate de formule pentru a calcula zilele săptămânii. Astăzi, vom opera pe o unitate de timp mai mare și vom învăța funcțiile pe care Microsoft Excel le oferă pentru luni.
În acest tutorial, veți învăța:
Funcția Excel MONTH - sintaxă și utilizări
Microsoft Excel oferă o funcție specială MONTH pentru a extrage o lună din dată, care returnează numărul lunii de la 1 (ianuarie) la 12 (decembrie).
Funcția MONTH poate fi utilizată în toate versiunile Excel 2016 - 2000, iar sintaxa sa este cât se poate de simplă:
MONTH(serial_number) Unde număr_de_serie este orice dată validă a lunii pe care încercați să o găsiți.
Pentru ca formulele Excel MONTH să funcționeze corect, o dată trebuie introdusă folosind funcția DATE(year, month, day). De exemplu, formula =MONTH(DATE(2015,3,1)) returnează 3, deoarece DATE reprezintă prima zi a lunii martie 2015.
Formule precum =MONTH("1-Mar-2015") de asemenea, funcționează bine, deși pot apărea probleme în scenarii mai complexe dacă datele sunt introduse ca text.
În practică, în loc de a specifica o dată în cadrul funcției MONTH, este mai convenabil să se facă referire la o celulă cu o dată sau să se furnizeze o dată returnată de o altă funcție. De exemplu:
=MONTH(A1) - returnează luna unei date din celula A1.
=MONTH(TODAY()) - returnează numărul lunii curente.
La prima vedere, funcția Excel MONTH poate părea simplă, dar, dacă vă uitați la exemplele de mai jos, veți fi uimit să aflați câte lucruri utile poate face de fapt.
Cum să obțineți numărul lunii din data în Excel
Există mai multe moduri de a obține luna din dată în Excel. Care dintre ele depinde de rezultatul exact pe care încercați să îl obțineți.
Funcția MONTH din Excel - obține numărul lunii din data
Aceasta este cea mai evidentă și cea mai ușoară modalitate de a converti data în lună în Excel. De exemplu:
=MONTH(A2)- returnează luna unei date din celula A2.=MONTH(DATE(2015,4,15))- revine la 4, care corespunde lunii aprilie.=MONTH("15-Apr-2015")- evident, revine și numărul 4.
Funcția TEXT în Excel - extrage luna ca un șir de text
O modalitate alternativă de a obține un număr de lună dintr-o dată Excel este utilizarea funcției TEXT:
=TEXT(A2, "m")- returnează un număr de lună fără zero în față, de la 1 la 12.=TEXT(A2, "mm")- returnează un număr de lună cu un zero înainte, ca 01 - 12.
Vă rugăm să fiți foarte atenți atunci când utilizați formulele TEXT, deoarece acestea returnează întotdeauna numerele lunii sub formă de șiruri de text. Prin urmare, dacă intenționați să efectuați alte calcule sau să utilizați numerele returnate în alte formule, ar fi mai bine să folosiți funcția Excel MONTH.
Următoarea captură de ecran demonstrează rezultatele returnate de toate formulele de mai sus. Vă rugăm să observați alinierea la dreapta a numerelor returnate de funcția MONTH (celulele C2 și C3), spre deosebire de valorile de text aliniate la stânga returnate de funcțiile TEXT (celulele C4 și C5).
Cum se extrage numele lunii din data în Excel
În cazul în care doriți să obțineți un nume de lună în loc de un număr, utilizați din nou funcția TEXT, dar cu un cod de dată diferit:
=TEXT(A2, "mmm")- returnează un nume de lună prescurtat, ca Jan - Dec.=TEXT(A2, "mmmm")- returnează un nume complet al lunii, ca ianuarie - decembrie.
Dacă nu doriți de fapt să convertiți data în lună în foaia de calcul Excel, doriți doar să afișarea numelui unei luni numai în loc de data completă, atunci nu doriți să folosiți formule.
Selectați o celulă (celule) cu date, apăsați Ctrl+1 pentru a deschide fereastra de date. Formatarea celulelor Dialog. pe pagina Număr fila, selectați Personalizat și introduceți fie "mmm", fie "mmmm" în câmpul Tip pentru a afișa numele prescurtat sau, respectiv, numele complet al lunii. În acest caz, intrările dvs. vor rămâne date Excel complet funcționale pe care le puteți utiliza în calcule și în alte formule. Pentru mai multe detalii despre modificarea formatului de dată, consultați Crearea unui format de dată personalizat în Excel.
Cum se convertește numărul lunii în numele lunii în Excel
Să presupunem că aveți o listă de numere (de la 1 la 12) în foaia de calcul Excel pe care doriți să o convertiți în nume de luni. Pentru a face acest lucru, puteți utiliza oricare dintre următoarele formule:
Pentru a returna un nume de lună prescurtat (ianuarie - decembrie):
=TEXT(A2*28, "mmm")
=TEXT(DATE(2015, A2, 1), "mmm")
Pentru a returna numele unei luni complete (ianuarie - decembrie):
=TEXT(A2*28, "mmmm")
=TEXT(DATE(2015, A2, 1), "mmmm")
În toate formulele de mai sus, A2 este o celulă cu un număr de lună. Și singura diferență reală între formule este reprezentată de codurile lunii:
- "mmm" - abrevierea din 3 litere a lunii, cum ar fi ianuarie - decembrie.
- "mmmm" - lună silabisită complet
- "mmmmm" - prima literă a numelui lunii
Cum funcționează aceste formule
Atunci când se utilizează împreună cu codurile de format pentru luna, cum ar fi "mmm" și "mmmm", Excel consideră numărul 1 ca fiind ziua 1 din ianuarie 1900. Înmulțind 1, 2, 3 etc. cu 28, se obțin zilele 28, 56, 84 etc. din anul 1900, care sunt în ianuarie, februarie, martie etc. Codul de format "mmm" sau "mmmm" afișează numai numele lunii.
Cum se convertește numele lunii în număr în Excel
Există două funcții Excel care vă pot ajuta să convertiți numele lunii în numere - DATEVALUE și MONTH. Funcția DATEVALUE din Excel convertește o dată stocată ca text într-un număr de serie pe care Microsoft Excel îl recunoaște ca fiind o dată. Și apoi, funcția MONTH extrage un număr de lună din acea dată.
Formula completă este următoarea:
=MONTH(DATEVALUE(A2 & "1"))
Unde A2 într-o celulă care conține numele lunii pe care doriți să o transformați într-un număr (& "1" este adăugat pentru ca funcția DATEVALUE să înțeleagă că este o dată).
Cum să obțineți ultima zi a lunii în Excel (funcția EOMONTH)
Funcția EOMONTH din Excel este utilizată pentru a returna ultima zi a lunii pe baza datei de început specificate. Are următoarele argumente, ambele obligatorii:
EOMONTH(start_date, luni)- Data_începutului - data de început sau o referință la o celulă cu data de început.
- Luni - numărul de luni înainte sau după data de început. Utilizați o valoare pozitivă pentru datele viitoare și o valoare negativă pentru datele trecute.
Iată câteva exemple de formule EOMONTH:
= LUNA(A2, 1) - returnează ultima zi a lunii, la o lună după data din celula A2.
= LUNA(A2, -1) - returnează ultima zi a lunii, cu o lună înainte de data din celula A2.
În locul unei referințe de celulă, puteți codifica o dată în formula EOMONTH. De exemplu, ambele formule de mai jos returnează ultima zi din aprilie.
=EOMONTH("15-Apr-2015", 0)
=EOMONTH(DATE(2015,4,15), 0)
Pentru a reveni la ultima zi a lunii curente , utilizați funcția TODAY() în primul argument al formulei EOMONTH, astfel încât data de astăzi să fie luată ca dată de început. luni argument pentru că nu vreți să schimbați luna în niciun caz.
=EOMONTH(TODAY(), 0)
Notă. Deoarece funcția Excel EOMONTH returnează numărul de serie care reprezintă data, trebuie să aplicați formatul de dată la o celulă (celule) cu ajutorul formulelor dvs. Consultați Cum să schimbați formatul de dată în Excel pentru pașii detaliați.
Și iată rezultatele obținute prin formulele Excel EOMONTH discutate mai sus:
Dacă doriți să calculați câte zile au mai rămas până la sfârșitul lunii curente, este suficient să scădeți data returnată de TODAY() din data returnată de EOMONTH și să aplicați formatul general la o celulă:
=EOMONTH(TODAY(), 0)-TODAY()
Cum să găsiți prima zi a lunii în Excel
După cum știți deja, Microsoft Excel oferă doar o singură funcție pentru a returna ultima zi a lunii (EOMONTH). Când vine vorba de prima zi a lunii, există mai multe moduri de a o obține.
Exemplul 1. Obțineți prima zi a lunii în funcție de numărul lunii
Dacă aveți numărul lunii, atunci utilizați o simplă formulă DATE ca aceasta:
=DATE( anul , numărul lunii , 1)De exemplu, =DATE(2015, 4, 1) va returna 1-Apr-15.
Dacă numerele se află într-o anumită coloană, de exemplu, în coloana A, puteți adăuga o referință de celulă direct în formulă:
=DATE(2015, B2, 1)
Exemplul 2. Obțineți prima zi a lunii dintr-o dată
Dacă doriți să calculați prima zi a lunii pe baza unei date, puteți utiliza din nou funcția Excel DATE, dar de data aceasta veți avea nevoie și de funcția MONTH pentru a extrage numărul lunii:
=DATE( an , LUNA( celula cu data ), 1)De exemplu, următoarea formulă va returna prima zi a lunii pe baza datei din celula A2:
=DATE(2015,MONTH(A2),1)
Exemplul 3. Găsiți prima zi a lunii pe baza datei curente
Atunci când calculele se bazează pe data de astăzi, utilizați o legătură de tip Excel EOMONTH și funcțiile TODAY:
=EOMONTH(TODAY(),0) +1 - se returnează în prima zi a lunii următoare.
După cum vă amintiți, am folosit deja o formulă similară EOMONTH pentru a obține ultima zi a lunii curente. Acum, este suficient să adăugați 1 la această formulă pentru a obține prima zi a lunii următoare.
În mod similar, puteți obține prima zi a lunii precedente și a lunii curente:
=EOMONTH(TODAY(),-2) +1 - returnează prima zi a lunii precedente.
=EOMONTH(TODAY(),-1) +1 - returnează prima zi a lunii curente.
De asemenea, ați putea utiliza Excel DATA pentru a rezolva această sarcină, deși formulele ar fi un pic mai lungi. De exemplu, ghiciți ce face următoarea formulă?
=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)
Da, returnează prima zi a lunii curente.
Și cum îl forțezi să returneze prima zi a lunii următoare sau a celei precedente? Mâinile în jos :) Trebuie doar să adaugi sau să scazi 1 la/din luna curentă:
Să se întoarcă în prima zi a lunii următoare:
=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)
Pentru a reveni la prima zi a lunii precedente:
=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)
Cum se calculează numărul de zile dintr-o lună
În Microsoft Excel, există o varietate de funcții pentru a lucra cu date și ore. Cu toate acestea, lipsește o funcție pentru a calcula numărul de zile dintr-o anumită lună. Prin urmare, va trebui să compensăm această omisiune cu propriile formule.
Exemplul 1. Pentru a obține numărul de zile pe baza numărului lunii
Dacă cunoașteți numărul lunii, următoarea formulă DAY / DATE va returna numărul de zile din luna respectivă:
=DAY(DATE( an , numărul lunii + 1, 1) -1)În formula de mai sus, funcția DATE returnează prima zi a lunii următoare, din care se scade 1 pentru a obține ultima zi a lunii dorite. Apoi, funcția DAY convertește data într-un număr de zile.
De exemplu, următoarea formulă indică numărul de zile din luna aprilie (a patra lună din an).
=DAY(DATE(2015, 4 +1, 1) -1)
Exemplul 2. Pentru a obține numărul de zile dintr-o lună pe baza datei
Dacă nu cunoașteți numărul lunii, dar aveți orice dată din luna respectivă, puteți utiliza funcțiile YEAR și MONTH pentru a extrage numărul anului și al lunii din dată. Trebuie doar să le încorporați în formula DAY / DATE discutată în exemplul de mai sus și vă va spune câte zile conține o anumită lună:
=DAY(DATA(AN(A2), LUNA(A2) +1, 1) -1)
Unde A2 este celula cu o dată.
Alternativ, puteți utiliza o formulă mult mai simplă DAY / EOMONTH. După cum vă amintiți, funcția Excel EOMONTH returnează ultima zi a lunii, deci nu aveți nevoie de calcule suplimentare:
=DAY(EOMONTH(A1, 0))
Următoarea captură de ecran demonstrează rezultatele returnate de toate formulele și, după cum vedeți, acestea sunt identice:
Cum se însumează datele pe lună în Excel
Într-un tabel mare, cu multe date, este posibil să aveți adesea nevoie să obțineți o sumă de valori pentru o anumită lună. Și acest lucru ar putea fi o problemă dacă datele nu au fost introduse în ordine cronologică.
Cea mai simplă soluție este să adăugați o coloană de ajutor cu o simplă formulă Excel MONTH care va converti datele în numere de lună. Să spunem că, dacă datele dvs. sunt în coloana A, utilizați =MONTH(A2).
Și acum, scrieți o listă de numere (de la 1 la 12, sau numai acele numere de lună care vă interesează) într-o coloană goală și adunați valorile pentru fiecare lună folosind o formulă SUMIF similară cu aceasta:
=SUMIF(C2:C15, E2, B2:B15)
Unde E2 este numărul lunii.
Următoarea captură de ecran arată rezultatul calculelor:
Dacă preferați să nu adăugați o coloană de ajutor la foaia Excel, nu este nicio problemă, puteți face fără ea. O funcție SUMPRODUCT puțin mai complicată va funcționa de minune:
=SUMPRODUCT((LUNA($A$2:$A$15)=$E2) * ($B$2:$B$15))
În care coloana A conține datele, coloana B conține valorile de însumat, iar E2 este numărul lunii.
Notă: Rețineți că ambele soluții de mai sus însumează toate valorile pentru o anumită lună, indiferent de an. Astfel, dacă foaia de calcul Excel conține date pentru mai mulți ani, toate vor fi însumate.
Cum să formatați condițional datele pe baza lunii
Acum că știți cum să utilizați funcțiile Excel MONTH și EOMONTH pentru a efectua diverse calcule în foile de calcul, puteți face un pas înainte și să îmbunătățiți prezentarea vizuală. Pentru aceasta, vom utiliza capacitățile de formatare condiționată Excel pentru date.
În plus față de exemplele oferite în articolul menționat mai sus, vă voi arăta acum cum puteți evidenția rapid toate celulele sau rândurile întregi legate de o anumită lună.
Exemplul 1. Evidențiați datele din luna curentă
În tabelul din exemplul anterior, să presupunem că doriți să evidențiați toate rândurile cu datele lunii curente.
În primul rând, extrageți numerele lunilor din datele din coloana A folosind cea mai simplă formulă =MONTH($A2). Apoi, comparați aceste numere cu luna curentă returnată de =MONTH(TODAY()). Ca rezultat, aveți următoarea formulă care returnează TRUE dacă numerele lunilor se potrivesc, FALSE în caz contrar:
=MONTH($A2)=MONTH(TODAY())
Creați o regulă de formatare condiționată Excel bazată pe această formulă, iar rezultatul poate semăna cu captura de ecran de mai jos (articolul a fost scris în aprilie, astfel încât toate datele din aprilie sunt evidențiate).
Exemplul 2. Evidențierea datelor în funcție de lună și zi
Și iată o altă provocare. Să presupunem că doriți să evidențiați în foaia de calcul sărbătorile importante, indiferent de an. Să spunem zilele de Crăciun și Anul Nou. Cum ați aborda această sarcină?
Pur și simplu folosiți funcția DAY din Excel pentru a extrage ziua lunii (1 - 31) și funcția MONTH pentru a obține numărul lunii, apoi verificați dacă DAY este egală cu 25 sau 31 și dacă MONTH este egală cu 12:
=AND(OR(ZI($A2)=25, ZI($A2)=31), LUNĂ(A2)=12)
Iată cum funcționează funcția LUNĂ în Excel. Se pare că este mult mai versatilă decât pare, nu-i așa?
În câteva dintre postările următoare, vom calcula săptămâni și ani și sperăm că veți mai învăța câteva trucuri utile. Dacă sunteți interesați de unități de timp mai mici, vă rugăm să consultați părțile anterioare ale seriei noastre Excel Dates (veți găsi link-urile mai jos). Vă mulțumesc pentru lectură și sper să ne vedem săptămâna viitoare!
