ટ્યુટોરીયલ બતાવે છે કે તમે સ્પષ્ટ કરેલ કોઈપણ સીમાંકક દ્વારા એક્સેલ 365 માં સ્ટ્રિંગ્સને વિભાજિત કરવા માટે તદ્દન નવા TEXTSPLIT ફંક્શનનો ઉપયોગ કેવી રીતે કરવો.

જ્યારે તમારે વિભાજિત કરવાની જરૂર હોય ત્યારે વિવિધ પરિસ્થિતિઓ હોઈ શકે છે. એક્સેલમાં કોષો. અગાઉના સંસ્કરણોમાં, અમે પહેલાથી જ ટેક્સ્ટ ટુ કૉલમ્સ અને ફિલ ફ્લેશ જેવા કાર્યને પૂર્ણ કરવા માટે સંખ્યાબંધ સાધનોથી સજ્જ હતા. હવે, અમારી પાસે આ માટે એક વિશેષ કાર્ય પણ છે, TEXTSPLIT, જે તમે ઉલ્લેખિત કરેલા પરિમાણોના આધારે કૉલમ અથવા/અને પંક્તિઓમાં એક સ્ટ્રિંગને બહુવિધ કોષોમાં અલગ કરી શકે છે.

Excel TEXTSPLIT ફંક્શન

એક્સેલમાં TEXTSPLIT ફંક્શન આપેલ સીમાંક દ્વારા ટેક્સ્ટ સ્ટ્રીંગને કૉલમ અથવા/અને પંક્તિઓમાં વિભાજિત કરે છે. પરિણામ એ એક ગતિશીલ એરે છે જે આપમેળે બહુવિધ કોષોમાં ફેલાય છે.

ફંક્શન 6 જેટલી દલીલો લે છે, જેમાંથી ફક્ત પ્રથમ બે જ જરૂરી છે.

TEXTSPLIT(ટેક્સ્ટ, col_delimiter, [row_delimiter], [ignore_empty], [match_mode], [pad_with])

ટેક્સ્ટ (જરૂરી) - વિભાજિત કરવા માટે ટેક્સ્ટ. સ્ટ્રિંગ અથવા સેલ સંદર્ભ તરીકે સપ્લાય કરી શકાય છે.

col_delimiter (જરૂરી) - એક અક્ષર(ઓ) જે સૂચવે છે કે ટેક્સ્ટને કૉલમમાં ક્યાં વિભાજિત કરવો. જો અવગણવામાં આવે તો, પંક્તિ_ડિલિમિટર વ્યાખ્યાયિત કરવું આવશ્યક છે.

રો_ડિલિમિટર (વૈકલ્પિક) - એક અક્ષર(ઓ) જે દર્શાવે છે કે ટેક્સ્ટને પંક્તિઓમાં ક્યાં વિભાજિત કરવો.

અવગણો_ખાલી (વૈકલ્પિક) - સ્પષ્ટ કરે છે કે ખાલી મૂલ્યોને અવગણવા કે નહીં:

• FALSE (ડિફૉલ્ટ) -વચ્ચેના મૂલ્ય વિના સળંગ સીમાંકકો માટે ખાલી કોષો બનાવો.
• TRUE - ખાલી મૂલ્યોને અવગણો, એટલે કે બે અથવા વધુ સળંગ સીમાંકકો માટે ખાલી કોષો બનાવશો નહીં.

મેચ_મોડ (વૈકલ્પિક) - સીમાંક માટે કેસ-સંવેદનશીલતા નક્કી કરે છે. ડિફૉલ્ટ રૂપે સક્ષમ.

• 0 (ડિફૉલ્ટ) - કેસ-સંવેદનશીલ
• 1 - કેસ-સંવેદનશીલ

pad_with (વૈકલ્પિક ) - દ્વિ-પરિમાણીય એરેમાં ખૂટતા મૂલ્યોની જગ્યાએ વાપરવા માટેનું મૂલ્ય. ડિફોલ્ટ એ #N/A ભૂલ છે.

ઉદાહરણ તરીકે, અલ્પવિરામ અને વિભાજક તરીકે જગ્યાનો ઉપયોગ કરીને A2 માં ટેક્સ્ટ સ્ટ્રીંગને બહુવિધ કોષોમાં વિભાજીત કરવા માટે, સૂત્ર છે:

