Dina sababaraha artikel panungtungan, urang geus ngabahas béda fungsi téks - fungsi nu dipaké pikeun ngamanipulasi string téks. Dinten fokus kami dina fungsi RIGHT, nu dirancang pikeun mulangkeun jumlah husus tina karakter ti sisi katuhu tina string. Sapertos pungsi Excel Text anu sanés, RIGHT saderhana pisan sareng lugas, tapi gaduh sababaraha kagunaan anu teu jelas anu tiasa ngabantosan padamelan anjeun.

Sintaksis fungsi Excel RIGHT

Pungsi RIGHT dina Excel mulangkeun jumlah karakter nu ditangtukeun ti tungtung string téks.

Sintaksis fungsi RIGHT nyaéta kieu:

Dimana :

• Teks (diperlukeun) - string téks nu Anjeun hoyong nimba karakter.
• Num_chars (opsional) - nu Jumlah karakter pikeun nimba, mimitian ti karakter paling katuhu.
  • Upami num_chars dileungitkeun, 1 karakter terakhir tina string dipulangkeun (standar).
  • Upami num_chars langkung ageung tibatan jumlah total karakter dina string, sadaya karakter dipulangkeun.
  • Lamun num_chars mangrupa angka négatif, rumus Katuhu ngabalikeun #VALUE! kasalahan.

Contona, pikeun nimba 3 karakter pamungkas tina string dina sél A2, paké rumus ieu:

=RIGHT(A2, 3)

Hasilna sigana sapertos kieu:

Catetan penting! Fungsi Excel RIGHT salawasna mulangkeun teksstring , sanajan nilai aslina mangrupa angka. Pikeun maksakeun rumus Katuhu pikeun ngahasilkeun angka, paké éta dina kombinasi sareng pungsi VALUE sapertos anu dipidangkeun dina conto ieu.

Kumaha ngagunakeun fungsi RIGHT dina Excel - conto rumus

Dina kahirupan nyata lembar kerja, fungsi Excel RIGHT jarang dipaké sorangan. Dina kalolobaan kasus, Anjeun bakal make eta babarengan jeung pungsi Excel séjén salaku bagian tina rumus nu leuwih kompleks.

Kumaha carana meunangkeun substring nu asalna sanggeus karakter nu tangtu

Upami Anjeun hoyong nimba a substring nu nuturkeun karakter husus, ngagunakeun boh SEARCH atawa fungsi FIND pikeun nangtukeun posisi karakter eta, subtract posisi tina total panjang string balik ku fungsi LEN, sarta narik eta loba karakter ti sisi katuhu tina string aslina.

Sebutkeun, cell A2 ngandung ngaran hareup jeung tukang dipisahkeun ku spasi, jeung anjeun boga tujuan pikeun narik ngaran tukang ka sél séjén. Candak rumus umum di luhur sareng anjeun nempatkeun A2 gaganti string , sareng " " (spasi) dina laju karakter:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Rumusna bakal ngahasilkeun hasil kieu:

Ku cara nu sarua, anjeun bisa meunangkeun substring nu nuturkeun karakter sejenna, misalna. koma, titik koma, hyphen, jsb. Contona, pikeun nimba substring nu asalna sanggeus hyphen,make rumus ieu:

=RIGHT(A2,LEN(A2)-SEARCH("-",A2))

Hasilna bakal siga kieu:

Kumaha cara nimba substring sanggeus kajadian pamungkas tina delimiter

Iraha kaayaan string kompléks nu ngandung sababaraha kajadian tina delimiter sarua, Anjeun bisa jadi mindeng kudu nimba téks ka katuhu tina lumangsungna delimiter panungtungan. Pikeun ngagampangkeun kahartos, tingali data sumber di handap ieu sareng hasil anu dipikahoyong:

Sapertos anu anjeun tingali dina screenshot di luhur, Kolom A ngandung daptar kasalahan. Tujuanana anjeun pikeun narik pedaran kasalahan anu asalna sanggeus titik panungtungan dina unggal string. Komplikasi tambahan nyaéta yén string aslina bisa ngandung angka béda tina instansi delimiter, f.eks. A3 ngandung 3 titik sedengkeun A5 ngan hiji.

