ဤသင်ခန်းစာတွင်၊ မတူညီသောအမှားများကို ထောင်ချောက်ဆင်ရန်နှင့် ကိုင်တွယ်ရန် IFERROR နှင့် VLOOKUP လုပ်ဆောင်ချက်များကို အတူတကွ မည်သို့အသုံးပြုရမည်ကို ကြည့်ရှုပါမည်။ ထို့အပြင်၊ သင်သည် IFERROR လုပ်ဆောင်ချက်များစွာကို တစ်ခုနှင့်တစ်ခု ချိတ်ဆက်ခြင်းဖြင့် Excel တွင် sequential vlookups ပြုလုပ်နည်းကို သင်လေ့လာသွားမည်ဖြစ်သည်။

Excel VLOOKUP နှင့် IFERROR - ဤလုပ်ဆောင်ချက်နှစ်ခုကို ပေါင်းစပ်လိုက်သောအခါတွင်တော့ သီးခြားစီ နားလည်ရခက်နိုင်သည် ။ ဤဆောင်းပါးတွင်၊ အသုံးများသောအသုံးပြုမှုများကိုဖော်ပြပြီး ဖော်မြူလာ၏ယုတ္တိကိုရှင်းလင်းစွာဖော်ပြသည့် လိုက်နာရန်လွယ်ကူသောဥပမာအနည်းငယ်ကို သင်တွေ့လိမ့်မည်။

သင့်တွင် IFERROR နှင့် VLOOKUP လုပ်ဆောင်ချက်များကို အတွေ့အကြုံများစွာမရှိပါက၊ ၎င်းသည် ဖြစ်နိုင်သည်။ အထက်ဖော်ပြပါလင့်ခ်များကို လိုက်နာခြင်းဖြင့် ၎င်းတို့၏အခြေခံများကို ဦးစွာပြန်လည်ပြင်ဆင်ရန် စိတ်ကူးကောင်းတစ်ခုဖြစ်သည်။

#N/A နှင့် အခြားအမှားများကို ကိုင်တွယ်ရန် Excel Vlookup မှ အဆင်မပြေသောအခါတွင် IFERROR VLOOKUP ဖော်မြူလာ

ရှာဖွေမှုတန်ဖိုးတစ်ခု၊ ၎င်းသည် ဤကဲ့သို့သော #N/A အမှားတစ်ခုကို လွှတ်ချလိုက်သည်-

သင့်လုပ်ငန်းလိုအပ်ချက်ပေါ်မူတည်၍ သင်သည် အမှားကို သင့်ကိုယ်ပိုင်စာသားဖြင့် ဖုံးကွယ်ထားလိုနိုင်သည်၊ သုည ၊ သို့မဟုတ် ဆဲလ်အလွတ်တစ်ခု။

ဥပမာ 1. အမှားများကို သင့်ကိုယ်ပိုင်စာသားဖြင့် အစားထိုးရန် IFERROR VLOOKUP ဖော်မြူလာ

စံအမှားအမှတ်အသားကို သင့်စိတ်ကြိုက်စာသားဖြင့် အစားထိုးလိုပါက၊ IFERROR တွင် VLOOKUP ဖော်မြူလာနှင့် 2nd အငြင်းအခုံ ( value_if_error ) တွင် သင်အလိုရှိသော မည်သည့်စာသားကိုမဆို ရိုက်ထည့်ပါ၊ ဥပမာ "မတွေ့ပါ":

ပင်မဇယားရှိ B2 ရှိ ရှာဖွေမှုတန်ဖိုးနှင့် ရှာဖွေမှုအကွာအဝေး A2:B4 နှင့်အတူဇယား၊ ဖော်မြူလာသည် အောက်ပါပုံသဏ္ဍာန်ကို ယူဆောင်သည်-

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

အောက်ပါ ဖန်သားပြင်ဓာတ်ပုံသည် ကျွန်ုပ်တို့၏ Excel IFERROR VLOOKUP ဖော်မြူလာလုပ်ဆောင်ချက်ကို ပြသသည်-

ထို ရလဒ်သည် ပိုမိုနားလည်နိုင်ပြီး အကြောက်အလန့်နည်းပါးပုံပေါ်သည်မဟုတ်လား?

ထိုနည်းအားဖြင့် သင်သည် IFERROR နှင့် INDEX MATCH ကိုတွဲသုံးနိုင်သည်-

=IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