=TEXTSPLIT(A2, ", ")

TEXTSPLIT ઉપલબ્ધતા

TEXTSPLIT ફંક્શન માત્ર Microsoft 365 (Windows અને Mac) માટે Excel અને વેબ માટે Excel માં ઉપલબ્ધ છે.

ટીપ્સ:

• એક્સેલ વર્ઝનમાં જ્યાં TEXTSPLIT ફંક્શન ઉપલબ્ધ નથી (એક્સેલ 365 સિવાય), તમે કોષોને વિભાજિત કરવા માટે ટેક્સ્ટ ટુ કૉલમ વિઝાર્ડનો ઉપયોગ કરી શકો છો.
• વિપરીત કાર્ય કરવા માટે, એટલે કે સમાવિષ્ટો સાથે જોડાવા માટે ચોક્કસ ડિલિમિટરનો ઉપયોગ કરીને એકમાં બહુવિધ કોષો, TEXTJOIN એ ઉપયોગમાં લેવાનું કાર્ય છે.

એક્સેલમાં સેલને વિભાજિત કરવા માટે મૂળભૂત TEXTSPLIT ફોર્મ્યુલા

શરૂઆત માટે, ચાલો જોઈએ કે TEXTSPLIT નો ઉપયોગ કેવી રીતે કરવો. ચોક્કસ સીમાંક દ્વારા ટેક્સ્ટ સ્ટ્રિંગને વિભાજિત કરવા માટે તેના સરળ સ્વરૂપમાં ફોર્મ્યુલા.

કોષને આડી રીતે સમગ્ર કૉલમમાં વિભાજિત કરો

આપેલ સેલની સામગ્રીને બહુવિધ કૉલમમાં વિભાજીત કરવા માટે, એક સપ્લાય કરોપ્રથમ ( ટેક્સ્ટ ) દલીલ માટે મૂળ સ્ટ્રિંગ ધરાવતા કોષનો સંદર્ભ અને સીમાંક જે બિંદુને ચિહ્નિત કરે છે જ્યાં બીજી ( કોલ_ડિલિમિટર ) દલીલ માટે વિભાજન થવું જોઈએ.

ઉદાહરણ તરીકે, A2 માં શબ્દમાળાને અલ્પવિરામ દ્વારા આડી રીતે અલગ કરવા માટે, સૂત્ર છે:

=TEXTSPLIT(A2, ",")

સીમાંકક માટે, અમે ડબલ અવતરણ (",") માં બંધ અલ્પવિરામનો ઉપયોગ કરીએ છીએ. .

પરિણામે, અલ્પવિરામ દ્વારા અલગ કરાયેલ દરેક આઇટમ વ્યક્તિગત કૉલમમાં જાય છે:

સેલને ઊભી રીતે પંક્તિઓમાં વિભાજિત કરો

ટેક્સ્ટને બહુવિધ પંક્તિઓમાં વિભાજિત કરવા માટે, ત્રીજી દલીલ ( પંક્તિ_ડિલિમિટર ) એ છે જ્યાં તમે સીમાંકન મૂકો છો. આ કિસ્સામાં બીજી દલીલ ( col_delimiter ) અવગણવામાં આવી છે.

ઉદાહરણ તરીકે, A2 માં મૂલ્યોને અલગ-અલગ પંક્તિઓમાં અલગ કરવા માટે, સૂત્ર છે:

=TEXTSPLIT(A2, ,",")

કૃપા કરીને નોંધ કરો કે, બંને કિસ્સાઓમાં, ફોર્મ્યુલા માત્ર એક કોષ (C2) માં દાખલ કરવામાં આવે છે. પડોશી કોષોમાં, પરત કરેલ મૂલ્યો આપમેળે ફેલાય છે. પરિણામી એરે (જેને સ્પિલ રેન્જ કહેવાય છે) વાદળી કિનારી સાથે પ્રકાશિત થાય છે જે દર્શાવે છે કે તેની અંદરની દરેક વસ્તુની ગણતરી ઉપલા ડાબા કોષમાં સૂત્ર દ્વારા કરવામાં આવે છે.

