ट्युटोरियलले एक्सेलमा AND साथै OR तर्कको साथमा धेरै IF कथनहरू कसरी सिर्जना गर्ने भनेर देखाउँछ। साथै, तपाईले IF लाई अन्य एक्सेल प्रकार्यहरूसँग कसरी प्रयोग गर्ने भनेर सिक्नुहुनेछ।

हाम्रो एक्सेल IF ट्युटोरियलको पहिलो भागमा, हामीले पाठको लागि एउटा सर्त सहितको सरल IF स्टेटमेन्ट कसरी निर्माण गर्ने भनेर हेर्यौं। संख्याहरू, मितिहरू, खाली र गैर-रिक्तहरू। शक्तिशाली डेटा विश्लेषणको लागि, तथापि, तपाईले एक पटकमा धेरै सर्तहरू मूल्याङ्कन गर्न आवश्यक पर्दछ। तलका सूत्र उदाहरणहरूले तपाईंलाई यो गर्नका लागि सबैभन्दा प्रभावकारी तरिकाहरू देखाउनेछन्।

बहु सर्तहरूसँग IF प्रकार्य कसरी प्रयोग गर्ने

संक्षेपमा, त्यहाँ दुई प्रकारका छन्। AND / OR तर्कमा आधारित बहु मापदण्ड भएको IF सूत्र । फलस्वरूप, तपाईंको IF सूत्रको तार्किक परीक्षणमा, तपाईंले यी मध्ये एउटा प्रकार्य प्रयोग गर्नुपर्छ:

• AND प्रकार्य - यदि सबै सर्तहरू पूरा भएमा TRUE फर्काउँछ; अन्यथा FALSE।
• वा प्रकार्य - यदि कुनै एकल सर्त पूरा भएमा TRUE फर्काउँछ; अन्यथा FALSE।

बिन्दुलाई राम्रोसँग बुझाउनको लागि, केही वास्तविक-जीवन सूत्र उदाहरणहरूको खोजी गरौं।

बहु सर्तहरू (र तर्क) सहित एक्सेल IF कथन

द दुई वा बढी सर्तहरू भएको Excel IF को सामान्य सूत्र यो हो:

IF(AND( condition1, condition2, …), value_if_true, value_if_false)

मानवमा अनुवाद गरिएको भाषा, सूत्र भन्छ: यदि अवस्था 1 सत्य हो र अवस्था 2 सत्य हो भने, फर्कनुहोस् value_if_true ; अन्यथा value_if_false फर्काउनुहोस्।

मान्नुहोस् तपाईंसँग B र C मा दुईवटा परीक्षाको अङ्कहरू सूचीबद्ध गर्ने तालिका छ। अन्तिम परीक्षामा उत्तीर्ण हुनको लागि, विद्यार्थीले दुवै अंक ५० भन्दा बढी हुनुपर्छ।

तार्किक परीक्षणको लागि, तपाइँ निम्न AND कथन प्रयोग गर्नुहुन्छ: AND(B2>50, C2>50)

यदि दुवै सर्तहरू सत्य छन् भने, सूत्रले "पास" फर्काउनेछ; यदि कुनै सर्त गलत छ भने - "फेल"।

=IF(AND(B2>50, B2>50), "Pass", "Fail")

सजिलो, हैन? तलको स्क्रिनसटले हाम्रो Excel IF /AND सूत्रले सही काम गर्छ भनी प्रमाणित गर्छ:

यस्तै प्रकारले, तपाईले एक्सेल IF प्रकार्यलाई धेरै पाठ सर्तहरू प्रयोग गर्न सक्नुहुन्छ।

का लागि उदाहरण, B2 र C2 दुबै 50 भन्दा ठूला भएमा "राम्रो" आउटपुट गर्न, "खराब" अन्यथा, सूत्र हो:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")

महत्त्वपूर्ण नोट! AND प्रकार्यले सबै सर्तहरू जाँच गर्दछ, भले पनि पहिले नै परीक्षण गरिएको (हरू) FALSE मा मूल्याङ्कन गरिएको छ। यस्तो व्यवहार अलि असामान्य छ किनकि धेरैजसो प्रोग्रामिङ भाषाहरूमा, पछिल्ला सर्तहरूको परीक्षण गरिँदैन यदि अघिल्लो परीक्षणहरू FALSE फिर्ता आएको छ।

