Tabla de contenido
El tutorial explica cómo utilizar las fórmulas COUNTIFS y COUNTIF con criterios múltiples en Excel basados en la lógica AND y OR. Encontrará varios ejemplos para diferentes tipos de datos: números, fechas, texto, caracteres comodín, celdas no vacías, etc.
De todas las funciones de Excel, COUNTIFS y COUNTIF son probablemente las que más se confunden porque se parecen mucho y ambas están pensadas para contar celdas basándose en los criterios especificados.
La diferencia es que COUNTIF está diseñado para contar celdas con una sola condición en un rango, mientras que COUNTIFS puede evaluar diferentes criterios en el mismo o en diferentes rangos. El objetivo de este tutorial es demostrar diferentes enfoques y ayudarle a elegir la fórmula más eficiente para cada tarea en particular.
Función COUNTIFS de Excel - sintaxis y uso
La función COUNTIFS de Excel cuenta las celdas de varios rangos en función de una o varias condiciones. La función está disponible en Excel 365, 2021, 2019, 2016, 2013, Excel 2010 y Excel 2007, por lo que puede utilizar los ejemplos siguientes en cualquier versión de Excel.
Sintaxis COUNTIFS
La sintaxis de la función COUNTIFS es la siguiente:
COUNTIFS(rango_criterios1, criterios1, [rango_criterios2, criterios2]...)- rango_de_criterios1 (obligatorio) - define el primer intervalo al que se aplica la primera condición ( criterios1 ).
- criterios1 (obligatorio) - establece la condición en forma de número , referencia de celda , cadena de texto , expresión u otro Función Excel El criterio define qué celdas se contarán y puede expresarse como 10, "<=32", A6, "caramelos".
- [rango_criterios2, criterios2]... (opcional) - son rangos adicionales y sus criterios asociados. Puede especificar hasta 127 pares rango/criterio en sus fórmulas.
De hecho, no es necesario que recuerde de memoria la sintaxis de la función COUNTIF. Microsoft Excel mostrará los argumentos de la función en cuanto empiece a escribir; el argumento que esté introduciendo en ese momento aparecerá resaltado en negrita.
Excel COUNTIFS - ¡Cosas para recordar!
- Puede utilizar la función COUNTIFS en Excel para contar celdas en un único rango con una única condición, así como en múltiples rangos con múltiples condiciones. En este último caso, sólo se contarán las celdas que cumplan todas las condiciones especificadas se cuentan.
- Cada rango adicional debe tener el mismo número de filas y columnas como primer rango ( rango_de_criterios1 argumento).
- Ambos contiguo y no contiguo rangos están permitidos.
- Si el criterio es una referencia a un celda vacía la función COUNTIFS lo trata como un valor cero (0).
- Puede utilizar la función caracteres comodín en los criterios: asterisco (*) y signo de interrogación (?). Consulte este ejemplo para más detalles.
Cómo utilizar COUNTIFS y COUNTIF con múltiples criterios en Excel
A continuación encontrará una serie de ejemplos de fórmulas que demuestran cómo utilizar las funciones COUNTIFS y COUNTIF en Excel para evaluar múltiples condiciones.
Cómo contar celdas con múltiples criterios (lógica AND)
Este escenario es el más fácil, ya que la función COUNTIFS de Excel está diseñada para contar sólo aquellas celdas para las que todas las condiciones especificadas son VERDADERAS. Lo llamamos la lógica AND, porque la función AND de Excel funciona de esta manera.
Fórmula 1. Fórmula COUNTIFS con criterios múltiples
Suponga que tiene una lista de productos como la que se muestra en la captura de pantalla siguiente. Desea obtener un recuento de los artículos que están en stock (el valor de la columna B es mayor que 0) pero que aún no se han vendido (el valor de la columna C es igual a 0).
La tarea puede realizarse utilizando esta fórmula:
=COUNTIFS(B2:B7,">0", C2:C7,"=0")
Y la cuenta es 2 (" Cerezas " y " Limones "):
Fórmula 2. Fórmula COUNTIFS con dos criterios
Cuando desee contar elementos con criterios idénticos, deberá suministrar cada uno de ellos rango_de_criterios / criterios par individualmente.
Por ejemplo, ésta es la fórmula correcta para contar los elementos que tienen 0 tanto en la columna B como en la columna C:
=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")
Esta fórmula COUNTIFS devuelve 1 porque sólo " Uvas " tienen valor "0" en ambas columnas.
Utilizando una fórmula más sencilla con un único rango_de_criterios como COUNTIFS(B2:C7,"=0") arrojaría un resultado diferente: el recuento total de celdas del rango B2:C7 que contienen un cero (que es 4 en este ejemplo).
Cómo contar celdas con múltiples criterios (lógica OR)
Como ha visto en los ejemplos anteriores, contar las celdas que cumplen todos los criterios especificados es fácil porque la función COUNTIFS está diseñada para trabajar de esta manera.
Pero ¿qué pasa si desea contar las células para las que como mínimo uno de los especificados condiciones es TRUE En general, hay dos formas de hacerlo: sumando varias fórmulas COUNTIF o utilizando una fórmula SUM COUNTIFS con una constante de matriz.
Fórmula 1. Suma dos o más fórmulas COUNTIF o COUNITFS
En la tabla siguiente, supongamos que desea contar las órdenes con el símbolo " Cancelado " y " Pendiente "Para hacerlo, basta con escribir 2 fórmulas Countif regulares y sumar los resultados:
=COUNTIF($C$2:$C$11, "Cancelado") + COUNTIF($C$2:$C$11, "Pendiente")
En caso de que cada una de las funciones deba evaluar más de una condición, utilice COUNTIFS en lugar de COUNTIF. Por ejemplo, para obtener el recuento de " Cancelado " y " Pendiente "pedidos de " Manzanas "utiliza esta fórmula:
=COUNTIFS($A$2:$A$11, "Manzanas", $C$2:$C$11, "Cancelado") + COUNTIFS($A$2:$A$11, "Manzanas", $C$2:$C$11, "Pendiente")
Fórmula 2. SUM COUNTIFS con una constante de matriz
En situaciones en las que tenga que evaluar muchos criterios, el enfoque anterior no es la mejor manera de hacerlo porque su fórmula crecería demasiado en tamaño. Para realizar los mismos cálculos en una fórmula más compacta, enumere todos sus criterios en una matriz constante, y suministre esa matriz a la función criterios de la función COUNTIFS. Para obtener el recuento total, incruste COUNTIFS dentro de la función SUM, de la siguiente manera:
SUMA(CONTADORES( gama ,{" criterios1 "," criterios2 "," criterios3 ",...}))En nuestra tabla de ejemplo, para contar los pedidos con el estado " Cancelado " o " Pendiente " o " En tránsito ", la fórmula sería la siguiente:
=SUMA(COUNTIFS($C$2:$C$11, {"cancelado", "pendiente", "en tránsito"}))
De forma similar, puede contar celdas basándose en dos o más rango_de_criterios / criterios Por ejemplo, para obtener el número de pares " Manzanas "órdenes que son " Cancelado " o " Pendiente " o " En tránsito "utiliza esta fórmula:
=SUMA(COUNTIFS($A$2:$A$11, "manzanas",$C$2:$C$11,{"cancelado", "pendiente", "en tránsito"}))
Puedes encontrar algunas formas más de contar celdas con lógica OR en este tutorial: Excel COUNTIF y COUNTIFS con condiciones OR.
Cómo contar números entre 2 números especificados
En general, las fórmulas COUNTIFS para números se dividen en 2 categorías: basadas en varias condiciones (explicadas en los ejemplos anteriores) y entre los dos valores que especifique. Esto último se puede lograr de dos maneras: utilizando la función COUNTIFS o restando un COUNTIF de otro.
Fórmula 1. COUNTIFS para contar las celdas entre dos números
Para averiguar cuántos números entre 5 y 10 (sin incluir 5 y 10) hay en las celdas C2 a C10, utiliza esta fórmula:
=COUNTIFS(C2:C10,">5", C2:C10,"<10")
Para incluir 5 y 10 en el recuento, utilice los operadores "mayor o igual que" y "menor o igual que":
=COUNTIFS(B2:B10,">=5", B2:B10,"<=10")
Fórmula 2. Fórmulas COUNTIF para contar números entre X e Y
Se puede obtener el mismo resultado restando una fórmula Countif de otra. La primera cuenta cuántos números son mayores que el valor del límite inferior (5 en este ejemplo). La segunda fórmula devuelve el recuento de números que son mayores que el valor del límite superior (10 en este caso). La diferencia entre el primer y el segundo número es el resultado que se busca.
- =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,">=10") - cuenta cuántos números mayores que 5 y menores que 10 hay en el rango C2:C10. Esta fórmula devolverá el mismo recuento que se muestra en la captura de pantalla anterior.
- =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - la fórmula cuenta cuántos números entre 5 y 10 hay en el intervalo C2:C10, incluyendo 5 y 10.
Cómo utilizar referencias de celdas en las fórmulas COUNTIFS
Cuando utilice operadores lógicos como ">", "<", "=" junto con referencias a celdas en sus fórmulas de Excel COUNTIFS, recuerde encerrar el operador entre "comillas dobles" y
añadir un ampersand (&) antes de una referencia de celda para construir una cadena de texto.
En un conjunto de datos de ejemplo, contemos " Manzanas " pedidos con importe superior a 200 $. Con rango_de_criterios1 en las celdas A2:A11 y rango_de_criterios2 en B2:B11, puede utilizar esta fórmula:
=COUNTIFS($A$2:$A$11, "Manzanas", $B$2:$B$11, ">200")
O bien, puede introducir los valores de sus criterios en determinadas celdas, digamos F1 y F2, y hacer referencia a esas celdas en su fórmula:
=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)
Fíjese en el uso de referencias absolutas de celda tanto en la celda criterios y rango_de_criterios lo que evita que la fórmula se rompa al copiarla en otras celdas.
Para más información sobre el uso de un ampersand en las fórmulas COUNTIF y COUNTIFS, consulte Excel COUNTIF - preguntas frecuentes.
Cómo utilizar COUNTIFS con caracteres comodín
En las fórmulas COUNTIFS de Excel, puede utilizar los siguientes caracteres comodín:
- Signo de interrogación (?) - coincide con cualquier carácter, utilícelo para contar las celdas que empiezan y/o terminan con determinados caracteres.
- Asterisco (*) - coincide con cualquier secuencia de caracteres, se utiliza para contar las celdas que contienen una palabra especificada o un carácter(es) como parte del contenido de la celda.
Sugerencia: si desea contar las celdas con un signo de interrogación o asterisco, escriba una tilde (~) antes del asterisco o signo de interrogación.
Veamos ahora cómo puede utilizar un carácter comodín en fórmulas COUNTIFS de la vida real en Excel. Supongamos que tiene una lista de proyectos en la columna A. Desea saber cuántos proyectos ya están asignados a alguien, es decir, tienen algún nombre en la columna B. Y puesto que estamos aprendiendo a utilizar la función COUNTIFS con criterios múltiples, añadamos una segunda condición - el carácter Fecha final en la columna D.
Esta es la fórmula que funciona a las mil maravillas:
=COUNTIFS(B2:B10,"*",D2:D10,""&""))
Tenga en cuenta que no puede utilizar un carácter comodín en el segundo criterio porque en la columna D tiene fechas en lugar de valores de texto. no en blanco celdas: ""&""
COUNTIFS y COUNTIF con criterios múltiples para las fechas
Las fórmulas COUNTIFS y COUNTIF que se utilizan para las fechas son muy similares a las fórmulas anteriores para los números.
Ejemplo 1. Contar fechas en un intervalo de fechas específico
Para contar las fechas que caen en un determinado intervalo de fechas, también puede utilizar una fórmula COUNTIFS con dos criterios o una combinación de dos funciones COUNTIF.
Por ejemplo, las siguientes fórmulas cuentan el número de fechas de las celdas C2 a C10 que están comprendidas entre el 1-Jun-2014 y el 7-Jun-2014, ambos inclusive:
=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")
=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")
Ejemplo 2. Contar fechas con varias condiciones
Del mismo modo, puede utilizar una fórmula COUNTIFS para contar el número de fechas en diferentes columnas que cumplen 2 o más condiciones. Por ejemplo, la fórmula siguiente averiguará cuántos productos se compraron después del 20 de mayo y se entregaron después del 1 de junio:
=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")
Ejemplo 3. Contar fechas con múltiples condiciones basadas en la fecha actual
Puede utilizar la función TODAY() de Excel en combinación con COUNTIF para contar fechas basándose en la fecha actual.
Por ejemplo, la siguiente fórmula COUNTIF con dos rangos y dos criterios le dirá cuántos productos ya se han comprado pero aún no se han entregado.
=COUNTIFS(C2:C9, ""&TODAY())
Esta fórmula permite muchas variaciones posibles. Por ejemplo, puede modificarla para que cuente cuántos productos se compraron hace más de una semana y aún no se han entregado:
=COUNTIFS(C2:C9, ""&TODAY())
Así es como se cuentan las celdas con múltiples criterios en Excel. Espero que estos ejemplos te resulten útiles. En fin, ¡te agradezco tu lectura y espero verte en nuestro blog la semana que viene!
