Bu eğitimde Excel rastgele sayı üreteci algoritmasının özellikleri açıklanmakta ve Excel'de rastgele sayılar, tarihler, parolalar ve diğer metin dizeleri üretmek için RAND ve RANDBETWEEN işlevlerinin nasıl kullanılacağı gösterilmektedir.

Excel'de rastgele sayı üretmenin farklı tekniklerini incelemeden önce, bunların gerçekte ne olduğunu tanımlayalım. Düz İngilizce'de rastgele veri, herhangi bir örüntü içermeyen bir dizi sayı, harf veya diğer simgelerdir.

Rastgeleliğin kriptografi, istatistik, piyango, kumar ve diğer birçok alanda çeşitli uygulamaları vardır. Ve her zaman talep gördüğü için, eski zamanlardan beri rastgele sayılar oluşturmak için bozuk para çevirme, zar atma, oyun kartlarını karıştırma gibi çeşitli yöntemler var olmuştur. Elbette, bu eğitimde bu tür "egzotik" tekniklere güvenmeyeceğiz ve aşağıdakilere odaklanacağızExcel'in rastgele sayı üretecinin sunabilecekleri.

Excel rastgele sayı üreteci - temel bilgiler

Excel rastgele üreteci tüm standart rastgelelik testlerini geçmesine rağmen gerçek rastgele sayılar. Ama hemen silip atmayın :) Sözde rastgele Excel rastgele işlevleri tarafından üretilen sayılar birçok amaç için uygundur.

Excel rastgele oluşturucu algoritmasına daha yakından bakalım, böylece ondan ne bekleyebileceğinizi ve ne bekleyemeyeceğinizi bilirsiniz.

Çoğu bilgisayar programı gibi, Excel rastgele sayı üreteci de sözde rasgele sayılar Bunun sizin için anlamı, teorik olarak, Excel tarafından üretilen rastgele sayıların, birinin üretecin algoritmasının tüm ayrıntılarını bilmesi koşuluyla tahmin edilebilir olduğudur. Bu, hiçbir zaman belgelenmemiş olmasının ve neredeyse hiç belgelenmeyecek olmasının nedenidir. Peki, Excel'deki rastgele sayı üreteci hakkında ne biliyoruz?

• Excel RAND ve RANDBETWEEN işlevleri, sözde rasgele sayılar üretir. Üniforma dağıtım diğer adıyla dikdörtgen dağılım, rastgele bir değişkenin alabileceği tüm değerler için eşit olasılık vardır. Tekdüze dağılıma iyi bir örnek tek bir zar atmaktır. Atışın sonucu altı olası değerdir (1, 2, 3, 4, 5, 6) ve bu değerlerin her birinin gerçekleşme olasılığı eşittir. Daha bilimsel bir açıklama için lütfen wolfram.com'a göz atın.
• Bilgisayarın sistem zamanından başlatıldığı söylenen Excel RAND veya RANDBETWEEN işlevini tohumlamanın bir yolu yoktur. Teknik olarak, bir tohum Bir Excel rastgele işlevi her çağrıldığında, benzersiz bir rastgele dizi döndüren yeni bir tohum kullanılır. Başka bir deyişle, Excel'deki rastgele sayı üretecini kullanırken, RAND veya RANDBETWEEN işleviyle, VBA ile veya başka herhangi bir yolla tekrarlanabilir bir dizi elde edemezsiniz.
• Excel 2003'ten önceki ilk Excel sürümlerinde, rastgele oluşturma algoritması nispeten küçük bir periyoda sahipti (1 milyondan az tekrar etmeyen rastgele sayı dizisi) ve uzun rastgele dizilerde birkaç standart rastgelelik testinde başarısız oldu. Bu nedenle, birisi hala eski bir Excel sürümüyle çalışıyorsa, RAND işlevini büyük simülasyon modelleriyle kullanmasanız iyi olur.

Eğer aradığınız gerçek rastgele veri, muhtemelen rastgeleliği atmosferik gürültüden gelen www.random.org gibi bir üçüncü taraf rastgele sayı üreteci kullanabilirsiniz. Rastgele sayılar, oyunlar ve piyangolar, renk kodları, rastgele adlar, parolalar, alfanümerik dizeler ve diğer rastgele verileri üretmek için ücretsiz hizmetler sunarlar.

