У апошніх артыкулах мы абмяркоўвалі розныя тэкставыя функцыі - тыя, якія выкарыстоўваюцца для працы з тэкставымі радкамі. Сёння наша ўвага сканцэнтравана на функцыі RIGHT, якая прызначана для вяртання зададзенай колькасці сімвалаў з правага боку радка. Як і іншыя тэкставыя функцыі Excel, RIGHT вельмі простая і зразумелая, тым не менш яна мае некалькі невідавочных ужыванняў, якія могуць апынуцца карыснымі ў вашай працы.

Сінтаксіс функцыі Excel RIGHT

Функцыя RIGHT у Excel вяртае зададзеную колькасць сімвалаў з канца тэкставага радка.

Сінтаксіс функцыі RIGHT наступны:

Дзе :

• Тэкст (абавязкова) - тэкставы радок, з якога вы хочаце атрымаць сімвалы.
• Num_chars (неабавязкова) - колькасць знакаў, якія трэба атрымаць, пачынаючы з самага правага сімвала.
  • Калі num_chars апушчана, вяртаецца 1 апошні сімвал радка (па змаўчанні).
  • Калі num_chars больш за агульную колькасць сімвалаў у радку, вяртаюцца ўсе сімвалы.
  • Калі num_chars з'яўляецца адмоўным лікам, формула Right вяртае #VALUE! памылка.

Напрыклад, каб атрымаць апошнія 3 сімвалы з радка ў ячэйцы A2, выкарыстоўвайце наступную формулу:

=RIGHT(A2, 3)

Вынік можа выглядаць прыкладна так:

Важная заўвага! Функцыя Excel RIGHT заўсёды вяртае тэкст радок , нават калі зыходнае значэнне з'яўляецца лікам. Каб прымусіць формулу Right выводзіць лік, выкарыстоўвайце яе ў спалучэнні з функцыяй VALUE, як паказана ў гэтым прыкладзе.

Як выкарыстоўваць функцыю RIGHT у Excel - прыклады формул

У рэальным жыцці працоўныя аркушы, функцыя Excel RIGHT рэдка выкарыстоўваецца сама па сабе. У большасці выпадкаў вы будзеце выкарыстоўваць яго разам з іншымі функцыямі Excel як частку больш складаных формул.

Як атрымаць падрадок, які ідзе пасля пэўнага сімвала

Калі вы хочаце атрымаць падрадок, які ідзе за пэўным сімвалам, выкарыстоўвайце функцыю ПОШУК або ЗНАЙСЦІ, каб вызначыць пазіцыю гэтага сімвала, адніміце пазіцыю ад агульнай даўжыні радка, якую вяртае функцыя LEN, і выцягніце гэту колькасць сімвалаў з самага правага боку зыходнага радка.

Скажам, ячэйка A2 змяшчае імя і прозвішча, падзеленыя прабелам, і вы імкнецеся перацягнуць прозвішча ў іншую ячэйку. Проста вазьміце агульную формулу вышэй і пастаўце A2 замест радка і " " (прабел) у тэмпе сімвала:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Формула дасць наступны вынік:

Аналагічным чынам вы можаце атрымаць падрадок, які ідзе пасля любога іншага сімвала, напрыклад. коска, кропка з коскі, злучок і г.д. Напрыклад, каб вылучыць падрадок, які ідзе пасля злучка,скарыстайцеся гэтай формулай:

=RIGHT(A2,LEN(A2)-SEARCH("-",A2))

Вынік будзе выглядаць прыкладна так:

Як атрымаць падрадок пасля апошняга ўваходжання раздзяляльніка

Калі пры працы са складанымі радкамі, якія ўтрымліваюць некалькі ўваходжанняў аднаго і таго ж раздзяляльніка, вам часта можа спатрэбіцца атрымаць тэкст справа ад апошняга раздзяляльніка. Каб было лягчэй зразумець, паглядзіце на наступныя зыходныя дадзеныя і жаданы вынік:

Як бачыце на скрыншоце вышэй, слупок A змяшчае спіс памылак. Ваша мэта - атрымаць апісанне памылкі, якое ідзе пасля апошняга двукроп'я ў кожным радку. Дадатковая складанасць заключаецца ў тым, што зыходныя радкі могуць утрымліваць розную колькасць асобнікаў-падзельнікаў, напрыклад. A3 змяшчае 3 двукроп'і, а A5 толькі адну.

