Makala yanaonyesha njia chache tofauti za kupata thamani ya juu zaidi katika Excel kulingana na hali moja au kadhaa unazobainisha.

Katika somo letu lililopita, tuliangalia matumizi ya kawaida ya chaguo za kukokotoa za MAX ambayo imeundwa kurejesha nambari kubwa zaidi katika mkusanyiko wa data. Katika hali zingine, hata hivyo, unaweza kuhitaji kuchimba chini kwenye data yako zaidi ili kupata dhamana ya juu kulingana na vigezo fulani. Hili linaweza kufanywa kwa kutumia fomula chache tofauti, na makala haya yanaelezea njia zote zinazowezekana.

fomula ya Excel MAX IF

Hadi hivi majuzi, Microsoft Excel haikuwa na fomula. kitendakazi cha MAX IF kilichojengwa ndani ili kupata thamani ya juu zaidi kulingana na masharti. Kwa kuanzishwa kwa MAXIFS katika Excel 2019, tunaweza kufanya max ya masharti kwa njia rahisi.

Katika Excel 2016 na matoleo ya awali, bado unapaswa kuunda fomula yako ya safu kwa kuchanganya MAX. fanya kazi kwa kauli ya IF:

Kuona jinsi hii generic MAX IKIWA fomula inafanya kazi kwenye data halisi, tafadhali zingatia mfano ufuatao. Tuseme, unayo meza na matokeo ya kuruka kwa muda mrefu ya wanafunzi kadhaa. Jedwali linajumuisha data ya raundi tatu, na unatafuta matokeo bora ya mwanariadha fulani, sema Jacob. Na majina ya wanafunzi katika A2:A10 na umbali katika C2:C10, fomula inachukua umbo hili:

=MAX(IF(A2:A10="Jacob", C2:C10))

Tafadhali kumbuka kuwa fomula ya mkusanyikolazima daima iingizwe kwa kushinikiza Ctrl + Shift + Ingiza funguo wakati huo huo. Kwa hivyo, inazungukwa kiotomatiki na mabano yaliyojipinda kama inavyoonyeshwa kwenye picha ya skrini hapa chini (kuandika brashi mwenyewe haitafanya kazi!).

Laha-kazi za maisha halisi, ni rahisi zaidi kuweka kigezo katika baadhi ya kiini, ili uweze kubadilisha hali kwa urahisi bila kubadilisha fomula. Kwa hivyo, tunaandika jina tunalotaka katika F1 na kupata matokeo yafuatayo:

=MAX(IF(A2:A10=F1, C2:C10))

Jinsi fomula hii inavyofanya kazi

Kwa mantiki mtihani wa kazi ya IF, tunalinganisha orodha ya majina (A2: A10) na jina la lengo (F1). Matokeo ya operesheni hii ni mkusanyiko wa TRUE na FALSE, ambapo thamani za TRUE zinawakilisha majina yanayolingana na jina lengwa (Jacob):

{FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE}

Kwa thamani_ if_true hoja, tunatoa matokeo ya kuruka kwa muda mrefu (C2:C10), kwa hivyo ikiwa jaribio la kimantiki litatathmini kuwa TRUE, nambari inayolingana kutoka safu C inarudishwa. Hoja ya value_ if_false imeachwa, ikimaanisha itakuwa na thamani FALSE ambapo sharti halijatimizwa:

{FALSE;FALSE;FALSE;5.48;5.42;5.57;FALSE;FALSE;FALSE}

Safu hii imetumwa kwa chaguo za kukokotoa MAX, ambayo hurejesha idadi ya juu zaidi ikipuuza thamani za FALSE.

Kidokezo. Ili kuona safu za ndani zilizojadiliwa hapo juu, chagua sehemu inayolingana ya fomula kwenye laha yako ya kazi na ubonyeze kitufe cha F9. Ili kuondoka kwenye modi ya tathmini ya fomula, bonyeza kitufe cha Esc.

fomula MAX IF yenye nyingivigezo