Tamam, bu oldukça uzun teknik giriş sona eriyor ve pratik ve daha faydalı şeylere geçiyoruz.

Excel RAND işlevi - rastgele gerçek sayılar oluşturun

Bu RAND Excel'deki işlev, rastgele sayılar oluşturmak için özel olarak tasarlanmış iki işlevden biridir. 0 ile 1 arasında rastgele bir ondalık sayı (gerçek sayı) döndürür.

RAND() uçucu bir işlevdir, yani çalışma sayfası her hesaplandığında yeni bir rasgele sayı oluşturulur. Ve bu, çalışma sayfasında herhangi bir eylem gerçekleştirdiğinizde, örneğin bir formülü güncelleştirdiğinizde (RAND formülü olması gerekmez, sayfadaki herhangi bir formül olabilir), bir hücreyi düzenlediğinizde veya yeni veri girdiğinizde gerçekleşir.

RAND işlevi Excel 365 - 2000'in tüm sürümlerinde mevcuttur.

Excel RAND işlevinin bağımsız değişkeni olmadığından, basitçe şunu girersiniz =RAND() bir hücreye yerleştirin ve ardından formülü istediğiniz kadar hücreye kopyalayın:

Şimdi bir adım daha ileri gidelim ve koşullarınıza göre rastgele sayılar üretmek için birkaç RAND formülü yazalım.

Formül 1. Aralığın üst sınır değerini belirtin

Sıfır ile herhangi bir sayı arasında rastgele sayılar üretmek için N değeri için RAND işlevini N ile çarparsınız:

Örneğin, 0'dan büyük veya eşit ancak 50'den küçük bir rastgele sayı dizisi oluşturmak için aşağıdaki formülü kullanın:

=RAND()*50

Not: Üst sınır değeri, döndürülen rastgele diziye asla dahil edilmez. Örneğin, 10 dahil olmak üzere 0 ile 10 arasında rastgele sayılar elde etmek istiyorsanız, doğru formül =RAND()*11 .

Formül 2. İki sayı arasında rastgele sayılar oluşturun

Belirttiğiniz herhangi iki sayı arasında rastgele bir sayı oluşturmak için aşağıdaki RAND formülünü kullanın:

Nerede A alt sınır değeridir (en küçük sayı) ve B üst sınır değeridir (en büyük sayı).

Örneğin, 10 ile 50 arasında rastgele sayılar oluşturmak için aşağıdaki formülü kullanabilirsiniz:

=RAND()*(50-10)+10

Not: Bu rastgele formül hiçbir zaman belirtilen aralığın en büyük sayısına eşit bir sayı döndürmeyecektir ( B değeri).

Formül 3. Excel'de rastgele tamsayılar oluşturma

Excel RAND işlevinin rastgele tamsayılar üretmesini sağlamak için, yukarıda belirtilen formüllerden birini alın ve INT işlevine sarın.

0-50 arasında rastgele tam sayılar oluşturmak için:

=INT(RAND()*50)

10-50 arasında rastgele tam sayılar üretmek için:

=INT(RAND()*(50-10)+10)

Excel RANDBETWEEN işlevi - belirli bir aralıkta rastgele tam sayılar oluşturun

RANDBETWEEN, Excel tarafından rastgele sayılar üretmek için sağlanan başka bir işlevdir. tamsayılar belirttiğiniz aralıkta:

Besbelli, b ottom en düşük sayıdır ve üst almak istediğiniz rastgele sayı aralığındaki en yüksek sayıdır.

RAND gibi, Excel'in RANDBETWEEN'i de uçucu bir işlevdir ve elektronik tablonuz her yeniden hesaplandığında yeni bir rastgele tamsayı döndürür.

Örneğin, 10 ile 50 arasında (10 ile 50 dahil) rastgele tamsayılar üretmek için aşağıdaki RANDBETWEEN formülünü kullanın:

=RANDBETWEEN(10, 50)

Excel'deki RANDBETWEEN işlevi hem pozitif hem de negatif sayılar oluşturabilir. Örneğin, -10 ila 10 arasında rastgele tam sayıların bir listesini almak için çalışma sayfanıza aşağıdaki formülü girin:

=RANDBETWEEN(-10, 10)

RANDBETWEEN işlevi Excel 365 - Excel 2007'de mevcuttur. Daha önceki sürümlerde, yukarıdaki Örnek 3'te gösterilen RAND formülünü kullanabilirsiniz.

Bu eğitimin ilerleyen bölümlerinde, RANDBETWEEN fonksiyonunun tamsayılar dışında rastgele değerler üretmek için nasıl kullanılacağını gösteren birkaç formül örneği daha bulacaksınız.

İpucu: Excel 365 ve Excel 2021'de, belirttiğiniz herhangi iki sayı arasında rastgele sayılardan oluşan bir dizi döndürmek için dinamik dizi RANDARRAY işlevini kullanabilirsiniz.

Belirtilen ondalık basamaklarla rastgele sayılar oluşturma

Excel'deki RANDBEETWEEN işlevi rastgele tam sayılar döndürmek için tasarlanmış olsa da, istediğiniz kadar ondalık basamaklı rastgele ondalık sayılar döndürmeye zorlayabilirsiniz.

Örneğin, ondalık basamağı bir olan bir sayı listesi elde etmek için alt ve üst değerleri 10 ile çarparsınız ve ardından döndürülen değeri 10'a bölersiniz:

Aşağıdaki RANDBETWEEN formülü 1 ile 50 arasında rastgele ondalık sayılar döndürür:

=RANDBETWEEN(1*10, 50*10)/10

Benzer şekilde, 1 ile 50 arasında 2 ondalık basamaklı rastgele sayılar üretmek için, RANDBETWEEN işlevinin bağımsız değişkenlerini 100 ile çarpar ve ardından sonucu 100'e bölersiniz:

=RANDBETWEEN(1*100, 50*100) / 100

Excel'de rastgele tarihler nasıl oluşturulur

Verilen iki tarih arasında rastgele tarihlerin bir listesini döndürmek için, DATEVALUE ile birlikte RANDBETWEEN işlevini kullanın:

Örneğin, 1-Haziran-2015 ile 30-Haziran-2015 arasındaki tarihlerin listesini almak için çalışma sayfanıza aşağıdaki formülü girin:

=RANDBETWEEN(DATEVALUE("1-Jun-2015"),DATEVALUE("30-Jun-2015"))

Alternatif olarak, DATEVALUE yerine DATE işlevini kullanabilirsiniz:

=RANDBETWEEN(DATE(2015,6,1),DATEVALUE(2015,6,30))

Hücre(ler)e tarih biçimini uygulamayı unutmayın; böylece buna benzer rastgele tarihlerden oluşan bir liste elde edersiniz:

Rastgele hafta içi veya hafta sonu oluşturma gibi bir dizi gelişmiş seçenek için Tarihler için Gelişmiş Rastgele Oluşturucu bölümüne göz atın.

Excel'de rastgele zamanlar nasıl eklenir

Dahili Excel sisteminde saatlerin ondalık sayılar olarak saklandığını hatırlayarak, rastgele gerçek sayılar eklemek için standart Excel RAND işlevini kullanabilir ve ardından saat biçimini hücrelere uygulayabilirsiniz:

Kriterlerinize göre rastgele zamanlar döndürmek için, aşağıda gösterildiği gibi daha spesifik rastgele formüller gereklidir.

Formül 1. Belirtilen aralıkta rastgele zamanlar oluşturun

Belirttiğiniz herhangi iki zaman arasına rastgele zamanlar eklemek için, Excel RAND ile birlikte TIME veya TIMEVALUE işlevini kullanın:

Örneğin, sabah 6:00 ile akşam 5:30 arasına rastgele bir saat eklemek için aşağıdaki formüllerden birini kullanabilirsiniz:

=TIME(6,0,0) + RAND() * (TIME(17,30,0) - TIME(6,0,0))

=TIMEVALUE("6:00 AM") + RAND() * (TIMEVALUE("5:30 PM") - TIMEVALUE("6:00 AM"))

Formül 2. Rastgele tarih ve saatler oluşturma

Rastgele bir liste oluşturmak için tari̇hler ve saatler , RANDBETWEEN ve DATEVALUE işlevlerinin bir kombinasyonunu kullanın:

Diyelim ki 1 Haziran 2015 ile 30 Haziran 2015 tarihleri arasına rastgele tarihler ve 7:30 AM ile 6:00 PM arasında bir saat eklemek istiyorsunuz, aşağıdaki formül işe yarayacaktır:

=RANDBETWEEN(DATEVALUE("1-Jun-2015"), DATEVALUE("30-Jun-2015")) + RANDBETWEEN(TIMEVALUE("7:30 AM") * 10000, TIMEVALUE("6:00 PM") * 10000) / 10000

Ayrıca sırasıyla TARİH ve SAAT fonksiyonlarını kullanarak tarih ve saat girebilirsiniz:

=RANDBETWEEN(DATE(2015,6,1), DATE(2015,6,30)) + RANDBETWEEN(TIME(7,30,0) * 10000, TIME(18,0,0) * 10000) / 10000

Excel'de rastgele harfler oluşturma

Rastgele bir harf döndürmek için üç farklı fonksiyonun kombinasyonu gereklidir:

=CHAR(RANDBETWEEN(CODE("A"),CODE("Z")))

Nerede A ilk karakterdir ve Z dahil etmek istediğiniz harf aralığındaki son karakterdir (alfabetik sırayla).

Yukarıdaki formülde:

• CODE, belirtilen harfler için sayısal ANSI kodları döndürür.
• RANDBETWEEN, CODE fonksiyonları tarafından döndürülen sayıları aralığın alt ve üst değerleri olarak alır.
• CHAR, RANDBETWEEN tarafından döndürülen rastgele ANSI kodlarını karşılık gelen harflere dönüştürür.

Not: ANSI kodları BÜYÜK HARF ve KÜÇÜK HARF karakterleri için farklı olduğundan, bu formül büyük/küçük harfe duyarlı .

Eğer birisi ANSI Karakter Kodları Tablosunu ezbere hatırlıyorsa, kodları doğrudan RANDBETWEEN fonksiyonuna vermenizi engelleyen hiçbir şey yoktur.

Örneğin, rastgele almak için BÜYÜK HARFLER arasında A (ANSI kodu 65) ve Z (ANSI kodu 90), yazarsınız:

=CHAR(RANDBETWEEN(65, 90))

Üretmek için küçük harfler gelen a (ANSI kodu 97) ile z (ANSI kodu 122), aşağıdaki formülü kullanırsınız:

=CHAR(RANDBETWEEN(97, 122))

gibi rastgele bir özel karakter eklemek için " # $ % & ' ( ) * + , - . /, ile birlikte RANDBETWEEN işlevini kullanın. alt parametresi 33 olarak ayarlanır (ANSI kodu "!') ve üst parametresi 47 olarak ayarlanmıştır ("/" için ANSI kodu).

=CHAR(RANDBETWEEN(33,47))

Excel'de metin dizeleri ve parolalar oluşturma

Excel'de rastgele bir metin dizesi oluşturmak için, birkaç CHAR / RANDBEETWEEN işlevini birleştirmeniz yeterlidir.

Örneğin, 4 karakterden oluşan bir parola listesi oluşturmak için buna benzer bir formül kullanabilirsiniz:

=RANDBETWEEN(0,9) & CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(97, 122)) & CHAR(RANDBETWEEN(33,47))

Formülü daha derli toplu hale getirmek için ANSI kodlarını doğrudan formülün içinde verdim. Dört işlev aşağıdaki rastgele değerleri döndürür:

• RANDBETWEEN(0,9) - 0 ile 9 arasında rastgele sayılar döndürür.
• CHAR(RANDBETWEEN(65,90)) - arasında rastgele BÜYÜK HARF döndürür A ve Z .
• CHAR(RANDBETWEEN(97, 122)) - arasında rastgele küçük harfler döndürür a ve z .
• CHAR(RANDBETWEEN(33,47)) - rastgele özel karakterler döndürür.

Yukarıdaki formülle oluşturulan metin dizeleri aşağıdaki gibi olacaktır " 4Np# " veya " 2Yu& ".