સબસ્ટ્રિંગ દ્વારા ટેક્સ્ટને વિભાજિત કરો

માં ઘણા કિસ્સાઓમાં, સ્રોત શબ્દમાળામાંના મૂલ્યોને અક્ષરોના ક્રમ, અલ્પવિરામ અને એક વિશિષ્ટ ઉદાહરણ તરીકે જગ્યા દ્વારા અલગ કરવામાં આવે છે. આ દૃશ્યને હેન્ડલ કરવા માટે, ડિલિમિટર માટે સબસ્ટ્રિંગનો ઉપયોગ કરો.

ઉદાહરણ તરીકે, A2 માં ટેક્સ્ટને બહુવિધ કૉલમમાં અલગ કરવા માટેઅલ્પવિરામ અને સ્પેસ દ્વારા, col_delimiter માટે ", " શબ્દમાળાનો ઉપયોગ કરો.

=TEXTSPLIT(A2, ", ")

આ સૂત્ર B2 પર જાય છે, અને પછી તમે તેને વધુમાં વધુ નકલ કરો છો. જરૂર મુજબ કોષો.

કૉલમ્સ અને પંક્તિઓમાં એકસાથે સ્ટ્રિંગને વિભાજિત કરો

ટેક્સ્ટ સ્ટ્રિંગને એક સમયે પંક્તિઓ અને કૉલમ્સમાં વિભાજિત કરવા માટે, તમારા TEXTSPLIT ફોર્મ્યુલામાં બંને સીમાંકકોને વ્યાખ્યાયિત કરો.

ઉદાહરણ તરીકે, A2 માં ટેક્સ્ટ સ્ટ્રિંગને કૉલમ અને પંક્તિઓમાં વિભાજિત કરવા માટે, અમે સપ્લાય કરીએ છીએ:

• col_delimiter
• માટે સમાન ચિહ્ન ("=") અલ્પવિરામ અને a row_delimiter

માટે ખાલી જગ્યા (", ") આ ફોર્મ્યુલા લે છે:

=TEXTSPLIT(A2, "=", ", ")

પરિણામ 2-D છે 2 કૉલમ્સ અને 3 પંક્તિઓનો સમાવેશ કરતું એરે:

બહુવિધ સીમાંકકો દ્વારા કોષોને અલગ કરો

સ્રોત સ્ટ્રિંગમાં બહુવિધ અથવા અસંગત સીમાંકકોને હેન્ડલ કરવા માટે, {"x","y" જેવા અરે સતતનો ઉપયોગ કરો. સીમાંકક દલીલ માટે ,"z"}.

નીચેના સ્ક્રીનશૉટમાં, A2 માં લખાણ અલ્પવિરામ (",") અને અર્ધવિરામ (";") સાથે અને સ્પેસ વગર બંને દ્વારા સીમાંકિત છે. સીમાંકનની બધી 4 વિવિધતાઓ દ્વારા સ્ટ્રિંગને પંક્તિઓમાં ઊભી રીતે વિભાજિત કરવા માટે, સૂત્ર છે:

=TEXTSPLIT(A2, , {",",", ",";","; "})

અથવા, તમે ફક્ત અલ્પવિરામ (",") અને અર્ધવિરામ ("; ") એરેમાં, અને પછી TRIM ફંક્શનની મદદથી વધારાની જગ્યાઓ દૂર કરો:

=TRIM(TEXTSPLIT(A2, , {",",";"}))

ખાલી મૂલ્યોને અવગણીને સ્પ્લિટ ટેક્સ્ટ

જો શબ્દમાળા સમાવે છે બે અથવા વધુ સળંગ સીમાંકકો તેમની વચ્ચે કોઈ મૂલ્ય વિના, તમે પસંદ કરી શકો છો કે આવી ખાલી અવગણના કરવી કે નહીંમૂલ્યો કે નહીં. આ વર્તણૂક ચોથા ઇગ્નોર_empty પેરામીટર દ્વારા નિયંત્રિત થાય છે, જે ડિફોલ્ટ FALSE પર હોય છે.

ડિફૉલ્ટ રૂપે, TEXTSPLIT ફંક્શન ખાલી મૂલ્યોને અવગણતું નથી. ડિફૉલ્ટ વર્તણૂક નીચેના ઉદાહરણની જેમ સ્ટ્રક્ચર્ડ ડેટા માટે સરસ રીતે કામ કરે છે.

