Sadržaj
Vodič objašnjava kako koristiti COUNTIFS i COUNTIF formule s više kriterija u Excelu na osnovu AND kao i OR logike. Naći ćete brojne primjere za različite tipove podataka - brojeve, datume, tekst, zamjenske znakove, ćelije koje nisu prazne i još mnogo toga.
Od svih Excel funkcija, COUNTIFS i COUNTIF se vjerovatno najčešće miješaju gore jer izgledaju vrlo slično i oba su namijenjena za brojanje ćelija na osnovu specificiranih kriterija.
Razlika je u tome što je COUNTIF dizajniran za brojanje ćelija s jednim uvjetom u jednom rasponu, dok COUNTIFS može procijeniti različite kriterije u istom ili u različitim rasponima. Cilj ovog tutorijala je demonstrirati različite pristupe i pomoći vam da odaberete najefikasniju formulu za svaki određeni zadatak.
Excel funkcija COUNTIFS - sintaksa i upotreba
Excel Funkcija COUNTIFS broji ćelije u više raspona na osnovu jednog ili više uslova. Funkcija je dostupna u Excel 365, 2021, 2019, 2016, 2013, Excel 2010 i Excel 2007, tako da možete koristiti donje primjere u bilo kojoj verziji Excela.
COUNTIFS sintaksa
sintaksa funkcije COUNTIFS je sljedeća:
COUNTIFS(opseg_kriterija1, kriterij1, [opseg_kriterija2, kriterij2]…)- opseg_kriterija1 (obavezno) - definira prvi raspon do kojeg se prvi uslov ( kriterijum1 ) će bitiprimijenjeno.
- kriterijum1 (obavezno) - postavlja uvjet u obliku broj , referenca ćelije , tekstualni niz , izraz ili neka druga Excel funkcija . Kriterijumi definiraju koje ćelije će se brojati i mogu se izraziti kao 10, "<=32", A6, "slatkiši".
- [opseg_kriterija2, kriterij2]… (opcionalno) - ovo su dodatni rasponi i njihovi povezani kriteriji. Možete specificirati do 127 parova raspona/kriterijuma u svojim formulama.
U stvari, ne morate pamtiti sintaksu funkcije COUNTIF napamet. Microsoft Excel će prikazati argumente funkcije čim počnete da kucate; argument koji trenutno unosite je označen podebljanim slovima.
Excel COUNTIFS - stvari koje treba zapamtiti!
- Možete koristiti funkciju COUNTIFS u Excelu da broj ćelija u jednom opsegu sa jednim uslovom, kao i u više opsega sa više uslova. Ako je ovo drugo, računaju se samo one ćelije koje ispunjavaju sve navedene uvjete .
- Svaki dodatni raspon mora imati isti broj redaka i stupaca kao prvi raspon ( raspon_kriterija1 argument).
- I kontinuirani i nesusjedni rasponi su dozvoljeni.
- Ako je kriterij referenca na praznu ćeliju , funkcija COUNTIFS je tretira kao nultu vrijednost (0).
- Možete koristiti zamjenski znakznakova u kriterijima - zvjezdica (*) i upitnik (?). Pogledajte ovaj primjer za sve detalje.
Kako koristiti COUNTIFS i COUNTIF s više kriterija u Excelu
U nastavku ćete pronaći niz primjera formule koji pokazuju kako koristiti COUNTIFS i COUNTIF funkcije u Excelu za procjenu više uslova.
Kako prebrojati ćelije s više kriterija (I logika)
Ovaj scenarij je najlakši jer je funkcija COUNTIFS u Excelu dizajnirana da broji samo one ćelije za koje su svi navedeni uvjeti TRUE. Mi to zovemo logikom I, jer Excelova funkcija I funkcionira na ovaj način.
Formula 1. COUNTIFS formula s više kriterija
Pretpostavimo da imate listu proizvoda kao što je prikazano na slici ispod. Želite dobiti broj artikala koji su na zalihama (vrijednost u koloni B je veća od 0) ali još nisu prodati (vrijednost je stupac C jednak 0).
Zadatak se može izvršiti. koristeći ovu formulu:
=COUNTIFS(B2:B7,">0", C2:C7,"=0")
I broj je 2 (" Trešnje " i " Limun "):
Formula 2. COUNTIFS formula sa dva kriterijuma
Kada želite da prebrojite stavke sa identičnim kriterijumima, i dalje morate da unesete svaki par raspon_kriterija / kriterijum pojedinačno.
Na primjer, evo prave formule za brojanje stavki koje imaju 0 i u koloni B i u stupcu C:
=COUNTIFS($B$2:$B$7,"=0", $C$2:$C$7,"=0")
Ova COUNTIFS formula vraća 1 jersamo " Grožđe " ima vrijednost "0" u oba stupca.
Upotreba jednostavnije formule s jednim raspon_kriterija kao COUNTIFS(B2: C7,"=0") bi dao drugačiji rezultat - ukupan broj ćelija u rasponu B2:C7 koji sadrži nulu (što je 4 u ovom primjeru).
Kako prebrojati ćelije s više kriterija ( ILI logika)
Kao što ste vidjeli u gornjim primjerima, brojanje ćelija koje ispunjavaju sve navedene kriterije je jednostavno jer je funkcija COUNTIFS dizajnirana da radi na ovaj način.
Ali što ako želite prebrojati ćelije za koje je barem jedan od specificiranih uvjeta TRUE , tj. zasnovan na logici ILI? Sve u svemu, postoje dva načina da se to uradi - dodavanjem nekoliko formula COUNTIF ili upotrebom formule SUM COUNTIFS sa konstantom niza.
Formula 1. Dodajte dvije ili više formula COUNTIF ili COUNITFS
U tabeli ispod, pretpostavimo da želite da prebrojite narudžbe sa statusom " Otkazano " i " Na čekanju ". Da biste to učinili, možete jednostavno napisati 2 regularne Countif formule i zbrojiti rezultate:
=COUNTIF($C$2:$C$11,"Cancelled") + COUNTIF($C$2:$C$11,"Pending")
U slučaju da svaka od funkcija treba da procjenjuje više od jedan uslov, koristite COUNTIFS umjesto COUNTIF. Na primjer, da biste dobili broj narudžbi " Otkazano " i " Na čekanju " za " Jabuke " koristite ovu formulu:
=COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Cancelled") + COUNTIFS($A$2:$A$11, "Apples", $C$2:$C$11,"Pending")
Formula 2. SUM COUNTIFS sa konstantom niza
U situacijama kadamorate procijeniti mnogo kriterija, gornji pristup nije najbolji način jer bi vaša formula postala prevelika. Da biste izvršili iste kalkulacije u kompaktnijoj formuli, navedite sve svoje kriterije u konstanti niza i dostavite taj niz u argument criteria funkcije COUNTIFS. Da biste dobili ukupan broj, ugradite COUNTIFS unutar funkcije SUM, ovako:
SUM(COUNTIFS( opseg ,{" kriterijum1 "," kriterijum2 "," kriterijum3 ",…}))U našoj tabeli uzorka, za prebrojavanje naloga sa statusom " Otkazano " ili " Na čekanju " ili " U tranzitu ", formula bi išla kako slijedi:
=SUM(COUNTIFS($C$2:$C$11, {"cancelled", "pending", "in transit"}))
Na sličan način možete brojati ćelije na osnovu dvije ili više parova raspon_kriterija / kriterija . Na primjer, da dobijete broj narudžbi " Jabuke " koje su " Otkazane " ili " Na čekanju " ili " U tranzitu " , koristite ovu formulu:
=SUM(COUNTIFS($A$2:$A$11,"apples",$C$2:$C$11,{"cancelled","pending","in transit"}))
Možete pronaći još nekoliko načina za brojanje ćelija sa ILI logikom u ovom vodiču: Excel COUNTIF i COUNTIFS sa OR uslovima.
Kako brojati brojeve između 2 određena broja
Uglavnom, COUNTIFS formule za brojeve spadaju u 2 kategorije - na osnovu nekoliko uslova (objašnjenih u gornjim primjerima) i između dvije vrijednosti koje navedete . Ovo posljednje se može postići na dva načina - korištenjem funkcije COUNTIFS ili oduzimanjem jednog COUNTIF oddrugo.
Formula 1. COUNTIFS za brojanje ćelija između dva broja
Da biste saznali koliko brojeva između 5 i 10 (ne uključujući 5 i 10) sadrži ćelije C2 do C10, koristite ova formula:
=COUNTIFS(C2:C10,">5", C2:C10,"<10")
Da biste uključili 5 i 10 u brojanje, koristite operatore "veće ili jednako" i "manje od ili jednako":
=COUNTIFS(B2:B10,">=5" , B2:B10,"<=10")
Formula 2. COUNTIF formule za brojanje brojeva između X i Y
Isti rezultat se može postići oduzimanjem jedne Countif formule od drugog. Prvi broji koliko je brojeva veći od vrijednosti donje granice (5 u ovom primjeru). Druga formula vraća broj brojeva koji su veći od vrijednosti gornje granice (10 u ovom slučaju). Razlika između prvog i drugog broja je rezultat koji tražite.
- =COUNTIF(C2:C10,">5")-COUNTIF(C2:C10,"> ;=10") - broji koliko je brojeva veći od 5 i manji od 10 u rasponu C2:C10. Ova formula će vratiti isti broj kao što je prikazano na slici iznad.
- =COUNTIF(C2:C10, ">=5")-COUNTIF(C2:C10, ">10") - formula broji koliko je brojeva između 5 i 10 u rasponu C2:C10, uključujući 5 i 10.
Kako koristiti reference ćelija u COUNTIFS formulama
Kada koristite logičke operatore kao što je ">","<", "=" zajedno sa referencama ćelija u vašim Excel formulama COUNTIFS, ne zaboravite da stavite operator u "dvostruke navodnike" i
dodate znak ampersand (&) prije reference ćelije da napravite tekst string.
U primjeru skupa podataka ispod, izbrojimo narudžbe " Jabuke " s iznosom većim od 200 USD. Sa raspon_kriterija1 u ćelijama A2:A11 i raspon_kriterija2 u B2:B11, možete koristiti ovu formulu:
=COUNTIFS($A$2:$A$11, "Apples", $B$2:$B$11, ">200")
Ili možete unijeti vrijednosti vaših kriterija u određenim ćelijama, recimo F1 i F2, i referencirajte te ćelije u vašoj formuli:
=COUNTIFS($A$2:$A$11, $F$1, $B$2:$B$11, ">"&$F$2)
Obratite pažnju na upotrebu apsolutnih referenci ćelija i u kriterijumima i criteria_range argumenti, koji sprečavaju da se formula pokvari kada se kopira u druge ćelije.
Za više informacija o upotrebi znaka ampersanda u formulama COUNTIF i COUNTIFS , pogledajte Excel COUNTIF - najčešća pitanja.
Kako koristiti COUNTIFS sa zamjenskim znakovima
U Excel formulama COUNTIFS možete koristiti sljedeće zamjenske znakove:
- Znak pitanja (?) - odgovara bilo kojem pojedinačnom znaku, koristite ga za brojanje ćelija koje počinju i/ili završavaju određenim znakovima.
- Zvjezdica (*) - odgovara bilo koji niz znakova, koristite ga za brojanje ćelija koje sadrže određenu riječ ili znak(e) kao dio sadržaj ćelije.
Savjet. Ako želite prebrojati ćelije sa stvarnim pitanjemoznaku ili zvjezdicu, otkucajte tildu (~) prije zvjezdice ili znaka pitanja.
Sada da vidimo kako možete koristiti zamjenski znak u stvarnim formulama COUNTIFS u Excelu. Pretpostavimo da imate listu projekata u koloni A. Želite znati koliko projekata je već nekome dodijeljeno, tj. imate bilo koje ime u koloni B. I pošto učimo kako koristiti funkciju COUNTIFS s više kriterija, dodajmo drugi uslov - Završni datum u koloni D također treba biti postavljen.
Ovo je formula koja radi kao poslastica:
=COUNTIFS(B2: B10,"*",D2:D10,""&""))
Imajte na umu da ne možete koristiti zamjenski znak u 2. kriteriju jer imate datume, a ne tekstualne vrijednosti u koloni D. Zato koristite kriterije koji pronalaze neprazne ćelije: ""&""
COUNTIFS i COUNTIF sa više kriterija za datume
Formule COUNTIFS i COUNTIF koje koristite za datume su vrlo slične gornjim formulama za brojeve.
Primjer 1. Brojite datume u određenom rasponu datuma
Da biste prebrojali datume koji spadaju u određeni raspon datuma, također možete koristiti formulu COUNTIFS s dva kriterija ili kombinaciju od dvije funkcije COUNTIF.
Na primjer, sljedeće formule broje broj datuma u ćelijama C2 do C10 koji padaju između 1. lipnja 2014. i 7. lipnja 2014., uključujući:
=COUNTIFS(C2:C9, ">=6/1/2014", C2:C9, "<=6/7/2014")
=COUNTIF(C2:C9, ">=6/1/2014") - COUNTIF(C2:C9, ">6/7/2014")
Primjer 2. Brojite datume saviše uslova
Na isti način, možete koristiti formulu COUNTIFS da izbrojite broj datuma u različitim kolonama koji ispunjavaju 2 ili više uslova. Na primjer, formula ispod će saznati koliko je proizvoda kupljeno nakon 20. maja i isporučeno nakon 1. juna:
=COUNTIFS(C2:C9, ">5/1/2014", D2:D9, ">6/7/2014")
Primjer 3. Broj datumi sa više uslova na osnovu trenutnog datuma
Možete koristiti Excelovu funkciju TODAY() u kombinaciji sa COUNTIF da biste brojali datume na osnovu trenutnog datuma.
Na primer, sledeća formula COUNTIF sa dva raspona i dva kriterija će vam reći koliko je proizvoda već kupljeno, ali još nije isporučeno.
=COUNTIFS(C2:C9, ""&TODAY())
Ova formula dozvoljava mnoge moguće varijacije. Na primjer, možete ga podesiti tako da broji koliko je proizvoda kupljeno prije više od tjedan dana i još nisu isporučeni:
=COUNTIFS(C2:C9, ""&TODAY())
Ovako brojite ćelije s više kriterija u Excelu. Nadam se da će vam ovi primjeri biti od pomoći. U svakom slučaju, zahvaljujem se na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!
