Tha an oideachadh a’ sealltainn mar a chleachdas tu an gnìomh TEXTSPLIT ùr-nodha gus teudan ann an Excel 365 a sgoltadh le delimiter sam bith a shònraicheas tu.

Dh’ fhaodadh gu bheil diofar shuidheachaidhean ann nuair a dh’ fheumas tu sgoltadh ceallan ann an Excel. Ann an dreachan nas tràithe, bha sinn mar-thà uidheamaichte le grunn ionnstramaidean gus an obair a choileanadh leithid Text to Colbhan agus Fill Flash. A-nis, tha gnìomh sònraichte againn airson seo cuideachd, TEXTSPLIT, a dh’ fhaodas sreang a sgaradh gu grunn cheallan thairis air colbhan no/agus sreathan a rèir nam paramadairean a shònraich thu.

Gnìomh TEXTSPLIT Excel

Bidh an gnìomh TEXTSPLIT ann an Excel a’ sgoltadh sreangan teacsa le delimiter sònraichte thairis air colbhan no/agus sreathan. 'S e an toradh a tha ann an sreath fiùghantach a bhios a' dòrtadh a-steach do dh'iomadh cealla gu fèin-obrachail.

Gabhaidh an gnìomh uiread ri 6 argamaidean, agus chan eil a dhìth ach a' chiad dhà dhiubh.

TEXTSPLIT(text, col_delimiter, [row_delimiter], [ignore_empty], [match_mode], [pad_with])

text (riatanach) - an teacsa ri sgoltadh. Gabhaidh seo a thoirt seachad mar shreang no mar iomradh cealla.

col_delimiter (riatanach) - caractar(ean) a sheallas far an roinnear an teacsa thairis air colbhan. Ma dh'fhàgar a-mach e, feumar row_delimiter a mhìneachadh.

row_delimiter (roghainneil) - caractar(an) a sheallas far an roinn thu an teacsa thairis air sreathan.

ignore_empty (roghainneil) - a’ sònrachadh am bu chòir dhut dearmad a dhèanamh air luachan falamh no nach bu chòir:

• FALSE (bunaiteach) -cruthaich ceallan falamh airson crìochan leantainneach às aonais luach eadar-dhealaichte.
• TRUE - seachain luachan falamh, i.e. na cruthaich ceallan falamh airson dhà no barrachd delimiters leantainneach.

> match_mode (roghainneil) - a’ dearbhadh cugallachd cùise airson an delimiter. Cuir an comas a ghnàth.

• 0 (bunaiteach) - cùis-mhothachail
• 1 - neo-mhothachail a’ chùis

pad_with (roghainneil ) - luach ri chleachdadh an àite luachan a tha a dhìth ann an arrays dà-thaobhach. 'S e mearachd #N/A a th' anns a' bhunait bhunaiteach.

Mar eisimpleir, airson sreang teacsa ann an A2 a roinn ann an ioma-cheallan a' cleachdadh cromag agus àite mar an dealaiche, 's e am foirmle:

=TEXTSPLIT(A2, ", ")

Ri fhaighinn TEXTSPLIT

Chan eil an gnìomh TEXTSPLIT ri fhaighinn ach ann an Excel airson Microsoft 365 (Windows agus Mac) agus Excel airson an lìon.

Molaidhean:

• Ann an dreachan Excel far nach eil an gnìomh TEXTSPLIT ri fhaighinn (ach a-mhàin Excel 365), faodaidh tu an draoidh Text to Columns a chleachdadh gus ceallan a roinn. ioma-cheallan a-steach do aon a’ cleachdadh delimiter sònraichte, is e TEXTJOIN an gnìomh a chleachdas tu.

Foirmle bunaiteach TEXTSPLIT gus cealla a roinn ann an Excel

Airson tòiseachadh, chì sinn mar a chleachdas tu TEXTSPLIT foirmle anns an riochd as sìmplidhe aige airson sreang teacsa a sgoltadh le delimiter sònraichte.

Sgaradh cealla gu còmhnard thar cholbhan

Gus susbaint cealla sònraichte a roinn ann an ioma-cholbhan, thoir seachad aiomradh air a' chill anns a bheil an t-sreang thùsail airson a' chiad argamaid ( text ) agus an t-iomradh a tha a' comharrachadh a' phuing far am bu chòir dhan sgaradh tachairt airson an dàrna argamaid ( col_delimiter ).

Mar eisimpleir, gus an t-sreang ann an A2 a sgaradh gu còmhnard le cromag, is e am foirmle:

=TEXTSPLIT(A2, ",")

Airson an delimiter, bidh sinn a’ cleachdadh cromag ceangailte ann an luachan dùbailte (“”,”) .