व्यवहारमा, एक उचित IF कथनले त्रुटिको परिणाम हुन सक्छ। विशिष्टता। उदाहरणका लागि, तलको सूत्रले #DIV/0 फर्काउँछ! ("शून्य द्वारा विभाजन" त्रुटि) यदि सेल A2 ० बराबर छ:

=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")

यसबाट बच्न, तपाईंले नेस्टेड IF प्रकार्य प्रयोग गर्नुपर्छ:

=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad") <3

थप जानकारीको लागि, कृपया Excel मा IF AND सूत्र हेर्नुहोस्।

बहुसँग एक्सेल IF प्रकार्यसर्तहरू (वा तर्क)

एउटा कुरा गर्न यदि कुनै सर्त पूरा भयो भने, अन्यथा केहि गर्नुहोस्, IF र OR प्रकार्यहरूको यो संयोजन प्रयोग गर्नुहोस्:

IF(OR( condition1 , condition2 , …), value_if_true, value_if_false)

माथि छलफल गरिएको IF / AND सूत्रबाट भिन्नता भनेको कुनै निर्दिष्ट अवस्था सत्य भएमा Excel ले TRUE फर्काउँछ।

त्यसोभए, यदि अघिल्लो सूत्रमा, हामीले AND को सट्टा OR प्रयोग गर्छौं:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

त्यसो भए कुनै पनि परीक्षामा ५० भन्दा बढी अंक ल्याउनेले "पास" पाउनेछ। स्तम्भ D. त्यस्ता अवस्थाहरूसँग, हाम्रा विद्यार्थीहरूसँग अन्तिम परीक्षा पास गर्ने राम्रो मौका छ (यभेट विशेष गरी केवल १ अंकले असफल भएकोमा अशुभ भएको छ :)

टिप। यदि तपाईँले पाठ सँग बहु IF कथन सिर्जना गर्दै हुनुहुन्छ र OR तर्क (अर्थात् एउटा सेल "यो" वा "त्यो" हुन सक्छ) को साथ एउटा कक्षमा मान परीक्षण गर्दै हुनुहुन्छ भने, तपाईँले थप कम्प्याक्ट निर्माण गर्न सक्नुहुन्छ। एरे स्थिरता प्रयोग गरेर सूत्र।

उदाहरणका लागि, सेल B2 कि त "डेलिभर गरिएको" वा "भुक्तानी" हो भने बिक्रीलाई "बंद" भनी चिन्ह लगाउनको लागि सूत्र हो:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

थप सूत्र उदाहरणहरू Excel IF OR प्रकार्यमा फेला पार्न सकिन्छ।

IF धेरै AND & वा कथनहरू

यदि तपाइँको कार्यलाई धेरै सर्तहरूको धेरै सेटहरू मूल्याङ्कन गर्न आवश्यक छ भने, तपाइँले दुबै AND र & वा एक पटकमा कार्यहरू।

हाम्रो नमूना तालिकामा, मानौं तपाईंसँग परीक्षाको नतिजा जाँच गर्नका लागि निम्न मापदण्डहरू छन्:

• सर्त १:परीक्षा1>50 र परीक्षा2>50
• सर्त 2: परीक्षा1>40 र परीक्षा2>60

यदि कुनै सर्त पूरा भएमा, अन्तिम परीक्षा उत्तीर्ण भएको मानिन्छ।

पहिलो नजरमा, सूत्र अलि गाह्रो देखिन्छ, तर वास्तवमा यो होइन! तपाईंले माथिका प्रत्येक सर्तहरूलाई AND कथनको रूपमा अभिव्यक्त गर्नुहोस् र तिनीहरूलाई OR प्रकार्यमा नेस्ट गर्नुहोस् (किनकि यो दुबै सर्तहरू पूरा गर्न आवश्यक छैन, या त पर्याप्त हुनेछ):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

त्यसपछि, प्रयोग गर्नुहोस् IF को तार्किक परीक्षणको लागि OR प्रकार्य र इच्छित value_if_true र value_if_false मानहरू आपूर्ति गर्नुहोस्। नतिजाको रूपमा, तपाईंले धेरै AND / OR अवस्थाहरूसँग निम्न IF सूत्र प्राप्त गर्नुहुन्छ:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

