ఎక్సెల్‌లో మరియు అలాగే లేదా లాజిక్‌తో బహుళ IF స్టేట్‌మెంట్‌లను ఎలా సృష్టించాలో ట్యుటోరియల్ చూపిస్తుంది. అలాగే, మీరు ఇతర Excel ఫంక్షన్‌లతో కలిపి IFను ఎలా ఉపయోగించాలో నేర్చుకుంటారు.

మా Excel IF ట్యుటోరియల్ మొదటి భాగంలో, మేము టెక్స్ట్ కోసం ఒక షరతుతో సరళమైన IF స్టేట్‌మెంట్‌ను ఎలా నిర్మించాలో చూసాము, సంఖ్యలు, తేదీలు, ఖాళీలు మరియు నాన్-ఖాళీలు. శక్తివంతమైన డేటా విశ్లేషణ కోసం, అయితే, మీరు తరచుగా ఒకేసారి అనేక పరిస్థితులను విశ్లేషించాల్సి ఉంటుంది. దిగువ ఫార్ములా ఉదాహరణలు దీన్ని చేయడానికి మీకు అత్యంత ప్రభావవంతమైన మార్గాలను చూపుతాయి.

బహుళ షరతులతో IF ఫంక్షన్‌ను ఎలా ఉపయోగించాలి

సారాంశంలో, రెండు రకాలు ఉన్నాయి మరియు / OR లాజిక్ ఆధారంగా బహుళ ప్రమాణాలతో ఫార్ములా . పర్యవసానంగా, మీ IF ఫార్ములా యొక్క తార్కిక పరీక్షలో, మీరు ఈ ఫంక్షన్‌లలో ఒకదానిని ఉపయోగించాలి:

• మరియు ఫంక్షన్ - అన్ని షరతులు నెరవేరినట్లయితే TRUEని అందిస్తుంది; లేకుంటే తప్పు.
• లేదా ఫంక్షన్ - ఏదైనా ఒకే షరతు కలిసినట్లయితే TRUEని అందిస్తుంది; లేకపోతే తప్పు.

పాయింట్‌ను మెరుగ్గా వివరించడానికి, కొన్ని నిజ జీవిత సూత్రాల ఉదాహరణలను పరిశోధిద్దాం.

బహుళ షరతులతో (మరియు లాజిక్) Excel IF స్టేట్‌మెంట్

ది రెండు లేదా అంతకంటే ఎక్కువ షరతులతో కూడిన Excel IF యొక్క సాధారణ సూత్రం ఇది:

IF(మరియు( షరతు1, షరతు2, …), value_if_true, value_if_false)

మానవ రూపంలోకి అనువదించబడింది భాష, ఫార్ములా ఇలా చెబుతోంది: షరతు 1 నిజమైతే మరియు షరతు 2 నిజమైతే, తిరిగి ఇవ్వండి value_if_true ; లేకుంటే value_if_false ని తిరిగి ఇవ్వండి.

మీరు B మరియు C నిలువు వరుసలలో రెండు పరీక్షల స్కోర్‌లను జాబితా చేసే పట్టికను కలిగి ఉన్నారని అనుకుందాం. ఆఖరి పరీక్షలో ఉత్తీర్ణత సాధించడానికి, విద్యార్థి తప్పనిసరిగా 50 కంటే ఎక్కువ స్కోర్‌లను కలిగి ఉండాలి.

తార్కిక పరీక్ష కోసం, మీరు క్రింది AND స్టేట్‌మెంట్‌ను ఉపయోగిస్తారు: AND(B2>50, C2>50)

రెండు షరతులు నిజమైతే, ఫార్ములా "పాస్"ని అందిస్తుంది; ఏదైనా షరతు తప్పు అయితే - "ఫెయిల్".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

సులభం, కాదా? దిగువ స్క్రీన్‌షాట్ మా Excel IF /AND ఫార్ములా సరిగ్గా పనిచేస్తుందని రుజువు చేస్తుంది:

అదే పద్ధతిలో, మీరు బహుళ టెక్స్ట్ షరతులు తో Excel IF ఫంక్షన్‌ను ఉపయోగించవచ్చు

. ఉదాహరణకు, B2 మరియు C2 రెండూ 50 కంటే ఎక్కువ ఉంటే "మంచిది" అని అవుట్‌పుట్ చేయడానికి, "చెడు" లేకపోతే, ఫార్ములా:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")

ముఖ్యమైన గమనిక! AND ఫంక్షన్ అన్ని షరతులను తనిఖీ చేస్తుంది, ఇప్పటికే పరీక్షించబడినవి(లు) తప్పుగా మూల్యాంకనం చేయబడినప్పటికీ. చాలా ప్రోగ్రామింగ్ లాంగ్వేజ్‌లలో ఇటువంటి ప్రవర్తన కొంచెం అసాధారణమైనది, ఎందుకంటే మునుపటి పరీక్షల్లో ఏదైనా తప్పుగా ఉంటే తదుపరి పరిస్థితులు పరీక్షించబడవు.

ఆచరణలో, సరైన IF స్టేట్‌మెంట్ దీని కారణంగా లోపం ఏర్పడవచ్చు. నిర్దిష్టత. ఉదాహరణకు, దిగువ ఫార్ములా #DIV/0ని అందిస్తుంది! ("సున్నా ద్వారా విభజించు" లోపం) సెల్ A2 0కి సమానంగా ఉంటే:

=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")

దీన్ని నివారించేందుకు, మీరు సమూహ IF ఫంక్షన్‌ని ఉపయోగించాలి:

=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

మరింత సమాచారం కోసం, దయచేసి Excelలో IF మరియు ఫార్ములా చూడండి.

Excel IF ఫంక్షన్‌తో బహుళషరతులు (OR లాజిక్)

ఏదైనా షరతు నెరవేరితే ఒక పని చేయడానికి, లేకుంటే వేరే ఏదైనా చేయండి, ఈ IF మరియు OR ఫంక్షన్‌ల కలయికను ఉపయోగించండి:

IF(OR( condition1 , condition2 , …), value_if_true, value_if_false)

పైన చర్చించిన IF / AND ఫార్ములా నుండి వ్యత్యాసం ఏమిటంటే, పేర్కొన్న షరతుల్లో ఏదైనా నిజమైతే Excel TRUEని అందిస్తుంది.

కాబట్టి, మునుపటి ఫార్ములాలో, మేము ANDకి బదులుగా OR ఉపయోగిస్తే:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

అప్పుడు ఎవరైనా పరీక్షలో 50 కంటే ఎక్కువ పాయింట్లు సాధించిన వారు "పాస్" పొందుతారు కాలమ్ D. అటువంటి షరతులతో, మా విద్యార్థులు చివరి పరీక్షలో ఉత్తీర్ణత సాధించడానికి మెరుగైన అవకాశం కలిగి ఉంటారు (విట్టీ కేవలం 1 పాయింట్‌తో విఫలమవడం చాలా దురదృష్టకరం :)

చిట్కా. మీరు టెక్స్ట్‌తో మల్టిపుల్ IF స్టేట్‌మెంట్‌ను క్రియేట్ చేస్తుంటే మరియు OR లాజిక్‌తో ఒక సెల్‌లో విలువను పరీక్షిస్తున్నట్లయితే (అంటే ఒక సెల్ "ఇది" లేదా "అది" కావచ్చు), అప్పుడు మీరు మరింత కాంపాక్ట్‌ను రూపొందించవచ్చు ఫార్ములా శ్రేణి స్థిరాంకాన్ని ఉపయోగిస్తుంది.

ఉదాహరణకు, సెల్ B2 "బట్వాడా" లేదా "చెల్లింపు" అయినట్లయితే, విక్రయాన్ని "మూసివేయబడింది" అని గుర్తు పెట్టడానికి, సూత్రం:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