Konci pikeun manggihan solusi nyaéta nangtukeun posisi delimiter panungtungan dina sumber string (kajadian panungtungan titik titik dina conto ieu). Jang ngalampahkeun ieu, anjeun bakal kudu make sakeupeul fungsi béda:

1. Kéngingkeun jumlah delimiters dina string aslina. Bagian anu gampang:
   • Mimitina, anjeun ngitung panjang total string nganggo fungsi LEN: LEN(A2)
   • Kadua, anjeun ngitung panjang string tanpa wates ku ngagunakeun Pungsi SUBSTITUTE nu ngagantikeun sakabéh kajadian titik titik kalawan nanaon: LEN(SUBSTITUTE(A2,":",""))
   • Ahirna, anjeun ngurangan panjang string aslina.tanpa pembatas tina total panjang string: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))

   Pikeun mastikeun rumusna jalan bener, anjeun bisa ngasupkeun kana sél misah, sarta hasilna bakal 2, nu jumlah titik dina sél A2.

2. Ganti pembatas panungtungan ku sababaraha karakter unik. Dina raraga nimba téks nu asalna sanggeus delimiter panungtungan dina string, urang kudu "nyirian" yén lumangsungna ahir delimiter dina sababaraha cara. Pikeun ieu, hayu urang ngaganti lumangsungna titik panungtungan ku karakter nu teu muncul mana dina string aslina, contona ku tanda pound (#).

   Upami anjeun wawuh sareng sintaksis fungsi Excel SUBSTITUTE, anjeun tiasa émut yén éta ngagaduhan argumen pilihan ka-4 (instance_num) anu ngamungkinkeun anjeun ngan ukur ngagentos kajadian khusus tina karakter anu ditangtukeun. Sarta saprak urang geus diitung jumlah delimiters dina string, cukup nyadiakeun fungsi di luhur dina argumen kaopat fungsi SUBSTITUTE sejen:

   =SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))

   Lamun nempatkeun rumus ieu dina sél misah. , éta bakal mulangkeun string ieu: ERROR:432#Connection timed out

3. Kéngingkeun posisi delimiter panungtungan dina string. Gumantung kana karakter naon nu Anjeun ngagantikeun delimiter panungtungan kalawan, ngagunakeun boh SEARCH hal-teu sensitip atawa PANgihan hal-sénsitip pikeun nangtukeun posisi karakter eta dina senar. Urang ngaganti titik panungtungankalawan tanda #, jadi kami nganggo rumus di handap pikeun manggihan posisi na:

   =SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))

   Dina conto ieu, rumus mulih 10, nu posisi # dina string diganti.

4. Mulangkeun substring ka katuhu tina pembatas anu terakhir. Ayeuna anjeun terang posisi delimiter anu terakhir dina senar, anu anjeun kedah laksanakeun nyaéta ngirangan jumlah éta tina total panjang senar, sareng kéngingkeun fungsi RIGHT pikeun ngabalikeun seueur karakter tina tungtung senar asli:

   =RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))

Sapertos anu dipidangkeun dina screenshot di handap, rumusna tiasa dianggo sampurna:

Upami anjeun damel sareng set data ageung dimana sél anu béda-béda tiasa ngandung pembatas anu béda, anjeun panginten hoyong pikeun ngalampirkeun rumus di luhur dina pungsi IFERROR pikeun nyegah kamungkinan kasalahan:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)

Upami senar nu tangtu teu ngandung hiji kajadian tina delimiter nu ditangtukeun, senar aslina bakal dipulangkeun, kawas dina baris 6 dina screenshot di handap:

Kumaha carana miceun N karakter munggaran tina string

Salain ti nimba substring tina tungtung string, fungsi Excel RIGHT aya gunana. dina kaayaan nalika anjeun hoyong miceun sajumlah karakter tina awal senar.

Dina set data anu dianggo dina prev Contona, Anjeun meureun hoyong miceun kecap "ERROR" nu nembongan dina mimiti unggal string sarta ninggalkeun ngan jumlah kasalahan jeung pedaran. Pikeun mibanda etarengse, ngurangan jumlah karakter nu bakal dipiceun tina total panjang string, sarta asupkeun angka eta ka num_chars argumen fungsi Excel RIGHT:

Dina conto ieu, urang miceun 6 karakter kahiji (5 hurup jeung titik dua) tina string téks dina A2, jadi rumus urang jadi saperti kieu:

=RIGHT(A2, LEN(A2)-6)

Naha pungsi Excel RIGHT bisa mulangkeun angka?

Sakumaha disebutkeun dina awal tutorial ieu, fungsi RIGHT dina Excel salawasna mulangkeun string téks sanajan lamun nilai aslina mangrupa angka. Tapi kumaha upami anjeun damel sareng set data numerik sareng hoyong kaluaranna ogé numerik? Solusi anu gampang nyaéta nyarang rumus Katuhu dina fungsi VALUE, anu dirarancang khusus pikeun ngarobih senar anu ngalambangkeun angka kana angka.

Contona, pikeun narik 5 karakter terakhir (kode pos) tina senar. dina A2 tur ngarobah karakter nu diekstrak jadi angka, make rumus ieu:

=VALUE(RIGHT(A2, 5))

Potret layar di handap nembongkeun hasilna - mangga perhatikeun angka-aligning katuhu dina kolom B, sabalikna kénca. -baris téks anu dijajarkeun dina kolom A:

Naha fungsi RIGHT henteu dianggo sareng kaping?

Kusabab fungsi Excel RIGHT dirancang pikeun dianggo sareng string téks, sedengkeun tanggal diwakilan ku angka dina sistem Excel internal, rumus Katuhu teu bisa meunangkeun hiji individubagian tina hiji tanggal kayaning poé, bulan atawa taun. Upami anjeun nyobian ngalakukeun ieu, anjeun bakal nampi sababaraha digit terakhir tina jumlah anu ngagambarkeun tanggal.

Upami anjeun gaduh tanggal 18-Jan-2017 dina sél A1. Upami anjeun nyobian nimba taun nganggo rumus RIGHT(A1,4), hasilna bakal 2753, nyaéta 4 digit terakhir tina nomer 42753 anu ngagambarkeun 18 Januari 2017 dina sistem Excel.

"Janten, kumaha carana abdi tiasa nyandak bagian tina tanggal hiji?", anjeun tiasa naros ka kuring. Ku ngagunakeun salah sahiji fungsi di handap ieu:

• Pungsi DAY pikeun nimba poé: =DAY(A1)
• fungsi BULAN pikeun meunangkeun bulan: =MONTH(A1)
• Pungsi YEAR pikeun narik sataun: =YEAR(A1)

Potret layar ieu nembongkeun hasil:

Upami tanggal anjeun dilambangkeun ku string téks , anu sering kajadian nalika anjeun ngekspor data tina sumber éksternal, teu aya anu ngahalangan anjeun ngagunakeun fungsi RIGHT pikeun narik sababaraha karakter terakhir dina senar anu ngagambarkeun bagian tina tanggal:

Excel RIGHT fungsi teu jalan - alesan jeung solusi

Lamun rumus Katuhu teu jalan katuhu dina LKS anjeun, paling dipikaresep éta alatan salah sahiji alesan ieu:

1. Aya hiji atawa leuwih spasi labuh dina data aslina. Pikeun gancang miceun spasi tambahan dina sél, make pungsi Excel TRIM atawa tambihan Cell Cleaner.
2. Argumen num_chars kurang ti nol . TinaTangtu, anjeun bakal boro rék nempatkeun angka négatip dina rumus anjeun dina ngahaja, tapi lamun argumen num_chars diitung ku fungsi Excel sejen atawa kombinasi fungsi béda jeung rumus Katuhu anjeun mulih #VALUE! kasalahan, pastikeun pikeun pariksa fungsi nested (s) pikeun kasalahan.
3. Nilai aslina nyaéta tanggal . Upami anjeun parantos ngiringan tutorial ieu, anjeun parantos terang naha fungsi RIGHT teu tiasa dianggo sareng kaping. Upami aya anu ngalangkungan bagian sateuacana, anjeun tiasa mendakan detil lengkep dina Naha fungsi Excel RIGHT teu tiasa dianggo sareng kaping.

Kieu kumaha anjeun nganggo fungsi RIGHT dina Excel. Pikeun ningali langkung caket kana rumus anu dibahas dina tutorial ieu, anjeun wilujeng sumping pikeun ngaunduh buku kerja conto kami di handap. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog urang minggu payun.

Sadia undeuran

Fungsi Excel RIGHT - conto (file .xlsx)