Tutorialak Excel MONTH eta EOMONTH funtzioen azkoinak eta torlojuak azaltzen ditu. Excel-en hilabetea datatik nola atera, hilabeteko lehen eta azken eguna lortu, hilabetearen izena zenbaki bihurtu eta gehiago erakusten duten formula-adibide sorta bat aurkituko duzu.

Aurreko artikuluan, astegunak kalkulatzeko hainbat formula aztertu ditugu. Gaur, denbora-unitate handiago batean funtzionatuko dugu eta Microsoft Excel-ek hilabetez eskaintzen dituen funtzioak ikasiko ditugu.

Tutorial honetan, hauxe ikasiko duzu:

Excel HILABETEA funtzioa - sintaxia eta erabilerak

Microsoft Excel-ek HILABETEA funtzio berezi bat eskaintzen du datatik hilabete bat ateratzeko, eta 1etik (urtarrila) eta 12ra (abendua) bitarteko hilabetearen zenbakia itzultzen du.

HILABETEA funtzioa Excel 2016 - 2000 bertsio guztietan erabil daiteke eta bere sintaxia izan daitekeen bezain sinplea da:

Non serial_number den bilatzen saiatzen ari zaren hilabeteko data baliozko bat.

Excel HILABETEA formulen lan zuzena lortzeko, data bat sartu behar da DATE (urtea, hilabetea, eguna) funtzioa erabiliz. Adibidez, =MONTH(DATE(2015,3,1)) formulak 3 ematen du DATE 2015eko martxoaren 1a adierazten baitu.

=MONTH("1-Mar-2015") bezalako formulek ere ondo funtzionatzen dute, nahiz eta egoera konplexuagoetan arazoak sor daitezke datak testu gisa sartzen badira.

Praktikan, HILABETEA funtzioaren barruan data zehaztu beharrean, komenigarriagoa da data edo gelaxka bat aipatzea.MONTH eta EOMONTH funtzioak zure lan-orrietan hainbat kalkulu egiteko, urrats bat gehiago eman dezakezu eta aurkezpen bisuala hobetu dezakezu. Horretarako, Excel baldintzapeko formatearen gaitasunak erabiliko ditugu datetarako.

Aipatutako artikuluan emandako adibideez gain, orain gelaxka guztiak edo errenkada osoak azkar nola nabarmen ditzakezun erakutsiko dizut. Hilabete jakin batekin erlazionatuta.

Adibidea 1. Uneko hilabeteko datak nabarmendu

Aurreko adibideko taulan, demagun errenkada guztiak uneko hilabeteko datarekin nabarmendu nahi dituzula.

Hasteko, hileko zenbakiak ateratzen dituzu A zutabeko datetatik =HILABETEA($A2) formula sinpleena erabiliz. Eta gero, zenbaki horiek =HILATEA(GAUR()) itzultzen duen uneko hilabetearekin alderatzen dituzu. Ondorioz, formula hau daukazu, EGIA itzultzen duena hilabeteetako zenbakiak bat datozenean, GEZURRA bestela:

=MONTH($A2)=MONTH(TODAY())

Sortu Excel baldintzazko formatu-araua formula honetan oinarrituta, eta zure emaitza baliteke. beheko pantaila-argazkiaren antza izan (artikulua apirilean idatzi zen, beraz, apirileko data guztiak nabarmenduta daude).

2. adibidea. Datak hilabete eta egunen arabera nabarmentzea

Eta hona beste erronka bat. Demagun zure lan-orrian jai nagusiak nabarmendu nahi dituzula urtea edozein dela ere. Demagun Gabonetako eta Urte Berriko egunak. Nola planteatuko zenuke zeregin honi?

Erabili Excel EGUNA funtzioa besterik gabeatera hilaren eguna (1 - 31) eta HILABETEA funtzioa hilabetearen zenbakia lortzeko, eta egiaztatu EGUNA 25 edo 31 berdina den eta HILABETEA 12 berdina den:

=AND(OR(DAY($A2)=25, DAY($A2)=31), MONTH(A2)=12)

Horrela funtzionatzen du Excel-en HILABETEA funtzioak. Itxura baino askoz polifazetikoa dela ematen du, ezta?

Hurrengo argitalpen pare batean, asteak eta urteak kalkulatuko ditugu eta, zorionez, trikimailu erabilgarriago batzuk ikasiko dituzu. Denbora-unitate txikiagoetan interesatzen bazaizu, begiratu gure Excel Dates seriearen aurreko zatiak (behean aurkituko dituzu estekak). Eskerrak ematen dizkizut irakurtzeagatik eta hurrengo astean elkartzea espero dut!

=MONTH(A1) - data baten hilabetea itzultzen du A1 gelaxkan.

=MONTH(TODAY()) - uneko hilabetearen zenbakia itzultzen du.

Lehen begiratuan, Excel HILABETEA. funtzioak itxura arrunta izan dezake. Baina begiratu beheko adibideei eta harritu egingo zara zenbat gauza erabilgarriak egin ditzakeen jakiteak.

Nola lortu hilabeteko zenbakia datatik Excel-en

Hainbat modu daude hilabetea lortzeko. datatik aurrera Excel-en. Zein aukeratu lortzen saiatzen ari zaren emaitzaren araberakoa da.

HILABETE funtzioa Excel-en - lortu hilabetearen zenbakia datatik

Hau da agerikoena eta errazena. Excel-en data hilabete bihurtzeko modua. Adibidez:

• =MONTH(A2) - A2 gelaxkan data baten hilabetea itzultzen du.
• =MONTH(DATE(2015,4,15)) - 4 apirileari dagokion itzultzen du.
• =MONTH("15-Apr-2015") - jakina, zenbakia itzultzen du. 4 ere.

TESTU funtzioa Excel-en - atera hilabetea testu-kate gisa

Excel data batetik hilabeteko zenbakia lortzeko beste modu bat erabiltzea da. TESTU-funtzioa:

• =TEXT(A2, "m") - hasierako zerorik gabeko hilabeteko zenbakia itzultzen du, 1 - 12 gisa.
• =TEXT(A2,"mm") - hilabeteko zenbaki bat itzultzen du hasierako zero batekin, 01 - 12 gisa.

Mesedez, kontu handiz ibili TESTU formulak erabiltzean, hilabeteko zenbakiak beti itzultzen baitituzte testu-kate gisa. Beraz, kalkulu gehiago egiteko asmoa baduzu edo itzulitako zenbakiak beste formula batzuetan erabiltzeko asmoa baduzu, hobe duzu Excel HILABETEA.funtzioa.

Ondoko pantaila-argazkiak goiko formula guztiek emandako emaitzak erakusten ditu. Mesedez, kontuan izan HILABETEA funtzioak (C2 eta C3 gelaxkak) itzultzen dituen zenbakien eskuineko lerrokadura, TESTU funtzioek (C4 eta C5 gelaxkak) itzultzen dituzten testu-balioak ezkerrera lerrokatuta daudenen aldean.

Nola atera hilabetearen izena datatik Excel-en

Zenbaki bat baino hilabeteko izena lortu nahi baduzu, berriro erabili TESTU funtzioa, baina data-kode ezberdin batekin:

• =TEXT(A2, "mmm") - hilabete-izen laburtua ematen du, urtarrila - abendua gisa.
• =TEXT(A2,"mmmm") - hilabete osoko izena ematen du, urtarrila - abendu gisa.

Ez baduzu zure Excel-eko lan-orrian data hilabetera bihurtu nahi, hilabetearen izena bistaratu besterik ez duzu nahi data osoa beharrean, orduan ez duzu nahi. edozein formula.