ఎక్సెల్ IF OR ఫంక్షన్‌లో మరిన్ని ఫార్ములా ఉదాహరణలు కనుగొనవచ్చు.

బహుళ మరియు & లేదా స్టేట్‌మెంట్‌లు

మీ పనికి అనేక సెట్ల బహుళ షరతులను మూల్యాంకనం చేయవలసి వస్తే, మీరు మరియు & లేదా ఒక సమయంలో విధులు.

మా నమూనా పట్టికలో, మీరు పరీక్ష ఫలితాలను తనిఖీ చేయడానికి క్రింది ప్రమాణాలను కలిగి ఉన్నారని అనుకుందాం:

• షరతు 1:exam1>50 మరియు exam2>50
• షరతు 2: exam1>40 మరియు exam2>60

షరతుల్లో దేనినైనా కలుసుకున్నట్లయితే, చివరి పరీక్ష ఉత్తీర్ణత సాధించినట్లు భావించబడుతుంది.

మొదటి చూపులో, ఫార్ములా కొంచెం గమ్మత్తైనదిగా అనిపిస్తుంది, కానీ నిజానికి అది కాదు! మీరు కేవలం పైన పేర్కొన్న ప్రతి షరతులను AND స్టేట్‌మెంట్‌గా వ్యక్తీకరించి, వాటిని OR ఫంక్షన్‌లో నిక్షిప్తం చేయండి (రెండు షరతులను పాటించాల్సిన అవసరం లేదు కాబట్టి, ఏదైనా సరిపోతుంది):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

అప్పుడు, ఉపయోగించండి IF యొక్క తార్కిక పరీక్ష కోసం OR ఫంక్షన్ మరియు కావలసిన value_if_true మరియు value_if_false విలువలను సరఫరా చేస్తుంది. ఫలితంగా, మీరు బహుళ AND / OR షరతులతో క్రింది IF సూత్రాన్ని పొందుతారు:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

క్రింద ఉన్న స్క్రీన్‌షాట్ మేము సూత్రాన్ని సరిగ్గా చేసామని సూచిస్తుంది:

సహజంగా , మీరు మీ IF ఫార్ములాల్లో కేవలం రెండు AND/OR ఫంక్షన్‌లను మాత్రమే ఉపయోగించేందుకు పరిమితం కాలేదు. మీరు వాటిని మీ వ్యాపార లాజిక్‌కు అవసరమైనంత వరకు ఉపయోగించవచ్చు:

• Excel 2007 మరియు అంతకంటే ఎక్కువ, మీకు 255 కంటే ఎక్కువ ఆర్గ్యుమెంట్‌లు లేవు మరియు IF ఫార్ములా మొత్తం పొడవు మించకూడదు 8,192 అక్షరాలు.
• Excel 2003 మరియు అంతకంటే తక్కువ, 30 కంటే ఎక్కువ ఆర్గ్యుమెంట్‌లు లేవు మరియు మీ IF ఫార్ములా మొత్తం పొడవు 1,024 అక్షరాలను మించకూడదు.

Nested IF స్టేట్‌మెంట్‌కి బహుళ తార్కిక పరీక్షలను తనిఖీ చేయండి

మీరు ఒకే ఫార్ములాలో బహుళ తార్కిక పరీక్షలను మూల్యాంకనం చేయాలనుకుంటే, మీరు అనేక ఫంక్షన్‌లను ఒకదానికొకటి కలపవచ్చు. ఇటువంటి ఫంక్షన్లను నెస్టెడ్ అంటారుIF ఫంక్షన్లు . మీరు తార్కిక పరీక్షల ఫలితాలపై ఆధారపడి విభిన్న విలువలను అందించాలనుకున్నప్పుడు అవి చాలా ఉపయోగకరంగా ఉంటాయి.

ఇక్కడ ఒక సాధారణ ఉదాహరణ ఉంది: మీరు విద్యార్థుల విజయాలను " మంచి "గా అర్హత పొందాలనుకుంటున్నారని అనుకుందాం. కింది స్కోర్‌ల ఆధారంగా " సంతృప్తికరంగా " మరియు " పేద ":

