Dina tutorial ieu, urang bakal ningali kumaha ngagunakeun fungsi IFERROR sareng VLOOKUP babarengan pikeun bubu sareng nanganan kasalahan anu béda. Salaku tambahan, anjeun bakal diajar kumaha ngalakukeun vlookups sequential dina Excel ku nyarang sababaraha fungsi IFERROR hiji kana anu sanés.

Excel VLOOKUP sareng IFERROR - dua pungsi ieu tiasa sesah kahartos nyalira, sumawona nalika digabungkeun. Dina artikel ieu, anjeun bakal mendakan sababaraha conto anu gampang diturutan anu ngémutan kagunaan umum sareng jelas ngagambarkeun logika rumus.

Upami anjeun teu gaduh seueur pangalaman sareng fungsi IFERROR sareng VLOOKUP, éta tiasa waé. mangrupakeun ide nu sae pikeun ngarévisi dasarna heula ku nuturkeun tumbu di luhur.

Rumus IFERROR VLOOKUP pikeun nanganan #N/A jeung kasalahan séjénna

Nalika Excel Vlookup gagal manggihan nilai lookup, éta ngalungkeun kasalahan #N/A, kawas kieu:

Gumantung kana kabutuhan bisnis Anjeun, Anjeun meureun hoyong nyamur kasalahan ku téks sorangan, nol , atawa sél kosong.

Conto 1. IFERROR nganggo rumus VLOOKUP pikeun ngaganti kasalahan ku téks anjeun sorangan

Upami anjeun hoyong ngagentos notasi kasalahan standar sareng téks khusus anjeun, bungkus anjeun Rumus VLOOKUP dina IFERROR, sareng ketik téks naon waé anu anjeun pikahoyong dina argumen ka-2 ( value_if_error ), contona "Teu kapanggih":

Kalayan nilai lookup dina B2 dina tabel Utama jeung rentang lookup A2:B4 dina Lookuptabél, rumusna bentukna kieu:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

Potret layar di handap nembongkeun rumus Excel IFERROR VLOOKUP dina aksi:

The Hasilna katingalina langkung kaharti sareng henteu pikasieuneun, sanés?

Ku cara anu sami, anjeun tiasa nganggo INDEKS MATCH sareng IFERROR:

=IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

IFERROR. Rumus INDEX MATCH hususna kapaké nalika anjeun badé narik niléy tina kolom anu aya di kénca kolom lookup (lookup kénca), sareng mulangkeun téks anjeun nyalira nalika teu aya anu kapendak.

Conto 2. IFERROR sareng VLOOKUP pikeun mulang kosong atanapi 0 upami teu aya anu kapendak

Upami anjeun henteu hoyong nunjukkeun naon waé nalika nilai panéangan henteu kapendak, kéngingkeun IFERROR nunjukkeun string kosong (""):

Dina conto urang, rumusna kieu:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

Sakumaha nu katingali, teu mulangkeun nanaon lamun nilai lookup teu aya dina daptar pilarian.

Upami anjeun hoyong ngaganti kasalahan ku nilai nol , nempatkeun 0 dina panungtungan a rgument:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

Perhatian! Fungsi Excel IFERROR nangkep sagala rupa kasalahan, henteu ngan ukur #N/A. Éta hadé atawa goréng? Sadayana gumantung kana tujuan anjeun. Upami anjeun hoyong nyumputkeun sadaya kasalahan anu mungkin, IFERROR Vlookup mangrupikeun jalan. Tapi éta bisa jadi téknik anu teu wijaksana dina loba kaayaan.

Contona, lamun anjeun geus nyieun rentang ngaranna pikeun data tabel anjeun, sarta salah ngeja ngaran éta dina anjeun.Rumus Vlookup, IFERROR bakal nyekel #NAME? kasalahan sarta ngaganti eta ku "Teu kapanggih" atawa téks séjén nu nyadiakeun. Hasilna, anjeun moal pernah terang yén rumus anjeun nganteurkeun hasil anu salah kecuali anjeun ningali kasalahanana sorangan. Dina kasus sapertos kitu, pendekatan anu langkung wajar bakal ngan ukur nangkep kasalahan #N/A. Jang ngalampahkeun ieu, paké rumus IFNA Vlookup dina Excel 2013 sareng anu langkung luhur, IF ISNA VLOOKUP dina sadaya vérsi Excel.

Intina nyaéta: ati-ati pisan nalika milih pendamping pikeun rumus VLOOKUP anjeun :)

Nest IFERROR dina VLOOKUP pikeun salawasna neangan hiji hal

