Оқулық Excel бағдарламасында ЖӘНЕ, сондай-ақ НЕМЕСЕ логикасы арқылы бірнеше IF операторларын жасау жолын көрсетеді. Сондай-ақ, сіз IF функциясын басқа Excel функцияларымен бірге пайдалануды үйренесіз.

Excel IF оқулығымыздың бірінші бөлімінде біз мәтіннің бір шарты бар қарапайым IF операторын құру жолын қарастырдық. сандар, күндер, бос орындар және бос еместер. Дегенмен қуатты деректерді талдау үшін бір уақытта бірнеше шарттарды бағалау қажет болуы мүмкін. Төмендегі формула мысалдары мұны істеудің ең тиімді жолдарын көрсетеді.

Егер бірнеше шарттармен IF функциясын қалай пайдалану керек

Негізінде екі түрі бар. ЖӘНЕ / НЕМЕСЕ логикасына негізделген бірнеше критерийлері бар IF формуласы . Демек, IF формулаңызды логикалық тексеруде мына функциялардың бірін пайдалану керек:

• ЖӘНЕ функциясы - барлық шарттар орындалса, АҚИҚАТ мәнін қайтарады; Әйтпесе ЖАЛҒАН.
• НЕМЕСЕ функциясы - кез келген жалғыз шарт орындалса, TRUE мәнін қайтарады; Әйтпесе ЖАЛҒАН.

Мәселені жақсырақ көрсету үшін нақты өмірден алынған формулалардың кейбір мысалдарын қарастырайық.

Бірнеше шарты бар Excel IF операторы (ЖӘНЕ логика)

Екі немесе одан да көп шарты бар Excel IF жалпы формуласы мына:

ЕГЕР(ЖӘНЕ( шарт1, шарт2, …), мән_егер_шын, мән_егер_жалған)

Адамға аударылған тілде формула былай дейді: 1-шарт ақиқат болса ЖӘНЕ 2-шарт ақиқат болса, қайтарыңыз мән_егер_шын болса ; else егер_жалған_мән қайтарады.

Сізде В және С бағандарында екі сынақтың ұпайлары көрсетілген кесте бар делік. Қорытынды емтиханды тапсыру үшін студенттің екі ұпайы да 50-ден жоғары болуы керек.

Логикалық сынақ үшін сіз келесі ЖӘНЕ операторын пайдаланасыз: ЖӘНЕ(B2>50, C2>50)

Егер екі шарттың екеуі де дұрыс болса, формула "Өту" мәнін береді; егер қандай да бір шарт жалған болса - «Сәтсіз».

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Оңай емес пе? Төмендегі скриншот Excel IF /AND формуласының дұрыс жұмыс істейтінін дәлелдейді:

Сол сияқты Excel IF функциясын бірнеше мәтін шарттарымен пайдалана аласыз.

үшін мысалы, егер B2 және C2 екеуі де 50-ден жоғары болса, «Жақсы» деп шығару үшін, әйтпесе «Нашар» формуласы:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")

Маңызды ескерту! ЖӘНЕ функциясы барлық шарттарды тексереді, тіпті әлдеқашан тексерілгендер ЖАЛҒАН деп бағаланса да. Мұндай мінез-құлық біршама ерекше, өйткені бағдарламалау тілдерінің көпшілігінде алдыңғы сынақтардың кез келгені ЖАЛҒАН болса, кейінгі шарттар тексерілмейді.

Іс жүзінде дұрыс болып көрінетін IF операторы осыған байланысты қатеге әкелуі мүмкін. ерекшелігі. Мысалы, төмендегі формула #DIV/0 қайтарады! («нөлге бөлу» қатесі) егер A2 ұяшығы 0-ге тең болса:

=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")

Бұған жол бермеу үшін кірістірілген IF функциясын пайдалану керек:

=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

Қосымша ақпарат алу үшін Excel бағдарламасындағы ЕГЕР ЖӘНЕ формуласын қараңыз.

Бірнеше түрі бар Excel IF функциясышарттар (НЕМЕСЕ логика)

