Tha an artaigil a’ sealltainn grunn dhòighean eadar-dhealaichte air an luach as motha fhaighinn ann an Excel stèidhichte air aon no grunn chumhachan a shònraich thu.

San oideachadh a rinn sinn roimhe, thug sinn sùil air na cleachdaidhean cumanta den ghnìomh MAX a tha air a dhealbhadh gus an àireamh as motha ann an stòr-dàta a thilleadh. Ann an cuid de shuidheachaidhean, ge-tà, is dòcha gum feum thu drileadh sìos a-steach don dàta agad gus an luach as àirde a lorg stèidhichte air slatan-tomhais sònraichte. Faodar seo a dhèanamh le bhith a' cleachdadh beagan fhoirmlean eadar-dhealaichte, agus tha an artaigil seo a' mìneachadh a h-uile dòigh a dh'fhaodadh a bhith ann.

Foirmle Excel MAX IF

Gu ruige o chionn ghoirid, cha robh faidhle aig Microsoft Excel. gnìomh MAX IF togte gus an luach as àirde fhaighinn stèidhichte air suidheachaidhean. Le toirt a-steach MAXIFS ann an Excel 2019, is urrainn dhuinn dòigh shìmplidh max a dhèanamh. gnìomh le aithris IF:

Gus faicinn mar a tha an MAX coitcheann seo Ma tha foirmle ag obair air dàta fìor, feuch an smaoinich thu air an eisimpleir a leanas. A dh 'aindeoin, tha bòrd agad le toraidhean leum fada grunn oileanach. Tha an clàr a 'toirt a-steach an dàta airson trì cuairtean, agus tha thu a' coimhead airson an toradh as fheàrr bho lùth-chleasaiche sònraichte, abair Jacob. Le ainmean nan oileanach ann an A2:A10 agus astaran ann an C2:C10, tha an fhoirmle a’ gabhail an cruth seo:

=MAX(IF(A2:A10="Jacob", C2:C10))

Thoir an aire gur foirmle rèiteFeumar a chuir a-steach an-còmhnaidh le bhith a’ putadh air na h-iuchraichean Ctrl + Shift + Enter aig an aon àm. Mar thoradh air an sin, tha e air a chuairteachadh gu fèin-ghluasadach le camagan lùbach mar a chithear san dealbh gu h-ìosal (cha bhith a’ taipeadh na braces le làimh ag obair!).

I duilleagan-obrach fìor, tha e nas fhasa an slat-tomhais a chuir a-steach ann an cuid cealla, gus an urrainn dhut an suidheachadh atharrachadh gu furasta gun a bhith ag atharrachadh na foirmle. Mar sin, bidh sinn a’ sgrìobhadh an ainm a tha thu ag iarraidh ann am F1 agus a’ faighinn an toradh a leanas:

=MAX(IF(A2:A10=F1, C2:C10))

Mar a tha am foirmle seo ag obair

Anns an loidsig deuchainn air gnìomh IF, bidh sinn a’ dèanamh coimeas eadar liosta nan ainmean (A2: A10) leis an ainm targaid (F1). 'S e toradh na h-obrach seo sreath de TRUE agus FALSE, far a bheil na luachan TRUE a' riochdachadh ainmean a tha a' freagairt ris an ainm targaid (Jacob):

Airson an luach_ if_true argamaid, bheir sinn seachad toraidhean leum fada (C2: C10), mar sin ma tha an deuchainn loidsigeach a’ measadh gu TRUE, thèid an àireamh co-fhreagarrach bho cholbh C a thilleadh. Tha an argamaid value_ if_false air a fàgail a-mach, a' ciallachadh nach bi ach luach FALSE ann far nach eil an suidheachadh air a choileanadh:

{FALSE;FALSE;FALSE;5.48;5.42;5.57;FALSE;FALSE;FALSE}

Tha an t-sreath seo air a bhiadhadh dhan ghnìomh MAX, a tillidh tu an àireamh as motha às aonais luachan FALSE.

Gliocas. Gus na h-innealan a-staigh a chaidh a dheasbad gu h-àrd fhaicinn, tagh am pàirt co-fhreagarrach den fhoirmle anns an duilleag-obrach agad agus brùth air an iuchair F9. Gus am modh measaidh foirmle fhàgail, brùth air an iuchair Esc.

foirmle MAX IF le iomaslatan-tomhais