Mar thoradh air an sin, bidh gach nì a tha air a sgaradh le cromag a’ dol a-steach do cholbh fa leth:

Sgaradh cealla gu dìreach thairis air sreathan

Gus teacsa a roinn thar ioma sreathan, an treas fear argamaid ( row_delimiter ) far a bheil thu a’ cur an delimiter. Tha an dàrna argamaid ( col_delimiter ) air a fàgail a-mach sa chùis seo.

Mar eisimpleir, gus na luachan ann an A2 a sgaradh ann an sreathan eadar-dhealaichte, 's e am foirmle:

=TEXTSPLIT(A2, ,",") <16

Thoir an aire, anns gach cùis, nach tèid am foirmle a chuir a-steach ach ann an aon chealla (C2). Ann an ceallan faisg air làimh, bidh na luachan a chaidh a thilleadh a’ dòrtadh gu fèin-ghluasadach. Tha an t-sreath a thig às (ris an canar raon dòrtadh) air a shoilleireachadh le crìoch ghorm a' sealltainn gu bheil a h-uile rud na bhroinn air a thomhas leis an fhoirmle sa chill gu h-àrd air an taobh chlì.

Sgaradh an teacsa le fo-thalamh

San Ann an iomadh cùis, tha na luachan anns an t-sreath thùsail air an sgaradh le sreath de charactaran, cromag agus àite mar eisimpleir àbhaisteach. Gus dèiligeadh ris an t-suidheachadh seo, cleachd fo-theann airson an delimiter.

Mar eisimpleir, gus an teacsa ann an A2 a sgaradh gu iomadh colbhle cromag is beàrn, cleachd an sreang " , " airson col_delimiter .

=TEXTSPLIT(A2, ", ")

Thèid am foirmle seo gu B2, agus an uairsin nì thu lethbhreac dheth tro uiread ceallan mar a dh’ fheumar.

Sgar sreang ann an colbhan is sreathan aig an aon àm

Gus sreang teacsa a roinn ann an sreathan agus colbhan aig an aon àm, mìnich an dà chrìoch san fhoirmle TEXTSPLIT agad.

Mar eisimpleir, gus an sreang teacsa ann an A2 a sgoltadh thairis air colbhan is sreathan, bheir sinn seachad:

• An soidhne co-ionnan ("=") airson col_delimiter
• cromag agus a space (", ") airson row_delimiter

Tha an fhoirmle iomlan a' gabhail an fhoirm seo:

=TEXTSPLIT(A2, "=", ", ")

'S e 2-D an toradh sreath anns a bheil 2 cholbh agus 3 sreathan:

Ceallan eadar-dhealaichte le ioma-chuibhrichean

Gus làimhseachadh ioma-chuingealachaidhean neo-chunbhalach san t-sreang thùsail, cleachd rèite seasmhach mar {"x",,"y" , "z"} airson an argamaid delimiter.

San dealbh-sgrìn gu h-ìosal, tha an teacsa ann an A2 air a chuingealachadh leis an dà chromag (",") agus leth-choloin (";") le agus às aonais beàrnan. Gus an t-sreang a roinn gu dìreach ann an sreathan leis a h-uile 4 caochladair air an delimiter, is e am foirmle:

=TEXTSPLIT(A2, , {",",", ",";","; "})

No, chan urrainn dhut ach cromag (",") agus leth-choloin ("; ") san t-sreath, agus an uairsin thoir air falbh beàrnan a bharrachd le cuideachadh bhon ghnìomh TRIM:

=TRIM(TEXTSPLIT(A2, , {",",";"}))

Sgaradh an teacsa gun a bhith mothachail air luachan falamh

Ma tha an t-sreang ann dà no barrachd delimiters leantainneach gun luach eatorra, faodaidh tu taghadh am bu chòir dhut an leithid de fhalamh a leigeil seachadluachan no nach eil. Tha smachd air a' ghiùlan seo leis a' cheathramh paramadair ignore_empty , a dh'fhàgas gu FALSE.

A ghnàth, cha leig an gnìomh TEXTSPLIT seachad luachan falamh. Tha an giùlan bunaiteach ag obair gu math airson dàta structaraichte mar a tha san eisimpleir gu h-ìosal.

Sa chlàr sampall seo, tha na sgòran a dhìth ann an cuid de shreathan. Tha am foirmle TEXTSPLIT leis an argamaid ignore_empty air a fàgail às no air a shuidheachadh gu FALSE a’ làimhseachadh na cùise seo gu foirfe, a’ cruthachadh cealla falamh airson gach luach falamh.

=TEXTSPLIT(A2, ", ")

No

