एक्सेलमध्ये AND तसेच OR लॉजिकसह अनेक IF स्टेटमेंट कसे तयार करायचे हे ट्युटोरियल दाखवते. तसेच, तुम्ही इतर एक्सेल फंक्शन्ससह IF कसे वापरायचे ते शिकाल.

आमच्या एक्सेल IF ट्युटोरियलच्या पहिल्या भागात, आम्ही मजकूरासाठी एका अटीसह एक साधे IF स्टेटमेंट कसे तयार करायचे ते पाहिले, संख्या, तारखा, रिक्त आणि नॉन-रिक्त. शक्तिशाली डेटा विश्लेषणासाठी, तथापि, आपल्याला एका वेळी अनेक परिस्थितींचे मूल्यमापन करावे लागेल. खालील फॉर्म्युला उदाहरणे तुम्हाला हे करण्याचे सर्वात प्रभावी मार्ग दाखवतील.

अनेक अटींसह IF फंक्शन कसे वापरावे

थोडक्यात, दोन प्रकारचे आहेत AND/OR तर्कावर आधारित अनेक निकषांसह IF सूत्र . परिणामी, तुमच्या IF सूत्राच्या तार्किक चाचणीमध्ये, तुम्ही यापैकी एक फंक्शन वापरावे:

• AND फंक्शन - सर्व अटी पूर्ण झाल्यास TRUE मिळवते; FALSE अन्यथा.
• किंवा फंक्शन - कोणतीही एक अट पूर्ण झाल्यास TRUE मिळवते; अन्यथा असत्य.

मुद्दा चांगल्या प्रकारे स्पष्ट करण्यासाठी, काही वास्तविक जीवनातील सूत्र उदाहरणे तपासूया.

एकाधिक अटींसह एक्सेल IF विधान (आणि तर्क)

द दोन किंवा अधिक अटींसह Excel IF चे जेनेरिक सूत्र हे आहे:

IF(AND( condition1, condition2, …), value_if_true, value_if_false)

मानवीमध्ये भाषांतरित भाषा, सूत्र म्हणते: जर अट 1 सत्य असेल आणि अट 2 सत्य असेल तर परत या value_if_true ; अन्यथा value_if_false परत करा.

समजा तुमच्याकडे स्तंभ B आणि C मध्ये दोन चाचण्यांच्या गुणांची सूची आहे. अंतिम परीक्षा उत्तीर्ण होण्यासाठी, विद्यार्थ्याचे दोन्ही गुण ५० पेक्षा जास्त असणे आवश्यक आहे.

तार्किक चाचणीसाठी, तुम्ही खालील AND विधान वापरता: AND(B2>50, C2>50)

दोन्ही अटी सत्य असल्यास, सूत्र "पास" देईल; कोणतीही अट चुकीची असल्यास - "अयशस्वी".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

सोपे, नाही का? खाली दिलेला स्क्रीनशॉट सिद्ध करतो की आमचा Excel IF /AND फॉर्म्युला बरोबर काम करतो:

अशाच प्रकारे, तुम्ही एक्सेल IF फंक्शन अनेक मजकूर परिस्थिती सह वापरू शकता.

साठी उदाहरणार्थ, B2 आणि C2 दोन्ही 50 पेक्षा जास्त असल्यास "चांगले" आउटपुट करण्यासाठी, "खराब" अन्यथा, सूत्र आहे:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")

महत्त्वाची टीप! AND फंक्शन सर्व अटी तपासते, जरी आधीच चाचणी केलेले(चे) असत्य मूल्यमापन केले असले तरीही. असे वर्तन थोडेसे असामान्य आहे कारण बहुतेक प्रोग्रामिंग भाषांमध्ये, मागील कोणत्याही चाचण्या चुकीच्या आल्यास त्यानंतरच्या परिस्थितीची चाचणी केली जात नाही.