तलको स्क्रिनसटले हामीले सूत्र सही गर्यौं भनेर संकेत गर्छ:

स्वाभाविक रूपमा , तपाईं आफ्नो IF सूत्रहरूमा केवल दुई AND/OR प्रकार्यहरू प्रयोग गर्न सीमित हुनुहुन्न। तपाईले ती मध्ये धेरै प्रयोग गर्न सक्नुहुन्छ तपाईको व्यवसायिक तर्कलाई आवश्यक भएमा, यदि यो:

• Excel 2007 र उच्चमा, तपाईसँग 255 भन्दा बढी तर्कहरू छैनन्, र IF सूत्रको कुल लम्बाइ नाघेको छैन। 8,192 वर्णहरू।
• Excel 2003 र कममा, त्यहाँ 30 भन्दा बढी तर्कहरू छैनन्, र तपाईंको IF सूत्रको कुल लम्बाइ 1,024 वर्णहरू भन्दा बढी हुँदैन।

नेस्टेड IF कथनलाई धेरै तार्किक परीक्षणहरू जाँच गर्नुहोस्

यदि तपाइँ एकल सूत्र भित्र धेरै तार्किक परीक्षणहरू मूल्याङ्कन गर्न चाहनुहुन्छ भने, तपाइँ धेरै प्रकार्यहरू एक अर्कोमा नेस्ट गर्न सक्नुहुन्छ। त्यस्ता प्रकार्यहरूलाई नेस्टेड भनिन्छIF कार्यहरू । तिनीहरू विशेष गरी उपयोगी साबित हुन्छन् जब तपाईं तार्किक परीक्षणको नतिजामा निर्भर गर्दै विभिन्न मानहरू फर्काउन चाहनुहुन्छ।

यहाँ एउटा सामान्य उदाहरण छ: मानौं तपाईं विद्यार्थीहरूको उपलब्धिलाई " राम्रो " को रूपमा योग्य बनाउन चाहनुहुन्छ। " सन्तोषजनक " र " खराब " निम्न अंकहरूमा आधारित:

• राम्रो: 60 वा बढी (>=60)
• सन्तोषजनक: 40 र 60 बीच (>40 र <60)
• खराब: 40 वा कम (<=40)

सूत्र लेख्नु अघि, क्रमलाई विचार गर्नुहोस् तपाईंले नेस्ट गर्न लाग्नु भएको कार्यहरूको। Excel ले तार्किक परीक्षणहरूलाई सूत्रमा देखा पर्ने क्रममा मूल्याङ्कन गर्नेछ। एकपटक सर्तलाई TRUE मा मूल्याङ्कन गरिसकेपछि, त्यसपछिका सर्तहरूको परीक्षण गरिँदैन, अर्थात् पहिलो TRUE नतिजा पछि सूत्र रोकिन्छ।

हाम्रो अवस्थामा, प्रकार्यहरू सबैभन्दा ठूलो देखि सानो सम्म मिलाइन्छ:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

स्वाभाविक रूपमा, आवश्यक भएमा तपाईले थप कार्यहरू नेस्ट गर्न सक्नुहुन्छ (आधुनिक संस्करणहरूमा 64 सम्म)।

थप जानकारीको लागि, कृपया Excel मा बहु नेस्टेड IF कथनहरू कसरी प्रयोग गर्ने हेर्नुहोस्।

बहु सर्तहरू भएको एक्सेल IF एरे सूत्र

परीक्षण गर्नको लागि Excel IF प्राप्त गर्ने अर्को तरिका धेरै सर्तहरू एरे सूत्र प्रयोग गरेर हो।

अन्ड तर्कसँग सर्तहरू मूल्याङ्कन गर्न, तारा चिन्ह प्रयोग गर्नुहोस्:

IF( condition1 ) * ( condition2 ) * …, value_if_true, value_if_false)

OR तर्कसँग सर्तहरू परीक्षण गर्न, प्लस चिन्ह प्रयोग गर्नुहोस्:

IF( condition1 ) + ( condition2 ) + …,value_if_true, value_if_false)