Hautatu datak dituzten gelaxka bat, sakatu Ktrl+1 Formatu gelaxkak elkarrizketa-koadroa irekitzeko. Zenbakia fitxan, hautatu Pertsonalizatua eta idatzi "mmm" edo "mmmm" Mota koadroan, hilabeteko izenak laburtuak edo osoak bistaratzeko, hurrenez hurren. Kasu honetan, zure sarrerak kalkuluetan eta beste formuletan erabil ditzakezun Excel data guztiz funtzionalak izango dira. Data-formatua aldatzeari buruzko xehetasun gehiago lortzeko, ikusi Excel-en data-formatu pertsonalizatu bat sortzea.

Nola bihurtu hilabete-zenbakia hilabete-izena Excel-en

Demagun, zenbaki zerrenda bat duzula (1etik 12ra)hilabete-izenetara bihurtu nahi duzun Excel lan-orrian. Horretarako, formula hauetako edozein erabil dezakezu:

Hilabete-izen laburtua itzultzeko (urtarrila - abendua):

=TEXT(A2*28, "mmm")

=TEXT(DATE(2015, A2, 1), "mmm")

Hilabete osoko izena itzultzeko (urtarrila - abendua):

=TEXT(A2*28, "mmmm")

=TEXT(DATE(2015, A2, 1), "mmmm")

Aurreko formula guztietan, A2 hilabeteko zenbakia duen gelaxka bat da. Eta formulen arteko desberdintasun erreal bakarra hilabete-kodeak dira:

• "mmm" - 3 letrako hilabeteko laburdura, hala nola urtarrila - abendua
• "mmmm" - hilabetea. guztiz idatzita
• "mmmmm" - hilaren izenaren lehen letra

Nola funtzionatzen duten formulak

Erabili direnean "mmm" eta "mmmm" bezalako hilabete formatuko kodeekin batera, Excel-ek 1. zenbakia 1900ko urtarrileko 1. eguna bezala hartzen du. 1, 2, 3 eta abar 28z biderkatuz, 28, 56, 84 eta abar egunak lortzen ari zara. 1900 urtekoak, urtarrilean, otsailean, martxoan, etab. "mmm" edo "mmmm" formatu-kodeak hilabetearen izena soilik erakusten du.

Nola bihurtu hilabetearen izena zenbakira Excel-en

DATEVALUE eta MONTH hilabeteen izenak zenbaki bihurtzeko bi funtzio daude. Excel-en DATEVALUE funtzioak testu gisa gordetako data Microsoft Excel-ek data gisa ezagutzen duen serie-zenbaki batera bihurtzen du. Eta gero, HILABETEA funtzioak hilabeteko zenbaki bat ateratzen du data horretatik.

Formula osoa hau da:

=MONTH(DATEVALUE(A2 & "1"))

Non A2 hilabetearen izena duen gelaxka batean.zenbaki bat bihurtu nahi duzu (&"1" gehitzen da DATEVALUE funtzioari data bat dela ulertzeko).

Nola lortu hilabeteko azken eguna. Excel (EOMONTH funtzioa)

Excel-en EOMONTH funtzioa hilabeteko azken eguna itzultzeko erabiltzen da zehaztutako hasiera-dataren arabera. Argumentu hauek ditu, biak beharrezkoak:

• Hasiera_data - hasiera-data edo hasiera-data duen gelaxka baten erreferentzia.
• Hilabeteak - hasiera-dataren aurreko edo ondorengo hilabete kopurua. Erabili balio positiboa etorkizuneko datetarako eta balio negatiboa iraganeko datetarako.

Hona hemen EOHILABE formula adibide batzuk:

=EOMONTH(A2, 1) - hileko azken eguna itzultzen du, hilabete bat geroago A2 gelaxkako data.

=EOMONTH(A2, -1) - hileko azken eguna itzultzen du, A2 gelaxkako data baino hilabete lehenago.

Geluxa-erreferentziaren ordez, data bat gogor kode dezakezu zure EOHILABE formula. Adibidez, beheko bi formulek apirileko azken eguna itzultzen dute.

=EOMONTH("15-Apr-2015", 0)