IFERROR INDEX MATCH ဖော်မြူလာသည် ရှာဖွေမှုကော်လံ၏ ဘယ်ဘက်တွင်ရှိသော ကော်လံတစ်ခုမှ တန်ဖိုးများကို ဆွဲထုတ်လိုသည့်အခါတွင် အထူးသဖြင့် အသုံးဝင်ပုံသည် ရှာဖွေမှုကော်လံ (ဘယ်ဘက်ရှာဖွေမှု) နှင့် ဘာမျှမတွေ့သောအခါတွင် သင့်ကိုယ်ပိုင်စာသားကို ပြန်ပေးပါသည်။

ဥပမာ 2. IFERROR နှင့်အတူ ဘာမှမတွေ့ပါက ဗလာ သို့မဟုတ် 0 ကိုပြန်ပေးရန် VLOOKUP

ရှာဖွေမှုတန်ဖိုးကိုမတွေ့သောအခါတွင် မည်သည့်အရာကိုမျှ မပြလိုပါက၊ IFERROR တွင် ဗလာစာကြောင်း ("") ကိုပြသပေးစေလိုပါသည်။

ကျွန်ုပ်တို့၏ဥပမာတွင်၊ ဖော်မြူလာမှာ အောက်ပါအတိုင်းဖြစ်သည်-

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

သင်မြင်သည့်အတိုင်း၊ ရှာဖွေမှုတန်ဖိုးသည် ရှာဖွေမှုစာရင်းတွင် မရှိသောအခါတွင် ၎င်းသည် မည်သည့်အရာမှ ပြန်ပေးမည်မဟုတ်ပါ။

အမှားကို သုညတန်ဖိုး ဖြင့် အစားထိုးလိုပါက၊ ထည့်ပါ 0 ၌နောက်ဆုံးတစ်ခု rgument-

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

သတိထားပါ။ ကောင်းလား ဆိုးလား အားလုံးက မင်းရဲ့ပန်းတိုင်ပေါ်မှာ မူတည်တယ်။ ဖြစ်နိုင်သောအမှားများကိုဖုံးကွယ်လိုပါက IFERROR Vlookup သည်သွားရမည့်လမ်းဖြစ်သည်။ သို့သော်၊ ၎င်းသည် အခြေအနေများစွာတွင် ပညာမဲ့နည်းပညာတစ်ခု ဖြစ်နိုင်သည်။

ဥပမာ၊ သင့်ဇယားဒေတာအတွက် အမည်ပေးထားသော အပိုင်းအခြားတစ်ခုကို ဖန်တီးပြီး ၎င်းအမည်ကို သင့်တွင် စာလုံးပေါင်းမှားပါက၊Vlookup ဖော်မြူလာ၊ IFERROR သည် #NAME ကိုဖမ်းမည်လား။ အမှားအယွင်းဖြစ်ပြီး ၎င်းကို "မတွေ့ပါ" သို့မဟုတ် သင်ပံ့ပိုးပေးသည့် အခြားစာသားဖြင့် အစားထိုးပါ။ ရလဒ်အနေဖြင့်၊ သင့်ဖော်မြူလာသည် မှားယွင်းသောရလဒ်များကို သင်ကိုယ်တိုင်မတွေ့ရှိပါက သင့်ဖော်မြူလာကို မည်သည့်အခါမျှ မသိနိုင်ပါ။ ထိုသို့သောအခြေအနေမျိုးတွင်၊ ပိုမိုကျိုးကြောင်းဆီလျော်သောချဉ်းကပ်မှုသည် #N/A အမှားများကိုသာ ပိတ်မိနေမည်ဖြစ်သည်။ ၎င်းအတွက်၊ Excel 2013 နှင့်အထက်ရှိ IFNA Vlookup ဖော်မြူလာကိုသုံးပါ၊ Excel ဗားရှင်းအားလုံးတွင် ISNA VLOOKUP ကိုသုံးပါ။

အဓိကအချက်မှာ- သင်၏ VLOOKUP ဖော်မြူလာအတွက် အဖော်ကိုရွေးချယ်ရာတွင် အလွန်သတိထားပါ။ :)

အောက်ပါအခြေအနေကို မြင်ယောင်ကြည့်ပါ- သင်သည် စာရင်းတစ်ခုရှိ တိကျသောတန်ဖိုးတစ်ခုကို ရှာဖွေပြီး ၎င်းကိုမတွေ့ပါ။ မင်းမှာ ဘာရွေးချယ်စရာတွေရှိလဲ။ N/A အမှားတစ်ခုရနိုင်သည် သို့မဟုတ် သင့်ကိုယ်ပိုင်မက်ဆေ့ချ်ကို ပြသပါ။ တကယ်တော့၊ တတိယရွေးချယ်စရာတစ်ခုရှိပါတယ် - သင်၏မူလတန်း vlookup မှားသွားပါက၊ သေချာပေါက်ရှိသောအရာတစ်ခုကိုရှာဖွေပါ။