एरे सूत्र सही तरिकाले पूरा गर्न, Ctrl + Shift + Enter कुञ्जीहरू सँगै थिच्नुहोस्। एक्सेल 365 र एक्सेल 2021 मा, यसले गतिशील एरेहरूको लागि समर्थनको कारणले नियमित सूत्रको रूपमा पनि काम गर्दछ।

उदाहरणका लागि, यदि B2 र C2 दुबै 50 भन्दा माथि छन् भने "पास" प्राप्त गर्न, सूत्र हो:

=IF((B2>50) * (C2>50), "Pass", "Fail")

मेरो एक्सेल ३६५ मा, सामान्य सूत्रले राम्रोसँग काम गर्छ (जसरी तपाइँ माथिको स्क्रिनसटमा देख्न सक्नुहुन्छ)। Excel 2019 र तल्लो मा, Ctrl + Shift + Enter सर्टकट प्रयोग गरेर यसलाई एरे सूत्र बनाउन सम्झनुहोस्।

OR तर्क संग धेरै अवस्थाहरूको मूल्याङ्कन गर्न, सूत्र हो:

=IF((B2>50) + (C2>50), "Pass", "Fail")

अन्य प्रकार्यहरूसँग IF प्रयोग गर्ने

यस खण्डले अन्य एक्सेल प्रकार्यहरूसँग संयोजनमा IF कसरी प्रयोग गर्ने र यसले तपाईंलाई के फाइदा दिन्छ भनेर वर्णन गर्दछ।

उदाहरण १. यदि #N VLOOKUP मा त्रुटि

जब VLOOKUP वा अन्य लुकअप प्रकार्यले केहि फेला पार्न सक्दैन, यसले #N/A त्रुटि फर्काउँछ। तपाईँको तालिकाहरू राम्रो देखाउनको लागि, तपाईँले #N/A भएमा शून्य, खाली, वा विशिष्ट पाठ फर्काउन सक्नुहुन्छ। यसको लागि, यो सामान्य सूत्र प्रयोग गर्नुहोस्:

IF(ISNA(VLOOKUP(…)), value_if_na , VLOOKUP(…))

उदाहरणका लागि:

यदि #N/ रिटर्न ०:

यदि E1 मा लुकअप मान फेला परेन भने, सूत्रले शून्य फर्काउँछ।

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

यदि #N/A खाली फर्काउँछ:

यदि लुकअप मान फेला परेन भने, सूत्रले केहि फर्काउँदैन (खाली स्ट्रिङ)।

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

यदि #N/A निश्चित पाठ फर्काउँछ:

यदि लुकअप मान फेला परेन, theसूत्रले विशिष्ट पाठ फर्काउँछ।

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))

थप सूत्र उदाहरणहरूको लागि, कृपया Excel मा IF कथनसँग VLOOKUP हेर्नुहोस्।

उदाहरण २. IF SUM, AVERAGE, MIN र MAX सँग कार्यहरू

निश्चित मापदण्डमा आधारित सेल मानहरूको योग गर्न, एक्सेलले SUMIF र SUMIFS प्रकार्यहरू प्रदान गर्दछ।

केही परिस्थितिहरूमा, तपाईंको व्यापार तर्कले IF को तार्किक परीक्षणमा SUM प्रकार्य समावेश गर्न आवश्यक हुन सक्छ। उदाहरणका लागि, B2 र C2 मा मानहरूको योगफलको आधारमा फरक पाठ लेबलहरू फर्काउन, सूत्र हो:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

यदि योग 130 भन्दा ठूलो छ भने, परिणाम "राम्रो हुन्छ। "; यदि 110 भन्दा बढी - "सन्तोषजनक', यदि 110 वा कम - "खराब"।

उस्तै तरिकामा, तपाईंले IF को तार्किक परीक्षणमा AVERAGE प्रकार्य इम्बेड गर्न सक्नुहुन्छ र औसत स्कोरको आधारमा विभिन्न लेबलहरू फर्काउन सक्नुहुन्छ। :

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

कुल स्कोर स्तम्भ D मा छ भनी मानेर, तपाईंले MAX र MIN प्रकार्यहरूको मद्दतले उच्चतम र न्यून मानहरू पहिचान गर्न सक्नुहुन्छ:

=IF(D2=MAX($D$2:$D$10), "Best result", "") <3

=IF(D2=MAX($D$2:$D$10), "Best result", "")