सराव मध्ये, योग्य IF विधानामुळे त्रुटी येऊ शकते. विशिष्टता उदाहरणार्थ, खालील सूत्र #DIV/0 मिळवेल! ("शून्य भागाकार" त्रुटी) जर सेल A2 0 च्या बरोबरीचा असेल:

=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")

हे टाळा, तुम्ही नेस्टेड IF फंक्शन वापरावे:

=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad") <3

अधिक माहितीसाठी, कृपया Excel मधील IF आणि सूत्र पहा.

एक्सेल IF फंक्शन एकाधिक सहअटी (किंवा तर्क)

कोणतीही अट पूर्ण झाल्यास एक गोष्ट करण्यासाठी, अन्यथा काहीतरी करण्यासाठी, IF आणि OR फंक्शन्सचे हे संयोजन वापरा:

IF(OR( condition1 , condition2 , …), value_if_true, value_if_false)

वर चर्चा केलेल्या IF / AND सूत्रातील फरक असा आहे की निर्दिष्ट केलेल्यापैकी कोणतीही परिस्थिती सत्य असल्यास Excel TRUE दर्शवते.

म्हणून, जर मागील सूत्रात, आपण AND च्या ऐवजी OR वापरतो:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

तर ज्याला दोन्हीपैकी कोणत्याही परीक्षेत ५० पेक्षा जास्त गुण असतील त्यांना "पास" मिळेल स्तंभ D. अशा अटींसह, आमच्या विद्यार्थ्यांना अंतिम परीक्षा उत्तीर्ण होण्याची अधिक चांगली संधी आहे (यवेट केवळ 1 गुणाने नापास होणे विशेषतः दुर्दैवी आहे :)

टीप. जर तुम्ही मल्टिपल IF स्टेटमेंट मजकूरासह तयार करत असाल आणि एका सेलमध्ये OR लॉजिकसह मूल्य तपासत असाल (म्हणजे सेल "हे" किंवा "ते" असू शकते), तर तुम्ही अधिक कॉम्पॅक्ट तयार करू शकता. अॅरे स्थिरांक वापरून सूत्र.

उदाहरणार्थ, सेल B2 एकतर "वितरित" किंवा "पेड" असल्यास, विक्री "बंद" म्हणून चिन्हांकित करण्यासाठी, सूत्र आहे:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

अधिक सूत्र उदाहरणे Excel IF OR फंक्शनमध्ये आढळू शकतात.

मल्टिपल AND & किंवा विधाने

तुमच्या कार्यासाठी अनेक अटींच्या अनेक संचांचे मूल्यमापन करणे आवश्यक असल्यास, तुम्हाला आणि आणि & किंवा एका वेळी कार्ये.

आमच्या नमुना सारणीमध्ये, समजा तुमच्याकडे परीक्षेचे निकाल तपासण्यासाठी खालील निकष आहेत:

• अट १:परीक्षा1>50 आणि परीक्षा2>50
• अट 2: परीक्षा1>40 आणि परीक्षा2>60

यापैकी कोणतीही एक अटी पूर्ण केली असल्यास, अंतिम परीक्षा उत्तीर्ण मानली जाते.

प्रथम दृष्टीक्षेपात, सूत्र थोडे अवघड वाटते, परंतु खरे तर तसे नाही! तुम्ही फक्त वरील प्रत्येक अटी AND स्टेटमेंट म्हणून व्यक्त करा आणि त्यांना OR फंक्शनमध्ये नेस्ट करा (दोन्ही अटी पूर्ण करणे आवश्यक नसल्यामुळे, एकतर पुरेसे असेल):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

मग, वापरा IF च्या तार्किक चाचणीसाठी OR फंक्शन आणि इच्छित value_if_true आणि value_if_false मूल्यांचा पुरवठा करते. परिणामी, तुम्हाला एकाधिक AND / OR अटींसह खालील IF सूत्र मिळेल:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

खालील स्क्रीनशॉट सूचित करतो की आम्ही सूत्र योग्य केले आहे:

स्वाभाविकपणे , तुम्ही तुमच्या IF सूत्रांमध्ये फक्त दोन AND/OR फंक्शन्स वापरण्यापुरते मर्यादित नाही. तुमच्‍या व्‍यवसाय लॉजिकला आवश्‍यक तितके तुम्‍ही त्‍यांचा वापर करू शकता, बशर्ते की:

• एक्सेल 2007 आणि त्‍याच्‍या वरच्‍या मध्‍ये, तुमच्‍याजवळ २५५ पेक्षा जास्त आर्ग्युमेंट नाहीत आणि IF सूत्राची एकूण लांबी ओलांडत नाही. 8,192 वर्ण.
• एक्सेल 2003 आणि त्यापेक्षा कमी मध्ये, 30 पेक्षा जास्त वितर्क नाहीत आणि तुमच्या IF सूत्राची एकूण लांबी 1,024 वर्णांपेक्षा जास्त नाही.

नेस्टेड IF स्टेटमेंट एकाधिक तार्किक चाचण्या तपासा

तुम्हाला एकाच सूत्रामध्ये अनेक तार्किक चाचण्यांचे मूल्यमापन करायचे असल्यास, तुम्ही अनेक फंक्शन्स एकमेकांमध्ये नेस्ट करू शकता. अशा फंक्शन्सना नेस्टेड म्हणतातIF फंक्शन्स . जेव्हा तुम्ही तार्किक चाचण्यांच्या निकालांवर अवलंबून भिन्न मूल्ये परत करू इच्छित असाल तेव्हा ते विशेषतः उपयुक्त ठरतात.

हे एक सामान्य उदाहरण आहे: समजा तुम्हाला विद्यार्थ्यांचे यश " चांगले " म्हणून पात्र करायचे आहे. खालील गुणांवर आधारित " समाधानकारक " आणि " खराब ":

• चांगले: 60 किंवा अधिक (>=60)
• समाधानकारक: 40 आणि 60 दरम्यान (>40 आणि <60)
• खराब: 40 किंवा कमी (<=40)

फॉर्म्युला लिहिण्यापूर्वी, ऑर्डरचा विचार करा ज्या फंक्शन्स तुम्ही नेस्ट करणार आहात. एक्सेल तार्किक चाचण्यांचे मूल्यमापन सूत्रामध्ये दिसतील त्या क्रमाने करेल. एकदा अटीचे मूल्यमापन TRUE झाल्यावर, त्यानंतरच्या परिस्थितीची चाचणी केली जात नाही, म्हणजे पहिल्या TRUE निकालानंतर सूत्र थांबते.

आमच्या बाबतीत, फंक्शन्स सर्वात मोठ्या ते सर्वात लहान अशी व्यवस्था केली जातात:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

साहजिकच, आवश्यक असल्यास तुम्ही अधिक फंक्शन्स नेस्ट करू शकता (आधुनिक आवृत्त्यांमध्ये 64 पर्यंत).

अधिक माहितीसाठी, कृपया Excel मध्ये एकाधिक नेस्टेड IF स्टेटमेंट कसे वापरावे ते पहा.

एकाधिक अटींसह एक्सेल IF अॅरे फॉर्म्युला

चाचणीसाठी एक्सेल IF मिळवण्याचा दुसरा मार्ग अ‍ॅरे फॉर्म्युला वापरून अनेक अटी आहेत.

अँड लॉजिकसह परिस्थितीचे मूल्यांकन करण्यासाठी, तारांकन वापरा:

IF( condition1 ) * ( condition2 ) * …, value_if_true, value_if_false)

OR तर्कासह परिस्थिती तपासण्यासाठी, अधिक चिन्ह वापरा:

IF( condition1 ) + ( condition2 ) + …,value_if_true, value_if_false)

अरे फॉर्म्युला योग्यरित्या पूर्ण करण्यासाठी, Ctrl + Shift + Enter की एकत्र दाबा. एक्सेल 365 आणि एक्सेल 2021 मध्ये, डायनॅमिक अॅरेच्या समर्थनामुळे हे नियमित सूत्र म्हणून देखील कार्य करते.

