Təlimat çoxlu şərtləri yoxlamaq üçün Excel-də iç-içə IF funksiyasından necə istifadə olunacağını izah edir. Siz Excel-də iç-içə düsturdan istifadə etmək üçün yaxşı alternativ ola biləcək bir neçə digər funksiyaları da öyrənəcəksiniz.

Siz adətən Excel iş vərəqlərində qərar qəbul etmə məntiqini necə tətbiq edirsiniz? Əksər hallarda, vəziyyətinizi yoxlamaq üçün ƏGƏR düsturundan istifadə edərdiniz və şərt yerinə yetirildikdə bir dəyəri, şərt yerinə yetirilmədikdə başqa bir dəyəri qaytarardınız. Birdən çox şərti qiymətləndirmək və nəticələrdən asılı olaraq müxtəlif dəyərləri qaytarmaq üçün siz bir-birinizin içərisinə çoxsaylı İF-ləri yerləşdirirsiniz.

Çox populyar olsa da, iç-içə IF ifadəsi Excel-də çoxlu şərtləri yoxlamağın yeganə yolu deyil. Bu dərslikdə siz mütləq araşdırmağa dəyər olan bir neçə alternativ tapacaqsınız.

Excel iç içə IF ifadəsi

Budur, ümumi formada klassik Excel iç içə IF düsturu :

Siz görə bilərsiniz ki, hər bir sonrakı IF funksiyası əvvəlki funksiyanın value_if_false arqumentinə daxil edilib. Hər bir ƏGƏR funksiyası öz mötərizələr dəstinə daxil edilmişdir, lakin bütün bağlanan mötərizələr düsturun sonundadır.

Ümumi iç-içə IF düsturumuz 3 şərti qiymətləndirir və 4 fərqli nəticə qaytarır (nəticə 4 qaytarılır) heç biri əgərendirmək üçün iş kitabı

Excel nested If ifadəsi - nümunələr (.xlsx faylı)

test şərt2 , DOĞRU olarsa - r nəticə2 qaytarın, YANLIŞ -

test şərt3 , DOĞRU olarsa - nəticə3 qaytarın, əgər YANLIŞ -

qaytarma nəticə4

Nümunə olaraq, bir sıra satıcılar üçün etdikləri satışların məbləğinə əsasən komissiyaları öyrənək:

Riyaziyyatda toplanmaların sırasını dəyişmək cəmi dəyişmir. Excel-də IF funksiyalarının sırasının dəyişdirilməsi nəticəni dəyişir. Niyə? Çünki iç-içə IF formulu ilk TRUE şərtinə uyğun gələn dəyəri qaytarır. Buna görə də, iç-içə IF ifadələrinizdə şərtləri düzgün istiqamətdə - formulunuzun məntiqindən asılı olaraq yüksəkdən aşağıya və ya aşağıdan yuxarıya - təşkil etmək çox vacibdir. Bizim vəziyyətimizdə əvvəlcə "ən yüksək" şərti, sonra "ikinci ən yüksək" şərti yoxlayırıq və s.:

=IF(B2>150, 10%, IF(B2>=101, 7%, IF(B2>=51, 5%, IF(B2>=1, 3%, ""))))

Əgər biz şərtləri tərs qaydada, aşağıdan yuxarıya doğru tərtib etsəniz, nəticələr səhv olardı, çünki düsturumuz 1-dən böyük hər hansı bir dəyər üçün ilk məntiqi testdən (B2>=1) sonra dayanacaq. Tutaq ki, bizdə 100 dollar var.satışda - 1-dən böyükdür, ona görə də düstur digər şərtləri yoxlamaz və nəticə olaraq 3% qaytarır.

Şərtləri aşağıdan yuxarıya doğru təşkil etmək istəyirsinizsə, o zaman "az"dan istifadə edin. " operatorunu işlədin və əvvəlcə "ən aşağı" şərti, sonra "ikinci ən aşağı" şərti və s. qiymətləndirin:

=IF($B2<1, 0%, IF($B2<51, 3%, IF($B2<101, 5%, IF($B2<=150, 7%, 10%))))

Gördüyünüz kimi, məntiqi qurmaq üçün kifayət qədər düşünmək lazımdır. iç içə IF ifadəsinin sonuna qədər düzgün. Microsoft Excel 64-ə qədər IF funksiyasını bir düsturda yerləşdirməyə icazə versə də, bu, həqiqətən iş vərəqlərində etmək istədiyiniz bir şey deyil. Beləliklə, əgər siz (və ya başqası) Excel daxili IF düsturunuza baxırsınızsa, onun əslində nə etdiyini anlamağa çalışırsınızsa, strategiyanıza yenidən baxmağın və yəqin ki, arsenalınızda başqa alət seçməyin vaxtıdır.