=TEXTSPLIT(A2, ", ", FALSE)

Mar thoradh air an sin, nochdaidh na luachan gu lèir anns na colbhan iomchaidh.

Air eagal ‘s gu bheil dàta aon-ghnèitheach anns na teudan agad, dh’ fhaodadh gum biodh e na adhbhar airson luachan falamh a leigeil seachad. Airson seo, suidhich an argamaid ignore_empty gu TRUE no 1.

Mar eisimpleir, gus na teudan gu h-ìosal a roinn a’ cur gach sgil ann an cealla air leth gun bheàrnan, ’s e am foirmle:

=TEXTSPLIT(A2, ", ", ,TRUE)

Anns a’ chùis seo, thathas a’ toirt aire gu tur do na luachan a tha a dhìth eadar luchd-crìochnachaidh leantainneach:

Sgaradh cealla a tha mothachail air cùis no cùis-mhothachail

Gus smachd a chumail air a’ chùis- cugallachd an delimiter, cleachd an còigeamh argamaid, match_mode .

Gu gnàthach, tha match_mode air a shuidheachadh gu 0, a’ fàgail TEXTSPLIT mothachail air cùis .

San eisimpleir seo, tha na h-àireamhan air an sgaradh le litrichean mòra "x" agus litrichean mòra "X". " mar andelimiter:

=TEXTSPLIT(A2, " x ")

Thoir an aire gu bheil beàrn aig an delimiter air gach taobh den litir " x " gus casg a chuir air beàrnan stiùiridh is luirg sna toraidhean.

Gus cugallachd cùise a chur dheth, bheir thu seachad 1 airson match_mode gus toirt air foirmle TEXTSPLIT a’ chùis litreach a leigeil seachad:

=TEXTSPLIT(A2, " x ", , ,1)

A-nis, a h-uile tha na teudan air an roinn gu ceart leis an dàrna cuid delimiter:

Pad luachan a dhìth ann an sreath 2D

Tha an argamaid mu dheireadh den ghnìomh TEXTSPLIT, pad_with , feumail ma tha fear no dhà tha barrachd luachan a dhìth anns an t-sreath thùsail. Nuair a bhios sreang mar seo air a roinn ann an dà cholbh agus sreathan, mar as àbhaist, tillidh Excel # N/A mhearachdan an àite nan luachan a tha a dhìth gun a bhith a’ mantadh structar sreath dà-thaobhach.

Anns an t-sreang gu h-ìosal, chan eil "="( col_delimiter ) ann às dèidh "Sgòr". Gus ionracas an t-sreath a thig às a chumail, bidh toraidhean TEXTSPLIT #N/A ri taobh “Sgòr”.

Gus an toradh a dhèanamh nas fhasa a chleachdadh, faodaidh tu luach sam bith a tha thu ag iarraidh a chur an àite na mearachd #N/A. Gu sìmplidh, sgrìobh an luach a tha thu ag iarraidh san argamaid pad_with .

Anns a’ chùis againn, dh’ fhaodadh sin a bhith na tàthan (“-”):

=TEXTSPLIT(A2, "=", ", ", , ,"-")

No sreang fhalamh (""):

=TEXTSPLIT(A2, "=", ", ", , ,"")

A-nis gu bheil thu air cleachdaidhean practaigeach ionnsachadh airson gach argamaid den ghnìomh TEXTSPLIT, bruidhnidh sinn air eisimpleirean adhartach no dhà a chuidicheas tu dèiligeadh ri dùbhlain neo-bheag anns na duilleagan-clèithe Excel agad.

Ceart cinn-lathagu latha, mìos agus bliadhna

Gus ceann-latha a roinn ann an aonadan fa leth, an toiseach feumaidh tu ceann-latha a thionndadh gu teacsa oir tha an gnìomh TEXTSPLIT a’ dèiligeadh ri sreangan teacsa fhad ‘s a tha cinn-latha Excel nan àireamhan.

An dòigh as fhasa Is e an dòigh air luach àireamhach a thionndadh gu teacsa le bhith a’ cleachdadh gnìomh TEXT. Dìreach dèan cinnteach gun toir thu seachad còd fòrmat iomchaidh airson do cheann-latha.

Anns a’ chùis againn, is e am foirmle:

=TEXT(A2, "m/d/yyyy")

Is e an ath cheum an gnìomh gu h-àrd a neadachadh ann an an argamaid 1d de TEXTSPLIT agus cuir a-steach an t-iomallaiche co-fhreagarrach airson an 2na no an 3mh argamaid, a rèir a bheil thu a’ roinn thairis air colbhan no sreathan. San eisimpleir seo, tha na h-aonadan ceann-latha air an cuingealachadh le slashes, mar sin cleachdaidh sinn "/" airson an argamaid col_delimiter :

