Excel IFERROR & VLOOKUP - ribe # N/A agus mearachdan eile

Michael Brown

27-05-2023 Excel
  • Roinn Seo
Michael Brown

San oideachadh seo, bidh sinn a’ coimhead air mar a chleachdas tu gnìomhan IFERROR agus VLOOKUP còmhla gus diofar mhearachdan a ghlacadh agus a làimhseachadh. A bharrachd air an sin, tha thu gu bhith ag ionnsachadh mar a nì thu vlookups sreath ann an Excel le bhith a’ neadachadh grunn ghnìomhan IFERROR aon air fear eile.

Excel VLOOKUP agus IFERROR - faodaidh gum bi an dà ghnìomh seo gu math doirbh a thuigsinn leotha fhèin, gun luaidh air nuair a thèid an cur còmhla. San artaigil seo, lorgaidh tu beagan eisimpleirean furasta a leantainn a tha a’ dèiligeadh ri cleachdaidhean cumanta agus a’ sealltainn loidsig nam foirmlean gu soilleir.

Mura h-eil mòran eòlas agad air gnìomhan IFERROR agus VLOOKUP, dh’ fhaodadh gur e 's e deagh bheachd a th' ann am bunaitean ath-sgrùdadh an toiseach le bhith a' leantainn nan ceanglaichean gu h-àrd.

    IFERROR VLOOKUP foirmle airson #N/A agus mearachdan eile a làimhseachadh

    Nuair nach lorg Excel Vlookup luach lorg, bidh e a’ tilgeil mearachd #N/A, mar seo:

    A rèir na feumalachdan gnìomhachais agad, is dòcha gum bi thu airson a’ mhearachd a chuir am falach leis an teacsa agad fhèin, neoni , neo cealla bàn.

    Eisimpleir 1. IFERROR le foirmle VLOOKUP gus an teacsa agad fhèin a chur an àite mhearachdan

    Ma tha thu airson teacsa àbhaisteach a chur an àite a' chomharra mearachd àbhaisteach, cuir a-steach do Foirmle VLOOKUP ann an IFERROR, agus taipidh teacsa sam bith a tha thu ag iarraidh san 2na argamaid ( value_if_error ), mar eisimpleir "Cha deach a lorg":

    IFERROR(VLOOKUP( …), "Cha deach lorg")

    Leis an luach lorg ann am B2 sa phrìomh chlàr agus an raon lorg A2:B4 anns an Lorgclàr, tha an cumadh a leanas air an fhoirmle:

    =IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

    Tha an dealbh-sgrìn gu h-ìosal a’ sealltainn ar foirmle Excel IFERROR VLOOKUP ann an gnìomh:

    The tha an toradh a’ coimhead tòrr nas so-thuigsinn agus fada nas eagallach, nach e?

    San aon dòigh, ’s urrainn dhut INDEX MATCH a chleachdadh còmhla ri IFERROR:

    =IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

    An IFERROR Tha foirmle INDEX MATCH gu sònraichte feumail nuair a tha thu airson luachan a tharraing à colbh a tha na laighe air taobh clì a' cholbh lorg (lorg clì), agus an teacsa agad fhèin a thilleadh nuair nach eil dad ri lorg.

    Eisimpleir 2. IFERROR le VLOOKUP gus tilleadh bàn neo 0 mura lorgar dad

    Mura h-eil thu airson dad a shealltainn nuair nach lorgar an luach sgrùdaidh, seall air IFERROR sreang falamh (""):

    IFERROR(VLOOKUP( …),"")

    Anns an eisimpleir againn, tha am foirmle a' dol mar a leanas:

    =IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

    Mar a chì thu, chan fhaigh e dad air ais nuair nach eil an luach lorg air an liosta rannsachaidh.

    Ma tha thu airson an luach neoni a chur an àite na mearachd, cuir 0 mu dheireadh a rgument:

    =IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

    Facal rabhadh! Bidh gnìomh Excel IFERROR a’ glacadh a h-uile seòrsa mearachd, chan e a-mhàin #N/A. A bheil e math no dona? Tha e uile an urra ris an amas agad. Ma tha thu airson a h-uile mearachd a dh’ fhaodadh a fhalach, is e IFERROR Vlookup an dòigh air adhart. Ach 's dòcha gur e innleachd neo-ghlic a tha ann an iomadh suidheachadh.

    Mar eisimpleir, ma tha thu air raon ainmichte a chruthachadh airson dàta a' bhùird agad, agus ma tha an t-ainm sin air a litreachadh ceàrr nadFoirmle vlookup, glacaidh IFERROR #NAME? mearachd agus cuir “Cha deach a lorg” no teacsa sam bith eile a bheir thu seachad na àite. Mar thoradh air an sin, is dòcha nach bi fios agad gu bheil am foirmle agad a’ lìbhrigeadh toraidhean ceàrr mura faic thu an typo thu fhèin. Ann an leithid de chùis, cha bhiodh dòigh-obrach nas reusanta a’ glacadh ach #N/A mhearachdan. Airson seo, cleachd foirmle IFNA Vlookup ann an Excel 2013 agus nas àirde, IF ISNA VLOOKUP anns a h-uile dreach Excel.

    Is e an loidhne gu h-ìosal: bi faiceallach nuair a thaghas tu companach airson na foirmle VLOOKUP agad :)

    Neadaich IFERROR taobh a-staigh VLOOKUP gus rudeigin a lorg an-còmhnaidh

    Smaoinich air an t-suidheachadh a leanas: seallaidh tu suas luach sònraichte ann an liosta agus cha lorg thu e. Dè na roghainnean a th’ agad? An dàrna cuid faigh mearachd N/A no seall do theachdaireachd fhèin. Gu fìrinneach, tha treas roghainn ann - ma thuislich do phrìomh vlookup, an uairsin lorg rudeigin eile a tha gu cinnteach ann!

    A’ toirt ar n-eisimpleir nas fhaide air adhart, cruthaichidh sinn deas-bhòrd de sheòrsa air choreigin don luchd-cleachdaidh againn a sheallas leudachadh dhaibh àireamh oifis shònraichte. Rud mar seo:

    Mar sin, ciamar a tharraingeas tu an leudachadh à colbh B stèidhichte air àireamh na h-oifis ann an D2? Leis an fhoirmle àbhaisteach Vlookup seo:

    =VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

    Agus obraichidh e gu math fhad ‘s a chuireas an luchd-cleachdaidh agad a-steach àireamh dhligheach ann an D2. Ach dè ma chuireas neach-cleachdaidh a-steach àireamh air choreigin nach eil ann? Anns a 'chùis seo, leig leotha fios a chur chun phrìomh oifis! Airson seo, cuiridh tu am foirmle gu h-àrd a-steach don fhaidhle luach argamaid IFERROR, is cuir Vlookup eile san argamaid value_if_error .

    Tha am foirmle iomlan beagan fada, ach obraichidh e gu math:

    > =IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

    Ma lorgar àireamh na h-oifis, gheibh an cleachdaiche an àireamh leudachaidh fhreagarrach:

    Mura lorgar àireamh na h-oifis, leudaich am prìomh oifis air a thaisbeanadh:

    Gus am foirmle a dhèanamh beagan nas toinnte, faodaidh tu dòigh eile a chleachdadh:

    An toiseach, dèan cinnteach a bheil an àireamh ann an D2 an làthair sa cholbh lorg (thoir an aire gun do shuidhich sinn col_index_num gu 1 airson an fhoirmle a choimhead agus luach a thilleadh bho cholbh A): VLOOKUP(D2,$A$2:$B$7,1,FALSE)

    Mura lorgar an àireamh oifis ainmichte, lorgaidh sinn an t-sreang “central office”, a tha gu cinnteach air an liosta sgrùdaidh. Airson seo, bidh thu a’ pasgadh a’ chiad VLOOKUP ann an IFERROR agus a’ neadachadh am measgachadh slàn seo am broinn gnìomh VLOOKUP eile:

    =VLOOKUP(IFERROR(VLOOKUP(D2,$A$2:$B$7,1,FALSE),"central office"),$A$2:$B$7,2)

    Uill, foirmle beagan eadar-dhealaichte, an aon toradh:

    Ach dè an t-adhbhar a th’ ann a bhith a’ coimhead suas “prìomh oifis”, faodaidh tu faighneachd dhomh. Carson nach toir thu seachad àireamh an leudachaidh gu dìreach ann an IFERROR? Leis gum faodadh an leudachadh atharrachadh aig àm air choreigin san àm ri teachd. Ma thachras seo, bidh agad ris an dàta agad ùrachadh dìreach aon turas sa chlàr stòr, gun a bhith draghail mu bhith ag ùrachadh gach foirmle VLOOKUP agad.

    Mar a nì thu VLOOKUPs sreath ann an Excel

    Ann an suidheachaidhean nuair Feumaidh tudèan na Vlookups sreath no ris an canar ann an Excel a rèir an do shoirbhich le rannsachadh ro-làimh no nach do dh'fhàillig, neadaich dà ghnìomh IFERROR no barrachd gus na Vlookups agad a ruith aon ri aon:

    IFERROR(VLOOKUP( …), IFERROR(VLOOKUP( …), IFERROR(VLOOKUP( …),,"Cha deach a lorg"))

    The obraichidh foirmle leis an loidsig a leanas:

    Mura lorg a’ chiad VLOOKUP dad, bidh a’ chiad IFERROR a’ glacadh mearachd agus a’ ruith VLOOKUP eile. Ma dh’ fhailicheas an dàrna VLOOKUP, glacaidh an dàrna IFERROR mearachd agus ruithidh e an treas VLOOKUP, agus mar sin air adhart. Ma thuislicheas a h-uile Vlookups, tillidh an IFERROR mu dheireadh am brath agad.

    Tha am foirmle neadachaidh IFERROR seo gu h-àraidh feumail nuair a dh'fheumas tu Vlookup a dhèanamh thairis air ioma-dhuilleag mar a chithear san eisimpleir gu h-ìosal.

    Canaidh sinn, tha trì liostaichean de dhàta aon-ghnèitheach agad ann an trì duilleagan-obrach eadar-dhealaichte (àireamhan oifis san eisimpleir seo), agus tha thu airson leudachadh fhaighinn airson àireamh sònraichte.

    A’ gabhail ris gu bheil an luach lorg ann an ceal A2 anns an duilleag làithreach, agus is e an raon sgrùdaidh A2:B5 ann an 3 duilleagan-obrach eadar-dhealaichte (Tuath, Deas is Iar), tha am foirmle a leanas ag obrachadh co-chòrdadh:

    =IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

    Mar sin, tha ar "slabhraidh" Bidh foirmle Vlookups" a' rannsachadh ann an trì duilleagan eadar-dhealaichte san òrdugh san do neadaich sinn iad san fhoirmle, agus a' toirt a' chiad mhaidse a lorgas e:

    Seo mar a chleachdas tu IFERROR le VLOOKUP ann an Excel. Tha mi a’ toirt taing dhut airson an leughadh agus tha mi an dòchas d’ fhaicinnair ar blog an ath sheachdain!

    Luchdaich a-nuas ri fhaighinn

    Eisimpleirean foirmle Excel IFERROR VLOOKUP

    Post roimhe Gnìomh Excel AVERAGEIFS le grunn shlatan-tomhais
    An ath phost Gnìomh Google Sheets IF - eisimpleirean cleachdaidh agus foirmle

    Tha Mìcheal Brown dèidheil air teicneòlas sònraichte le dìoghras airson pròiseasan iom-fhillte a dhèanamh nas sìmplidhe a’ cleachdadh innealan bathar-bog. Le còrr air deich bliadhna de eòlas anns a’ ghnìomhachas teignigeach, tha e air urram a thoirt dha na sgilean aige ann am Microsoft Excel agus Outlook, a bharrachd air Google Sheets agus Docs. Tha blog Mhìcheil gu sònraichte airson a chuid eòlais agus eòlais a cho-roinn le daoine eile, a’ toirt seachad molaidhean agus clasaichean-oideachaidh a tha furasta a leantainn airson cinneasachd agus èifeachdas a leasachadh. Ge bith co-dhiù a tha thu nad neach-proifeiseanta eòlach no nad neach-tòiseachaidh, tha blog Mhìcheal a 'tabhann lèirsinn luachmhor agus comhairle phractaigeach airson a bhith a' faighinn a 'chuid as fheàrr às na h-innealan bathar-bog riatanach sin.