Егер кез келген шарт орындалса, бір әрекетті орындау үшін, әйтпесе басқа әрекетті орындаңыз, IF және НЕМЕСЕ функцияларының осы тіркесімін пайдаланыңыз:

IF(OR(<) 1>шарт1 , шарт2 , …), мән_егер_шын, мән_егер_жалған)

Жоғарыда талқыланған ЕГЕР / ЖӘНЕ формуласынан айырмашылығы, көрсетілген шарттардың кез келгені ақиқат болса, Excel бағдарламасы ШЫНДЫҚ қайтарады.

Сонымен, егер алдыңғы формулада ЖӘНЕ орнына НЕМЕСЕ қолдансақ:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Онда кез келген емтиханда 50-ден жоғары ұпай жинаған кез келген адам "Өтпелі" алады. D бағаны. Мұндай шарттарда біздің студенттердің қорытынды емтиханды тапсыру мүмкіндігі жоғары болады (Иветте бар болғаны 1 ұпайға үлгермей қалуы ерекше бақытсыз :)

Кеңес. Егер сіз мәтінмен бірнеше IF операторын жасап, НЕМЕСЕ логикасы бар бір ұяшықтағы мәнді тексеріп жатсаңыз (яғни, ұяшық «осы» немесе «бұл» болуы мүмкін), онда сіз ықшамырақ құра аласыз. массив константасын пайдаланатын формула.

Мысалы, егер B2 ұяшығы "жеткізілген" немесе "төленген" болса, сатуды "жабық" деп белгілеу үшін формула:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

Қосымша формула мысалдарын Excel IF OR функциясынан табуға болады.

IF бірнеше ЖӘНЕ & НЕМЕСЕ мәлімдемелері

Егер тапсырма бірнеше шарттар жиынтығын бағалауды қажет етсе, ЖӘНЕ & НЕМЕСЕ бір уақытта жұмыс істейді.

Үлгі кестеде емтихан нәтижелерін тексеруге арналған келесі критерийлер бар делік:

• 1-шарт:емтихан1>50 және емтихан2>50
• 2-шарт: емтихан1>40 және емтихан2>60

Егер шарттардың біреуі орындалса, қорытынды емтихан өтті деп есептеледі.

Бір қарағанда, формула сәл қиын болып көрінеді, бірақ іс жүзінде олай емес! Сіз жай ғана жоғарыда аталған шарттардың әрқайсысын ЖӘНЕ операторы ретінде өрнектеп, НЕМЕСЕ функциясына кірістіріңіз (себебі екі шартты орындау қажет емес, екеуі де жеткілікті):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Одан кейін пайдаланыңыз IF логикалық сынағы үшін НЕМЕСЕ функциясын және қажетті егер_шын_мән және егер_жалған_мән мәндерін беріңіз. Нәтижесінде сіз бірнеше ЖӘНЕ / НЕМЕСЕ шарттары бар келесі IF формуласын аласыз:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

Төмендегі скриншот формуланы дұрыс орындағанымызды көрсетеді:

Әрине , сіз IF формулаларыңызда тек екі ЖӘНЕ/НЕМЕСЕ функциясын пайдаланумен шектелмейсіз. Сіз олардың бизнес логикасы талап ететіндей көпшілігін пайдалана аласыз, егер:

• Excel 2007 және одан жоғары нұсқаларында сізде 255 аргументтен көп емес және IF формуласының жалпы ұзындығы аспаса. 8 192 таңба.
• Excel 2003 және одан төменірек нұсқаларында 30 аргументтен аспайды және IF формуласының жалпы ұзындығы 1024 таңбадан аспайды.

Егер кірістірілген IF операторы бірнеше логикалық сынақтарды тексеру

Бір формуланың ішінде бірнеше логикалық сынақтарды бағалағыңыз келсе, бірнеше функцияларды бір-біріне кірістіруге болады. Мұндай функциялар кірістірілген деп аталадыIF функциялары . Олар логикалық сынақтардың нәтижелеріне байланысты әртүрлі мәндерді қайтарғыңыз келсе, әсіресе пайдалы болады.

Міне, әдеттегі мысал: сіз оқушылардың жетістіктерін " Жақсы " ретінде бағалауды қалайсыз делік, " Қанағаттанарлық " және " Нашар " келесі ұпайларға негізделген:

• Жақсы: 60 немесе одан жоғары (>=60)
• Қанағаттанарлық: 40 пен 60 (>40 және <60)
• Нашар: 40 немесе одан аз (<=40)

Формуланы жазбас бұрын, ретті қарастырыңыз ұяға салатын функциялар. Excel логикалық сынақтарды формулада көрсетілген ретпен бағалайды. Шарт TRUE мәніне бағаланғаннан кейін, келесі шарттар тексерілмейді, яғни формула бірінші АҚИҚАТ нәтижеден кейін тоқтайды.

Біздің жағдайда функциялар үлкеннен кішіге қарай реттелген:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Әрине, қажет болса, қосымша функцияларды кірістіруге болады (қазіргі нұсқаларда 64-ке дейін).

Қосымша ақпарат алу үшін Excel бағдарламасында бірнеше кірістірілген IF операторларын пайдалану жолын қараңыз.

Бірнеше шарттары бар Excel IF массив формуласы

Excel IF нұсқасын тексеру үшін алудың басқа жолы бірнеше шарттар массив формуласын пайдалану арқылы жүзеге асырылады.

Жағдайларды ЖӘНЕ логикасы арқылы бағалау үшін жұлдызшаны пайдаланыңыз:

IF( шарт1 ) * ( шарт2 ) * …, мән_егер_шын, мән_егер_жалған)

НЕМЕСЕ логикасы арқылы шарттарды тексеру үшін қосу белгісін пайдаланыңыз:

IF( шарт1 ) + ( шарт2 ) + …,мән_егер_шын, мән_егер_жалған)

Жиым формуласын дұрыс толтыру үшін Ctrl + Shift + Enter пернелерін бірге басыңыз. Excel 365 және Excel 2021 нұсқаларында бұл динамикалық массивтерді қолдауға байланысты кәдімгі формула ретінде де жұмыс істейді.

Мысалы, егер B2 және C2 мәндерінің екеуі де 50-ден үлкен болса, "Өту" алу үшін формула:

=IF((B2>50) * (C2>50), "Pass", "Fail")

Менің Excel 365-де қалыпты формула жақсы жұмыс істейді (жоғарыдағы скриншоттардан көріп отырғаныңыздай). Excel 2019 және одан төменірек нұсқаларында Ctrl + Shift + Enter пернелер тіркесімін пайдалану арқылы оны массив формуласына айналдыруды ұмытпаңыз.

НЕМЕСЕ логикасы арқылы бірнеше шарттарды бағалау үшін формула:

=IF((B2>50) + (C2>50), "Pass", "Fail")

Егер басқа функциялармен бірге пайдалану

Бұл бөлім IF функциясын басқа Excel функцияларымен бірге пайдалану жолын және бұл сізге қандай пайда беретінін түсіндіреді.

1-мысал. Егер #N /VLOOKUP қатесі

VLOOKUP немесе басқа іздеу функциясы бірдеңені таба алмаса, ол #N/A қатесін береді. Кестелер әдемірек көрінуі үшін #Жоқ болса, нөлді, бос немесе нақты мәтінді қайтаруға болады. Ол үшін мына жалпы формуланы пайдаланыңыз:

ЕГЕР(ISNA(VLOOKUP(…)), мән егер_на , VLOOKUP(…))

Мысалы:

Егер #Жоқ/ Қайтару 0:

Е1 ішіндегі іздеу мәні табылмаса, формула нөлді қайтарады.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

Егер #N/A қайтарылатын бос орын:

Егер іздеу мәні табылмаса, формула ештеңені қайтармайды (бос жол).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

Егер #N/A белгілі бір мәтінді қайтарса:

Егер іздеу мәні табылмады,формула нақты мәтінді қайтарады.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))

Қосымша формула мысалдары үшін Excel бағдарламасындағы IF мәлімдемесі бар VLOOKUP бөлімін қараңыз.

2-мысал. SUM, AVERAGE, MIN және MAX бар IF функциялар

Белгілі бір критерийлерге негізделген ұяшық мәндерін қосу үшін Excel SUMIF және SUMIFS функцияларын қамтамасыз етеді.

