Оқулық Excel 365 жүйесінде сіз көрсеткен кез келген бөлгіш арқылы жолдарды бөлу үшін жаңа TEXTSPLIT функциясын қалай пайдалану керектігін көрсетеді.

Бөлу қажет болған кезде әртүрлі жағдайлар болуы мүмкін. Excel бағдарламасындағы ұяшықтар. Бұрынғы нұсқаларда біз мәтінді бағандарға толтыру және жарқылды толтыру сияқты тапсырмаларды орындауға арналған бірқатар құралдармен жабдықталған болатынбыз. Енді бізде бұл үшін арнайы функция бар TEXTSPLIT, ол жолды сіз көрсеткен параметрлер негізінде бағандар немесе/немесе жолдар бойынша бірнеше ұяшықтарға бөле алады.

Excel TEXTSPLIT функциясы

Excel бағдарламасындағы TEXTSPLIT функциясы мәтін жолдарын берілген бөлгіш арқылы бағандар немесе/немесе жолдар бойынша бөледі. Нәтиже автоматты түрде бірнеше ұяшықтарға төгілетін динамикалық массив болып табылады.

Функция 6 аргумент қабылдайды, олардың тек алғашқы екеуі ғана қажет.

TEXTSPLIT(мәтін, col_delimiter, [row_delimiter], [елемеу_бос], [сәйкестік_режимі], [қосылған_төбені])

мәтін (міндетті) - бөлетін мәтін. Жол немесе ұяшық сілтемесі ретінде берілуі мүмкін.

col_delimiter (міндетті) - мәтінді бағандар бойынша қай жерде бөлу керектігін көрсететін таңба(лар). Өткізілмесе, жол_бөлгіші анықталуы керек.

жол_бөлгіші (міндетті емес) - жолдар бойынша мәтінді қай жерде бөлу керектігін көрсететін таңба(лар).

елеу_бос (міндетті емес) - бос мәндерді елемеу немесе елемеу керектігін көрсетеді:

• ЖАЛҒАН (әдепкі) -арасында мәні жоқ дәйекті бөлгіштер үшін бос ұяшықтарды жасау.
• ШЫН – бос мәндерді елемеу, яғни екі немесе одан да көп қатардағы бөлгіштер үшін бос ұяшықтарды жасамау.

сәйкестік_режимі (міндетті емес) - бөлгіштің регистрге сезімталдығын анықтайды. Әдепкі бойынша қосылған.

• 0 (әдепкі) - регистрді ескермейді
• 1 - регистрді ескермейді

pad_with (қосымша ) - екі өлшемді массивтердегі жетіспейтін мәндердің орнына қолданылатын мән. Әдепкі - #Жоқ/қате.

Мысалы, бөлгіш ретінде үтір мен бос орынды пайдаланып, A2 мәтін жолын бірнеше ұяшықтарға бөлу үшін формула:

=TEXTSPLIT(A2, ", ")

TEXTSPLIT қолжетімділігі

TEXTSPLIT функциясы тек Microsoft 365 (Windows және Mac) үшін Excel және вебке арналған Excel бағдарламасында қол жетімді.

Кеңестер:

• TEXTSPLIT функциясы қол жетімді емес Excel нұсқаларында (Excel 365-тен басқа), ұяшықтарды бөлу үшін Мәтіннен бағандарға арналған шеберді пайдалануға болады.
• Кері тапсырманы орындау үшін, яғни мазмұнына қосылу үшін. белгілі бір бөлгішті пайдаланып бірнеше ұяшықтарды біреуіне біріктіру, TEXTJOIN — қолданылатын функция.

Excel бағдарламасында ұяшықты бөлуге арналған негізгі TEXTSPLIT формуласы

Бастау үшін TEXTSPLIT пайдалану жолын көрейік. Мәтін жолын белгілі бір бөлгіш арқылы бөлуге арналған қарапайым пішіндегі формула.

Ұяшықты бағандар бойынша көлденең бөлу

Берілген ұяшықтың мазмұнын бірнеше бағандарға бөлу үшін,бірінші ( мәтін ) аргумент үшін бастапқы жолды және екінші ( түс_бөлгіш ) аргумент үшін бөлу орын алатын нүктені белгілейтін бөлгішті қамтитын ұяшыққа сілтеме.

