இந்த டுடோரியலில், வெவ்வேறு பிழைகளைச் சிக்க வைத்து கையாள்வதற்கு IFERROR மற்றும் VLOOKUP செயல்பாடுகளை ஒன்றாகப் பயன்படுத்துவது எப்படி என்பதைப் பார்ப்போம். கூடுதலாக, பல IFERROR செயல்பாடுகளை ஒன்றன் பின் ஒன்றாக இணைத்து எக்செல் இல் வரிசைமுறை vlookupகளை எவ்வாறு செய்வது என்பதை நீங்கள் கற்றுக் கொள்ளப் போகிறீர்கள்.

Excel VLOOKUP மற்றும் IFERROR - இந்த இரண்டு செயல்பாடுகளையும் தனித்தனியாகப் புரிந்துகொள்வது மிகவும் கடினமாக இருக்கலாம், அவை இணைக்கப்படும்போது ஒருபுறம் இருக்கட்டும். இந்தக் கட்டுரையில், பொதுவான பயன்பாடுகளை எடுத்துரைக்கும் மற்றும் சூத்திரங்களின் தர்க்கத்தை தெளிவாக விளக்கும் சில எளிய பின்பற்றக்கூடிய எடுத்துக்காட்டுகளை நீங்கள் காணலாம்.

IFERROR மற்றும் VLOOKUP செயல்பாடுகளில் உங்களுக்கு அதிக அனுபவம் இல்லையென்றால், அது இருக்கலாம் மேலே உள்ள இணைப்புகளைப் பின்பற்றுவதன் மூலம் முதலில் அவர்களின் அடிப்படைகளை மறுபரிசீலனை செய்வது நல்லது.

#N/A மற்றும் பிற பிழைகளைக் கையாள IFERROR VLOOKUP சூத்திரம்

எக்செல் Vlookup கண்டுபிடிக்கத் தவறினால் ஒரு தேடல் மதிப்பு, இது ஒரு #N/A பிழையை ஏற்படுத்துகிறது, இது போன்றது:

உங்கள் வணிகத் தேவைகளைப் பொறுத்து, உங்கள் சொந்த உரையான பூஜ்ஜியத்துடன் பிழையை மறைக்க விரும்பலாம் , அல்லது ஒரு வெற்று செல்.

எடுத்துக்காட்டு 1. பிழைகளை உங்கள் சொந்த உரையுடன் மாற்ற VLOOKUP சூத்திரத்துடன் IFERROR

உங்கள் தனிப்பயன் உரையுடன் நிலையான பிழைக் குறிப்பை மாற்ற விரும்பினால், உங்கள் IFERROR இல் VLOOKUP சூத்திரம், மற்றும் 2வது வாதத்தில் நீங்கள் விரும்பும் எந்த உரையையும் தட்டச்சு செய்யவும் ( value_if_error ), எடுத்துக்காட்டாக "கண்டுபிடிக்கப்படவில்லை":

முதன்மை அட்டவணையில் உள்ள B2 இல் தேடுதல் மதிப்பு மற்றும் தேடுதலில் A2:B4 வரம்புடன்அட்டவணை, சூத்திரம் பின்வரும் வடிவத்தை எடுக்கும்:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

கீழே உள்ள ஸ்கிரீன்ஷாட் எங்களின் Excel IFERROR VLOOKUP சூத்திரத்தை செயலில் காட்டுகிறது:

முடிவு மிகவும் புரிந்துகொள்ளக்கூடியதாகவும் மிகவும் குறைவான பயமுறுத்துவதாகவும் தெரிகிறது, இல்லையா?

இதே முறையில், நீங்கள் IFERROR உடன் INDEX MATCH ஐப் பயன்படுத்தலாம்:

=IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

The IFERROR INDEX MATCH சூத்திரம், தேடல் நெடுவரிசையின் இடதுபுறத்தில் இருக்கும் (இடது தேடல்) நெடுவரிசையிலிருந்து மதிப்புகளை இழுக்க விரும்பும் போது குறிப்பாக பயனுள்ளதாக இருக்கும், மேலும் எதுவும் கிடைக்காதபோது உங்கள் சொந்த உரையைத் திருப்பி அனுப்பவும்.

எடுத்துக்காட்டு 2. உடன் IFERROR VLOOKUP ஐ வெறுமையாக அல்லது எதுவும் கிடைக்கவில்லை என்றால் 0 என்பதைத் திரும்பப் பெறவும்

தேடல் மதிப்பு காணப்படாதபோது எதையும் காட்ட விரும்பவில்லை எனில், காலி சரத்தை ("") காட்ட IFERROR:

எங்கள் எடுத்துக்காட்டில், சூத்திரம் பின்வருமாறு செல்கிறது:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

நீங்கள் பார்க்க முடியும், தேடுதல் மதிப்பு தேடல் பட்டியலில் இல்லாதபோது அது எதையும் தராது 0 கடைசியில் ஏ rgument:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

