Во последните неколку статии, разговаравме за различни текстуални функции - оние што се користат за манипулирање со текстуални низи. Денес, нашиот фокус е на функцијата RIGHT, која е дизајнирана да враќа одреден број знаци од најдесната страна на низата. Како и другите функции за текст на Excel, RIGHT е многу едноставен и јасен, но сепак има неколку неочигледни употреби кои може да се покажат како корисни во вашата работа.

Синтакса на функцијата Excel RIGHT

Функцијата RIGHT во Excel го враќа наведениот број знаци од крајот на текстуалната низа.

Синтаксата на функцијата RIGHT е како што следува:

Каде :

• Текст (задолжително) - текстуалната низа од која сакате да извлечете знаци.
• Num_chars (изборно) - број на знаци за извлекување, почнувајќи од најдесниот знак.
  • Ако се испушти num_chars , се враќа 1 последен знак од низата (стандардно).
  • Ако num_chars е поголем од вкупниот број на знаци во низата, сите знаци се враќаат.
  • Ако num_chars е негативен број, формулата Right ја враќа #VALUE! грешка.

На пример, за да ги извлечете последните 3 знаци од низата во ќелијата A2, користете ја оваа формула:

=RIGHT(A2, 3)

Резултатот може да изгледа нешто слично на ова:

Важна забелешка! Функцијата Excel RIGHT секогаш враќа текстстринг , дури и ако оригиналната вредност е број. За да ја принудите формулата Right да даде број, користете ја во комбинација со функцијата VALUE како што е прикажано во овој пример.

Како да се користи RIGHT функцијата во Excel - примери на формула

Во реалниот живот работни листови, функцијата Excel RIGHT ретко се користи сама по себе. Во повеќето случаи, ќе го користите заедно со други функции на Excel како дел од посложени формули.

Како да добиете подниза што доаѓа по одреден знак

Во случај да сакате да извлечете подниза што следи одреден знак, користете или SEARCH или FIND функција за да ја одредите позицијата на тој знак, одземете ја позицијата од вкупната должина на низата што ја враќа функцијата LEN и повлечете толку знаци од најдесната страна на оригиналната низа.

Да речеме, ќелија А2 ги содржи името и презимето одделени со празно место, а вие имате за цел да го повлечете презимето во друга ќелија. Само земете ја генеричката формула погоре и ставете A2 наместо низа и " " (простор) со темпо од знак:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Формулата ќе го даде следниов резултат:

На сличен начин, можете да добиете подниза што следи кој било друг знак, на пр. запирка, точка-запирка, цртичка, итн. На пример, да се извлече подниза што доаѓа по цртичка,користете ја оваа формула:

=RIGHT(A2,LEN(A2)-SEARCH("-",A2))

Резултатот ќе изгледа слично на ова:

Како да се извлече подниза по последното појавување на разграничувачот

Кога кога се занимавате со сложени низи кои содржат неколку појави на ист разграничувач, честопати можеби ќе треба да го вратите текстот десно од последната појава на разграничувач. За полесно да ги разберете работите, погледнете ги следните изворни податоци и посакуваниот резултат:

Како што можете да видите на сликата од екранот погоре, колоната А содржи листа на грешки. Вашата цел е да го повлечете описот на грешката што доаѓа по последната две точки во секоја низа. Дополнителна компликација е тоа што оригиналните низи може да содржат различен број на примери на разграничувачи, на пр. А3 содржи 3 две точки додека А5 само една.

Клучот за наоѓање решение е да се одреди позицијата на последниот разграниувач во изворната низа (последната појава на две точки во овој пример). За да го направите ова, ќе треба да користите неколку различни функции:

1. Добијте го бројот на разграничувачи во оригиналната низа. Тоа е лесен дел:
   • Прво, ја пресметувате вкупната должина на низата користејќи ја функцијата LEN: LEN(A2)
   • Второ, ја пресметувате должината на низата без разграничувачи со користење на SUBSTITUTE функција која ги заменува сите појави на дебелото црево со ништо: LEN(SUBSTITUTE(A2,":",""))
   • На крајот, ја одземате должината на оригиналната низабез разграничувачи од вкупната должина на низата: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))

   За да бидете сигурни дека формулата работи правилно, можете да ја внесете во посебна ќелија, а резултатот ќе биде 2, што е бројот на две точки во ќелијата А2.

2. Заменете го последниот разграниувач со некој уникатен знак. За да го извлечеме текстот што доаѓа по последниот разгранич во низата, треба на некој начин да ја „означиме“ таа конечна појава на разграничувачот. За ова, да го замениме последното појавување на дебелото црево со знак што не се појавува никаде во оригиналните низи, на пример со знак за фунта (#).

   Ако сте запознаени со синтаксата на функцијата Excel SUBSTITUTE, може да се сетите дека таа го има 4-от изборен аргумент (instance_num) кој овозможува замена само на одредена појава на наведениот знак. И бидејќи веќе го пресметавме бројот на разграничувачи во низата, едноставно внесете ја горната функција во четвртиот аргумент на друга функција SUBSTITUTE:

   Исто така види: Како да ги филтрирате и сортирате ќелиите по боја во Excel

   =SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))

   Ако ја ставите оваа формула во посебна ќелија , ќе ја врати оваа низа: ERROR:432#Времето на врската истече