Мысалы, A2 форматындағы жолды көлденеңінен үтір арқылы бөлу үшін мына формула табылады:

=TEXTSPLIT(A2, ",")

Бөлгіш үшін қос тырнақшаға алынған үтірді қолданамыз (",") .

Нәтижесінде үтірмен бөлінген әрбір элемент жеке бағанға өтеді:

Ұяшықты жолдар бойынша тігінен бөлу

Мәтінді бірнеше жолдар бойынша бөлу үшін үшінші аргумент ( жол_айырғыш ) бөлгішті орналастыратын жер. Бұл жағдайда екінші аргумент ( түс_бөлгіш ) өткізілмейді.

Мысалы, A2 ішіндегі мәндерді әртүрлі жолдарға бөлу үшін мына формула:

=TEXTSPLIT(A2, ,",")

Екі жағдайда да формула тек бір ұяшыққа (C2) енгізілетінін ескеріңіз. Көрші ұяшықтарда қайтарылған мәндер автоматты түрде төгіледі. Алынған массив (төгілу ауқымы деп аталады) оның ішіндегі барлық нәрсе жоғарғы сол жақ ұяшықтағы формула бойынша есептелетінін көрсететін көк жиекпен бөлектеледі.

Мәтінді ішкі жол бойынша бөлу

Ішінде көптеген жағдайларда бастапқы жолдағы мәндер таңбалар тізбегі арқылы бөлінеді, үтір және бос орын әдеттегі мысал болып табылады. Бұл сценарийді өңдеу үшін бөлгіш үшін ішкі жолды пайдаланыңыз.

Мысалы, A2 форматындағы мәтінді бірнеше бағандарға бөлу үшінүтір және бос орын арқылы col_delimiter үшін ", " жолын пайдаланыңыз.

=TEXTSPLIT(A2, ", ")

Бұл формула B2-ге өтеді, содан кейін оны сонша көп жерге көшіріңіз. қажетінше жасушалар.

Жолды бірден бағандар мен жолдарға бөлу

Мәтін жолын бір уақытта жолдар мен бағандарға бөлу үшін TEXTSPLIT формуласында екі бөлгішті де анықтаңыз.

Мысалы, A2 мәтін жолын бағандар мен жолдар бойынша бөлу үшін біз мыналарды береміз:

• Теңдік белгісін ("=") col_delimiter
• Үтір және бос орын (", ") жол_айырғышы

Толық формула келесі пішінді алады:

=TEXTSPLIT(A2, "=", ", ")

Нәтиже - 2-D 2 баған мен 3 жолдан тұратын массив:

Ұяшықтарды бірнеше бөлгіштер арқылы бөлу

Негізгі жолдағы бірнеше немесе сәйкес келмейтін бөлгіштерді өңдеу үшін {"x","y" сияқты жиым тұрақтысын пайдаланыңыз. ,"z"} бөлгіш аргументі үшін.

Төмендегі скриншотта A2 форматындағы мәтін бос орынмен және бос орынсыз үтірмен (",") және нүктелі үтірмен (";") бөлінген. Бөлгіштің барлық 4 нұсқасы бойынша жолды тігінен жолдарға бөлу үшін формула:

=TEXTSPLIT(A2, , {",",", ",";","; "})

Немесе тек үтірді ("") және нүктелі үтірді ("; ") массивінде, содан кейін TRIM функциясының көмегімен қосымша бос орындарды алып тастаңыз:

=TRIM(TEXTSPLIT(A2, , {",",";"}))

Бос мәндерді елемей мәтінді бөлу

Егер жолда екі немесе одан да көп қатарлы бөлгіштердің арасында мән жоқ болса, мұндай босты елемеу немесе елемеу таңдауға боладықұндылықтар немесе жоқ. Бұл әрекет төртінші ignore_empty параметрімен бақыланады, ол әдепкі бойынша ЖАЛҒАН.

Әдепкі бойынша, TEXTSPLIT функциясы бос мәндерді елемейді. Әдепкі әрекет төмендегі мысалдағыдай құрылымдық деректер үшін жақсы жұмыс істейді.

Бұл үлгі кестеде кейбір жолдарда ұпайлар жоқ. елемеу_бос аргументі түсірілген немесе ЖАЛҒАН мәніне орнатылған TEXTSPLIT формуласы әрбір бос мән үшін бос ұяшық жасай отырып, бұл істі тамаша өңдейді.

