টিউটোরিয়ালটি দেখায় কিভাবে Excel এ AND এর পাশাপাশি OR লজিক দিয়ে একাধিক IF স্টেটমেন্ট তৈরি করতে হয়। এছাড়াও, আপনি অন্যান্য এক্সেল ফাংশনগুলির সাথে কিভাবে IF ব্যবহার করবেন তা শিখবেন।

আমাদের এক্সেল IF টিউটোরিয়ালের প্রথম অংশে, আমরা পাঠ্যের জন্য একটি শর্ত সহ একটি সাধারণ IF স্টেটমেন্ট কীভাবে তৈরি করা যায় তা দেখেছি, সংখ্যা, তারিখ, ফাঁকা এবং অ-খালি। শক্তিশালী ডেটা বিশ্লেষণের জন্য, যাইহোক, আপনাকে প্রায়ই এক সময়ে একাধিক শর্ত মূল্যায়ন করতে হতে পারে। নীচের সূত্র উদাহরণগুলি আপনাকে এটি করার সবচেয়ে কার্যকর উপায়গুলি দেখাবে৷

একাধিক শর্তগুলির সাথে IF ফাংশন কীভাবে ব্যবহার করবেন

সংক্ষেপে, দুটি ধরণের রয়েছে AND/OR যুক্তির উপর ভিত্তি করে একাধিক মানদণ্ড সহ IF সূত্র । ফলস্বরূপ, আপনার IF সূত্রের যৌক্তিক পরীক্ষায়, আপনার এই ফাংশনগুলির মধ্যে একটি ব্যবহার করা উচিত:

• AND ফাংশন - সমস্ত শর্ত পূরণ হলে TRUE প্রদান করে; অন্যথায় মিথ্যা৷
• অথবা ফাংশন - যদি কোন একক শর্ত পূরণ করা হয় তবে TRUE প্রদান করে; অন্যথায় মিথ্যা।

বিন্দুটি আরও ভালভাবে ব্যাখ্যা করার জন্য, আসুন কিছু বাস্তব-জীবনের সূত্রের উদাহরণ অনুসন্ধান করা যাক।

এক্সেল IF বিবৃতি একাধিক শর্ত সহ (এবং যুক্তি)

দুই বা ততোধিক শর্ত সহ Excel IF এর জেনেরিক সূত্র হল:

IF(AND( condition1, condition2, …), value_if_true, value_if_false)

মানুষে অনুবাদ করা হয়েছে ভাষা, সূত্র বলছে: শর্ত 1 সত্য এবং শর্ত 2 সত্য হলে, ফিরে আসুন value_if_true ; অন্যথায় value_if_false ফেরত দিন।

ধরুন আপনার B এবং C কলামে দুটি পরীক্ষার স্কোর তালিকাভুক্ত একটি টেবিল রয়েছে। চূড়ান্ত পরীক্ষায় উত্তীর্ণ হওয়ার জন্য, একজন শিক্ষার্থীর উভয়ের স্কোর 50-এর বেশি হতে হবে।

যৌক্তিক পরীক্ষার জন্য, আপনি নিম্নলিখিত AND বিবৃতিটি ব্যবহার করুন: AND(B2>50, C2>50)

যদি উভয় শর্তই সত্য হয়, সূত্রটি "পাস" প্রদান করবে; যদি কোনো শর্ত মিথ্যা হয় - "ফেল"।

=IF(AND(B2>50, B2>50), "Pass", "Fail")

সহজ, তাই না? নীচের স্ক্রিনশটটি প্রমাণ করে যে আমাদের এক্সেল IF /AND সূত্র সঠিকভাবে কাজ করে:

একইভাবে, আপনি একাধিক টেক্সট শর্ত সহ এক্সেল IF ফাংশন ব্যবহার করতে পারেন।

এর জন্য উদাহরণস্বরূপ, B2 এবং C2 উভয়ই 50-এর বেশি হলে "ভাল" আউটপুট করতে, "খারাপ" অন্যথায়, সূত্রটি হল:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")

গুরুত্বপূর্ণ নোট! AND ফাংশন সমস্ত শর্ত পরীক্ষা করে, এমনকি যদি ইতিমধ্যে পরীক্ষিত একটি(গুলি) FALSE তে মূল্যায়ন করা হয়। এই ধরনের আচরণ কিছুটা অস্বাভাবিক কারণ বেশিরভাগ প্রোগ্রামিং ল্যাঙ্গুয়েজগুলিতে, পূর্ববর্তী কোনো পরীক্ষায় যদি FALSE ফিরে আসে তাহলে পরবর্তী শর্তগুলি পরীক্ষা করা হয় না৷