=EOMONTH(DATE(2015,4,15), 0)

Uneko hilabeteko azken eguna itzultzeko , GAUR() funtzioa erabiltzen duzu zure EOHILABE formulako lehen argumentuan, gaurko data hasiera data gisa hartzeko. Eta, 0 jarri duzu months argumentuan, ez duzulako hilabetea ere aldatu nahi.

=EOMONTH(TODAY(), 0)

Oharra. Excel EOMONTH funtzioak data adierazten duen serie zenbakia itzultzen duenez, duzudata-formatua zure formulekin gelaxka bati aplikatzeko. Ikusi Excel-en data-formatua nola aldatu urrats zehatzetarako.

Eta hona hemen goian aipatu ditugun Excel EOMONTH formulek itzultzen dituzten emaitzak:

Uneko hilabetearen amaierarako zenbat egun falta diren kalkulatu nahi baduzu, Besterik gabe, GAUR ()-k itzultzen duen data EOMONTH-ek itzulitako datatik kendu eta Formatu Orokorra aplikatu gelaxka bati:

=EOMONTH(TODAY(), 0)-TODAY()

Nola aurkitu hilabeteko lehen eguna Excel-en

Dagoeneko dakizuenez, Microsoft Excel-ek funtzio bakarra eskaintzen du hileko azken eguna (EOMONTH) itzultzeko. Hilabeteko lehen egunari dagokionez, lortzeko modu bat baino gehiago dago.

1. Adibidea. Lortu hileko 1. eguna hilabetearen zenbakiaren arabera

Baduzu. hilabete-zenbakia, eta, ondoren, erabili DATA formula sinple bat honela:

Adibidez, =DATE(2015, 4, 1) 1-apiril-15 itzuliko du.

Zure zenbakiak zutabe jakin batean kokatzen badira, esan A zutabean, gelaxka-erreferentzia bat gehi dezakezu zuzenean formulan:

=DATE(2015, B2, 1)

2. adibidea. Lortu hilabeteko 1. eguna data batetik

Hileko lehen eguna data batean oinarrituta kalkulatu nahi baduzu, egin dezakezu erabili Excel DATE funtzioa berriro, baina oraingoan MONTH funtzioa ere beharko duzu hilabete zenbakia ateratzeko:

HorretarakoAdibidez, formula honek hileko lehen eguna itzuliko du A2 gelaxkako datan oinarrituta:

=DATE(2015,MONTH(A2),1)

Adibidea 3. Aurkitu lehen eguna hilabeteko uneko datan oinarrituta

Zure kalkuluak gaurko datan oinarritzen direnean, erabili Excel EOHILATEA eta GAUR funtzioen lotura:

=EOMONTH(TODAY(),0) +1 - 1.a itzultzen du. hurrengo hilabeteko eguna.

Gogoratzen duzunez, dagoeneko EOHILABE antzeko formula bat erabili dugu uneko hilabeteko azken eguna lortzeko. Eta orain, formula horri 1 gehitu besterik ez duzu hurrengo hilabeteko lehen eguna lortzeko.

Antzera, aurreko eta oraingo hilabeteko lehen eguna lor dezakezu:

=EOMONTH(TODAY(),-2) +1 - aurreko hilabeteko 1. eguna itzultzen du.

=EOMONTH(TODAY(),-1) +1 - uneko hilabeteko 1. eguna itzultzen du.

Excel DATA funtzioa ere erabil dezakezu kudeatzeko. zeregin hori, nahiz eta formulak luzeagoak izango liratekeen. Adibidez, asmatu zer egiten duen hurrengo formulak?

=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)

Bai, uneko hilabeteko lehen eguna itzultzen du.

Eta nola behartzen duzu itzultzera hurrengo edo aurreko hilabeteko lehen eguna? Eskuz behera :) Besterik gabe, gehitu edo kendu 1 uneko hilabeteari:

Hurrengo hilabeteko lehen eguna itzultzeko:

=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)