एउटै स्तम्भमा दुवै लेबलहरू राख्न, माथिका प्रकार्यहरूलाई अर्कोमा नेस्ट गर्नुहोस्:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))

त्यसैगरी, तपाईंले आफ्नो अनुकूलनसँग IF प्रयोग गर्न सक्नुहुन्छ। प्रकार्यहरू। उदाहरणका लागि, तपाईंले सेल रङमा आधारित फरक परिणामहरू फर्काउन यसलाई GetCellColor वा GetCellFontColor सँग जोड्न सक्नुहुन्छ।

अतिरिक्त, एक्सेलले सर्तहरूमा आधारित डेटा गणना गर्न धेरै प्रकार्यहरू प्रदान गर्दछ। विस्तृत सूत्र उदाहरणहरूको लागि, कृपया निम्न जाँच गर्नुहोस्ट्यूटोरियलहरू:

• COUNTIF - सर्त पूरा गर्ने कक्षहरू गणना गर्नुहोस्
• COUNTIFS - धेरै मापदण्डहरू भएका कक्षहरू गणना गर्नुहोस्
• SUMIF - सशर्त योग कक्षहरू
• SUMIFS - धेरै मापदण्डका साथ सेलहरू योग

उदाहरण 3. ISNUMBER, ISTEXT र ISBLANK सँग IF

पाठ, संख्या र खाली कक्षहरू पहिचान गर्न, Microsoft Excel ले विशेष प्रकार्यहरू प्रदान गर्दछ जस्तै ISTEXT, ISNUMBER र ISBLANK। तिनीहरूलाई तीन नेस्टेड IF कथनहरूको तार्किक परीक्षणहरूमा राखेर, तपाईंले एकै पटकमा सबै फरक डेटा प्रकारहरू पहिचान गर्न सक्नुहुन्छ:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))

उदाहरण ४. IF र CONCATENATE

प्रति IF को नतिजा र केही पाठलाई एउटा कक्षमा आउटपुट गर्नुहोस्, CONCATENATE वा CONCAT (एक्सेल 2016 - 365 मा) र IF प्रकार्यहरू सँगै प्रयोग गर्नुहोस्। उदाहरणका लागि:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

तलको स्क्रिनसट हेर्दा, तपाईंलाई सूत्रले के गर्छ भनेर कुनै स्पष्टीकरणको आवश्यकता पर्दैन:

यदि ISERROR / Excel मा ISNA सूत्र

Excel को आधुनिक संस्करणहरूमा त्रुटिहरू ट्र्याप गर्न र तिनीहरूलाई अर्को गणना वा पूर्वनिर्धारित मान - IFERROR (एक्सेल 2007 र पछिको) र IFNA (एक्सेल 2013 र पछि) संग प्रतिस्थापन गर्न विशेष प्रकार्यहरू छन्। पहिलेको एक्सेल संस्करणहरूमा, तपाईंले यसको सट्टा IF ISERROR र IF ISNA संयोजनहरू प्रयोग गर्न सक्नुहुन्छ।

फरक यो हो कि IFERROR र ISERROR ले #VALUE!, #N/A, #NAME?, सहित सबै सम्भावित Excel त्रुटिहरू ह्यान्डल गर्दछ। #REF!, #NUM!, #DIV/0!, र #NULL!। जबकि IFNA र ISNA #N/A त्रुटिहरूमा मात्र विशेषज्ञ हुन्छन्।

उदाहरणका लागि,"शून्य द्वारा विभाजन" त्रुटि (#DIV/0!) लाई तपाइँको अनुकूल पाठको साथ बदल्नुहोस्, तपाइँ निम्न सूत्र प्रयोग गर्न सक्नुहुन्छ:

=IF(ISERROR(A2/B2), "N/A", A2/B2)

र मैले प्रयोग गर्ने बारे यति मात्र भन्नु पर्छ। एक्सेलमा IF प्रकार्य। पढ्नुभएकोमा म तपाईंलाई धन्यवाद दिन्छु र अर्को हप्ता हाम्रो ब्लगमा भेट्ने आशा गर्दछु!

डाउनलोडका लागि अभ्यास कार्यपुस्तिका

Excel IF बहु मापदण्ड - उदाहरणहरू (.xlsx फाइल)