San suidheachadh nuair a dh'fheumas tu an luach as motha a lorg stèidhichte air barrachd air aon chumha, faodaidh tu an dàrna cuid:

Cleachd aithrisean neadachaidh IF gus slatan-tomhais a bharrachd a chur a-steach:

No làimhsich grunn shlatan-tomhais le bhith a’ cleachdadh an obrachaidh iomadachaidh:

Canaidh sinn gu bheil toraidhean bhalaich is nigheanan agad ann an aon chlàr agus gu bheil thu airson an leum as fhaide a lorg am measg nan nigheanan ann an cuairt 3. Airson sin a dhèanamh , cuiridh sinn a-steach a’ chiad shlat-tomhais (boireann) ann an G1, an dàrna slat-tomhais (3) ann an G2, agus cleachdaidh sinn na foirmlean a leanas gus an luach as motha obrachadh a-mach:

=MAX(IF(B2:B16=G1, IF(C2:C16=G2, D2:D16)))

=MAX(IF((B2:B16=G1)*(C2:C16=G2), D2:D16))

Seach gur e foirmlean eagrachaidh a th' anns an dà chuid, cuimhnich gun brùth thu Ctrl + Shift + Enter gus an lìonadh gu ceart.

Mar a chithear san dealbh-sgrìn gu h-ìosal, bheir na foirmlean an aon toradh a-mach, agus mar sin dè am fear a chleachdas tu a cùis dhut ur roghainn phearsanta. Dhòmhsa, tha am foirmle leis an loidsig Boolean nas fhasa a leughadh agus a thogail – leigidh e leat na h-uimhir de shuidheachaidhean a tha thu ag iarraidh a chur ris gun a bhith a’ neadachadh gnìomhan IF a bharrachd.

Mar a tha na foirmlean seo ag obair

Tha a’ chiad fhoirmle a’ cleachdadh dà ghnìomh neadachaidh IF gus dà shlat-tomhais a mheasadh. Ann an deuchainn loidsigeach a’ chiad aithris IF, bidh sinn a’ dèanamh coimeas eadar na luachan sa cholbh Gnè(B2: B16) leis an t-slat-tomhais ann an G1 ("Boireann"). Is e an toradh seo sreath de luachan TRUE agus FALSE far a bheil TRUE a’ riochdachadh dàta a tha a rèir an t-slat-tomhais:

{FALSE; FALSE; FALSE; TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; TRUE; TRUE; TRUE}

San aon dòigh, bidh an dàrna gnìomh IF a’ sgrùdadh nan luachan sa cholbh Cruinn (C2 :C16) mu choinneamh an t-slat-tomhais ann an G2.

Airson na h-argamaid value_if_true san dàrna aithris IF, bheir sinn seachad toraidhean an leum fhada (D2:D16), agus mar seo gheibh sinn na nithean aig a bheil TRUE anns a’ chiad dà raon ann an suidheachaidhean co-fhreagarrach (ie na nithean far a bheil an gnè “boireann” agus cruinn 3):

{FALSE; FALSE; FALSE; FALSE; FALSE; 4.63; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; 4.52}

Bidh an t-sreath mu dheireadh seo a’ dol gu gnìomh MAX agus tillidh e an àireamh as motha.

Tha an dàrna foirmle a' measadh nan aon shuidheachaidhean taobh a-staigh aon deuchainn loidsigeach agus tha an obrachadh iomadachaidh ag obair mar an gnìomhaiche AND:

Nuair a chleachdar na luachan TRUE is FALSE ann an gin obrachadh àireamhachd, tha iad air an tionndadh gu 1's agus 0's, fa leth. Agus leis gu bheil iomadachadh le 0 an-còmhnaidh a’ toirt neoni, chan eil anns an raon a thig às a sin ach 1 nuair a tha a h-uile suidheachadh TRUE. Tha an t-sreath seo air a mheasadh ann an deuchainn loidsigeach gnìomh IF, a thilleas na h-astaran a fhreagras air na h-eileamaidean 1 (TRUE).

MAX IF gun rèite

Tha mòran de luchd-cleachdaidh Excel, mise nam measg, nan claon-bhreith an aghaidh foirmlean array agus feuch ri faighinn cuidhteas iad far an gabh sin dèanamh. Gu fortanach, tha beagan ghnìomhan aig Microsoft Excel a bhios a’ làimhseachadh raon gu dùthchasach, agus is urrainn dhuinn fear a chleachdadhdhe na gnìomhan sin, 's e sin SUMPRODUCT, mar sheòrsa de "wrapper" timcheall air MAX.