Lehenengo eguna itzultzeko aurreko hilabeteko:

=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)

Nola kalkulatu hilabete bateko egun kopurua

Microsoft Excel-en, hainbat funtzio daude datak eta lan egiteko.aldiz. Hala ere, ez du hilabete jakin bateko egun kopurua kalkulatzeko funtziorik. Beraz, hutsegite hori gure formulekin osatu beharko dugu.

1. Adibidea. Hilaren zenbakiaren araberako egun kopurua lortzeko

Hilabetearen zenbakia ezagutzen baduzu, EGUNA/DATA formula honek hilabete horretako egun kopurua itzuliko du:

Goiko formulan, DATA funtzioak hurrengo hilabeteko lehen eguna itzultzen du, eta hortik 1 kentzen duzu nahi duzun hilabeteko azken eguna lortzeko. Eta gero, EGUNA funtzioak data egun-zenbaki bihurtzen du.

Adibidez, hurrengo formulak apirileko egun kopurua itzultzen du (urteko 4. hilabetea).

=DAY(DATE(2015, 4 +1, 1) -1)

2. adibidea. Hilabeteko egun kopurua dataren arabera lortzeko

Hilabete-zenbakirik ez badakizu baina hilabete horretan datarik baduzu, URTEA eta HILABETEA erabil ditzakezu. datatik urtea eta hilabete zenbakia ateratzeko funtzioak. Besterik gabe, txertatu goiko adibidean aztertutako EGUNA / DATA formulan, eta hilabete jakin batek zenbat egun dituen esango dizu:

=DAY(DATE(YEAR(A2), MONTH(A2) +1, 1) -1)

Non A2 data duen gelaxka den.

Bestela, EGUNA / EOHILABE formula askoz errazagoa erabil dezakezu. Gogoratzen duzunez, Excel EOHILABE funtzioak hileko azken eguna itzultzen du, beraz, ez duzu kalkulu gehigarririk behar:

=DAY(EOMONTH(A1, 0))

Ondoko pantaila-argazkiak erakusten duFormula guztiek itzultzen dituzten emaitzak, eta ikusten duzun bezala, berdinak dira:

Nola batu datuak hilabeteka Excel-en

Taula handi batean datu asko, baliteke hilabete jakin baterako balioen batura bat lortu behar izatea. Eta hori arazo bat izan daiteke datuak ordena kronologikoan sartu ez badira.

Irtenbiderik errazena datak hilabeteko zenbaki bihurtuko dituen Excel HILABETEA formula sinple batekin zutabe laguntzaile bat gehitzea da. Esan, zure datak A zutabean badaude, =HILABETEA(A2) erabiltzen duzula.

Eta orain, idatzi zenbakien zerrenda bat (1etik 12ra, edo zuretzat interesgarriak diren hilabeteko zenbakiak soilik). ) zutabe huts batean, eta hilabete bakoitzeko balioak batura honen antzeko SUMIF formula erabiliz:

=SUMIF(C2:C15, E2, B2:B15)

Non E2 hilabetearen zenbakia den.

Ondoko pantaila-argazkiak erakusten du. kalkuluen emaitza:

Nahiago baduzu zutabe laguntzaile bat gehitzea Excel orrira, ez dago arazorik, gabe egin dezakezu. Apur bat zailagoa den SUMPRODUCT funtzioak atsegina izango du:

=SUMPRODUCT((MONTH($A$2:$A$15)=$E2) * ($B$2:$B$15))

A zutabeak datak dituenean, B zutabeak batu beharreko balioak ditu eta E2 hilabetearen zenbakia da.

Ohar. Kontuan izan goiko soluzio biek hilabete jakin bateko balio guztiak batzen dituztela urtea edozein dela ere. Beraz, zure Excel lan-orriak hainbat urtetako datuak baditu, guztiak batu egingo dira.

Nola baldintzatuta formateatu datak hilabetean oinarrituta

Orain Excel nola erabiltzen badakizu