Tabela e përmbajtjes
Tutoriali tregon se si të krijohen deklarata të shumta IF në Excel me AND si dhe me logjikën OSE. Gjithashtu, do të mësoni se si të përdorni IF së bashku me funksionet e tjera të Excel.
Në pjesën e parë të tutorialit tonë të Excel IF, ne shikuam se si të ndërtoni një deklaratë të thjeshtë IF me një kusht për tekstin, numra, data, bosh dhe jo bosh. Për analizë të fuqishme të të dhënave, megjithatë, shpesh mund t'ju duhet të vlerësoni kushte të shumta në të njëjtën kohë. Shembujt e formulave më poshtë do t'ju tregojnë mënyrat më efektive për ta bërë këtë.
Si të përdorni funksionin IF me kushte të shumta
Në thelb, ekzistojnë dy lloje të IF formula me kritere të shumta bazuar në logjikën DHE / OSE . Rrjedhimisht, në testin logjik të formulës suaj IF, duhet të përdorni një nga këto funksione:
- DHE funksioni - kthen TRUE nëse të gjitha kushtet plotësohen; FALSE ndryshe.
- Funksioni OSE - kthen TRUE nëse plotësohet ndonjë kusht i vetëm ; E rreme ndryshe.
Për të ilustruar më mirë pikën, le të hetojmë disa shembuj të formulave të jetës reale.
Deklarata e Excel IF me kushte të shumta (AND logjikë)
The formula e përgjithshme e Excel IF me dy ose më shumë kushte është kjo:
IF(AND( kushti1, kushti2, …), vlera_if_true, vlera_if_false)Përkthyer në një njeri gjuhë, formula thotë: Nëse kushti 1 është i vërtetë DHE kushti 2 është i vërtetë, kthehu vlera_nëse_e vërtetë ; ndryshe ktheni value_if_false .
Supozoni se keni një tabelë që rendit rezultatet e dy testeve në kolonat B dhe C. Për të kaluar provimin përfundimtar, një student duhet t'i ketë të dyja pikët më të mëdha se 50.
Për testin logjik, përdorni deklaratën AND të mëposhtme: AND(B2>50, C2>50)
Nëse të dyja kushtet janë të vërteta, formula do të kthejë "Kalojë"; nëse ndonjë kusht është i rremë - "Dështon".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Lehtë, apo jo? Pamja e ekranit më poshtë dëshmon se formula jonë Excel IF / AND funksionon siç duhet: 
Në mënyrë të ngjashme, mund të përdorni funksionin Excel IF me shumë kushte teksti .
Për Për shembull, për të nxjerrë "Mirë" nëse të dyja B2 dhe C2 janë më të mëdha se 50, "E keqe" përndryshe, formula është:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") 
Shënim i rëndësishëm! Funksioni AND kontrollon të gjitha kushtet , edhe nëse ato të testuara tashmë janë vlerësuar në FALSE. Një sjellje e tillë është paksa e pazakontë pasi në shumicën e gjuhëve të programimit, kushtet e mëvonshme nuk testohen nëse ndonjë nga testet e mëparshme është kthyer FALSE.
Në praktikë, një deklaratë në dukje e saktë IF mund të rezultojë në një gabim për shkak të kësaj specifika. Për shembull, formula e mëposhtme do të kthente #DIV/0! (gabim "pjesto me zero") nëse qeliza A2 është e barabartë me 0:
=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")
Për ta shmangur këtë, duhet të përdorni një funksion IF të mbivendosur:
=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
Për më shumë informacion, ju lutemi shihni formulën IF AND në Excel.
Funksioni Excel IF me shumëkushte (logjikë OSE)
Për të bërë një gjë nëse plotësohet ndonjë kusht , përndryshe bëni diçka tjetër, përdorni këtë kombinim të funksioneve IF dhe OR:
IF(OR( kushti1 , kushti2 , …), vlera_if_true, vlera_if_false)Dallimi nga formula IF / DHE e diskutuar më sipër është se Excel kthen TRUE nëse ndonjë nga kushtet e specifikuara është e vërtetë.
Pra, nëse në formulën e mëparshme përdorim OR në vend të AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Atëherë kushdo që ka më shumë se 50 pikë në secilin provim do të marrë "Kalo" në kolona D. Me kushte të tilla, studentët tanë kanë një shans më të mirë për të kaluar provimin përfundimtar (Yvette është veçanërisht e pafat duke dështuar me vetëm 1 pikë :) 
Këshillë. Në rast se po krijoni një deklaratë të shumëfishtë IF me tekst dhe po testoni një vlerë në një qelizë me logjikën OSE (d.m.th. një qelizë mund të jetë "kjo" ose "ajo"), atëherë mund të ndërtoni një më kompakte formulë duke përdorur një konstante grupi.
Për shembull, për të shënuar një shitje si "të mbyllur" nëse qeliza B2 është ose "dorëzuar" ose "paguar", formula është:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
Më shumë shembuj formulash mund të gjenden në funksionin Excel IF OR.
IF me shumë AND & Deklaratat OSE
Nëse detyra juaj kërkon vlerësimin e disa grupeve të kushteve të shumta, do t'ju duhet të përdorni të dyja AND & OSE funksionon në të njëjtën kohë.
Në tabelën tonë të mostrës, supozoni se keni kriteret e mëposhtme për të kontrolluar rezultatet e provimit:
- Kushti 1:provimi 1>50 dhe provimi 2>50
- Kushti 2: provimi 1>40 dhe provimi 2>60
Nëse plotësohet një nga kushtet, provimi përfundimtar konsiderohet i kaluar.
Në pamje të parë, formula duket pak e ndërlikuar, por në fakt nuk është! Ju thjesht shprehni secilën prej kushteve të mësipërme si një deklaratë AND dhe i vendosni ato në funksionin OR (pasi nuk është e nevojshme të plotësohen të dyja kushtet, do të mjaftojë njëra prej tyre):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Më pas, përdorni funksioni OR për testin logjik të IF dhe jep vlerat e dëshiruara value_if_true dhe value_if_false . Si rezultat, ju merrni formulën e mëposhtme IF me kushte të shumta DHE / OSE:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
Pamja e ekranit më poshtë tregon se ne e kemi bërë formulën siç duhet: 
Natyrshëm , nuk jeni të kufizuar në përdorimin e vetëm dy funksioneve DHE/OR në formulat tuaja IF. Ju mund të përdorni aq sa kërkon logjika e biznesit tuaj, me kusht që:
- Në Excel 2007 dhe më lart, të mos keni më shumë se 255 argumente dhe gjatësia totale e formulës IF të mos kalojë 8192 karaktere.
- Në Excel 2003 e më poshtë, nuk ka më shumë se 30 argumente dhe gjatësia totale e formulës suaj IF nuk i kalon 1024 karaktere.
Deklarata IF e ndërlidhur në kontrolloni testet e shumta logjike
Nëse dëshironi të vlerësoni teste të shumta logjike brenda një formule të vetme, atëherë mund të futni disa funksione njëri në tjetrin. Funksione të tilla quhen të mbivendosurIF funksionet . Ato rezultojnë veçanërisht të dobishme kur dëshironi të ktheni vlera të ndryshme në varësi të rezultateve të testeve logjike.
Ja një shembull tipik: supozoni se doni të kualifikoni arritjet e nxënësve si " Mirë ", " Kënaqshme " dhe " Dobët " bazuar në rezultatet e mëposhtme:
- Mirë: 60 ose më shumë (>=60)
- Kënaqshme: ndërmjet 40 dhe 60 (>40 dhe <60)
- Dobët: 40 ose më pak (<=40)
Para se të shkruani një formulë, merrni parasysh rendin të funksioneve që do të folesh. Excel do të vlerësojë testet logjike sipas renditjes që ato shfaqen në formulë. Pasi një kusht vlerësohet në TRUE, kushtet pasuese nuk testohen, që do të thotë se formula ndalon pas rezultatit të parë TRUE.
Në rastin tonë, funksionet renditen nga më i madhi tek më i vogli:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Natyrisht, mund të futni më shumë funksione nëse është e nevojshme (deri në 64 në versionet moderne). 
Për më shumë informacion, ju lutemi shikoni Si të përdorni deklarata të shumta të mbivendosura IF në Excel.
Formula e grupit Excel IF me kushte të shumta
Një mënyrë tjetër për të testuar një Excel IF kushte të shumëfishta është duke përdorur një formulë grupi.
Për të vlerësuar kushtet me logjikën AND, përdorni yllin:
IF( kushti1 ) * ( kushti2 ) * …, vlera_nëse_true, vlera_nëse_false)Për të testuar kushtet me logjikën OSE, përdorni shenjën plus:
Për të plotësuar saktë një formulë grupi, shtypni së bashku tastet Ctrl + Shift + Enter. Në Excel 365 dhe Excel 2021, kjo funksionon gjithashtu si një formulë e rregullt për shkak të mbështetjes për vargje dinamike.
Për shembull, për të marrë "Pass" nëse të dyja B2 dhe C2 janë më të mëdha se 50, formula është:
=IF((B2>50) * (C2>50), "Pass", "Fail") 
Në Excel 365 tim, një formulë normale funksionon mirë (siç mund ta shihni në pamjet e mësipërme). Në Excel 2019 dhe më poshtë, mos harroni ta bëni atë një formulë grupi duke përdorur shkurtoren Ctrl + Shift + Enter.
Për të vlerësuar kushte të shumta me logjikën OSE, formula është:
=IF((B2>50) + (C2>50), "Pass", "Fail") 
Përdorimi i IF së bashku me funksionet e tjera
Ky seksion shpjegon se si të përdorni IF në kombinim me funksionet e tjera të Excel dhe çfarë përfitimesh ju jep kjo.
Shembulli 1. Nëse #N /Një gabim në VLOOKUP
Kur VLOOKUP ose funksioni tjetër i kërkimit nuk mund të gjejë diçka, ai kthen një gabim #N/A. Për t'i bërë tabelat tuaja të duken më bukur, mund të ktheni zero, bosh ose tekst specifik nëse #N/A. Për këtë, përdorni këtë formulë të përgjithshme:
Për shembull:
Nëse #N/ Një kthim 0:
Nëse vlera e kërkimit në E1 nuk gjendet, formula kthen zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
Nëse #N/A kthen bosh:
Nëse vlera e kërkimit nuk gjendet, formula nuk kthen asgjë (një varg bosh).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
Nëse #N/A kthen një tekst të caktuar:
Nëse Vlera e kërkimit nuk është gjetur,formula kthen tekst specifik.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) 
Për më shumë shembuj të formulave, ju lutemi shihni VLOOKUP me deklaratën IF në Excel.
Shembulli 2. IF me SUM, AVERAGE, MIN dhe MAX funksionet
Për të përmbledhur vlerat e qelizave bazuar në kritere të caktuara, Excel ofron funksionet SUMIF dhe SUMIFS.
Në disa situata, logjika e biznesit tuaj mund të kërkojë përfshirjen e funksionit SUM në testin logjik të IF. Për shembull, për të kthyer etiketa të ndryshme teksti në varësi të shumës së vlerave në B2 dhe C2, formula është:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
Nëse shuma është më e madhe se 130, rezultati është "i mirë "; nëse është më i madh se 110 – "kënaqshëm", nëse 110 ose më i ulët - "i dobët". 
Në një mënyrë të ngjashme, mund të futni funksionin AVERAGE në testin logjik të IF dhe të ktheni etiketa të ndryshme bazuar në rezultatin mesatar :
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Duke supozuar se rezultati total është në kolonën D, mund të identifikoni vlerat më të larta dhe më të ulëta me ndihmën e funksioneve MAX dhe MIN:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
Për t'i pasur të dyja etiketat në një kolonë, ndërlidhni funksionet e mësipërme njëra në tjetrën:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) 
Po kështu, mund të përdorni IF së bashku me porosinë tuaj funksionet. Për shembull, mund ta kombinoni me GetCellColor ose GetCellFontColor për të kthyer rezultate të ndryshme bazuar në një ngjyrë qelize.
Përveç kësaj, Excel ofron një numër funksionesh për llogaritjen e të dhënave bazuar në kushtet. Për shembuj të detajuar të formulës, ju lutem shikoni sa vijonmësime:
- COUNTIF - numëro qelizat që plotësojnë një kusht
- COUNTIFS - numëro qelizat me kritere të shumta
- SUMIF - shuma me kusht qelizat
- SUMIFS - shuma e qelizave me kritere të shumta
Shembulli 3. IF me ISNUMBER, ISTEXT dhe ISBLANK
Për të identifikuar tekstin, numrat dhe qelizat bosh, Microsoft Excel ofron funksione të veçanta si ISTEXT, ISNUMBER dhe ISBLANK. Duke i vendosur ato në testet logjike të tre deklaratave IF të mbivendosur, ju mund të identifikoni të gjitha llojet e ndryshme të të dhënave në të njëjtën kohë:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) 
Shembulli 4. IF dhe CONCATENATE
Për nxirrni rezultatin e IF dhe disa tekste në një qelizë, përdorni funksionet CONCATENATE ose CONCAT (në Excel 2016 - 365) dhe IF së bashku. Për shembull:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Duke parë pamjen e ekranit më poshtë, vështirë se do të keni nevojë për ndonjë shpjegim se çfarë bën formula: 
NËSE ISERROR / Formula ISNA në Excel
Versionet moderne të Excel kanë funksione të veçanta për të kapur gabimet dhe për t'i zëvendësuar ato me një llogaritje tjetër ose vlerë të paracaktuar - IFERROR (në Excel 2007 e më vonë) dhe IFNA (në Excel 2013 e më vonë). Në versionet e mëparshme të Excel, në vend të tyre mund të përdorni kombinimet IF ISERROR dhe IF ISNA.
Dallimi është se IFERROR dhe ISERROR trajtojnë të gjitha gabimet e mundshme të Excel, duke përfshirë #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, dhe #NULL!. Ndërsa IFNA dhe ISNA specializohen vetëm në gabimet #N/A.
Për shembull, për tëzëvendëso gabimin "pjesto me zero" (#DIV/0!) me tekstin tënd të personalizuar, mund të përdorësh formulën e mëposhtme:
=IF(ISERROR(A2/B2), "N/A", A2/B2) 
Dhe kjo është gjithçka që kam për të thënë për përdorimin e Funksioni IF në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!
Praktikoni librin e punës për shkarkim
Excel IF kritere të shumta - shembuj (skedari .xlsx)