Dikkatli olun! Rastgele parolalar oluşturmak için benzer bir formül kullanırsanız, bunlar güçlü olmayacaktır. Elbette, daha fazla CHAR / RANDBETWEEN işlevini zincirleyerek daha uzun metin dizeleri oluşturamayacağınızı söyleyen bir şey yoktur. Ancak, sırayı veya karakterleri rastgele hale getirmek imkansızdır, yani 1. işlev her zaman bir sayı döndürür, 2. işlev bir büyük harf döndürür ve bu böyle devam eder.

Excel'de herhangi bir uzunlukta ve desende metin dizeleri üretebilen gelişmiş bir rastgele parola oluşturucu arıyorsanız, test dizeleri için Gelişmiş Rastgele Oluşturucu'nun yeteneklerine göz atmak isteyebilirsiniz.

Ayrıca, yukarıdaki formülle oluşturulan metin dizelerinin çalışma sayfanız her yeniden hesaplandığında değişeceğini lütfen unutmayın. Dizelerinizin veya parolalarınızın oluşturulduktan sonra aynı kalmasını sağlamak için, RANDBETWEEN işlevinin değerleri güncellemesini durdurmanız gerekecektir, bu da bizi doğrudan bir sonraki bölüme götürür.

RAND ve RANDBETWEEN'in yeniden hesaplanması nasıl önlenir

Sayfa her yeniden hesaplandığında değişmeyecek kalıcı bir rastgele sayılar, tarihler veya metin dizeleri kümesi elde etmek istiyorsanız, aşağıdaki tekniklerden birini kullanın:

1. RAND veya RANDBETWEEN işlevlerinin aşağıdaki durumlarda yeniden hesaplanmasını durdurmak için bir hücre 'ye basın, bu hücreyi seçin, formül çubuğuna geçin ve formülü değeriyle değiştirmek için F9 tuşuna basın.
2. Bir Excel rastgele işlevinin yeniden hesaplanmasını önlemek için Özel> Değerleri Yapıştır özelliğini kullanın. Rastgele formülün bulunduğu tüm hücreleri seçin, kopyalamak için Ctrl + C tuşlarına basın, ardından seçilen aralığa sağ tıklayın ve Özel Yapıştır > Değerler .

Rastgele sayıları "dondurmaya" yönelik bu teknik hakkında daha fazla bilgi edinmek için Formülleri değerlerle değiştirme bölümüne bakın.

Excel'de benzersiz rastgele sayılar nasıl oluşturulur

Excel'in rastgele işlevlerinden hiçbiri benzersiz rastgele değerler üretemez. Rastgele sayılardan oluşan bir liste oluşturmak istiyorsanız kopyalar olmadan aşağıdaki adımları uygulayın:

1. Rastgele sayılardan oluşan bir liste oluşturmak için RAND veya RANDBETWEEN işlevini kullanın. Gerçekten ihtiyacınız olandan daha fazla değer oluşturun çünkü bazıları daha sonra silinecek kopyalar olacaktır.
2. Formülleri yukarıda açıklandığı gibi değerlere dönüştürün.
3. Excel'in yerleşik aracını veya Excel için gelişmiş Yinelenen Kaldırıcımızı kullanarak yinelenen değerleri kaldırın.

Daha fazla çözümü şu eğitimde bulabilirsiniz: Yinelemesiz rastgele sayılar nasıl oluşturulur?

Excel için Gelişmiş Rastgele Sayı Üreteci

Artık Excel'de rastgele işlevleri nasıl kullanacağınızı bildiğinize göre, çalışma sayfalarınızda rastgele sayılar, tarihler veya metin dizeleri listesi oluşturmanın daha hızlı, daha kolay ve formülsüz bir yolunu göstereyim.

AbleBits Random Generator for Excel, Excel'in RAND ve RANDBETWEEN işlevlerine daha güçlü ve kullanıcı dostu bir alternatif olarak tasarlanmıştır. Microsoft Excel 2019, 2016, 2013, 2010, 2007 ve 2003'ün tüm sürümleriyle eşit derecede iyi çalışır ve standart rastgele işlevlerin kalite ve kullanılabilirlik sorunlarının çoğunu giderir.

AbleBits Rastgele Sayı Üreteci algoritması

Rastgele Jeneratörümüzü uygulamalı olarak göstermeden önce, tam olarak ne sunduğumuzu bilmeniz için algoritması hakkında birkaç önemli not vermeme izin verin.