• మంచిది: 60 లేదా అంతకంటే ఎక్కువ (>=60)
• సంతృప్తికరంగా: 40 మరియు 60 మధ్య (>40 మరియు <60)
• పేద: 40 లేదా అంతకంటే తక్కువ (<=40)

ఫార్ములా వ్రాయడానికి ముందు, ఆర్డర్‌ను పరిగణించండి మీరు గూడు చేయబోయే విధులు. Excel ఫార్ములాలో కనిపించే క్రమంలో తార్కిక పరీక్షలను మూల్యాంకనం చేస్తుంది. ఒక షరతు TRUEకి మూల్యాంకనం చేసిన తర్వాత, తదుపరి షరతులు పరీక్షించబడవు, అంటే మొదటి TRUE ఫలితం తర్వాత ఫార్ములా ఆగిపోతుంది.

మా విషయంలో, ఫంక్షన్‌లు పెద్దవి నుండి చిన్నవి వరకు అమర్చబడతాయి:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

సహజంగా, అవసరమైతే మీరు మరిన్ని ఫంక్షన్‌లను నెస్ట్ చేయవచ్చు (ఆధునిక సంస్కరణల్లో 64 వరకు).

మరింత సమాచారం కోసం, దయచేసి Excelలో బహుళ సమూహ IF స్టేట్‌మెంట్‌లను ఎలా ఉపయోగించాలో చూడండి.

బహుళ షరతులతో Excel IF అర్రే ఫార్ములా

పరీక్షించడానికి Excel IFని పొందడానికి మరొక మార్గం శ్రేణి సూత్రాన్ని ఉపయోగించడం ద్వారా బహుళ షరతులు.

మరియు లాజిక్‌తో షరతులను అంచనా వేయడానికి, నక్షత్రం గుర్తును ఉపయోగించండి:

IF( కండిషన్1 ) * ( కండిషన్2 ) * …, value_if_true, value_if_false)

OR లాజిక్‌తో షరతులను పరీక్షించడానికి, ప్లస్ గుర్తును ఉపయోగించండి:

IF( condition1 ) + ( condition2 ) + …,value_if_true, value_if_false)

అరే ఫార్ములాను సరిగ్గా పూర్తి చేయడానికి, Ctrl + Shift + Enter కీలను కలిపి నొక్కండి. Excel 365 మరియు Excel 2021లో, డైనమిక్ శ్రేణుల మద్దతు కారణంగా ఇది సాధారణ ఫార్ములాగా కూడా పని చేస్తుంది.

ఉదాహరణకు, B2 మరియు C2 రెండూ 50 కంటే ఎక్కువ ఉంటే "పాస్" పొందడానికి, ఫార్ములా:

=IF((B2>50) * (C2>50), "Pass", "Fail")

నా Excel 365లో, ఒక సాధారణ ఫార్ములా బాగానే పని చేస్తుంది (మీరు పై స్క్రీన్‌షాట్‌లలో చూడగలిగినట్లు). Excel 2019 మరియు అంతకంటే తక్కువలో, Ctrl + Shift + Enter సత్వరమార్గాన్ని ఉపయోగించడం ద్వారా దీన్ని శ్రేణి ఫార్ములాగా మార్చాలని గుర్తుంచుకోండి.

OR లాజిక్‌తో బహుళ షరతులను అంచనా వేయడానికి, ఫార్ములా:

=IF((B2>50) + (C2>50), "Pass", "Fail")

ఇతర ఫంక్షన్‌లతో కలిపి IFను ఉపయోగించడం

ఇతర Excel ఫంక్షన్‌లతో కలిపి IFని ఎలా ఉపయోగించాలో మరియు ఇది మీకు ఎలాంటి ప్రయోజనాలను ఇస్తుందో ఈ విభాగం వివరిస్తుంది.

ఉదాహరణ 1. #N అయితే /VLOOKUPలో లోపం