বাস্তবে, একটি আপাতদৃষ্টিতে সঠিক IF স্টেটমেন্ট এর কারণে একটি ত্রুটি হতে পারে নির্দিষ্টতা উদাহরণস্বরূপ, নীচের সূত্রটি ফেরত দেবে #DIV/0! ("শূন্য দ্বারা ভাগ করুন" ত্রুটি) যদি সেল A2 0 এর সমান হয়:

=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")

এটি এড়াতে, আপনার একটি নেস্টেড IF ফাংশন ব্যবহার করা উচিত:

=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad") <3

আরো তথ্যের জন্য, অনুগ্রহ করে এক্সেলে IF AND সূত্র দেখুন৷

এক্সেল IF ফাংশন একাধিক সহশর্ত (বা যুক্তি)

কোন শর্ত পূরণ হলে একটি কাজ করতে, অন্যথায় অন্য কিছু করতে, IF এবং OR ফাংশনগুলির এই সংমিশ্রণটি ব্যবহার করুন:

IF(OR( condition1 , condition2 , …), value_if_true, value_if_false)

উপরে আলোচনা করা IF / AND সূত্র থেকে পার্থক্য হল যে নির্দিষ্ট শর্তগুলির মধ্যে যেকোনও সত্য হলে Excel TRUE প্রদান করে।

সুতরাং, যদি পূর্ববর্তী সূত্রে, আমরা AND এর পরিবর্তে OR ব্যবহার করি:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

তাহলে যে কেউ উভয় পরীক্ষায় 50 এর বেশি পয়েন্ট পাবে সে "পাস" পাবে কলাম D. এই ধরনের শর্তগুলির সাথে, আমাদের ছাত্রদের চূড়ান্ত পরীক্ষায় উত্তীর্ণ হওয়ার আরও ভাল সুযোগ রয়েছে (ইভেট বিশেষত দুর্ভাগ্যজনক মাত্র 1 পয়েন্টে ব্যর্থ হওয়া :)

টিপ। আপনি যদি একটি টেক্সট সহ একাধিক IF স্টেটমেন্ট তৈরি করেন এবং OR যুক্তি দিয়ে একটি কক্ষে একটি মান পরীক্ষা করছেন (অর্থাৎ একটি সেল "এই" বা "সেটি" হতে পারে), তাহলে আপনি আরও কমপ্যাক্ট তৈরি করতে পারেন একটি অ্যারে ধ্রুবক ব্যবহার করে সূত্র।

উদাহরণ স্বরূপ, সেল B2 হয় "ডেলিভার করা" বা "পেইড" হলে সেলকে "বন্ধ" হিসেবে চিহ্নিত করতে, সূত্রটি হল:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

এক্সেল IF OR ফাংশনে আরও সূত্রের উদাহরণ পাওয়া যাবে।

ইফ একাধিক AND & বা বিবৃতি

যদি আপনার টাস্কের একাধিক শর্তের কয়েকটি সেট মূল্যায়নের প্রয়োজন হয়, তাহলে আপনাকে AND & উভয়ই ব্যবহার করতে হবে। অথবা একটি সময়ে ফাংশন।

আমাদের নমুনা টেবিলে, ধরুন আপনার পরীক্ষার ফলাফল পরীক্ষা করার জন্য নিম্নলিখিত মানদণ্ড রয়েছে:

• শর্ত 1:exam1>50 এবং exam2>50
• শর্ত 2: exam1>40 এবং exam2>60

যদি যেকোনও একটি শর্ত পূরণ করা হয়, তাহলে চূড়ান্ত পরীক্ষা পাস বলে গণ্য হবে।

প্রথম দৃষ্টিতে, সূত্রটি একটু জটিল মনে হলেও বাস্তবে তা নয়! আপনি উপরের প্রতিটি শর্তকে একটি AND স্টেটমেন্ট হিসাবে প্রকাশ করুন এবং সেগুলিকে OR ফাংশনে নেস্ট করুন (যেহেতু উভয় শর্ত পূরণ করার প্রয়োজন নেই, উভয়ই যথেষ্ট হবে):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