ကျွန်ုပ်တို့၏ဥပမာကိုထပ်မံရယူပါ၊ တိုးချဲ့မှုတစ်ခုပြသမည့် ကျွန်ုပ်တို့အသုံးပြုသူများအတွက် ဒက်ရှ်ဘုတ်တစ်မျိုးကို ဖန်တီးကြပါစို့။ သီးခြားရုံးအရေအတွက်။ ဤအရာကဲ့သို့သော အရာ-

ဒါဆို D2 ရှိ ရုံးနံပါတ်ကို အခြေခံ၍ ကော်လံ B မှ extension ကို သင်မည်ကဲ့သို့ ဆွဲထုတ်မည်နည်း။ ဤပုံမှန် Vlookup ဖော်မြူလာဖြင့်-

=VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

ထို့ပြင် သင့်အသုံးပြုသူများသည် D2 တွင် မှန်ကန်သောနံပါတ်တစ်ခုထည့်သရွေ့ ၎င်းသည် ကောင်းမွန်စွာအလုပ်လုပ်မည်ဖြစ်ပါသည်။ သို့သော် အသုံးပြုသူတစ်ဦးသည် တည်ရှိခြင်းမရှိသော နံပါတ်အချို့ကို ထည့်သွင်းပါက မည်သို့နည်း။ ဒီကိစ္စမှာ ဗဟိုရုံးကို ခေါ်ပါစေ။ ဤအတွက်၊ သင်သည် အထက်ဖော်ပြပါ ပုံသေနည်းကို အဆိုပါနေရာတွင် ထည့်သွင်းပါ။IFERROR ၏ တန်ဖိုး အငြင်းအခုံဖြစ်ပြီး အခြား Vlookup ကို value_if_error အငြင်းအခုံတွင် ထည့်ပါ။

ပြီးပြည့်စုံသော ဖော်မြူလာမှာ အနည်းငယ်ရှည်သော်လည်း ၎င်းသည် ကောင်းမွန်စွာအလုပ်လုပ်ပါသည်-

=IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

ရုံးနံပါတ်ကို တွေ့ရှိပါက၊ အသုံးပြုသူသည် သက်ဆိုင်ရာ တိုးချဲ့နံပါတ်ကို ရရှိသည်-

ရုံးနံပါတ်ကို ရှာမတွေ့ပါက၊ ဗဟိုရုံးခွဲ ပြထားသည်-

ဖော်မြူလာနည်းနည်းပိုကျစ်လစ်စေရန်၊ သင်သည် မတူညီသောချဉ်းကပ်နည်းကိုသုံးနိုင်သည်-

ပထမဦးစွာ D2 တွင်နံပါတ်ရှိမရှိစစ်ဆေးပါ။ ရှာဖွေမှုကော်လံတွင် (ကော်လံ A မှတန်ဖိုးကိုရှာဖွေရန်နှင့်ပြန်ရန်ဖော်မြူလာအတွက် col_index_num ကို 1 သို့ သတ်မှတ်ကြောင်း ကျေးဇူးပြု၍ သတိပြုပါ) - VLOOKUP(D2,$A$2:$B$7,1,FALSE)

သတ်မှတ်ထားသော ရုံးနံပါတ်ကို ရှာမတွေ့ပါက၊ ရှာဖွေမှုစာရင်းတွင် သေချာပေါက်ဖြစ်သည့် "ဗဟိုရုံး" ဟူသော စာကြောင်းကို ကျွန်ုပ်တို့ ရှာဖွေပါသည်။ ၎င်းအတွက်၊ သင်သည် ပထမ VLOOKUP ကို ​​IFERROR တွင် ခြုံပြီး အခြား VLOOKUP လုပ်ဆောင်ချက်အတွင်းတွင် ဤပေါင်းစပ်မှုတစ်ခုလုံးကို အသိုက်ပြုလုပ်ပါ-

=VLOOKUP(IFERROR(VLOOKUP(D2,$A$2:$B$7,1,FALSE),"central office"),$A$2:$B$7,2)

အင်း၊ အနည်းငယ်ကွဲပြားသော ဖော်မြူလာ၊ တူညီသောရလဒ်-