Katika hali unapohitaji kupata thamani ya juu zaidi kulingana na hali zaidi ya moja, unaweza:

Kutumia taarifa za IF zilizowekwa ili kujumuisha vigezo vya ziada:

Au shughulikia vigezo vingi kwa kutumia operesheni ya kuzidisha:

Tuseme una matokeo ya wavulana na wasichana katika jedwali moja na ungependa kupata mruko mrefu zaidi kati ya wasichana katika raundi ya 3. Ili ifanyike , tunaweka kigezo cha kwanza (kike) katika G1, kigezo cha pili (3) katika G2, na kutumia fomula zifuatazo kuhesabu thamani ya juu zaidi:

=MAX(IF(B2:B16=G1, IF(C2:C16=G2, D2:D16)))

=MAX(IF((B2:B16=G1)*(C2:C16=G2), D2:D16))

Kwa kuwa zote mbili ni fomula za mkusanyiko, tafadhali kumbuka kubonyeza Ctrl + Shift + Enter ili kuzikamilisha ipasavyo.

Kama inavyoonyeshwa kwenye picha ya skrini iliyo hapa chini, fomula hutoa matokeo sawa, kwa hivyo ni ipi ya kutumia suala la yo upendeleo wako binafsi. Kwangu mimi, fomula iliyo na mantiki ya Boolean ni rahisi kusoma na kuunda - inaruhusu kuongeza masharti mengi unavyotaka bila kuweka vitendaji vya ziada vya IF.

Jinsi fomula hizi zinavyofanya kazi.

Fomula ya kwanza hutumia vitendakazi viwili vya IF vilivyoorodheshwa kutathmini vigezo viwili. Katika jaribio la kimantiki la taarifa ya kwanza ya IF, tunalinganisha maadili katika safu wima ya Jinsia(B2:B16) kwa kigezo katika G1 ("Mwanamke"). Matokeo yake ni mkusanyiko wa thamani za TRUE na FALSE ambapo TRUE inawakilisha data inayolingana na kigezo:

{FALSE; FALSE; FALSE; TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; TRUE; TRUE; TRUE}

Kwa mtindo sawa, chaguo la kukokotoa la pili la IF hukagua thamani katika safu wima ya Mzunguko (C2) :C16) dhidi ya kigezo katika G2.

Kwa value_if_true hoja katika taarifa ya pili ya IF, tunatoa matokeo ya kurukaruka kwa muda mrefu (D2:D16), na kwa njia hii tunapata bidhaa. ambazo zina TRUE katika safu mbili za kwanza katika nafasi zinazolingana (yaani vitu ambapo jinsia ni "mwanamke" na pande zote ni 3):

{FALSE; FALSE; FALSE; FALSE; FALSE; 4.63; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; 4.52}

Safu hii ya mwisho inakwenda kwenye chaguo la kukokotoa la MAX na hurejesha nambari kubwa zaidi.

Mfumo wa pili hutathmini hali sawa ndani ya jaribio moja la kimantiki na operesheni ya kuzidisha hufanya kazi kama waendeshaji AND:

Wakati thamani za TRUE na FALSE zinatumika katika hali yoyote. operesheni ya hesabu, hubadilishwa kuwa 1 na 0, kwa mtiririko huo. Na kwa sababu kuzidisha kwa 0 daima kunatoa sifuri, safu inayotokana ina 1 tu wakati masharti yote ni KWELI. Mkusanyiko huu unatathminiwa katika jaribio la kimantiki la chaguo za kukokotoa za IF, ambalo hurejesha umbali unaolingana na vipengele 1 (TRUE).

MAX IF bila mkusanyiko

Watumiaji wengi wa Excel, ikiwa ni pamoja na mimi. chuki dhidi ya fomula za safu na jaribu kuziondoa popote inapowezekana. Kwa bahati nzuri, Microsoft Excel ina vitendaji vichache vinavyoshughulikia safu asili, na tunaweza kutumia mojaya vitendaji kama hivyo, yaani SUMPRODUCT, kama aina ya "kanda" karibu na MAX.