তারপর, ব্যবহার করুন IF এর লজিক্যাল পরীক্ষার জন্য OR ফাংশন এবং পছন্দসই value_if_true এবং value_if_false মান সরবরাহ করে। ফলস্বরূপ, আপনি একাধিক AND / OR শর্তাবলী সহ নিম্নলিখিত IF সূত্রটি পাবেন:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

নীচের স্ক্রিনশটটি নির্দেশ করে যে আমরা সূত্রটি ঠিক করেছি:

স্বাভাবিকভাবে , আপনি আপনার IF সূত্রে শুধুমাত্র দুটি AND/OR ফাংশন ব্যবহার করার মধ্যে সীমাবদ্ধ নন। আপনার ব্যবসায়িক যুক্তির প্রয়োজন অনুসারে আপনি সেগুলির অনেকগুলি ব্যবহার করতে পারেন, তবে শর্ত থাকে যে:

• Excel 2007 এবং উচ্চতর, আপনার কাছে 255টির বেশি আর্গুমেন্ট নেই এবং IF সূত্রের মোট দৈর্ঘ্য অতিক্রম না করে 8,192 অক্ষর।
• এক্সেল 2003 এবং তার নিচে, 30টির বেশি আর্গুমেন্ট নেই এবং আপনার IF সূত্রের মোট দৈর্ঘ্য 1,024 অক্ষরের বেশি নয়।

নেস্টেড IF স্টেটমেন্ট একাধিক লজিক্যাল পরীক্ষা চেক করুন

আপনি যদি একটি সূত্রের মধ্যে একাধিক লজিক্যাল পরীক্ষার মূল্যায়ন করতে চান, তাহলে আপনি একাধিক ফাংশন একে অপরের মধ্যে নেস্ট করতে পারেন। এই ধরনের ফাংশনকে বলা হয় নেস্টেডIF ফাংশন । যৌক্তিক পরীক্ষার ফলাফলের উপর নির্ভর করে আপনি যখন বিভিন্ন মান ফেরত দিতে চান তখন তারা বিশেষভাবে কার্যকর বলে প্রমাণিত হয়।

এখানে একটি সাধারণ উদাহরণ: ধরুন আপনি " ভাল " হিসাবে ছাত্রদের কৃতিত্বের যোগ্যতা অর্জন করতে চান। নিম্নলিখিত স্কোরের উপর ভিত্তি করে " সন্তোষজনক " এবং " খারাপ ":

• ভাল: 60 বা তার বেশি (>=60)
• সন্তোষজনক: 40 এবং 60 এর মধ্যে (>40 এবং <60)
• দরিদ্র: 40 বা তার কম (<=40)

একটি সূত্র লেখার আগে, অর্ডারটি বিবেচনা করুন ফাংশন আপনি নেস্ট যাচ্ছেন. এক্সেল যৌক্তিক পরীক্ষাগুলিকে সূত্রে প্রদর্শিত ক্রমে মূল্যায়ন করবে। একবার একটি শর্ত সত্যে মূল্যায়ন করা হলে, পরবর্তী শর্তগুলি পরীক্ষা করা হয় না, যার অর্থ প্রথম সত্য ফলাফলের পরে সূত্রটি বন্ধ হয়ে যায়।

আমাদের ক্ষেত্রে, ফাংশনগুলিকে সবচেয়ে বড় থেকে ছোট পর্যন্ত সাজানো হয়:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

স্বাভাবিকভাবে, প্রয়োজন হলে আপনি আরও ফাংশন নেস্ট করতে পারেন (আধুনিক সংস্করণে 64 পর্যন্ত)।

আরো তথ্যের জন্য, অনুগ্রহ করে দেখুন কিভাবে এক্সেলে একাধিক নেস্টেড IF স্টেটমেন্ট ব্যবহার করবেন।

এক্সেল IF অ্যারে সূত্র একাধিক শর্ত সহ

পরীক্ষা করার জন্য একটি Excel IF পাওয়ার আরেকটি উপায় একাধিক শর্ত একটি অ্যারে সূত্র ব্যবহার করে।

AND যুক্তি দিয়ে শর্ত মূল্যায়ন করতে, তারকাচিহ্ন ব্যবহার করুন:

IF( condition1 ) * ( condition2 ) * …, value_if_true, value_if_false)

OR যুক্তি দিয়ে শর্ত পরীক্ষা করতে, যোগ চিহ্নটি ব্যবহার করুন:

IF( condition1 ) + ( condition2 ) + …,value_if_true, value_if_false)