Ətraflı məlumat üçün. , lütfən, Excel-in iç içə IF ifadəsinə baxın.

VƏZƏ/VƏ şərtləri ilə iç-içə IF

Bir neçə müxtəlif şərtlər toplusunu qiymətləndirmək lazım gələrsə, siz OR-dan istifadə edərək həmin şərtləri ifadə edə bilərsiniz. VƏ funksiyası, funksiyaları IF ifadələrinin içinə yerləşdirin və sonra IF ifadələrini bir-birinə yerləşdirin.

VƏ ya ifadələri ilə Excel-də iç-içə IF

VEYA funksiyasından istifadə etməklə siz iki və ya daha çoxunu yoxlaya bilərsiniz. hər IF funksiyasının məntiqi testində müxtəlif şərtlər və OR arqumentlərindən hər hansı (ən azı biri) DOĞRU olaraq qiymətləndirilərsə, TRUE qaytarın. Bunun həqiqətən necə işlədiyini görmək üçün, lütfən, nəzərdən keçirinaşağıdakı misal.

Fərz edək ki, sizdə iki satış sütunu var, deyək ki, B sütununda yanvar satışları və C sütununda fevral satışları. Siz hər iki sütundakı rəqəmləri yoxlamaq və daha yüksək rəqəm əsasında komissiya hesablamaq istəyirsiniz. Başqa sözlə, siz aşağıdakı məntiqlə düstur qurursunuz: əgər yanvar və ya fevral satışları 150 dollardan çox olarsa, satıcı 10% komissiya alır, yanvar və ya fevral satışları 101 dollardan çox və ya ona bərabərdirsə, satıcı 7% komissiya alır. , və s.

Bunu yerinə yetirmək üçün OR(B2>150, C2>150) kimi bir neçə OF ifadəsini yazın və onları yuxarıda müzakirə olunan IF funksiyalarının məntiqi testlərinə yerləşdirin. Nəticədə, siz bu düstur alırsınız:

=IF(OR(B2>150, C2>150), 10%, IF(OR(B2>=101, C2>=101),7%, IF(OR(B2>=51, C2>=51), 5%, IF(OR(B2>=1, C2>=1), 3%, ""))))

Və daha yüksək satış məbləğinə əsasən komissiya təyin edin:

Üçün daha çox düstur nümunəsi üçün lütfən, Excel IF OR ifadəsinə baxın.

VƏ ifadələri ilə Excel-də iç-içə IF

Məntiqi testlərinizə çoxsaylı şərtlər daxildirsə və bütün bu şərtlər DOĞRU olaraq qiymətləndirilməlidirsə, onları ifadə edin. AND funksiyasından istifadə etməklə.

Məsələn, daha az satış sayına əsasən komissiyalar təyin etmək üçün yuxarıdakı düsturdan istifadə edin və OR-u AND ifadələri ilə əvəz edin. Başqa cür desək, siz Excel-ə deyirsiniz ki, yalnız yanvar və fevral satışları 150 dollardan çox olarsa 10%, yanvar və fevral satışları 101 dollardan çox və ya ona bərabər olarsa 7% və s.

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, ""))))

Nəticədə iç içə IF düsturumuz komissiyanı hesablayırB və C sütunlarında aşağı rəqəmə əsaslanır. Əgər sütun boşdursa, heç bir komissiya yoxdur, çünki AND şərtlərinin heç biri yerinə yetirilmir:

Əgər siz' d boş xanalar əvəzinə 0% qaytarmaq istər, sonuncu arqumentdəki boş sətri (''") 0% ilə əvəz edin:

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, 0%))))

Ətraflı məlumatı burada tapa bilərsiniz: Çoxlu VƏ/VƏ ya şərtləri olan Excel IF.

Excel-də iç içə IF əvəzinə VLOOKUP

Siz "miqyas", yəni ədədi dəyərlərin davamlı diapazonları ilə məşğul olduqda birlikdə bütün diapazonu əhatə edir, əksər hallarda siz daxili IF-lər əvəzinə VLOOKUP funksiyasından istifadə edə bilərsiniz.

Başlanğıclar üçün aşağıdakı skrinşotda göstərildiyi kimi istinad cədvəli hazırlayın. Sonra təxmini uyğunluq , yəni aralıq_axtarış arqumenti DOĞRU olaraq təyin olunduqda.