VLOOKUP లేదా ఇతర శోధన ఫంక్షన్ ఏదైనా కనుగొనలేనప్పుడు, అది #N/A లోపాన్ని అందిస్తుంది. మీ పట్టికలు చక్కగా కనిపించేలా చేయడానికి, మీరు #N/A అయితే సున్నా, ఖాళీ లేదా నిర్దిష్ట వచనాన్ని అందించవచ్చు. దీని కోసం, ఈ సాధారణ సూత్రాన్ని ఉపయోగించండి:

IF(ISNA(VLOOKUP(...)), value_if_na , VLOOKUP(…))

ఉదాహరణకు:

అయితే #N/ A రిటర్న్ 0:

E1లో శోధన విలువ కనుగొనబడకపోతే, ఫార్ములా సున్నాని అందిస్తుంది.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

#N/A ఖాళీగా ఉంటే:

లుకప్ విలువ కనుగొనబడకపోతే, ఫార్ములా ఏమీ ఇవ్వదు (ఖాళీ స్ట్రింగ్).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

#N/A నిర్దిష్ట వచనాన్ని తిరిగి ఇస్తే:

శోధన విలువ కనుగొనబడలేదు, దిఫార్ములా నిర్దిష్ట వచనాన్ని అందిస్తుంది.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))

మరిన్ని ఫార్ములా ఉదాహరణల కోసం, దయచేసి Excelలో IF స్టేట్‌మెంట్‌తో VLOOKUPని చూడండి.

ఉదాహరణ 2. SUM, AVERAGE, MIN మరియు MAXతో ఉంటే ఫంక్షన్‌లు

నిర్దిష్ట ప్రమాణాల ఆధారంగా సెల్ విలువలను సంకలనం చేయడానికి, Excel SUMIF మరియు SUMIFS ఫంక్షన్‌లను అందిస్తుంది.

కొన్ని సందర్భాల్లో, IF యొక్క లాజికల్ టెస్ట్‌లో SUM ఫంక్షన్‌ని చేర్చడం మీ వ్యాపార లాజిక్ అవసరం కావచ్చు. ఉదాహరణకు, B2 మరియు C2లోని విలువల మొత్తాన్ని బట్టి వేర్వేరు టెక్స్ట్ లేబుల్‌లను అందించడానికి, సూత్రం:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

మొత్తం 130 కంటే ఎక్కువ ఉంటే, ఫలితం "మంచిది "; 110 కంటే ఎక్కువ ఉంటే - "సంతృప్తికరంగా', 110 లేదా అంతకంటే తక్కువ ఉంటే - "పేద".

ఇదే పద్ధతిలో, మీరు IF యొక్క తార్కిక పరీక్షలో సగటు ఫంక్షన్‌ను పొందుపరచవచ్చు మరియు సగటు స్కోర్ ఆధారంగా వేర్వేరు లేబుల్‌లను అందించవచ్చు :

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

మొత్తం స్కోర్ కాలమ్ Dలో ఉందని ఊహిస్తే, మీరు MAX మరియు MIN ఫంక్షన్‌ల సహాయంతో అత్యధిక మరియు అత్యల్ప విలువలను గుర్తించవచ్చు:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

రెండు లేబుల్‌లను ఒక నిలువు వరుసలో ఉంచడానికి, ఎగువన ఉన్న ఫంక్షన్‌లను ఒకదానికొకటి కలపండి:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))

అలాగే, మీరు మీ కస్టమ్‌తో కలిపి IFని ఉపయోగించవచ్చు ఫంక్షన్‌లు ఉదాహరణకు, సెల్ కలర్ ఆధారంగా విభిన్న ఫలితాలను అందించడానికి మీరు దీన్ని GetCellColor లేదా GetCellFontColorతో మిళితం చేయవచ్చు.

అంతేకాకుండా, షరతుల ఆధారంగా డేటాను లెక్కించడానికి Excel అనేక ఫంక్షన్‌లను అందిస్తుంది. వివరణాత్మక ఫార్ములా ఉదాహరణల కోసం, దయచేసి క్రింది వాటిని తనిఖీ చేయండిట్యుటోరియల్‌లు:

• COUNTIF - షరతుకు అనుగుణంగా ఉండే కణాలను లెక్కించండి
• COUNTIFS - బహుళ ప్రమాణాలతో సెల్‌లను లెక్కించండి
• SUMIF - షరతులతో కూడిన మొత్తం సెల్‌లు
• SUMIFS - బహుళ ప్రమాణాలతో మొత్తం సెల్‌లు

ఉదాహరణ 3. ISNUMBER, ISTEXT మరియు ISBLANKతో ఉంటే

టెక్స్ట్, సంఖ్యలు మరియు ఖాళీ సెల్‌లను గుర్తించడానికి, Microsoft Excel ISTEXT, ISNUMBER వంటి ప్రత్యేక ఫంక్షన్‌లను అందిస్తుంది మరియు ISBLANK. మూడు సమూహ IF స్టేట్‌మెంట్‌ల తార్కిక పరీక్షల్లో వాటిని ఉంచడం ద్వారా, మీరు అన్ని విభిన్న డేటా రకాలను ఒకేసారి గుర్తించవచ్చు:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))

ఉదాహరణ 4. IF మరియు CONCATENATE

కు IF ఫలితాన్ని మరియు కొంత వచనాన్ని ఒక సెల్‌లోకి అవుట్‌పుట్ చేయండి, CONCATENATE లేదా CONCAT (Excel 2016 - 365లో) మరియు IF ఫంక్షన్‌లను కలిపి ఉపయోగించండి. ఉదాహరణకు:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

దిగువ స్క్రీన్‌షాట్‌ను చూస్తే, ఫార్ములా ఏమి చేస్తుందో మీకు వివరించాల్సిన అవసరం లేదు:

ISERROR అయితే / Excelలో ISNA ఫార్ములా

Excel యొక్క ఆధునిక సంస్కరణలు లోపాలను ట్రాప్ చేయడానికి మరియు వాటిని మరొక గణన లేదా ముందే నిర్వచించిన విలువతో భర్తీ చేయడానికి ప్రత్యేక విధులను కలిగి ఉంటాయి - IFERROR (Excel 2007 మరియు తరువాతి కాలంలో) మరియు IFNA (Excel 2013లో మరియు తరువాత). మునుపటి Excel సంస్కరణల్లో, మీరు బదులుగా IF ISERROR మరియు IF ISNA కలయికలను ఉపయోగించవచ్చు.

తేడా ఏమిటంటే IFERROR మరియు ISERROR #VALUE!, #N/A, #NAME?, సహా సాధ్యమయ్యే అన్ని Excel ఎర్రర్‌లను నిర్వహిస్తాయి. #REF!, #NUM!, #DIV/0!, మరియు #NULL!. IFNA మరియు ISNA కేవలం #N/A ఎర్రర్‌లలో మాత్రమే ప్రత్యేకతను కలిగి ఉన్నాయి.

ఉదాహరణకు, కు"సున్నా ద్వారా విభజించు" దోషాన్ని (#DIV/0!) మీ అనుకూల టెక్స్ట్‌తో భర్తీ చేయండి, మీరు క్రింది సూత్రాన్ని ఉపయోగించవచ్చు:

=IF(ISERROR(A2/B2), "N/A", A2/B2)

మరియు నేను దీన్ని ఉపయోగించడం గురించి చెప్పాల్సింది అంతే Excelలో IF ఫంక్షన్. నేను చదివినందుకు ధన్యవాదాలు మరియు వచ్చే వారం మా బ్లాగ్‌లో మిమ్మల్ని చూడాలని ఆశిస్తున్నాను!

డౌన్‌లోడ్ కోసం వర్క్‌బుక్‌ను ప్రాక్టీస్ చేయండి

Excel IF బహుళ ప్రమాణాలు - ఉదాహరణలు (.xlsx ఫైల్)