Tha am foirmle coitcheann MAX IF gun eagar mar a leanas:

Gu nàdarra, faodaidh tu barrachd phaidhrichean raon/slat-tomhais a chur ris ma tha a dhìth.

Gus am foirmle fhaicinn an gnìomh, cleachdaidh sinn an dàta bhon eisimpleir roimhe. Is e an t-amas an leum as àirde de lùth-chleasaiche boireann fhaighinn ann an cuairt 3:

=SUMPRODUCT(MAX(((B2:B16=G1) * (C2:C16=G2) * (D2:D16))))

Tha am foirmle seo air a cho-fharpais le buille-iuchrach Enter àbhaisteach agus a’ tilleadh an aon toradh ris an fhoirmle MAX IF rèite:

A’ tilgeadh sùil nas mionaidiche air an dealbh gu h-àrd, chì thu gu bheil geansaidhean mì-dhligheach air an comharrachadh le “x” anns na h-eisimpleirean roimhe seo a-nis le 0 luachan ann an sreathan 3, 11 agus 15 , agus tha an ath earrann a’ mìneachadh carson.

Mar a tha am foirmle seo ag obair

Mar le foirmle MAX IF, bidh sinn a’ measadh dà shlatan-tomhais le bhith a’ dèanamh coimeas eadar gach luach anns a’ Gnè (B2: B16) agus Cruinn ( C2: C16) le slatan-tomhais ann an ceallan G1 agus G2. Is e an toradh dà raon de luachan TRUE agus FALSE. Le bhith ag iomadachadh eileamaidean nan arrays anns na h-aon shuidheachaidhean tionndaidhidh sin TRUE agus FALSE gu 1 agus 0, fa leth, far a bheil 1 a’ riochdachadh na nithean a choinnicheas an dà shlat-tomhais. Anns an treas sreath iomadaichte tha toraidhean leum fada (D2: D16). Agus leis gu bheil iomadachadh le 0 a’ toirt neoni, chan eil ach na nithean aig a bheil 1 (TRUE) anns na dreuchdan co-fhreagarrachmairsinn:

{0; 0; 0; 0; 0; 4.63; 0; 0; 0; 0; 0; 0; 0; 0; 4.52}

Air eagal 's gu bheil luach teacsa sam bith aig max_range , tillidh an obrachadh iomadachaidh a' mhearachd #VALUE air sgàth 's nach obraich am foirmle gu lèir.<3

Bheir an gnìomh MAX e às an seo agus tillidh e an àireamh as motha a choinnicheas ris na cumhachan ainmichte. Bidh an t-sreath a thig às a sin anns a bheil aon eileamaid {4.63} a’ dol chun ghnìomh SUMPRODUCT agus bheir e a-mach an àireamh as motha ann an cealla.

Thoir an aire. Air sgàth an loidsig shònraichte aice, tha am foirmle ag obair leis na h-uamhasan a leanas:

• Feumaidh àireamhan a-mhàin a bhith san raon far an lorg thu an luach as àirde. Ma tha luachan teacsa sam bith ann, #VALUE! mearachd air a thilleadh.
• Chan urrainn dhan fhoirmle measadh a dhèanamh air a' chumha "chan eil e co-ionnan ri neoni" ann an seata dàta àicheil. Gus an luach as motha a lorg gun aire air neoni, cleachd an dàrna cuid foirmle MAX IF no gnìomh MAXIFS.

Foirmle Excel MAX IF le OR loidsig

Gus an luach as motha a lorg nuair sam bith de na cumhaichean ainmichte air an coileanadh, cleachd am foirmle MAX IF air a bheil thu eòlach mu thràth leis an loidsig Boolean, ach cuir ris na cumhaichean an àite an iomadachadh.

Air neo, faodaidh tu am foirmle neo-eagraichte a leanas a chleachdadh :

Mar eisimpleir, obraich a-machan toradh as fheàrr ann an cuairtean 2 is 3. Thoir an aire gu bheil an obair ann an cànan Excel air a chur ri chèile ann an dòigh eadar-dhealaichte: thoir air ais an luach as motha mas e 2 no 3 a th’ anns a’ chuairt.

Leis na cuairtean ann am B2:B10 , na toraidhean ann an C2: C10 agus slatan-tomhais ann am F1 agus H1, tha am foirmle a’ dol mar a leanas:

=MAX(IF((B2:B10=F1) + (B2:B10=H1), C2:C10))

Cuir a-steach am foirmle le putadh air a’ phrìomh mheasgachadh Ctrl + Shift + Enter agus gheibh thu an toradh seo:

Faodar an luach as motha leis na h-aon chumhaichean a lorg cuideachd le bhith a’ cleachdadh na foirmle neo-eagraichte seo:

=SUMPRODUCT(MAX(((B2:B10=F1) + (B2:B10=H1)) * C2:C10))

Ach, feumaidh sinn na luachan "x" gu lèir ann an colbh C a chur an àite le neoni sa chùis seo a chionn 's nach obraich SUMPRODUCT MAX ach le dàta àireamhach:

Mar a dh'obraicheas na foirmlean seo

Bidh am foirmle rèite ag obair dìreach san aon dòigh ri MAX IF le AND logic ach a-mhàin gun tèid thu còmhla ris na slatan-tomhais le bhith a’ cleachdadh an obrachaidh cur-ris an àite iomadachadh. Ann am foirmlean rèite, bidh cur-ris ag obair mar an gnìomhaiche OR:

Le bhith a’ cur suas dà shreath de TRUE agus FALSE (a thig bho bhith a’ sgrùdadh nan luachan ann am B2: B10 mu choinneamh nan slatan-tomhais ann am F1 agus H1) a’ toirt a-mach sreath de 1 agus 0 far a bheil 1 a’ riochdachadh na nithean airson a bheil an dàrna suidheachadh TRUE agus 0 a’ riochdachadh na nithean airson a bheil an dà chumha FALSE. Mar thoradh air an sin, tha an gnìomh IF “a’ cumail ”na h-uile nithean ann an C2: C10 ( value_if_true ) airson a bheil suidheachadh sam bith TRUE (1); thèid FALSE a chur an àite na rudan a tha air fhàgail oir tha anChan eil argamaid value_if_false air a shònrachadh.

Tha am foirmle neo-eagraichte ag obair san aon dòigh. Is e an t-eadar-dhealachadh, an àite deuchainn loidsigeach IF, gu bheil thu ag iomadachadh na h-eileamaidean den raon 1 agus 0 leis na h-eileamaidean den raon toraidhean leum fada (C2: C10) anns na h-àiteachan co-fhreagarrach. Bidh seo a’ cur às do nithean nach eil a’ coinneachadh ri cumha sam bith (tha 0 anns a’ chiad sreath) agus a’ cumail na nithean a tha a’ coinneachadh ri aon de na cumhaichean (bidh 1 agad sa chiad sreath).

MAXIFS – dòigh fhurasta gus an ìre as àirde a lorg luach le cumhachan

Tha luchd-cleachdaidh Excel 2019, 2021 agus Excel 365 saor bhon trioblaid a bhith a’ taomadh arrays gus am foirmle MAX IF aca fhèin a thogail. Tha na dreachan seo de Excel a’ toirt seachad a’ ghnìomh MAXIFS ris an robhar a’ feitheamh o chionn fhada a nì lorg air an luach as motha le cumhachan cluiche chloinne.

Sa chiad argamaid de MAXIFS, cuiridh tu a-steach an raon anns am bu chòir an luach as àirde a lorg (D2: D16 sa chùis againn), agus anns na h-argamaidean às deidh sin faodaidh tu suas ri 126 paidhir raon / slatan-tomhais a chuir a-steach. Mar eisimpleir:

=MAXIFS(D2:D16, B2:B16, G1, C2:C16, G2)

Mar a chithear san dealbh-sgrìn gu h-ìosal, chan eil duilgheadas sam bith aig an fhoirmle shìmplidh seo le bhith a’ giullachd an raoin anns a bheil an dà chuid luachan àireamhach is teacsa:

Airson mion-fhiosrachadh mun ghnìomh seo, faic an gnìomh Excel MAXIFS le eisimpleirean foirmle.

Sin mar a lorgas tu an luach as motha le cumhachan ann an Excel. Tha mi a’ toirt taing dhut airson do leughadh agus tha mi an dòchas d’ fhaicinn air ar blog an ath thurasseachdain!

Cleachd leabhar-obrach airson luchdachadh a-nuas

Eisimpleirean foirmle Excel MAX IF (faidhle .xlsx)