Fomula ya jumla ya MAX IF bila safu ni kama ifuatavyo:

Kwa kawaida, unaweza kuongeza masafa/kigezo jozi zaidi ikiwa inahitajika.

Ili kuona fomula inavyofanya kazi, tutakuwa tukitumia data kutoka kwa mfano uliopita. Lengo ni kupata upeo wa juu kabisa wa kuruka kwa mwanariadha wa kike katika raundi ya 3:

=SUMPRODUCT(MAX(((B2:B16=G1) * (C2:C16=G2) * (D2:D16))))

Fomula hii inashindanishwa na kibonye cha kawaida cha Enter na huleta matokeo sawa na safu ya fomula ya MAX IF:

Ukiangalia kwa makini picha ya skrini iliyo hapo juu, unaweza kugundua kuwa miruko isiyo sahihi iliyotiwa alama ya "x" katika mifano iliyotangulia sasa ina thamani 0 katika safu mlalo ya 3, 11 na 15. , na sehemu inayofuata inaeleza kwa nini.

Jinsi fomula hii inavyofanya kazi

Kama ilivyo kwa fomula ya MAX IF, tunatathmini vigezo viwili kwa kulinganisha kila thamani katika Jinsia (B2:B16) na Mzunguko ( C2:C16) safu wima zenye vigezo katika visanduku vya G1 na G2. Matokeo yake ni safu mbili za thamani za TRUE na FALSE. Kuzidisha vipengele vya safu katika nafasi sawa hubadilisha TRUE na FALSE kuwa 1 na 0, mtawalia, ambapo 1 inawakilisha vipengele vinavyotimiza vigezo vyote viwili. Safu ya tatu iliyozidishwa ina matokeo ya kuruka kwa muda mrefu (D2:D16). Na kwa sababu kuzidisha kwa 0 kunatoa sifuri, ni vitu tu ambavyo vina 1 (TRUE) katika nafasi zinazolingana.Surve:

{0; 0; 0; 0; 0; 4.63; 0; 0; 0; 0; 0; 0; 0; 0; 4.52}

Ikiwa max_range ina thamani yoyote ya maandishi, operesheni ya kuzidisha italeta hitilafu ya #VALUE kwa sababu ambayo fomula nzima haitafanya kazi.

Chaguo za kukokotoa za MAX huichukua kutoka hapa na kurudisha nambari kubwa zaidi inayotimiza masharti maalum. Mkusanyiko unaotokana unaojumuisha kipengele kimoja {4.63} huenda kwa chaguo za kukokotoa za SUMPRODUCT na hutoa nambari ya juu zaidi katika kisanduku.

Kumbuka. Kwa sababu ya mantiki yake mahususi, fomula hufanya kazi na tahadhari zifuatazo:

• Masafa ambapo unatafuta thamani ya juu lazima iwe na nambari pekee. Ikiwa kuna maadili yoyote ya maandishi, #VALUE! hitilafu imerejeshwa.
• Mfumo hauwezi kutathmini hali ya "siyo sawa na sifuri" katika seti hasi ya data. Ili kupata thamani ya juu zaidi ya kupuuza sufuri, tumia fomula ya MAX IF au chaguo za kukokotoa za MAXIFS.

fomula ya Excel MAX IF yenye AU mantiki

Ili kupata thamani ya juu zaidi ikiwa yoyote kati ya masharti yaliyobainishwa yametimizwa, tumia fomula tayari inayojulikana MAX IF yenye mantiki ya Boolean, lakini ongeza masharti badala ya kuyazidisha.

Badala yake, unaweza kutumia fomula ifuatayo isiyo ya mkusanyiko :

Kama mfano, wacha tufanye kazimatokeo bora zaidi katika raundi ya 2 na 3. Tafadhali zingatia kuwa katika lugha ya Excel, kazi imeundwa kwa njia tofauti: rudisha thamani ya juu ikiwa duru ni 2 au 3.