=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/")

Sgar ceallan agus thoir air falbh cuid de charactaran <7

Smaoinich air seo: tha thu air sreang fhada a roinn na phìosan, ach tha cuid de charactaran nach eileas ag iarraidh fhathast san t-sreath a thàinig às, leithid bracaidean san dealbh-sgrìn gu h-ìosal:

=TEXTSPLIT(A2, " ", "; ")

Gus stripeadh far na brathan fosglaidh is dùnaidh aig aon àm, neadaich dà ghnìomh SUBSTITUTE aon a-steach do fhear eile (gach fear a’ cur sreang fhalamh an àite aon bhratagan) agus cleachd am foirmle TEXTSPLIT airson argamaid text den taobh a-staigh SUBSTITUTE:

=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "")

Gliocas. Ma tha cus charactaran a bharrachd anns an raon mu dheireadh, faodaidh tu an glanadh le bhith a’ cleachdadh aon de na dòighean a tha air am mìneachadh san artaigil seo: Mar a bheir thu air falbh caractaran nach eileas ag iarraidh ann an Excel.

Spart strings a' leum thairis air luachan sònraichte

Ma tha thu airson na teudan gu h-ìosal a sgaradh ann an 4 colbhan: Ciad ainm , Ainm mu dheireadh , Sgòr , agus Toradh . Is e an duilgheadas a th’ ann gu bheil an tiotal “Mgr” ann an cuid de shreathan. no "Ms.", air sgàth 's gu bheil na co-dhùnaidhean uile ceàrr:

Chan eil am fuasgladh follaiseach ach gu math sìmplidh :)

A bharrachd air na crìochan a th' ann mar-thà, 's iad sin beàrn (" ") agus cromag agus beàrn (", "), bidh thu a' gabhail a-steach na teudan "Mr." agus "Ms." san t-sreath col_delimiter seasmhach, gus am bi an gnìomh a' cleachdadh nan tiotalan fhèin gus na teacs. Gus luachan falamh a leigeil seachad, shuidhich thu an argamaid ignore_empty gu TRUE.

=TEXTSPLIT(A2, {" ",", ","Mr. ","Ms. "}, ,TRUE)

A-nis, tha na toraidhean gu tur foirfe!

Roghainnean eile TEXTSPLIT

Ann an dreachan Excel far nach eil taic ann don ghnìomh TEXTSPLIT, is urrainn dhut teudan a roinn le bhith a’ cleachdadh measgachadh eadar-dhealaichte den ghnìomh SEARCH / FIND le LEFT, RIGHT agus MID. Gu sònraichte:

• Search neo-mhothachail cùise no cùis-mhothachail FIND a’ dearbhadh suidheachadh an delimiter taobh a-staigh sreang, agus
• Tha na gnìomhan LEFT, RIGHT, agus MID a’ toirt a-mach fo-sreang roimhe , an dèidh no eadar dà eisimpleir den delimiter.

Anns a’ chùis againn, gus na luachan a tha air an sgaradh le cromag agus beàrn a roinn, thèid na foirmlean mar a leanas.

Gus an t-ainm a tharraing a-mach:

=LEFT(A2, SEARCH(",", A2, 1) -1)

Gus an sgòr a tharraing:

=MID(A2, SEARCH(",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)

Gus antoradh:

=RIGHT(A2, LEN(A2) - SEARCH(",",  A2, SEARCH(",",  A2) + 1)-1)

Airson mìneachadh mionaideach air loidsig nan foirmlean, faic Mar a roinneadh tu teudan a rèir caractar no masg.

Thoir an aire nach eil eu-coltach ris an raon fiùghantach Gnìomh TEXTSPLIT, tha na foirmlean sin a’ leantainn an dòigh-obrach traidiseanta aon-fhoirmle-aon-chealla. Cuiridh tu a-steach am foirmle sa chiad chill, agus an uairsin slaod e sìos an colbh gus lethbhreac a dhèanamh dha na ceallan gu h-ìosal.

Tha an dealbh-sgrìn gu h-ìosal a’ sealltainn na toraidhean:

Sin mar a roinneadh tu ceallan ann an Excel 365 le bhith a’ cleachdadh TEXTSPLIT no fuasglaidhean eile ann an dreachan nas tràithe. Tha mi a’ toirt taing dhut airson do leughadh agus tha mi an dòchas d’fhaicinn air ar blog an ath sheachdain!

Cleachd leabhar-obrach airson luchdachadh a-nuas

TEXTSPLIT function to split strings – formula examples (.xlsx file)

<3 3> | 3>