આ નમૂના કોષ્ટકમાં, અમુક સ્ટ્રીંગ્સમાં સ્કોર્સ ખૂટે છે. ignore_empty દલીલ સાથે TEXTSPLIT ફોર્મ્યુલા અવગણવામાં આવે છે અથવા FALSE પર સેટ કરે છે તે આ કેસને સંપૂર્ણ રીતે હેન્ડલ કરે છે, દરેક ખાલી મૂલ્ય માટે એક ખાલી કોષ બનાવે છે.

=TEXTSPLIT(A2, ", ")

અથવા

=TEXTSPLIT(A2, ", ", FALSE)

પરિણામે, બધી કિંમતો યોગ્ય કૉલમમાં દેખાય છે.

જો તમારી સ્ટ્રીંગમાં એકરૂપ ડેટા હોય, તો તે ખાલી મૂલ્યોને અવગણવાનું કારણ બની શકે છે. આ માટે, ignore_empty દલીલને TRUE અથવા 1 પર સેટ કરો.

ઉદાહરણ તરીકે, દરેક કૌશલ્યને અલગ કોષમાં ગેપ વિના મૂકીને નીચેની સ્ટ્રિંગ્સને વિભાજીત કરવા માટે, સૂત્ર છે:

=TEXTSPLIT(A2, ", ", ,TRUE)

આ કિસ્સામાં, સળંગ સીમાંકકો વચ્ચે ગુમ થયેલ મૂલ્યોને સંપૂર્ણપણે અવગણવામાં આવે છે:

સેલ વિભાજન કેસ-સંવેદનશીલ અથવા કેસ-સંવેદનશીલ

કેસને નિયંત્રિત કરવા- સીમાંકની સંવેદનશીલતા, પાંચમી દલીલનો ઉપયોગ કરો, match_mode .

ડિફૉલ્ટ રૂપે, match_mode 0 પર સેટ છે, TEXTSPLIT કેસ-સેન્સિટિવ<બનાવે છે 9>.

> " તરીકેસીમાંક:

=TEXTSPLIT(A2, " x ")

પરિણામોમાં આગળ અને પાછળની જગ્યાઓ અટકાવવા માટે કૃપા કરીને ધ્યાન આપો કે સીમાંકમાં અક્ષર " x " ની બંને બાજુએ એક જગ્યા છે.

કેસની સંવેદનશીલતાને બંધ કરવા માટે, તમે TEXTSPLIT ફોર્મ્યુલાને અક્ષર કેસને અવગણવા માટે દબાણ કરવા માટે match_mode માટે 1 સપ્લાય કરો છો:

=TEXTSPLIT(A2, " x ", , ,1)

હવે, બધા શબ્દમાળાઓ ક્યાં તો સીમાંકક દ્વારા યોગ્ય રીતે વિભાજિત થાય છે:

2D એરેમાં પૅડ ખૂટે છે

TEXTSPLIT ફંક્શનની છેલ્લી દલીલ, pad_with , એક અથવા સ્ત્રોત શબ્દમાળામાં વધુ મૂલ્યો ખૂટે છે. જ્યારે આવી સ્ટ્રિંગને કૉલમ અને પંક્તિઓ બંનેમાં વિભાજિત કરવામાં આવે છે, ત્યારે ડિફૉલ્ટ રૂપે, એક્સેલ દ્વિ-પરિમાણીય એરેની રચનાને ગુમ ન કરવા માટે ખૂટતા મૂલ્યોને બદલે #N/A ભૂલો આપે છે.

નીચેની સ્ટ્રિંગમાં, "સ્કોર" પછી કોઈ "=" ( col_delimiter ) નથી. પરિણામી એરેની અખંડિતતા રાખવા માટે, TEXTSPLIT આઉટપુટ #N/A "સ્કોર" ની બાજુમાં આપે છે.

પરિણામને વધુ વપરાશકર્તા-મૈત્રીપૂર્ણ બનાવવા માટે, તમે #N/A ભૂલને તમે જોઈતા કોઈપણ મૂલ્ય સાથે બદલી શકો છો. બસ, pad_with દલીલમાં ઇચ્છિત મૂલ્ય ટાઇપ કરો.