=TEXTSPLIT(A2, ", ")

Не

=TEXTSPLIT(A2, ", ", FALSE)

Нәтижесінде барлық мәндер сәйкес бағандарда пайда болады.

Егер жолдарыңызда біртекті деректер болса, бос мәндерді елемеу себебі болуы мүмкін. Ол үшін елеспеу_бос аргументін ШЫН немесе 1 мәніне орнатыңыз.

Мысалы, әрбір дағдыны бос орындарсыз бөлек ұяшыққа орналастыратын төмендегі жолдарды t бөлу үшін формула:

=TEXTSPLIT(A2, ", ", ,TRUE)

Бұл жағдайда дәйекті бөлгіштер арасындағы жетіспейтін мәндер толығымен еленбейді:

Ұяшықтарды бөлу регистрді немесе регистрді сезбейді

Регистрді басқару үшін- бөлгіштің сезімталдығы, бесінші аргументті пайдаланыңыз, сәйкестік_режимі .

Әдепкі бойынша, сәйкестік_режимі 0 мәніне орнатылып, TEXTSPLIT регистрді ескереді .

Бұл мысалда сандар кіші "x" және бас "X" әріптерімен бөлінген.

Әдепкі регистр сезімталдығы бар формула тек "x" кіші әріпін қабылдайды. " ретіндебөлгіш:

=TEXTSPLIT(A2, " x ")

Нәтижелерде алдыңғы және кейінгі бос орындарды болдырмау үшін бөлгіште " x " әрпінің екі жағында бос орын бар екеніне назар аударыңыз.

Регистрлердің сезімталдығын өшіру үшін TEXTSPLIT формуласын әріп регистрін елемеуге мәжбүрлеу үшін сәйкестік_режимі үшін 1 береді:

=TEXTSPLIT(A2, " x ", , ,1)

Енді, барлығы жолдар қандай да бір бөлгіш арқылы дұрыс бөлінген:

2D массивінде Pad жетіспейтін мәндер

TEXTSPLIT функциясының соңғы аргументі, pad_with , бір немесе бастапқы жолда көбірек мәндер жоқ. Мұндай жол бағандарға да, жолдарға да бөлінгенде, әдепкі бойынша Excel екі өлшемді массив құрылымын бұзбау үшін жетіспейтін мәндердің орнына #N/A қателерін қайтарады.

Төмендегі жолда, "Ұпайдан" кейін "=" ( col_delimiter ) жоқ. Алынған массивтің тұтастығын сақтау үшін TEXTSPLIT "Ұпай" жанындағы #N/A шығарады.

Нәтижені қолданушыға ыңғайлы ету үшін #N/A қатесін қалаған кез келген мәнмен ауыстыруға болады. Жай ғана pad_with аргументінде қажетті мәнді теріңіз.

Біздің жағдайда бұл сызықша («-»):

=TEXTSPLIT(A2, "=", ", ", , ,"-")

Немесе бос жол («»):

=TEXTSPLIT(A2, "=", ", ", , ,"")

Енді TEXTSPLIT функциясының әрбір аргументінің практикалық қолданылуын үйрендіңіз, сізге көмектесетін бірнеше қосымша мысалдарды талқылайық. Excel электрондық кестелеріндегі маңызды емес қиындықтарды жеңіңіз.

Күндерді бөлукүнге, айға және жылға

Күнді жеке бірліктерге бөлу үшін алдымен күнді мәтінге түрлендіру керек, себебі TEXTSPLIT функциясы мәтін жолдарымен жұмыс істейді, ал Excel күндері сандар болып табылады.

Ең оңайы сандық мәнді мәтінге түрлендіру жолы TEXT функциясын пайдалану болып табылады. Күніңізге сәйкес пішім кодын бергеніңізге сенімді болыңыз.

Біздің жағдайда формула:

=TEXT(A2, "m/d/yyyy")

Келесі қадам жоғарыда аталған функцияны кірістендіру болып табылады. TEXTSPLIT 1-аргументін таңдаңыз және бағандар немесе жолдар бойынша бөлетініңізге байланысты 2-ші немесе 3-ші аргумент үшін сәйкес бөлгішті енгізіңіз. Бұл мысалда күн бірліктері қиғаш сызықтармен бөлінген, сондықтан col_delimiter аргументі үшін "/" қолданамыз:

=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/")

Ұяшықтарды бөлу және белгілі бір таңбаларды жою

Мынаны елестетіп көріңізші: сіз ұзын жолды бөліктерге бөлдіңіз, бірақ нәтижесінде алынған массив әлі де кейбір қажетсіз таңбаларды қамтиды, мысалы, төмендегі скриншоттағы жақшалар:

=TEXTSPLIT(A2, " ", "; ")

Жолдан шығару үшін ашу және жабу жақшаларын бір уақытта өшіріп, екі SUBSTITUTE функциясын бір-біріне салыңыз (әрқайсысы бір жақшаны бос жолмен ауыстырады) және ішкі SUBSTITUTE:

мәтінінің мәтін аргументі үшін TEXTSPLIT формуласын пайдаланыңыз.

=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "")

Кеңес. Соңғы массивте тым көп қосымша таңбалар болса, оларды осы мақалада сипатталған әдістердің бірін пайдаланып тазалауға болады: Excel бағдарламасында қажетсіз таңбаларды жою жолы.

Белгілі мәндерді өткізіп жіберетін жолдарды бөлу

Төмендегі жолдарды 4 бағанға бөлгіңіз келсе делік: Аты , Тегі , Ұпай , және Нәтиже . Мәселе мынада, кейбір жолдарда «мырза» атауы бар. немесе "ханым", сондықтан нәтижелер дұрыс емес:

Шешім анық емес, бірақ өте қарапайым :)

Бос орын болып табылатын қолданыстағы бөлгіштерге қосымша (" ") және үтір мен бос орын (", "), сіз col_delimiter жиым тұрақтысына "Мырза" және "Ханым" жолдарын қосасыз, осылайша функция тақырыпты бөлу үшін тақырыптардың өзін пайдаланады. мәтін. Бос мәндерді елемеу үшін ignore_empty аргументін ШЫН мәніне орнатасыз.

=TEXTSPLIT(A2, {" ",", ","Mr. ","Ms. "}, ,TRUE)

Енді нәтижелер мүлдем тамаша!

TEXTSPLIT баламалары

TEXTSPLIT функциясына қолдау көрсетілмейтін Excel нұсқаларында SEARCH / FIND функциясының СОЛ, ОҢ және ОРТА арқылы әртүрлі тіркесімдерін пайдалану арқылы жолдарды бөлуге болады. Атап айтқанда:

• Іс-регистрді ескермеу немесе регистрге сезімтал табу, және сол,
• сол, оң және MED функциялары бұрын субструкцияны шығарады , бөлгіштің екі данасынан кейін немесе арасында.

Біздің жағдайда үтір және бос орын арқылы бөлінген мәндерді бөлу үшін формулалар келесідей болады.

Атын шығару үшін:

=LEFT(A2, SEARCH(",", A2, 1) -1)

Ұпайды шығару үшін:

=MID(A2, SEARCH(",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)

Алу үшіннәтиже:

=RIGHT(A2, LEN(A2) - SEARCH(",",  A2, SEARCH(",",  A2) + 1)-1)

Формулалар логикасын егжей-тегжейлі түсіндіру үшін Жолдарды таңба немесе маска бойынша бөлу жолын қараңыз.

Динамикалық массивтен айырмашылығы мынаны есте сақтаңыз. TEXTSPLIT функциясы, бұл формулалар дәстүрлі бір формула бір ұяшықты тәсілге сәйкес келеді. Сіз формуланы бірінші ұяшыққа енгізесіз, содан кейін оны төмендегі ұяшықтарға көшіру үшін оны бағанға сүйреп апарасыз.

Төмендегі скриншот нәтижелерді көрсетеді:

Excel 365 жүйесінде ұяшықтарды осылай бөлуге болады. TEXTSPLIT немесе бұрынғы нұсқалардағы балама шешімдерді пайдалану арқылы. Оқығаныңыз үшін алғыс айтамын және келесі аптада блогымызда көреміз деп үміттенемін!

Жүктеп алуға арналған жұмыс кітабын жаттықтыру

Жолдарды бөлуге арналған TEXTSPLIT функциясы – формула мысалдары (.xlsx файлы)