Axtarış dəyərinin B2-də olduğunu və istinad cədvəlinin F2:G5 olduğunu fərz etsək, düstur aşağıdakı kimi gedir :

=VLOOKUP(B2,$F$2:$G$5,2,TRUE)

Lütfən, qeyd edin ki, biz cədvəl_massivi -ni mütləq istinadlarla düzəldirik ($F$2:$G$5) formulun digər xanalara düzgün surətdə kopyalanması üçün:

Vlookup düsturunuzun son arqumentini DOĞRU olaraq təyin etməklə, Excel-ə bildirin ən yaxın uyğunluğu axtarın - əgər dəqiq uyğunluq tapılmazsa, axtarış dəyərindən kiçik olan növbəti ən böyük dəyəri qaytarın. Nəticədə, düsturunuz yalnız axtarış cədvəlindəki dəqiq dəyərlərə deyil, həm də hər hansı birinə uyğun olacaqarasına düşən dəyərlər.

Məsələn, B3-də axtarış dəyəri $95-dir. Bu nömrə axtarış cədvəlində yoxdur və dəqiq uyğunluğu olan Vlookup bu halda #N/A xətası qaytaracaq. Lakin təxmini uyğunluğu olan Vlookup axtarış dəyərindən az olan ən yaxın dəyəri tapana qədər axtarışa davam edir (bu, bizim nümunəmizdə 50 dollardır) və eyni cərgənin ikinci sütunundan dəyəri qaytarır (bu, 5%).

Bəs əgər axtarış dəyəri axtarış cədvəlindəki ən kiçik rəqəmdən azdırsa və ya axtarış xanası boşdursa necə? Bu halda, Vlookup düsturu #N/A xətasını qaytaracaq. Əgər həqiqətən istədiyiniz kimi deyilsə, VLOOKUP-u IFERROR-da yerləşdirin və axtarış dəyəri tapılmadıqda çıxış üçün dəyəri təmin edin. Məsələn:

=IFERROR(VLOOKUP(B2, $F$2:$G$5, 2, TRUE), "Outside range")

Vacib qeyd! Təxmini uyğunluğu olan Vlookup düsturunun düzgün işləməsi üçün axtarış cədvəlindəki ilk sütun artan qaydada , kiçikdən böyüyə doğru çeşidlənməlidir.

Ətraflı məlumat üçün, lütfən, Tam uyğunluğa baxın. VLOOKUP və təqribi uyğunluq VLOOKUP.

İçlənmiş ƏGƏR funksiyasına alternativ olaraq IFS bəyanatı

Excel 2016 və sonrakı versiyalarda Microsoft çoxsaylı şərtləri qiymətləndirmək üçün xüsusi funksiya təqdim etdi - IFS funksiyası.

IFS düsturu 127-ə qədər məntiqi_test / həqiqi_əgər_dəyər cütünü idarə edə bilər və TRUE olaraq qiymətləndirilən ilk məntiqi test "qalib":

Yuxarıdakı sintaksisə uyğun olaraq, iç içə IF düsturumuz bu şəkildə yenidən qurula bilər:

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%)

Lütfən, diqqət yetirin ki, Göstərilən şərtlərdən heç biri yerinə yetirilmədikdə IFS funksiyası #N/A xətası qaytarır. Bunun qarşısını almaq üçün düsturunuzun sonuna daha bir məntiqi_test / əgər_əgər_əgər_dəyər əlavə edə bilərsiniz ki, bu da 0 və ya boş sətir ("") qaytaracaq və ya heç biri yoxdursa, istədiyiniz dəyəri verəcəkdir. əvvəlki məntiqi testlər DOĞRUDUR:

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%, TRUE, "")

Nəticədə B sütununda müvafiq xana olarsa, düsturumuz #N/A xətası əvəzinə boş sətir (boş xana) qaytaracaq. boş və ya mətn və ya mənfi rəqəm ehtiva edir.

Qeyd. İçəri daxil edilmiş IF kimi, Excel-in IFS funksiyası DOĞRU olaraq qiymətləndirilən birinci şərtə uyğun olan dəyəri qaytarır, buna görə də IFS düsturunda məntiqi testlərin ardıcıllığı vacibdir.

Ətraflı məlumat üçün bunun əvəzinə Excel IFS funksiyasına baxın. iç içə IF.

Excel-də iç-içə IF düsturu yerinə SEÇİN

Excel-də bir düstur daxilində çoxlu şərtləri sınamağın başqa bir yolu SEÇİN funksiyasından istifadə etməkdir. siyahı həmin dəyərin mövqeyinə əsaslanır.