અમારા કિસ્સામાં, તે હાઇફન ("-") હોઈ શકે છે:

=TEXTSPLIT(A2, "=", ", ", , ,"-")

અથવા ખાલી શબ્દમાળા (""):

=TEXTSPLIT(A2, "=", ", ", , ,"")

હવે તમે TEXTSPLIT ફંક્શનની દરેક દલીલના વ્યવહારિક ઉપયોગો શીખ્યા છો, ચાલો કેટલાક અદ્યતન ઉદાહરણોની ચર્ચા કરીએ જે તમને મદદ કરી શકે. તમારી એક્સેલ સ્પ્રેડશીટ્સમાં બિન-તુચ્છ પડકારોનો સામનો કરો.

તારીખને વિભાજિત કરોદિવસ, મહિનો અને વર્ષમાં

તારીખને વ્યક્તિગત એકમોમાં વિભાજીત કરવા માટે, પ્રથમ તમારે તારીખને ટેક્સ્ટમાં કન્વર્ટ કરવાની જરૂર છે કારણ કે TEXTSPLIT ફંક્શન ટેક્સ્ટ સ્ટ્રીંગ્સ સાથે કામ કરે છે જ્યારે એક્સેલ તારીખો સંખ્યાઓ છે.

સૌથી સરળ આંકડાકીય મૂલ્યને ટેક્સ્ટમાં કન્વર્ટ કરવાની રીત TEXT ફંક્શનનો ઉપયોગ કરીને છે. ફક્ત તમારી તારીખ માટે યોગ્ય ફોર્મેટ કોડ આપવાનું સુનિશ્ચિત કરો.

અમારા કિસ્સામાં, સૂત્ર છે:

=TEXT(A2, "m/d/yyyy")

આગલું પગલું એ ઉપરોક્ત ફંક્શનને નેસ્ટ કરવાનું છે. TEXTSPLIT ની 1લી દલીલ અને 2જી અથવા 3જી દલીલ માટે અનુરૂપ સીમાંક દાખલ કરો, તમે કૉલમ અથવા પંક્તિઓમાં વિભાજન કરી રહ્યાં છો તેના આધારે. આ ઉદાહરણમાં, તારીખ એકમોને સ્લેશ સાથે સીમાંકિત કરવામાં આવે છે, તેથી અમે col_delimiter દલીલ માટે "/" નો ઉપયોગ કરીએ છીએ:

=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/")

કોષોને વિભાજિત કરો અને અમુક અક્ષરોને દૂર કરો

આની કલ્પના કરો: તમે લાંબી સ્ટ્રીંગને ટુકડાઓમાં વિભાજિત કરી છે, પરંતુ પરિણામી એરેમાં હજુ પણ કેટલાક અનિચ્છનીય અક્ષરો છે, જેમ કે નીચેના સ્ક્રીનશોટમાં કૌંસ:

=TEXTSPLIT(A2, " ", "; ")

એક સમયે ઓપનિંગ અને ક્લોઝિંગ કૌંસની બહાર, બે SUBSTITUTE ફંક્શનને એક બીજામાં નેસ્ટ કરો (દરેક કૌંસને ખાલી સ્ટ્રિંગથી બદલીને) અને આંતરિક સબસ્ટિટ્યુટની ટેક્સ્ટ દલીલ માટે TEXTSPLIT ફોર્મ્યુલાનો ઉપયોગ કરો:

=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "")

ટીપ. જો અંતિમ એરેમાં ઘણા બધા વધારાના અક્ષરો છે, તો તમે આ લેખમાં વર્ણવેલ પદ્ધતિઓમાંથી એકનો ઉપયોગ કરીને તેમને શુદ્ધ કરી શકો છો: Excel માં અનિચ્છનીય અક્ષરોને કેવી રીતે દૂર કરવા.

ચોક્કસ મૂલ્યોને અવગણીને સ્પ્લિટ સ્ટ્રીંગ્સ