Кейбір жағдайларда бизнес логикасы IF логикалық сынағына SUM функциясын қосуды талап етуі мүмкін. Мысалы, B2 және C2 мәндерінің қосындысына байланысты әр түрлі мәтін белгілерін қайтару үшін формула:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

Егер қосынды 130-дан үлкен болса, нәтиже "жақсы" болады. "; 110-нан жоғары болса – «қанағаттанарлық», 110 немесе одан төмен болса – «нашар».

Осылайша, ОРТА функциясын IF логикалық сынағына ендіруге және орташа балл негізінде әртүрлі белгілерді қайтаруға болады. :

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Жалпы балл D бағанында болса, MAX және MIN функцияларының көмегімен ең жоғары және ең төменгі мәндерді анықтауға болады:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

Екі белгіні бір бағанда алу үшін жоғарыдағы функцияларды бір-біріне кірістіріңіз:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))

Сол сияқты, IF параметрін теңшелетін функциямен бірге пайдалануға болады. функциялары. Мысалы, ұяшық түсіне негізделген әртүрлі нәтижелерді қайтару үшін оны GetCellColor немесе GetCellFontColor көмегімен біріктіруге болады.

Сонымен қатар, Excel бағдарламасы шарттар негізінде деректерді есептеу үшін бірқатар функцияларды қамтамасыз етеді. Толық формула мысалдары үшін, төмендегілерді тексеріңізоқулықтар:

• COUNTIF - шартқа сәйкес келетін ұяшықтарды санау
• COUNTIFS - бірнеше критерийі бар ұяшықтарды санау
• SUMIF - ұяшықтарды шартты түрде қосу
• SUMIFS - бірнеше шартты ұяшықтарды қосу

Мысал 3. ISNUMBER, ISTEXT және ISBLANK бар ЕГЕР

Мәтінді, сандарды және бос ұяшықтарды анықтау үшін Microsoft Excel бағдарламасы ISTEXT, ISNUMBER сияқты арнайы функцияларды қамтамасыз етеді. және ISBLANK. Оларды үш кірістірілген IF операторының логикалық сынақтарына орналастыру арқылы сіз барлық әр түрлі деректер түрлерін бір әрекетте анықтай аласыз:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))

4-мысал. IF және CONCATENATE

Кімге IF нәтижесін және кейбір мәтінді бір ұяшыққа шығару үшін, CONCATENATE немесе CONCAT (Excel 2016 - 365 нұсқасында) және IF функцияларын бірге пайдаланыңыз. Мысалы:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Төмендегі скриншотқа қарап, формуланың не істейтінін түсіндірудің қажеті шамалы:

Егер ҚАТЕ БОЛСА / Excel бағдарламасындағы ISNA формуласы

Excel бағдарламасының заманауи нұсқаларында қателерді ұстау және оларды басқа есептеумен немесе алдын ала анықталған мәнмен ауыстыру үшін арнайы функциялар бар - IFERROR (Excel 2007 және одан кейінгі нұсқаларында) және IFNA (Excel 2013 және одан кейінгі нұсқаларында). Бұрынғы Excel нұсқаларында оның орнына ЕГЕР ҚАТЕ және ИСНА ҚАТЕЛІК тіркесімдерін пайдалануға болады.

Айырмашылығы мынада: ҚАУІПСІЗ және ҚАТЕЛІК барлық ықтимал Excel қателерін өңдейді, соның ішінде #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, және #NULL!. IFNA және ISNA тек #N/A қателеріне маманданғанымен.

Мысалы,"нөлге бөлу" қатесін (#DIV/0!) теңшелетін мәтінмен ауыстырсаңыз, келесі формуланы пайдалана аласыз:

=IF(ISERROR(A2/B2), "N/A", A2/B2)

Және осыны пайдалану туралы айтарым осы ғана. Excel бағдарламасындағы IF функциясы. Оқығаныңыз үшін алғыс айтамын және келесі аптада блогымызда көреміз деп үміттенемін!

Жүктеп алуға арналған жұмыс кітабы

Excel IF бірнеше критерийлері - мысалдар (.xlsx файлы)