ဒါပေမယ့် "ဗဟိုရုံး" ကို ရှာကြည့်ဖို့ ဘာအကြောင်းကြောင့်လဲလို့ မေးနိုင်ပါတယ်။ IFERROR တွင် တိုးချဲ့နံပါတ်ကို အဘယ်ကြောင့် တိုက်ရိုက်မပေးရသနည်း။ တိုးချဲ့မှုသည် အနာဂတ်တစ်ချိန်ချိန်တွင် ပြောင်းလဲနိုင်သောကြောင့်ဖြစ်သည်။ ထိုသို့ဖြစ်လာပါက၊ သင်၏ VLOOKUP ဖော်မြူလာတစ်ခုစီကို အပ်ဒိတ်လုပ်ရန် စိတ်မပူဘဲ အရင်းအမြစ်ဇယားတွင် တစ်ကြိမ်သာ သင့်ဒေတာကို အပ်ဒိတ်လုပ်ရမည်ဖြစ်ပါသည်။

Excel တွင် ဆက်တိုက် VLOOKUPs လုပ်နည်း

အခြေအနေများတွင်၊ သင်လုပ်ဖို့ ... လိုပါတယ် sequential သို့မဟုတ် chained Excel in Vlookups ဟုခေါ်သော ကြိုတင်ရှာဖွေမှု အောင်မြင်သည် သို့မဟုတ် မအောင်မြင်ခြင်းအပေါ် မူတည်၍ သင်၏ Vlookups တစ်ခုပြီးတစ်ခု လုပ်ဆောင်ရန် IFERROR လုပ်ဆောင်ချက်နှစ်ခု သို့မဟုတ် ထို့ထက်ပိုသော လုပ်ဆောင်ချက်များကို စုစည်းထားသည်-

The ဖော်မြူလာသည် အောက်ပါယုတ္တိဗေဒနှင့် အလုပ်လုပ်သည်-

ပထမ VLOOKUP သည် ဘာမှမတွေ့ပါက၊ ပထမ IFERROR သည် အမှားတစ်ခုကို ဖမ်းပြီး အခြား VLOOKUP ကို ​​လုပ်ဆောင်သည်။ ဒုတိယ VLOOKUP မအောင်မြင်ပါက ဒုတိယ IFERROR သည် error တစ်ခုဖမ်းပြီး တတိယ VLOOKUP ကို ​​run သည်။ Vlookups အားလုံး မှားသွားပါက၊ နောက်ဆုံး IFERROR သည် သင့်မက်ဆေ့ဂျ်ကို ပြန်ပေးပါသည်။

အောက်ပါဥပမာတွင် ပြထားသည့်အတိုင်း စာရွက်အများအပြား တွင် Vlookup ပြုလုပ်ရသည့်အခါတွင် အထူးအသုံးဝင်ပါသည်။

ဆိုပါစို့၊ သင့်တွင် မတူညီသော အလုပ်စာရွက်သုံးခု (ဤဥပမာရှိ ရုံးခန်းနံပါတ်များ) တွင် တစ်သားတည်းဖြစ်နေသော ဒေတာစာရင်းသုံးမျိုးရှိပြီး အချို့နံပါတ်များအတွက် တိုးချဲ့မှုတစ်ခုရယူလိုပါသည်။

ရှာဖွေမှုတန်ဖိုးသည် ဆဲလ် A2 တွင် ရှိနေသည်ဟု ယူဆရပါသည်။ လက်ရှိစာရွက်တွင်၊ ရှာဖွေမှုအပိုင်းအခြားသည် A2:B5 သည် မတူညီသောအလုပ်စာရွက် 3 ခုတွင် (မြောက်၊ တောင်နှင့် အနောက်)၊ အောက်ပါဖော်မြူလာသည် ကုသနည်းတစ်ခုဖြစ်သည်-

=IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

ထို့ကြောင့် ကျွန်ုပ်တို့၏ "သံကြိုးများ" Vlookups" ဖော်မြူလာသည် ၎င်းတို့ကို ဖော်မြူလာတွင် စုစည်းထားသည့် အစီအစဥ်ဖြင့် မတူညီသော အလွှာသုံးခုတွင် ဖော်မြူလာရှာဖွေပြီး ၎င်းကို တွေ့ရှိသည့် ပထမဆုံး ကိုက်ညီမှုအား ယူဆောင်လာပါသည်-

ဤသည်မှာ VLOOKUP တွင် IFERROR ကို သင်အသုံးပြုပုံဖြစ်သည်။ Excel။ ဖတ်ရှု့ပေးတဲ့အတွက် ကျေးဇူးပါလို့ မျှော်လင့်ပါတယ်။ကျွန်ုပ်တို့၏ဘလော့ဂ်တွင် လာမည့်အပတ်တွင်!

ရရှိနိုင်သော ဒေါင်းလုဒ်များ

Excel IFERROR VLOOKUP ဖော်မြူလာနမူနာများ