Nümunə verilənlər bazamıza tətbiq edilən düstur aşağıdakı formanı alır:

=CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%)

Birinci arqumentdə ( index_num ), siz bütün şərtləri qiymətləndirirsiniz və nəticələri əlavə edirsiniz. verilmişki, TRUE 1-ə, FALSE isə 0-a bərabərdir, bu yolla siz qaytarılacaq dəyərin mövqeyini hesablayırsınız.

Məsələn, B2-dəki dəyər 150 dollardır. Bu dəyər üçün ilk 3 şərt DOĞRU, sonuncu (B2 > 150) isə YANLIŞ-dır. Beləliklə, index_num 3-ə bərabərdir, yəni 3-cü dəyər qaytarılır, bu da 7% təşkil edir.

İpucu. Məntiqi testlərdən heç biri DOĞRU deyilsə, index_num 0-a bərabərdir və düstur #VALUE! səhv. Asan bir düzəliş, SEÇİM funksiyasını IFERROR funksiyasına belə bağlamaqdır:

=IFERROR(CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%), "")

Ətraflı məlumat üçün düstur nümunələri ilə Excel CHOOSE funksiyasına baxın.

Excel-də iç-içə IF-in qısa forması kimi SWITCH funksiyası

Ölkələrlə deyil, əvvəlcədən təyin edilmiş sabit dəyərlər dəsti ilə məşğul olduğunuz hallarda, SWITCH funksiyası kompleksə kompakt alternativ ola bilər. iç içə IF ifadələri:

SWITCH funksiyası ifadə -ni dəyərlər siyahısına qarşı qiymətləndirir və ilk tapılmış uyğunluğa uyğun nəticəni qaytarır.

Siz komissiyanı satış məbləğləri deyil, aşağıdakı qiymətlər əsasında hesablamaq istəsəniz, bu kompaktdan istifadə edə bilərsiniz. Excel-də iç-içə IF düsturunun versiyası:

=SWITCH(C2, "A", 10%, "B", 7%, "C", 5%, "D", 3%, "")

Və ya aşağıdakı ekran görüntüsündə göstərildiyi kimi istinad cədvəli yarada və sərt kodlanmış dəyərlər əvəzinə xana istinadlarından istifadə edə bilərsiniz:

=SWITCH(C2, $F$2, $G$2, $F$3, $G$3, $F$4, $G$4, $F$5, $G$5, "")

Zəhmət olmasaDiqqət yetirin ki, biz birincidən başqa bütün istinadları $ işarəsi ilə kilidləyirik ki, düsturun digər xanalara köçürülməsi zamanı dəyişməsin:

Qeyd. SWITCH funksiyası yalnız Excel 2016 və daha yeni versiyalarda mövcuddur.

Ətraflı məlumat üçün lütfən, SWITCH funksiyasına baxın - iç içə IF ifadəsinin yığcam forması.

Excel-də çoxsaylı IF funksiyalarının birləşdirilməsi

Əvvəlki misalda qeyd edildiyi kimi, SWITCH funksiyası yalnız Excel 2016-da təqdim edilib. Köhnə Excel versiyalarında oxşar tapşırıqları yerinə yetirmək üçün siz Concatenate operatorundan (&) və ya CONCATENATE funksiyasından istifadə etməklə iki və ya daha çox ƏGƏR ifadəsini birləşdirə bilərsiniz. .

Məsələn:

=(IF(C2="a", 10%, "") & IF(C2="b", 7%, "") & IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Vəya

=CONCATENATE(IF(C2="a", 10%, ""), IF(C2="b", 7%, ""), IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Sizdə olduğu kimi fərq etdikdə, hər iki düsturda nəticəni 1-ə vururuq. Concatenate düsturunun qaytardığı sətri ədədə çevirmək üçün edilir. Əgər gözlənilən nəticə mətndirsə, onda vurma əməliyyatına ehtiyac yoxdur.

Ətraflı məlumat üçün Excel-də CONCATENATE funksiyasına baxın.

Microsoft Excel-in bir neçə yaxşı alternativ təqdim etdiyini görə bilərsiniz. iç içə IF düsturlarına və ümid edirəm ki, bu dərslik sizə iş vərəqlərində onlardan necə istifadə etməyiniz barədə bəzi ipucular verdi. Bu dərslikdə müzakirə olunan nümunələrə daha yaxından baxmaq üçün aşağıdakı nümunə iş dəftərimizi yükləyə bilərsiniz. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

Məşq edin