3. Добијте ја позицијата на последниот разграниувач во низата. Во зависност од тоа со кој знак сте го замениле последниот разграничувач, користете или SEARCH без чувствителност на букви или FIND за да ја одредите позицијата на тој знак во низата. Го заменивме последното дебело цревосо знакот #, па ја користиме следнава формула за да ја дознаеме нејзината позиција:

   =SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))

   Во овој пример, формулата враќа 10, што е позицијата на # во заменетиот стринг.

4. Врати подниза десно од последниот разграниувач. Сега кога ја знаете позицијата на последниот разграничувач во низата, се што треба да направите е да го одземе тој број од вкупната должина на низата и да ја добие функцијата RIGHT за да врати толку знаци од крајот на оригиналната низа:

   =RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))

Како што е прикажано на екранот подолу, формулата функционира совршено:

Ако работите со голема база на податоци каде што различни ќелии може да содржат различни разграничувачи, можеби ќе сакате за да се приложи горната формула во функцијата IFERROR за да се спречат можни грешки:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)

Во случај одредена низа да не содржи ниту една појава на наведениот разграниувач, ќе се врати оригиналната низа, како во редот 6 во скриншот подолу:

Како да ги отстраните првите N знаци од низата

Покрај извлекувањето на подниза од крајот на низата, функцијата Excel RIGHT ви е корисна во ситуации кога сакате да отстраните одреден број знаци од почетокот на низата.

Во базата на податоци што се користи во претходно На пример, можеби ќе сакате да го отстраните зборот „ERROR“ што се појавува на почетокот на секоја низа и да ги оставите само бројот на грешката и описот. Да го имамготово, одземете го бројот на знаци што треба да се отстранат од вкупната должина на низата и доставете го тој број на аргументот num_chars на функцијата Excel RIGHT:

Во овој пример, ги отстрануваме првите 6 знаци (5 букви и две точки) од текстуалната низа во A2, така што нашата формула оди како следува:

=RIGHT(A2, LEN(A2)-6)

Дали функцијата Excel RIGHT може да врати број?

Како што беше споменато во почетокот на ова упатство, функцијата RIGHT во Excel секогаш враќа низа текстови дури и ако оригиналната вредност е број. Но, што ако работите со нумеричка база на податоци и сакате и излезот да биде нумерички? Лесно решение е вгнездување на формулата Right во функцијата VALUE, која е специјално дизајнирана да конвертира низа што претставува број во број.

На пример, да се извлечат последните 5 знаци (поштенски код) од низата во A2 и претворете ги извлечените знаци во број, користете ја оваа формула:

=VALUE(RIGHT(A2, 5))

Сликата од екранот подолу го покажува резултатот - ве молиме забележете ги броевите со десно порамнување во колоната Б, наспроти лево -порамнети текстуални низи во колоната А:

Зошто функцијата RIGHT не работи со датуми?

Бидејќи функцијата Excel RIGHT е дизајнирана да работи со текстуални низи, додека датумите се претставени со броеви во внатрешниот Excel систем, формулата Right не е во можност да врати поединецдел од датумот како ден, месец или година. Ако се обидете да го направите ова, сè што ќе добиете е неколку последни цифри од бројот што претставува датум.

Да се ​​претпостави дека го имате датумот 18-јан-2017 во ќелијата A1. Ако се обидете да ја извлечете годината со формулата RIGHT(A1,4), резултатот би бил 2753, што е последните 4 цифри од бројот 42753 што го претставува 18 јануари 2017 година во системот Excel.

„Па, како да повратам одреден дел од датумот?“, можеби ќе ме прашате. Со користење на една од следниве функции:

• Функција DAY за извлекување ден: =DAY(A1)
• MONTH функција за да се добие месец: =MONTH(A1)
• ГОДИНА Функција за повлекување година: =YEAR(A1)

Следната слика од екранот ги прикажува резултатите:

Ако вашите датуми се претставени со текстуални низи , што е често случај кога извезувате податоци од надворешен извор, ништо не ве спречува да ја користите функцијата RIGHT за да ги повлечете последните неколку знаци во низата што претставуваат одреден дел од датумот:

Excel RIGHT функцијата не работи - причини и решенија

Ако формулата Right не работи правилно во вашиот работен лист, најверојатно тоа е поради една од следниве причини:

1. Постои една или повеќе заостанати простори во оригиналните податоци. За брзо отстранување на дополнителните празни места во ќелиите, користете ја функцијата Excel TRIM или додатокот за чистење ќелии.
2. Аргументот num_chars е помал од нула . Насе разбира, тешко дека ќе сакате намерно да ставите негативен број во формулата, но ако аргументот num_chars се пресметува со друга функција на Excel или комбинација од различни функции и вашата формула Right ја враќа #VALUE! грешка, проверете дали има грешки во вгнездените функции.
3. Оригиналната вредност е датум . Ако внимателно го следевте ова упатство, веќе знаете зошто функцијата RIGHT не може да работи со датуми. Ако некој го прескокнал претходниот дел, можете да најдете целосни детали во Зошто функцијата Excel RIGHT не работи со датуми.

Вака ја користите функцијата RIGHT во Excel. За да ги погледнете подетално формулите дискутирани во ова упатство, добредојдени сте да ја преземете нашата примерок работна книга подолу. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела.

Достапни преземања

Excel RIGHT функција - примери (датотека .xlsx)