Na mizunguko iliyoorodheshwa katika B2:B10. , matokeo katika C2:C10 na vigezo katika F1 na H1, fomula inakwenda kama ifuatavyo:

=MAX(IF((B2:B10=F1) + (B2:B10=H1), C2:C10))

Ingiza fomula kwa kubonyeza Ctrl + Shift + Enter mchanganyiko wa vitufe na utapata matokeo haya:

Thamani ya juu iliyo na masharti sawa pia inaweza kupatikana kwa kutumia fomula hii isiyo ya mkusanyiko:

=SUMPRODUCT(MAX(((B2:B10=F1) + (B2:B10=H1)) * C2:C10))

Hata hivyo, tunahitaji kubadilisha thamani zote za "x" katika safu wima C na sufuri katika kesi hii kwa sababu SUMPRODUCT MAX inafanya kazi na data ya nambari pekee:

Jinsi fomula hizi zinavyofanya kazi

Fomula ya mkusanyiko hufanya kazi kwa njia sawa kabisa na MAX IF na AND mantiki isipokuwa kwamba unajiunga na kigezo kwa kutumia operesheni ya kuongeza badala ya kuzidisha. Katika fomula za safu, nyongeza hufanya kazi kama opereta AU:

Kuongeza safu mbili za TRUE na FALSE (ambayo hutokana na kuangalia thamani katika B2:B10 dhidi ya vigezo katika F1 na H1) hutoa safu ya 1 na 0 ambapo 1 inawakilisha vipengee ambavyo hali yoyote ni TRUE na 0 inawakilisha vitu ambavyo masharti yote mawili ni FALSE. Matokeo yake, kitendakazi cha IF "huweka" vitu vyote katika C2:C10 ( value_if_true ) ambayo sharti lolote ni TRUE (1); vitu vilivyobaki vinabadilishwa na FALSE kwa sababu value_if_false hoja haijabainishwa.

Fomula isiyo ya safu hufanya kazi kwa njia sawa. Tofauti ni kwamba badala ya jaribio la kimantiki la IF, unazidisha vipengele vya safu ya 1 na 0 kwa vipengele vya safu ya matokeo ya kuruka kwa muda mrefu (C2:C10) katika nafasi zinazolingana. Hii inabatilisha vipengee ambavyo havikidhi masharti yoyote (vina 0 katika safu ya kwanza) na kuweka vipengee vinavyokidhi mojawapo ya masharti (kuwa na 1 katika safu ya kwanza).

MAXIFS - njia rahisi ya kupata juu zaidi. thamani na masharti

Watumiaji wa Excel 2019, 2021 na Excel 365 hawana shida ya kudhibiti safu ili kuunda fomula yao ya MAX IF. Matoleo haya ya Excel hutoa chaguo za kukokotoa za MAXIFS zilizosubiriwa kwa muda mrefu ambazo hufanya kutafuta thamani kubwa zaidi kwa kutumia masharti ya kucheza kwa mtoto.

Katika hoja ya kwanza ya MAXIFS, unaweka safu ambamo thamani ya juu zaidi inapaswa kupatikana (D2: D16 kwa upande wetu), na katika hoja zinazofuata unaweza kuingiza hadi masafa 126/jozi za vigezo. Kwa mfano:

=MAXIFS(D2:D16, B2:B16, G1, C2:C16, G2)

Kama inavyoonyeshwa kwenye picha ya skrini iliyo hapa chini, fomula hii rahisi haina tatizo na kuchakata masafa ambayo yana thamani za nambari na maandishi:

Kwa maelezo ya kina kuhusu chaguo za kukokotoa, tafadhali angalia chaguo la kukokotoa la Excel MAXIFS na mifano ya fomula.

Hivyo ndivyo unavyoweza kupata thamani ya juu zaidi ukitumia masharti katika Excel. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogi yetu ijayowiki!

Jizoeze kitabu cha kazi kupakua

mifano ya fomula ya Excel MAX IF (faili.xlsx)