• Excel için AbleBits Rastgele Sayı Üreticisi, yüksek kaliteli sözde rastgeleleştirme için bir endüstri standardı olarak kabul edilen Mersenne Twister algoritmasına dayanmaktadır.
• Akla gelebilecek tüm senaryolar için fazlasıyla yeterli olan 2^19937 - 1 gibi çok uzun bir periyoda sahip 32 bitlik tamsayılardan oluşan normal dağılımlı bir dizi üreten MT19937 sürümünü kullanıyoruz.
• Bu yöntem kullanılarak üretilen rastgele sayılar çok yüksek kalitededir. Rastgele Sayı Üreticisi, iyi bilinen NIST İstatistiksel Test Paketi ve Diehard testleri ve TestU01 Crush rastgelelik testlerinden bazıları dahil olmak üzere istatistiksel rastgelelik için birçok testi başarıyla geçmiştir.

Excel rastgele işlevlerinin aksine, Rastgele Sayı Üreticimiz şunları oluşturur kalıcı rastgele değerler Bir elektronik tablo yeniden hesaplandığında değişmeyen.

Daha önce de belirtildiği gibi, Excel için bu gelişmiş Rastgele Sayı Üreticisi, aşağıdaki gibi çeşitli rastgele değerler oluşturmak için formülsüz (ve dolayısıyla hatasız :) bir yol sunar:

• Benzersiz sayılar da dahil olmak üzere rastgele tam sayılar veya ondalık sayılar
• Rastgele tarihler (iş günleri, hafta sonları veya her ikisi ve isteğe bağlı olarak benzersiz tarihler)
• Belirli bir uzunluk ve desendeki parolalar dahil olmak üzere rastgele metin dizeleri veya maske ile
• DOĞRU ve YANLIŞ rastgele Boole değerleri
• Özel listelerden rastgele seçim

Ve şimdi, söz verdiğimiz gibi Rastgele Sayı Üreticisini çalışırken görelim.

Excel'de rastgele sayılar oluşturma

AbleBits Rastgele Sayı Üreticisi ile rastgele sayıların bir listesini oluşturmak Oluşturmak Düğme.

Benzersiz rastgele tamsayılar üretme

Tek yapmanız gereken rastgele tamsayılarla doldurulacak aralığı seçmek, alt ve üst değerleri ayarlamak ve isteğe bağlı olarak Benzersiz Değerler Kutu.

Rastgele gerçek sayılar üretme (ondalık sayılar)

Benzer şekilde, belirttiğiniz aralıkta bir dizi rastgele ondalık sayı oluşturabilirsiniz.

Excel'de rastgele tarihler oluşturma

Tarihler için Rastgele Sayı Üreticimiz aşağıdaki seçenekleri sunar:

• Belirli bir zaman dilimi için rastgele tarihler oluşturun - en alttaki tarihi Kimden kutusundaki en üst tarih ve için Kutu.
• Hafta içi, hafta sonu veya her ikisini de dahil edin.
• Benzersiz tarihler oluşturun.

Rastgele metin dizeleri ve parolalar oluşturun

Rastgele sayılar ve tarihlerin yanı sıra, bu Rastgele Oluşturucu ile belirli karakter kümelerine sahip rastgele alfanümerik dizeleri kolayca oluşturabilirsiniz. Maksimum dize uzunluğu 99 karakterdir, bu da gerçekten güçlü parolalar oluşturmaya olanak tanır.

AbleBits Rastgele Sayı Üreticisi tarafından sağlanan benzersiz bir seçenek maskeye göre rastgele metin dizeleri Bu, küresel olarak benzersiz tanımlayıcılar (GUID), posta kodları, SKU'lar ve benzerlerini oluşturmak için çok kullanışlı bir özelliktir.

Örneğin, rastgele GUID'lerin bir listesini almak için Onaltılık karakter kümesini seçip ????????-????-????-???????????? yazın. Maske kutusunda, ekran görüntüsünde gösterildiği gibi:

Rastgele Oluşturucumuzu denemek isterseniz, Excel için Ultimate Paketimizin bir parçası olarak aşağıdan indirebilirsiniz.

Mevcut indirmeler

Rastgele formül örnekleri (.xlsx dosyası)

Ultimate Suite 14 günlük tam işlevli sürüm (.exe dosyası)