একটি অ্যারে সূত্র সঠিকভাবে সম্পূর্ণ করতে, Ctrl + Shift + Enter কী একসাথে টিপুন। এক্সেল 365 এবং এক্সেল 2021-এ, এটি ডায়নামিক অ্যারেগুলির সমর্থনের কারণে একটি নিয়মিত সূত্র হিসাবেও কাজ করে৷

উদাহরণস্বরূপ, যদি B2 এবং C2 উভয়ই 50-এর বেশি হয় তবে "পাস" পেতে, সূত্রটি হল:

=IF((B2>50) * (C2>50), "Pass", "Fail")

আমার এক্সেল 365-এ, একটি সাধারণ সূত্র ঠিক কাজ করে (যেমন আপনি উপরের স্ক্রিনশটগুলিতে দেখতে পাচ্ছেন)। Excel 2019 এবং তার নিচের ক্ষেত্রে, Ctrl + Shift + Enter শর্টকাট ব্যবহার করে এটিকে একটি অ্যারে সূত্র তৈরি করতে ভুলবেন না।

OR যুক্তি দিয়ে একাধিক শর্তের মূল্যায়ন করতে, সূত্রটি হল:

=IF((B2>50) + (C2>50), "Pass", "Fail")

অন্যান্য ফাংশনের সাথে একসাথে IF ব্যবহার করা

এই বিভাগটি ব্যাখ্যা করে কিভাবে অন্যান্য এক্সেল ফাংশনগুলির সাথে IF ব্যবহার করতে হয় এবং এটি আপনাকে কী সুবিধা দেয়।

উদাহরণ 1. যদি #N /VLOOKUP-এ একটি ত্রুটি

যখন VLOOKUP বা অন্যান্য লুকআপ ফাংশন কিছু খুঁজে পায় না, এটি একটি #N/A ত্রুটি প্রদান করে। আপনার টেবিলগুলিকে আরও সুন্দর দেখাতে, আপনি #N/A হলে শূন্য, ফাঁকা বা নির্দিষ্ট পাঠ্য ফেরত দিতে পারেন। এর জন্য, এই জেনেরিক সূত্রটি ব্যবহার করুন:

IF(ISNA(VLOOKUP(…)), value_if_na , VLOOKUP(…))

উদাহরণস্বরূপ:

যদি #N/ একটি রিটার্ন 0:

যদি E1-এ লুকআপ মান পাওয়া না যায়, সূত্রটি শূন্য দেয়।

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

যদি #N/A ফাঁকা দেয়:

লুকআপ মান পাওয়া না গেলে, সূত্রটি কিছুই প্রদান করে না (একটি খালি স্ট্রিং)।

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

যদি #N/A নির্দিষ্ট পাঠ্য ফেরত দেয়:

যদি সন্ধান মান পাওয়া যায় না,সূত্র নির্দিষ্ট টেক্সট প্রদান করে।

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))

আরো সূত্র উদাহরণের জন্য, অনুগ্রহ করে এক্সেলের IF স্টেটমেন্ট সহ VLOOKUP দেখুন।

উদাহরণ 2. SUM, AVERAGE, MIN এবং MAX সহ IF ফাংশন

নির্দিষ্ট মানদণ্ডের উপর ভিত্তি করে সেল মানগুলি যোগ করতে, এক্সেল SUMIF এবং SUMIFS ফাংশনগুলি প্রদান করে৷

কিছু ​​পরিস্থিতিতে, আপনার ব্যবসার লজিকের প্রয়োজন হতে পারে IF এর লজিক্যাল পরীক্ষায় SUM ফাংশন অন্তর্ভুক্ত করা৷ উদাহরণস্বরূপ, B2 এবং C2 এর মানের যোগফলের উপর নির্ভর করে বিভিন্ন টেক্সট লেবেল ফেরত দিতে, সূত্রটি হল:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

যদি যোগফল 130-এর বেশি হয়, ফলাফল "ভাল "; যদি 110-এর বেশি হয় - "সন্তোষজনক', যদি 110 বা কম - "দরিদ্র।"

একইভাবে, আপনি IF-এর লজিক্যাল পরীক্ষায় AVERAGE ফাংশন এম্বেড করতে পারেন এবং গড় স্কোরের উপর ভিত্তি করে বিভিন্ন লেবেল ফেরত দিতে পারেন। :

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

মোট স্কোরটি কলাম D-এ অনুমান করে, আপনি MAX এবং MIN ফাংশনের সাহায্যে সর্বোচ্চ এবং সর্বনিম্ন মান সনাক্ত করতে পারেন:

=IF(D2=MAX($D$2:$D$10), "Best result", "") <3

=IF(D2=MAX($D$2:$D$10), "Best result", "")

একটি কলামে উভয় লেবেল থাকতে, উপরের ফাংশনগুলিকে একটির মধ্যে নেস্ট করুন:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))

অনুরূপভাবে, আপনি আপনার কাস্টম সহ IF ব্যবহার করতে পারেন ফাংশন। উদাহরণ স্বরূপ, সেলের রঙের উপর ভিত্তি করে বিভিন্ন ফলাফল দিতে আপনি এটিকে GetCellColor বা GetCellFontColor এর সাথে একত্রিত করতে পারেন।

এছাড়া, Excel শর্তের উপর ভিত্তি করে ডেটা গণনা করার জন্য অনেকগুলি ফাংশন প্রদান করে। বিস্তারিত সূত্র উদাহরণের জন্য, নিম্নলিখিত চেক আউট অনুগ্রহ করেটিউটোরিয়াল:

• COUNTIF - একটি শর্ত পূরণ করে এমন কক্ষ গণনা করুন
• COUNTIFS - একাধিক মানদণ্ড সহ কক্ষ গণনা করুন
• SUMIF - শর্তসাপেক্ষে কোষের যোগফল
• SUMIFS - একাধিক মানদণ্ড সহ কোষের যোগফল

উদাহরণ 3. ISNUMBER, ISTEXT এবং ISBLANK সহ IF

পাঠ্য, সংখ্যা এবং ফাঁকা ঘর সনাক্ত করতে, Microsoft Excel বিশেষ ফাংশন প্রদান করে যেমন ISTEXT, ISNUMBER এবং ISBLANK। তিনটি নেস্টেড IF স্টেটমেন্টের যৌক্তিক পরীক্ষায় তাদের স্থাপন করে, আপনি একযোগে সমস্ত বিভিন্ন ডেটা প্রকার সনাক্ত করতে পারেন:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))

উদাহরণ 4. IF এবং CONCATENATE

প্রতি IF এর ফলাফল এবং কিছু টেক্সট একটি ঘরে আউটপুট করুন, CONCATENATE বা CONCAT (Excel 2016 - 365-এ) এবং IF ফাংশন একসাথে ব্যবহার করুন। উদাহরণস্বরূপ:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

নীচের স্ক্রিনশটটি দেখলে, সূত্রটি কী করে তার জন্য আপনার খুব কমই কোনো ব্যাখ্যার প্রয়োজন হবে:

ইফরির হলে / Excel-এ ISNA সূত্র

Excel-এর আধুনিক সংস্করণের বিশেষ ফাংশন রয়েছে ত্রুটিগুলিকে ফাঁদে ফেলতে এবং সেগুলিকে অন্য গণনা বা পূর্বনির্ধারিত মান দিয়ে প্রতিস্থাপন করার জন্য - IFERROR (Excel 2007 এবং পরবর্তীতে) এবং IFNA (Excel 2013 এবং পরবর্তীতে)। পূর্ববর্তী এক্সেল সংস্করণগুলিতে, আপনি পরিবর্তে IF ISERROR এবং IF ISNA সমন্বয়গুলি ব্যবহার করতে পারেন৷

পার্থক্য হল যে IFERROR এবং ISERROR সমস্ত সম্ভাব্য এক্সেল ত্রুটিগুলি পরিচালনা করে, যার মধ্যে #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, এবং #NULL!। যদিও IFNA এবং ISNA শুধুমাত্র #N/A ত্রুটিতে বিশেষজ্ঞ।

উদাহরণস্বরূপ,আপনার কাস্টম পাঠ্যের সাথে "শূন্য দ্বারা ভাগ করুন" ত্রুটিটি (#DIV/0!) প্রতিস্থাপন করুন, আপনি নিম্নলিখিত সূত্রটি ব্যবহার করতে পারেন:

=IF(ISERROR(A2/B2), "N/A", A2/B2)

এবং এটি ব্যবহার করার বিষয়ে আমার শুধু এটাই বলতে হবে এক্সেলে IF ফাংশন। পড়ার জন্য আমি আপনাকে ধন্যবাদ জানাই এবং আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব বলে আশা করছি!

ডাউনলোডের জন্য অনুশীলন ওয়ার্কবুক

এক্সেল আইএফ একাধিক মানদণ্ড - উদাহরণ (.xlsx ফাইল)