Bayangkeun kaayaan di handap ieu: Anjeun néangan up a nilai husus dina daptar tur teu manggihan eta. Naon pilihan anjeun gaduh? Boh meunang kasalahan N / A atawa némbongkeun pesen anjeun sorangan. Sabenerna, aya pilihan katilu - lamun vlookup primér anjeun kasandung, teras neangan hal sejenna nu pasti aya!

Nyandak conto urang salajengna, hayu urang nyieun sababaraha jenis dasbor pikeun pamaké urang nu bakal némbongkeun aranjeunna extension. jumlah hiji kantor husus. Sapertos kieu:

Jadi, kumaha carana narik ekstensi ti kolom B dumasar kana nomer kantor di D2? Kalayan rumus Vlookup biasa ieu:

=VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

Jeung éta bakal jalan nicely salami pamaké anjeun ngasupkeun nomer valid dina D2. Tapi kumaha upami pangguna ngalebetkeun sababaraha nomer anu henteu aya? Dina hal ieu, hayu aranjeunna nelepon kantor puseur! Jang ngalampahkeun ieu, anjeun ngasupkeun rumus di luhur dina value argumen IFERROR, sarta nempatkeun Vlookup sejen dina value_if_error argumen.

Rumus lengkepna rada panjang, tapi jalanna sampurna:

=IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

Upami nomer kantor kapanggih, pangguna nampi nomer ekstensi anu cocog:

Upami nomer kantor teu kapendak, ekstensi kantor pusat dipintonkeun:

Pikeun nyieun rumus rada kompak, Anjeun bisa make pendekatan nu beda:

Kahiji, pariksa naha nomer dina D2 aya. dina kolom lookup (mangga perhatikeun yén kami nyetél col_index_num ka 1 pikeun rumus pikeun milarian sareng ngabalikeun nilai tina kolom A): VLOOKUP(D2,$A$2:$B$7,1,FALSE)

Upami nomer kantor anu ditunjuk henteu kapendak, teras urang milarian string "kantor pusat", anu pasti aya dina daptar milarian. Pikeun ieu, anjeun mungkus VLOOKUP munggaran dina IFERROR sareng nyarang kombinasi ieu di jero fungsi VLOOKUP anu sanés:

=VLOOKUP(IFERROR(VLOOKUP(D2,$A$2:$B$7,1,FALSE),"central office"),$A$2:$B$7,2)

Muhun, rumus anu rada béda, hasilna sami:

Tapi naon sababna milarian "kantor pusat", anjeun tiasa naros ka kuring. Naha henteu nyayogikeun nomer ekstensi langsung di IFERROR? Kusabab extension bisa robah di sawatara titik di mangsa nu bakal datang. Upami ieu kajantenan, anjeun kedah ngapdet data anjeun ngan sakali dina tabel sumber, tanpa hariwang ngeunaan ngapdet unggal rumus VLOOKUP anjeun.

Kumaha cara ngalakukeun VLOOKUP anu berurutan dina Excel

Dina kaayaan nalika Anjeun kedahngalakukeun nu disebut sequential atawa chained Vlookups dina Excel gumantung kana naha pilarian saméméhna suksés atawa gagal, sarang dua atawa leuwih fungsi IFERROR pikeun ngajalankeun Vlookups anjeun hiji-hiji:

The rumus jalan kalawan logika handap:

Lamun VLOOKUP kahiji teu manggihan nanaon, IFERROR kahiji bubu kasalahan sarta ngajalankeun VLOOKUP sejen. Lamun VLOOKUP kadua gagal, IFERROR kadua nyekel kasalahan sarta ngajalankeun VLOOKUP katilu, jeung saterusna. Upami sadaya Vlookups kasandung, IFERROR anu terakhir bakal ngabalikeun pesen anjeun.

Rumus IFERROR bersarang ieu hususna kapaké nalika anjeun kedah Vlookup dina sababaraha lembar sapertos anu dipidangkeun dina conto di handap ieu.

Sebutkeun, anjeun gaduh tilu daptar data homogen dina tilu lembar kerja anu béda (nomer kantor dina conto ieu), sareng anjeun badé kéngingkeun ekstensi pikeun nomer anu tangtu.

Anggap nilai panéangan aya dina sél A2 dina lembar ayeuna, sarta rentang lookup nyaeta A2:B5 dina 3 lembar kerja béda (Kalér, Kidul jeung Kulon), rumus di handap dianggo saréat:

=IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

Jadi, urang "dirantai" Vlookups" rumus milarian dina tilu lembar anu béda dina urutan anu kami sarangkeun dina rumus, sareng ngahasilkeun pertandingan anu munggaran anu dipendakan:

Kieu kumaha anjeun nganggo IFERROR sareng VLOOKUP dina Excel. Kuring hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningalidina blog urang minggu hareup!

Sadia undeuran

Excel IFERROR VLOOKUP conto rumus