Ключ да пошуку рашэння - вызначыць пазіцыю апошняга раздзяляльніка ў зыходным радку (апошняе з'яўленне двукроп'я ў гэтым прыкладзе). Каб зрабіць гэта, вам трэба будзе выкарыстоўваць некалькі розных функцый:

1. Атрымаць колькасць раздзяляльнікаў у зыходным радку. Гэта простая частка:
   • Па-першае, вы вылічваеце агульную даўжыню радка з дапамогай функцыі LEN: LEN(A2)
   • Па-другое, вы вылічваеце даўжыню радка без раздзяляльнікаў з дапамогай Функцыя SUBSTITUTE, якая замяняе ўсе ўваходжанні двукроп'я нічым: LEN(SUBSTITUTE(A2,":",""))
   • Нарэшце, вы адымаеце даўжыню зыходнага радкабез раздзяляльнікаў ад агульнай даўжыні радка: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))

   Каб пераканацца, што формула працуе правільна, вы можаце ўвесці яе ў асобную ячэйку, і вынік будзе 2, што з'яўляецца колькасцю двукроп'яў у ячэйцы A2.

2. Замяніце апошні раздзяляльнік нейкім унікальным сімвалам. Для таго, каб атрымаць тэкст, які ідзе пасля апошняга раздзяляльніка ў радку, нам трэба нейкім чынам «пазначыць» гэта канчатковае з'яўленне раздзяляльніка. Для гэтага давайце заменім апошняе ўваходжанне двукроп'я на сімвал, які не сустракаецца нідзе ў зыходных радках, напрыклад, на знак фунта (#).

   Калі вы знаёмыя з сінтаксісам функцыі SUBSTITUTE Excel, вы, магчыма, памятаеце, што ў яе ёсць 4-ы неабавязковы аргумент (нумар_экземпляра), які дазваляе замяняць толькі канкрэтнае ўваходжанне ўказанага сімвала. І паколькі мы ўжо падлічылі колькасць раздзяляльнікаў у радку, проста ўвядзіце вышэйзгаданую функцыю ў чацвёрты аргумент іншай функцыі SUBSTITUTE:

   =SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))

   Глядзі_таксама: Функцыя Excel FILTER - дынамічная фільтрацыя з дапамогай формул

   Калі вы змясціце гэту формулу ў асобную ячэйку , ён верне гэты радок: ПАМЫЛКА:432#Час чакання злучэння скончыўся

3. Атрымаць пазіцыю апошняга раздзяляльніка ў радку. У залежнасці ад таго, якім сімвалам вы замянілі апошні раздзяляльнік, выкарыстоўвайце або SEARCH без уліку рэгістра, або FIND, каб вызначыць пазіцыю гэтага сімвала ў радку. Мы замянілі апошнюю двукроп'еса знакам #, таму мы выкарыстоўваем наступную формулу, каб высветліць яго пазіцыю:

   =SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))

   У гэтым прыкладзе формула вяртае 10, што з'яўляецца пазіцыяй # у замененым радку.

4. Вярнуць падрадок справа ад апошняга раздзяляльніка. Цяпер, калі вы ведаеце пазіцыю апошняга раздзяляльніка ў радку, усё, што вам трэба зрабіць, гэта адняць гэты лік ад агульнай даўжыні радка і атрымаць ПРАВІЛЬНУЮ функцыю, каб вярнуць такую ​​колькасць сімвалаў з канца зыходнага радка:

   =RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))

Як паказана на скрыншоце ніжэй, формула працуе ідэальна:

Калі вы працуеце з вялікім наборам даных, дзе розныя ячэйкі могуць утрымліваць розныя падзельнікі, вам можа спатрэбіцца каб уключыць прыведзеную вышэй формулу ў функцыю IFERROR, каб прадухіліць магчымыя памылкі:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)

Калі пэўны радок не змяшчае ніводнага ўваходжання ўказанага раздзяляльніка, будзе вернуты зыходны радок, як у радку 6 на скрыншоце ніжэй:

Як выдаліць першыя N сімвалаў з радка

Акрамя здабывання падрадка з канца радка, карысная функцыя Excel RIGHT у сітуацыях, калі вы хочаце выдаліць пэўную колькасць сімвалаў з пачатку радка.

У наборы дадзеных, які выкарыстоўваецца ў папярэднім Напрыклад, вы можаце выдаліць слова "ПАМЫЛКА", якое з'яўляецца ў пачатку кожнага радка, і пакінуць толькі нумар памылкі і апісанне. Каб гэта былозроблена, адніміце колькасць сімвалаў, якія трэба выдаліць, з агульнай даўжыні радка і пастаўце гэты лік у аргумент num_chars функцыі Excel RIGHT:

У гэтым прыкладзе мы выдаляем першыя 6 сімвалаў (5 літар і двукроп'е) з тэкставага радка ў A2, таму наша формула мае выгляд наступнае:

=RIGHT(A2, LEN(A2)-6)

Ці можа функцыя Excel RIGHT вяртаць лік?

Як было сказана ў пачатку гэтага падручніка, функцыя RIGHT у Excel заўсёды вяртае тэкставы радок, нават калі зыходнае значэнне - лік. Але што, калі вы працуеце з лікавым наборам дадзеных і жадаеце, каб вынік таксама быў лікавым? Простым абыходным шляхам з'яўляецца ўкладванне формулы Right у функцыю VALUE, якая спецыяльна распрацавана для пераўтварэння радка, які прадстаўляе лік, у лік.

Напрыклад, каб атрымаць апошнія 5 сімвалаў (паштовы індэкс) з радка у A2 і пераўтварыце вынятыя сімвалы ў лік, выкарыстоўвайце наступную формулу:

=VALUE(RIGHT(A2, 5))

На скрыншоце ніжэй паказаны вынік - калі ласка, звярніце ўвагу на выраўноўванне лічбаў у слупку B па правым краі, а не па левым -выраўнаваныя тэкставыя радкі ў слупку A:

Чаму функцыя ПРАВА не працуе з датамі?

Паколькі функцыя ПРАВА ў Excel прызначана для працы з тэкставымі радкамі, а даты прадстаўлены лічбамі ў ва ўнутранай сістэме Excel правільная формула не можа атрымаць асобучастка даты, напрыклад дзень, месяц ці год. Калі вы паспрабуеце зрабіць гэта, усё, што вы атрымаеце, гэта некалькі апошніх лічбаў нумара, які прадстаўляе дату.

Выкажам здагадку, што ў вас ёсць дата 18-Jan-2017 у ячэйцы A1. Калі вы паспрабуеце вылучыць год з дапамогай формулы RIGHT(A1,4), вынік будзе 2753, які з'яўляецца апошнімі 4 лічбамі ліку 42753, які прадстаўляе 18 студзеня 2017 г. у сістэме Excel.

"Такім чынам, як я магу атрымаць пэўную частку даты?", Вы можаце спытаць мяне. З дапамогай адной з наступных функцый:

• функцыя DAY для вылучэння дня: =DAY(A1)
• функцыя MONTH для атрымання месяца: =MONTH(A1)
• Функцыя YEAR для атрымання года: =YEAR(A1)

На наступным скрыншоце паказаны вынікі:

Калі вашы даты прадстаўлены тэкставымі радкамі , што часта бывае, калі вы экспартуеце даныя з вонкавай крыніцы, нішто не перашкаджае вам выкарыстоўваць функцыю ПРАВА, каб атрымаць некалькі апошніх сімвалаў у радку, якія прадстаўляюць пэўную частку даты:

Excel ПРАВА функцыя не працуе - прычыны і рашэнні

Калі правільная формула не працуе належным чынам на вашым аркушы, хутчэй за ўсё, гэта з-за адной з наступных прычын:

1. Існуе адна ці некалькі прабелы ў канцы ў зыходных дадзеных. Каб хутка выдаліць лішнія прабелы ў ячэйках, выкарыстоўвайце функцыю Excel TRIM або надбудову Cell Cleaner.
2. Аргумент num_chars меншы за нуль . звядома, вы наўрад ці захочаце наўмысна паставіць адмоўны лік у сваю формулу, але калі аргумент num_chars вылічваецца іншай функцыяй Excel або камбінацыяй розных функцый і ваша формула Right вяртае #VALUE! памылка, абавязкова праверце ўкладзеныя функцыі(-і) на наяўнасць памылак.
3. Зыходнае значэнне - гэта дата . Калі вы ўважліва сачылі за гэтым падручнікам, вы ўжо ведаеце, чаму функцыя RIGHT не можа працаваць з датамі. Калі нехта прапусціў папярэдні раздзел, вы можаце знайсці падрабязную інфармацыю ў раздзеле Чаму функцыя Excel RIGHT не працуе з датамі.

Вось як вы выкарыстоўваеце функцыю RIGHT у Excel. Каб больш уважліва разгледзець формулы, якія абмяркоўваюцца ў гэтым уроку, вы можаце загрузіць наш узор рабочай кнігі ніжэй. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні.

Даступныя спампоўкі

Функцыя Excel RIGHT - прыклады (.xlsx файл)