उदाहरणार्थ, B2 आणि C2 दोन्ही 50 पेक्षा जास्त असल्यास "पास" मिळवण्यासाठी, सूत्र आहे:

=IF((B2>50) * (C2>50), "Pass", "Fail")

माझ्या एक्सेल 365 मध्ये, एक सामान्य सूत्र अगदी चांगले कार्य करते (जसे तुम्ही वरील स्क्रीनशॉटमध्ये पाहू शकता). Excel 2019 आणि त्यापेक्षा कमी मध्ये, Ctrl + Shift + Enter शॉर्टकट वापरून याला अॅरे फॉर्म्युला बनवण्याचे लक्षात ठेवा.

OR लॉजिकसह अनेक परिस्थितींचे मूल्यमापन करण्यासाठी, सूत्र आहे:

=IF((B2>50) + (C2>50), "Pass", "Fail")

इतर फंक्शन्ससह IF एकत्र वापरणे

हा विभाग IF इतर Excel फंक्शन्सच्या संयोजनात कसा वापरायचा आणि यामुळे तुम्हाला कोणते फायदे मिळतात हे स्पष्ट करते.

उदाहरण 1. जर #N VLOOKUP मध्ये /ए एरर

जेव्हा VLOOKUP किंवा इतर लुकअप फंक्शन काही शोधू शकत नाही, ते #N/A एरर मिळवते. तुमची सारणी अधिक छान दिसण्यासाठी, तुम्ही #N/A असल्यास शून्य, रिक्त किंवा विशिष्ट मजकूर परत करू शकता. यासाठी, हे जेनेरिक सूत्र वापरा:

IF(ISNA(VLOOKUP(…)), value_if_na , VLOOKUP(…))

उदाहरणार्थ:

If #N/ रिटर्न 0:

जर E1 मधील लुकअप व्हॅल्यू आढळले नाही, तर सूत्र शून्य मिळवते.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

जर #N/A रिक्त रिटर्न:

लूकअप मूल्य आढळले नसल्यास, सूत्र काहीही देत ​​नाही (रिक्त स्ट्रिंग).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

जर #N/A विशिष्ट मजकूर परत करत असेल:

जर शोध मूल्य आढळले नाही, दसूत्र विशिष्ट मजकूर मिळवते.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))

अधिक सूत्र उदाहरणांसाठी, कृपया Excel मध्ये IF स्टेटमेंटसह VLOOKUP पहा.

उदाहरण 2. IF SUM, AVERAGE, MIN आणि MAX सह फंक्शन्स

विशिष्ट निकषांवर आधारित सेल व्हॅल्यूची बेरीज करण्यासाठी, एक्सेल SUMIF आणि SUMIFS फंक्शन्स प्रदान करते.

काही परिस्थितींमध्ये, तुमच्या व्यवसाय लॉजिकला IF च्या लॉजिकल टेस्टमध्ये SUM फंक्शन समाविष्ट करण्याची आवश्यकता असू शकते. उदाहरणार्थ, B2 आणि C2 मधील मूल्यांच्या बेरजेवर अवलंबून भिन्न मजकूर लेबले परत करण्यासाठी, सूत्र आहे:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

जर बेरीज 130 पेक्षा जास्त असेल तर परिणाम "चांगला आहे "; 110 पेक्षा जास्त असल्यास - "समाधानकारक', जर 110 किंवा कमी - "खराब".

तत्सम पद्धतीने, तुम्ही IF च्या तार्किक चाचणीमध्ये AVERAGE फंक्शन एम्बेड करू शकता आणि सरासरी स्कोअरवर आधारित भिन्न लेबले परत करू शकता. :

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

एकूण स्कोअर स्तंभ D मध्ये आहे असे गृहीत धरून, तुम्ही MAX आणि MIN फंक्शन्सच्या मदतीने सर्वोच्च आणि सर्वात कमी मूल्ये ओळखू शकता:

=IF(D2=MAX($D$2:$D$10), "Best result", "") <3

=IF(D2=MAX($D$2:$D$10), "Best result", "")

एका स्तंभात दोन्ही लेबले ठेवण्यासाठी, वरील फंक्शन्स एकमेकांमध्ये नेस्ट करा:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))

तसेच, तुम्ही तुमच्या कस्टमसह IF वापरू शकता फंक्शन्स. उदाहरणार्थ, सेल कलरवर आधारित वेगवेगळे परिणाम मिळवण्यासाठी तुम्ही ते GetCellColor किंवा GetCellFontColor सह एकत्र करू शकता.

याव्यतिरिक्त, एक्सेल परिस्थितीवर आधारित डेटाची गणना करण्यासाठी अनेक फंक्शन्स प्रदान करते. तपशीलवार सूत्र उदाहरणांसाठी, कृपया खालील तपासाट्यूटोरियल:

• COUNTIF - अटी पूर्ण करणाऱ्या सेलची गणना करा
• COUNTIFS - एकाधिक निकषांसह सेल मोजा
• SUMIF - सशर्त बेरीज सेल
• SUMIFS - एकाधिक निकषांसह बेरीज सेल

उदाहरण 3. ISNUMBER, ISTEXT आणि ISBLANK सह IF

मजकूर, संख्या आणि रिक्त सेल ओळखण्यासाठी, Microsoft Excel ISTEXT, ISNUMBER सारखी विशेष कार्ये प्रदान करते आणि ISBLANK. तीन नेस्टेड IF विधानांच्या तार्किक चाचण्यांमध्ये ठेवून, तुम्ही एकाच वेळी सर्व भिन्न डेटा प्रकार ओळखू शकता:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))

उदाहरण 4. IF आणि CONCATENATE

ते IF चा निकाल आणि काही मजकूर एका सेलमध्ये आउटपुट करा, CONCATENATE किंवा CONCAT (एक्सेल 2016 - 365 मध्ये) आणि IF फंक्शन्स एकत्र वापरा. उदाहरणार्थ:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

खालील स्क्रीनशॉट पाहता, सूत्र काय करते याचे स्पष्टीकरण तुम्हाला क्वचितच लागेल:

जर ISERROR / Excel मधील ISNA फॉर्म्युला

Excel च्या आधुनिक आवृत्त्यांमध्ये त्रुटी पकडण्यासाठी आणि त्यांना दुसर्‍या गणना किंवा पूर्वनिर्धारित मूल्यासह पुनर्स्थित करण्यासाठी विशेष कार्ये आहेत - IFERROR (एक्सेल 2007 आणि नंतरच्या मध्ये) आणि IFNA (एक्सेल 2013 आणि नंतरमध्ये). पूर्वीच्या एक्सेल आवृत्त्यांमध्ये, तुम्ही त्याऐवजी IF ISERROR आणि IF ISNA संयोजन वापरू शकता.

फरक हा आहे की IFERROR आणि ISERROR सर्व संभाव्य Excel त्रुटी हाताळतात, ज्यात #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, आणि #NULL!. IFNA आणि ISNA केवळ #N/A त्रुटींमध्ये विशेषज्ञ असताना.

उदाहरणार्थ, तेतुमच्या सानुकूल मजकुरासह "विभाजित करा शून्य" त्रुटी (#DIV/0!) बदला, तुम्ही खालील सूत्र वापरू शकता:

=IF(ISERROR(A2/B2), "N/A", A2/B2)

आणि वापरण्याबद्दल मला एवढेच म्हणायचे आहे Excel मध्ये IF फंक्शन. वाचल्याबद्दल मी तुमचा आभारी आहे आणि तुम्हाला पुढील आठवड्यात आमच्या ब्लॉगवर भेटण्याची आशा आहे!

डाउनलोड करण्यासाठी सराव वर्कबुक

एक्सेल IF एकाधिक निकष - उदाहरणे (.xlsx फाइल)