ધારો કે તમે નીચેની સ્ટ્રીંગ્સને 4 કૉલમમાં અલગ કરવા માંગો છો: પ્રથમ નામ , છેલ્લું નામ , સ્કોર , અને પરિણામ . સમસ્યા એ છે કે કેટલાક શબ્દમાળાઓ શીર્ષક ધરાવે છે "શ્રી." અથવા "Ms.", જેના કારણે પરિણામો બધા ખોટા છે:

સોલ્યુશન સ્પષ્ટ નથી પરંતુ એકદમ સરળ છે :)

હાલના સીમાંકકો ઉપરાંત, જે જગ્યા છે (" ") અને અલ્પવિરામ અને સ્પેસ (", "), તમે col_delimiter એરે કોન્સ્ટન્ટમાં "Mr. " અને "Ms. " શબ્દમાળાઓનો સમાવેશ કરો, જેથી ફંક્શન શીર્ષકોને અલગ કરવા માટે પોતાને ઉપયોગ કરે છે. ટેક્સ્ટ ખાલી મૂલ્યોને અવગણવા માટે, તમે ignore_empty દલીલને TRUE પર સેટ કરો.

=TEXTSPLIT(A2, {" ",", ","Mr. ","Ms. "}, ,TRUE)

હવે, પરિણામો એકદમ પરફેક્ટ છે!

TEXTSPLIT વિકલ્પો

એક્સેલ વર્ઝનમાં જ્યાં TEXTSPLIT ફંક્શન સપોર્ટેડ નથી, તમે SEARCH / FIND ફંક્શનના વિવિધ સંયોજનોનો ઉપયોગ કરીને LEFT, RIGHT અને MID સાથે સ્ટ્રિંગ્સને વિભાજિત કરી શકો છો. ખાસ કરીને:

• કેસ-અસંવેદનશીલ શોધ અથવા કેસ-સંવેદનશીલ FIND સ્ટ્રિંગની અંદર સીમાંકની સ્થિતિ નક્કી કરે છે, અને
• ડાબે, જમણે અને મધ્યમ ફંક્શન્સ પહેલાં સબસ્ટ્રિંગને બહાર કાઢે છે , સીમાંકકના બે ઉદાહરણો પછી અથવા વચ્ચે.

અમારા કિસ્સામાં, અલ્પવિરામ અને અવકાશ દ્વારા વિભાજિત મૂલ્યોને વિભાજિત કરવા માટે, સૂત્રો નીચે મુજબ છે.

નામ કાઢવા માટે:

=LEFT(A2, SEARCH(",", A2, 1) -1)

સ્કોરને ખેંચવા માટે:

=MID(A2, SEARCH(",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)

મેળવવા માટેપરિણામ:

=RIGHT(A2, LEN(A2) - SEARCH(",",  A2, SEARCH(",",  A2) + 1)-1)

સૂત્રોના તર્કની વિગતવાર સમજૂતી માટે, અક્ષર અથવા માસ્ક દ્વારા શબ્દમાળાઓને કેવી રીતે વિભાજિત કરવી તે જુઓ.

કૃપા કરીને ધ્યાનમાં રાખો કે ગતિશીલ એરેથી વિપરીત TEXTSPLIT ફંક્શન, આ સૂત્રો પરંપરાગત વન-ફોર્મ્યુલા-વન-સેલ અભિગમને અનુસરે છે. તમે પ્રથમ કોષમાં ફોર્મ્યુલા દાખલ કરો, અને પછી તેને નીચેના કોષોમાં નકલ કરવા માટે કૉલમની નીચે ખેંચો.

નીચેનો સ્ક્રીનશોટ પરિણામો બતાવે છે:

એક્સેલ 365માં કોષોને આ રીતે વિભાજિત કરવા અગાઉના સંસ્કરણોમાં TEXTSPLIT અથવા વૈકલ્પિક ઉકેલોનો ઉપયોગ કરીને. વાંચવા બદલ હું તમારો આભાર માનું છું અને આગામી અઠવાડિયે તમને અમારા બ્લોગ પર મળવાની આશા રાખું છું!

ડાઉનલોડ માટે પ્રેક્ટિસ વર્કબુક

ટેક્સ્ટસ્પ્લિટ ફંક્શન ટુ સ્પ્લિટ સ્ટ્રિંગ્સ – ફોર્મ્યુલા ઉદાહરણો (.xlsx ફાઇલ)