எச்சரிக்கை வார்த்தை! எக்செல் IFERROR செயல்பாடு #N/A மட்டுமின்றி அனைத்து வகையான பிழைகளையும் பிடிக்கிறது. இது நல்லதா கெட்டதா? அனைத்தும் உங்கள் இலக்கைப் பொறுத்தது. சாத்தியமான அனைத்து பிழைகளையும் மறைக்க விரும்பினால், IFERROR Vlookup செல்ல வழி. ஆனால் பல சூழ்நிலைகளில் இது ஒரு விவேகமற்ற நுட்பமாக இருக்கலாம்.

உதாரணமாக, உங்கள் டேபிள் தரவிற்கு பெயரிடப்பட்ட வரம்பை உருவாக்கி, உங்களில் அந்த பெயரை தவறாக எழுதியிருந்தால்Vlookup சூத்திரம், IFERROR #NAMEஐப் பிடிக்குமா? பிழை மற்றும் அதை "கண்டுபிடிக்கப்படவில்லை" அல்லது நீங்கள் வழங்கும் வேறு ஏதேனும் உரை என்று மாற்றவும். இதன் விளைவாக, எழுத்துப்பிழையை நீங்களே கண்டறிந்தால் தவிர, உங்கள் சூத்திரம் தவறான முடிவுகளை வழங்குவதை நீங்கள் அறியமாட்டீர்கள். இதுபோன்ற ஒரு சந்தர்ப்பத்தில், மிகவும் நியாயமான அணுகுமுறை #N/A பிழைகளை மட்டுமே சிக்க வைக்கும். இதற்கு, Excel 2013 மற்றும் அதற்கு மேற்பட்டவற்றில் IFNA Vlookup சூத்திரத்தைப் பயன்படுத்தவும், எல்லா Excel பதிப்புகளிலும் ISNA VLOOKUP ஐப் பயன்படுத்தவும்.

இதன் முக்கிய அம்சம் என்னவென்றால்: உங்கள் VLOOKUP சூத்திரத்திற்கு ஒரு துணையைத் தேர்ந்தெடுக்கும்போது மிகவும் கவனமாக இருங்கள் :)

எப்போதுமே எதையாவது கண்டுபிடிக்க VLOOKUP க்குள் IFERROR Nest IFERROR

பின்வரும் சூழ்நிலையை கற்பனை செய்து பாருங்கள்: பட்டியலில் குறிப்பிட்ட மதிப்பை நீங்கள் தேடுகிறீர்கள், அதைக் கண்டுபிடிக்க முடியவில்லை. உங்களுக்கு என்ன தேர்வுகள் உள்ளன? N/A பிழையைப் பெறலாம் அல்லது உங்கள் சொந்த செய்தியைக் காட்டலாம். உண்மையில், மூன்றாவது விருப்பம் உள்ளது - உங்கள் முதன்மை vlookup தடுமாறினால், நிச்சயமாக வேறு ஏதாவது ஒன்றைத் தேடுங்கள்!

எங்கள் உதாரணத்தை மேலும் எடுத்துக்கொண்டால், எங்கள் பயனர்களுக்கு நீட்டிப்பைக் காண்பிக்கும் ஒருவித டாஷ்போர்டை உருவாக்குவோம். ஒரு குறிப்பிட்ட அலுவலகத்தின் எண்ணிக்கை. இது போன்ற ஒன்று:

எனவே, D2 இல் உள்ள அலுவலக எண்ணின் அடிப்படையில் B நெடுவரிசையிலிருந்து நீட்டிப்பை எவ்வாறு இழுப்பது? இந்த வழக்கமான Vlookup சூத்திரத்துடன்:

=VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

மேலும் உங்கள் பயனர்கள் D2 இல் சரியான எண்ணை உள்ளிடும் வரை இது நன்றாக வேலை செய்யும். ஆனால் ஒரு பயனர் இல்லாத சில எண்ணை உள்ளீடு செய்தால் என்ன செய்வது? இந்த வழக்கில், அவர்கள் மத்திய அலுவலகத்தை அழைக்கட்டும்! இதற்கு, மேலே உள்ள சூத்திரத்தை நீங்கள் உட்பொதிக்கிறீர்கள்IFERROR இன் மதிப்பு வாதம், மேலும் value_if_error வாதத்தில் மற்றொரு Vlookup ஐ வைக்கவும்.

முழுமையான சூத்திரம் சற்று நீளமானது, ஆனால் அது சரியாக வேலை செய்கிறது:

=IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

அலுவலக எண் கண்டறியப்பட்டால், பயனர் தொடர்புடைய நீட்டிப்பு எண்ணைப் பெறுவார்:

அலுவலக எண் கிடைக்கவில்லை என்றால், மத்திய அலுவலக நீட்டிப்பு காட்டப்படும்:

சூத்திரத்தை இன்னும் கொஞ்சம் சுருக்கமாக மாற்ற, நீங்கள் வேறு அணுகுமுறையைப் பயன்படுத்தலாம்:

முதலில், D2 இல் உள்ள எண் உள்ளதா எனச் சரிபார்க்கவும் தேடல் நெடுவரிசையில் (சூத்திரத்தை மேலே பார்க்கவும் மற்றும் நெடுவரிசை A இலிருந்து மதிப்பை வழங்கவும் col_index_num ஐ 1 ஆக அமைத்துள்ளோம் என்பதை கவனியுங்கள்): VLOOKUP(D2,$A$2:$B$7,1,FALSE)

குறிப்பிட்ட அலுவலக எண் கிடைக்கவில்லை என்றால், "மத்திய அலுவலகம்" என்ற சரத்தைத் தேடுவோம், அது நிச்சயமாக தேடல் பட்டியலில் இருக்கும். இதற்கு, நீங்கள் முதல் VLOOKUP ஐ IFERROR இல் போர்த்தி, மற்றொரு VLOOKUP செயல்பாட்டிற்குள் இந்த முழு கலவையையும் இணைக்கவும்:

=VLOOKUP(IFERROR(VLOOKUP(D2,$A$2:$B$7,1,FALSE),"central office"),$A$2:$B$7,2)

சரி, சற்று வித்தியாசமான சூத்திரம், அதே முடிவு:

ஆனால் "மத்திய அலுவலகத்தை" தேடுவதற்கான காரணம் என்ன, நீங்கள் என்னிடம் கேட்கலாம். ஏன் IFERROR இல் நீட்டிப்பு எண்ணை நேரடியாக வழங்கக்கூடாது? ஏனென்றால் எதிர்காலத்தில் ஒரு கட்டத்தில் நீட்டிப்பு மாறலாம். இது நடந்தால், உங்கள் ஒவ்வொரு VLOOKUP சூத்திரங்களையும் புதுப்பிப்பதைப் பற்றி கவலைப்படாமல், மூல அட்டவணையில் உங்கள் தரவை ஒருமுறை புதுப்பிக்க வேண்டும்.

எக்செல் இல் வரிசைமுறை VLOOKUP களை எப்படி செய்வது

சூழ்நிலைகளில் நீங்கள் வேண்டும்எக்ஸெல் இல் சீக்வென்ஷியல் அல்லது சங்கிலி Vlookups என்று அழைக்கப்படுவதைச் செய்யுங்கள் IFERROR(VLOOKUP( ... ), IFERROR(VLOOKUP( ... ), IFERROR(VLOOKUP( ... ),"கண்டுபிடிக்கவில்லை")))

தி சூத்திரம் பின்வரும் தர்க்கத்துடன் செயல்படுகிறது:

முதல் VLOOKUP எதையும் கண்டுபிடிக்கவில்லை என்றால், முதல் IFERROR ஒரு பிழையைப் பிடித்து மற்றொரு VLOOKUP ஐ இயக்குகிறது. இரண்டாவது VLOOKUP தோல்வியுற்றால், இரண்டாவது IFERROR பிழையைப் பிடித்து மூன்றாவது VLOOKUP ஐ இயக்குகிறது. எல்லா Vlookupகளும் தடுமாறினால், கடைசி IFERROR உங்கள் செய்தியை வழங்கும்.

இந்த உள்ளமைக்கப்பட்ட IFERROR சூத்திரம் கீழே உள்ள எடுத்துக்காட்டில் காட்டப்பட்டுள்ளபடி பல தாள்கள் முழுவதும் Vlookup செய்யும் போது மிகவும் பயனுள்ளதாக இருக்கும்.

தேடல் மதிப்பு செல் A2 இல் இருப்பதாக வைத்துக்கொள்வோம். தற்போதைய தாளில், மற்றும் 3 வெவ்வேறு பணித்தாள்களில் (வடக்கு, தெற்கு மற்றும் மேற்கு) தேடல் வரம்பு A2:B5 ஆக உள்ளது, பின்வரும் சூத்திரம் விருந்தளிக்கும்:

=IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

எனவே, எங்கள் "சங்கிலி Vlookups" சூத்திரம் மூன்று வெவ்வேறு தாள்களில் நாங்கள் சூத்திரத்தில் உள்ளமைக்கப்பட்ட வரிசையில் தேடுகிறது, மேலும் அது கண்டுபிடிக்கும் முதல் பொருத்தத்தைக் கொண்டுவருகிறது:

இவ்வாறு நீங்கள் VLOOKUP உடன் IFERROR ஐப் பயன்படுத்துகிறீர்கள் எக்செல். படித்ததற்கு நன்றி மற்றும் உங்களைப் பார்ப்பேன் என்று நம்புகிறேன்அடுத்த வாரம் எங்கள் வலைப்பதிவில்!

கிடைக்கும் பதிவிறக்கங்கள்

Excel IFERROR VLOOKUP சூத்திர எடுத்துக்காட்டுகள்