Ուսուցումը բացատրում է, թե ինչպես օգտագործել Excel-ում տեղադրված IF ֆունկցիան՝ մի քանի պայմաններ ստուգելու համար: Դուք նաև կսովորեք մի քանի այլ գործառույթներ, որոնք կարող են լավ այլընտրանք լինել Excel-ում ներկառուցված բանաձևի օգտագործման համար:

Ինչպե՞ս եք սովորաբար իրականացնում որոշումների կայացման տրամաբանությունը ձեր Excel-ի աշխատաթերթերում: Շատ դեպքերում, դուք պետք է օգտագործեք IF բանաձևը ձեր պայմանը ստուգելու համար և վերադարձնեք մեկ արժեք, եթե պայմանը բավարարված է, ևս մեկ արժեք, եթե պայմանը չկատարվի: Մեկից ավելի պայմաններ գնահատելու և արդյունքներից կախված տարբեր արժեքներ վերադարձնելու համար դուք տեղադրում եք մի քանի IF-ներ միմյանց ներսում:

Չնայած շատ տարածված է, բայց IF ցուցումը Excel-ում բազմաթիվ պայմաններ ստուգելու միակ միջոցը չէ: Այս ձեռնարկում դուք կգտնեք մի քանի այլընտրանքներ, որոնք անպայման արժե ուսումնասիրել:

Excel nested IF հայտարարություն

Ահա դասական Excel-ի մեջ տեղադրված IF բանաձևը ընդհանուր ձևով: :

Դուք կարող եք տեսնել, որ յուրաքանչյուր հաջորդ IF ֆունկցիան ներկառուցված է նախորդ ֆունկցիայի value_if_false արգումենտում: Յուրաքանչյուր IF ֆունկցիա կցվում է փակագծերի իր հավաքածուի մեջ, բայց բոլոր փակող փակագծերը գտնվում են բանաձևի վերջում:

Մեր ընդհանուր nested IF բանաձևը գնահատում է 3 պայման և վերադարձնում 4 տարբեր արդյունք (արդյունք 4-ը վերադարձվում է եթե ոչ մեկըաշխատանքային գրքույկ ներբեռնման համար

Excel-ի մեջ տեղադրված If-ի դրույթներ - օրինակներ (.xlsx ֆայլ)

թեստ պայման2 , եթե TRUE - վերադարձ r արդյունք2 , եթե FALSE -

փորձարկում պայման3 , եթե TRUE - վերադարձ արդյունք3 , եթե FALSE -

վերադարձ արդյունք4

Որպես օրինակ, եկեք պարզենք միջնորդավճարները մի շարք վաճառողների համար` ելնելով նրանց կատարած վաճառքի չափից.

Մաթեմատիկայում ավելացումների հերթականությունը փոխելը չի ​​փոխում գումարը: Excel-ում IF ֆունկցիաների հերթականությունը փոխելը փոխում է արդյունքը: Ինչո՞ւ։ Քանի որ տեղադրված IF բանաձևը վերադարձնում է առաջին TRUE պայմանին համապատասխանող արժեք : Հետևաբար, ձեր տեղադրված IF հայտարարություններում շատ կարևոր է պայմանները դասավորել ճիշտ ուղղությամբ՝ բարձրից ցածր կամ ցածրից բարձր՝ կախված ձեր բանաձևի տրամաբանությունից: Մեր դեպքում մենք նախ ստուգում ենք «ամենաբարձր» պայմանը, այնուհետև «երկրորդ ամենաբարձրը» և այսպես շարունակ.

=IF(B2>150, 10%, IF(B2>=101, 7%, IF(B2>=51, 5%, IF(B2>=1, 3%, ""))))

Եթե տեղադրենք պայմանները հակառակ հերթականությամբ, ներքևից վեր, արդյունքները բոլորը սխալ կլինեն, քանի որ մեր բանաձևը կդադարի առաջին տրամաբանական փորձարկումից հետո (B2>=1) 1-ից մեծ ցանկացած արժեքի համար: Ենթադրենք, մենք ունենք $100:վաճառքներում - այն 1-ից մեծ է, ուստի բանաձևը չի ստուգի այլ պայմաններ և արդյունքում կվերադարձնի 3%:

Եթե նախընտրում եք պայմանները դասավորել ցածրից մինչև բարձր, ապա օգտագործեք «պակաս, քան օպերատորը և նախ գնահատեք «ամենացածր» պայմանը, հետո «երկրորդ ամենացածրը» և այլն:

=IF($B2<1, 0%, IF($B2<51, 3%, IF($B2<101, 5%, IF($B2<=150, 7%, 10%))))

Ինչպես տեսնում եք, տրամաբանությունը կառուցելու համար բավական շատ մտածել է պետք: տեղադրված IF դրույթի ճիշտ մինչև վերջ: Եվ չնայած Microsoft Excel-ը թույլ է տալիս տեղադրել մինչև 64 IF ֆունկցիաներ մեկ բանաձևում, դա այն չէ, ինչ դուք իսկապես կցանկանայիք անել ձեր աշխատաթերթերում: Այսպիսով, եթե դուք (կամ մեկ ուրիշը) նայում եք ձեր Excel-ի մեջ տեղադրված IF բանաձևին՝ փորձելով պարզել, թե ինչ է այն իրականում անում, ժամանակն է վերանայել ձեր ռազմավարությունը և հավանաբար ընտրել այլ գործիք ձեր զինանոցում:

Լրացուցիչ տեղեկությունների համար , խնդրում ենք տեսնել Excel-ի մեջ տեղադրված IF հայտարարությունը:

Ներդրված IF-ը OR/AND պայմաններով

Այն դեպքում, երբ ձեզ անհրաժեշտ է գնահատել տարբեր պայմանների մի քանի խմբեր, կարող եք արտահայտել այդ պայմանները, օգտագործելով OR, ինչպես նաև AND ֆունկցիան, տեղադրեք գործառույթները IF հայտարարությունների ներսում, այնուհետև տեղադրեք IF հայտարարությունները միմյանց մեջ:

Excel-ում IF-ի մեջ տեղադրված OR հայտարարություններով

Օգտագործելով OR ֆունկցիան, կարող եք ստուգել երկու կամ ավելի տարբեր պայմաններ յուրաքանչյուր IF ֆունկցիայի տրամաբանական թեստում և վերադարձրեք TRUE, եթե OR արգումենտներից որևէ մեկը (առնվազն մեկը) գնահատվում է TRUE: Տեսնելու համար, թե ինչպես է այն իրականում աշխատում, խնդրում ենք հաշվի առնելՀետևյալ օրինակին:

Ենթադրենք, որ դուք ունեք վաճառքի երկու սյունակ, ասենք, հունվարի վաճառքները B սյունակում և փետրվարի վաճառքները սյունակում C: Դուք ցանկանում եք ստուգել երկու սյունակների թվերը և հաշվարկել միջնորդավճարը ավելի բարձր թվի հիման վրա: Այլ կերպ ասած, դուք կառուցում եք բանաձև հետևյալ տրամաբանությամբ. եթե հունվարի կամ փետրվար ամսվա վաճառքները գերազանցում են $150-ը, ապա վաճառողը ստանում է 10% միջնորդավճար, եթե հունվարին կամ փետրվարին վաճառքը գերազանցում է կամ հավասար է $101-ին, ապա վաճառողը ստանում է 7% միջնորդավճար: , և այլն:

Այն ավարտելու համար գրեք մի քանի OF հայտարարություններ, ինչպիսիք են OR(B2>150, C2>150) և տեղադրեք դրանք վերը քննարկված IF ֆունկցիաների տրամաբանական թեստերում: Արդյունքում, դուք ստանում եք հետևյալ բանաձևը.

=IF(OR(B2>150, C2>150), 10%, IF(OR(B2>=101, C2>=101),7%, IF(OR(B2>=51, C2>=51), 5%, IF(OR(B2>=1, C2>=1), 3%, ""))))

Եվ միջնորդավճարը նշանակվում է վաճառքի ավելի բարձր գումարի հիման վրա.

ավելի շատ բանաձևերի օրինակներ, խնդրում ենք դիտել Excel IF OR հայտարարությունը:

Excel-ում տեղադրված IF-ը AND հայտարարություններով

Եթե ձեր տրամաբանական թեստերը ներառում են մի քանի պայմաններ, և այդ բոլոր պայմանները պետք է գնահատվեն որպես TRUE, արտահայտեք դրանք: օգտագործելով AND ֆունկցիան:

Օրինակ, միջնորդավճարներ նշանակելու համար՝ հիմնվելով ավելի քիչ վաճառքի վրա, վերցրեք վերը նշված բանաձևը և փոխարինեք ԿԱՄ-ը AND հայտարարություններով: Այլ կերպ ասած, դուք ասում եք Excel-ին վերադարձնել 10% միայն այն դեպքում, եթե հունվարի և փետրվար ամսվա վաճառքները գերազանցում են $150-ը, 7%, եթե հունվարի և փետրվարի վաճառքները մեծ են կամ հավասար են $101-ի և այլն:

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, ""))))

Արդյունքում, մեր տեղադրված IF բանաձևը հաշվարկում է միջնորդավճարըB և C սյունակների ստորին թվի հիման վրա: Եթե որևէ սյունակ դատարկ է, ապա ընդհանրապես միջնորդավճար չկա, քանի որ AND պայմաններից և ոչ մեկը չի բավարարվում.

Եթե դուք' d ցանկանում է վերադարձնել 0% դատարկ բջիջների փոխարեն, փոխարինել դատարկ տողը (''") վերջին արգումենտում 0%-ով:

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, 0%))))

Լրացուցիչ տեղեկություններ կարող եք գտնել այստեղ՝ Excel IF մի քանի AND/OR պայմաններով:

VLOOKUP-ի փոխարեն Excel-ում տեղադրված IF-ի փոխարեն

Երբ գործ ունեք «սանդղակների», այսինքն՝ թվային արժեքների շարունակական միջակայքերի հետ: որոնք միասին ընդգրկում են ամբողջ տիրույթը, շատ դեպքերում դուք կարող եք օգտագործել VLOOKUP ֆունկցիան՝ տեղադրված IF-ների փոխարեն:

Սկզբի համար կազմեք հղումային աղյուսակ, ինչպես ցույց է տրված ստորև ներկայացված սքրինշոթում: Եվ այնուհետև կառուցեք Vlookup բանաձևը <-ով: 16>մոտավոր համընկնում , այսինքն` range_lookup արգումենտով սահմանված է TRUE:

Ենթադրենք, որ որոնման արժեքը B2-ում է, իսկ հղման աղյուսակը` F2:G5, բանաձևը կատարվում է հետևյալ կերպ. :

=VLOOKUP(B2,$F$2:$G$5,2,TRUE)

Խնդրում ենք նկատի ունենալ, որ մենք ամրագրում ենք աղյուսակի_զանգվածը բացարձակ հղումներով ($F$2:$G$5) բանաձևի այլ բջիջներում ճիշտ պատճենելու համար.

Ձեր Vlookup բանաձևի վերջին արգումենտը դնելով TRUE, դուք Excel-ին ասում եք. որոնել ամենամոտ համընկնում - եթե ճշգրիտ համընկնում չի գտնվել, վերադարձրեք հաջորդ ամենամեծ արժեքը, որը փոքր է որոնման արժեքից: Արդյունքում, ձեր բանաձևը կհամապատասխանի ոչ միայն որոնման աղյուսակի ճշգրիտ արժեքներին, այլև ցանկացածինարժեքներ, որոնք ընկած են միջև:

Օրինակ, B3-ում որոնման արժեքը $95 է: Այս թիվը գոյություն չունի որոնման աղյուսակում, և ճշգրիտ համընկնումով Vlookup-ը այս դեպքում կվերադարձնի #N/A սխալ: Սակայն մոտավոր համընկնումով Vlookup-ը շարունակում է որոնումը, մինչև գտնի մոտակա արժեքը, որը փոքր է որոնման արժեքից (որը մեր օրինակում $50 է) և վերադարձնի արժեք նույն շարքի երկրորդ սյունակից (որը կազմում է 5%):

Բայց ի՞նչ անել, եթե որոնման արժեքը փոքր է փնտրման աղյուսակի ամենափոքր թվից կամ որոնման բջիջը դատարկ է: Այս դեպքում Vlookup բանաձեւը կվերադարձնի #N/A սխալը: Եթե ​​դա այն չէ, ինչ դուք իրականում ցանկանում եք, տեղադրեք VLOOKUP-ը IFERROR-ի ներսում և ստացեք արժեքը, երբ որոնման արժեքը չի գտնվել: Օրինակ՝

=IFERROR(VLOOKUP(B2, $F$2:$G$5, 2, TRUE), "Outside range")

Կարևոր նշում: Մոտավոր համընկնումով Vlookup բանաձևի ճիշտ աշխատանքի համար որոնման աղյուսակի առաջին սյունակը պետք է դասավորված լինի աճման կարգով ՝ ամենափոքրից մինչև ամենամեծը:

Լրացուցիչ տեղեկությունների համար տե՛ս Ճշգրիտ համընկնումը: VLOOKUP ընդդեմ մոտավոր համընկնման VLOOKUP-ի:

IFS-ի հայտարարությունը որպես ներկառուցված IF ֆունկցիայի այլընտրանք

Excel 2016-ում և ավելի ուշ տարբերակներում Microsoft-ը ներկայացրել է մի քանի պայմանների գնահատման հատուկ ֆունկցիա՝ IFS ֆունկցիան:

IFS բանաձևը կարող է ընդունել մինչև 127 logical_test / value_if_true զույգ, և առաջին տրամաբանական թեստը, որը գնահատվում է TRUE «հաղթում է».

Համաձայն վերոհիշյալ շարահյուսության, մեր տեղադրված IF բանաձևը կարող է վերակառուցվել հետևյալ կերպ.

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%)

Խնդրում ենք ուշադրություն դարձնել, որ IFS ֆունկցիան վերադարձնում է #N/A սխալը, եթե նշված պայմաններից ոչ մեկը չի բավարարվում: Սրանից խուսափելու համար կարող եք ևս մեկ logical_test / value_if_true ավելացնել ձեր բանաձևի վերջում, որը կվերադարձնի 0 կամ դատարկ տող ("") կամ ձեր ուզած արժեքները, եթե ոչ մեկը: Նախորդ տրամաբանական թեստերը ճշմարիտ են.

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%, TRUE, "")

Արդյունքում մեր բանաձևը #N/A սխալի փոխարեն կվերադարձնի դատարկ տող (դատարկ բջիջ), եթե B սյունակի համապատասխան բջիջը դատարկ կամ պարունակում է տեքստ կամ բացասական թիվ:

Նշում. Ինչպես ներկառուցված IF-ը, Excel-ի IFS ֆունկցիան վերադարձնում է արժեք, որը համապատասխանում է առաջին պայմանին, որը գնահատվում է TRUE, այդ իսկ պատճառով IFS բանաձևում տրամաբանական թեստերի հերթականությունը կարևոր է:

Լրացուցիչ տեղեկությունների համար, փոխարենը տես Excel IFS ֆունկցիան: nested IF.

CHOOSE փոխարեն nested IF բանաձևը Excel-ում

Excel-ում մեկ բանաձևի մեջ բազմաթիվ պայմաններ փորձարկելու մեկ այլ եղանակ է CHOOSE ֆունկցիայի օգտագործումը, որը նախատեսված է արժեք վերադարձնելու համար: ցանկը, որը հիմնված է այդ արժեքի դիրքի վրա:

Կիրառվելով մեր նմուշային տվյալների բազայի վրա, բանաձևը ստանում է հետևյալ ձևը.

=CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%)

Առաջին արգումենտում ( index_num ), դուք գնահատում եք բոլոր պայմանները և գումարում արդյունքները: Տրված էոր TRUE-ը հավասար է 1-ի, իսկ FALSE-ը 0-ի, այս կերպ Դուք հաշվարկում եք վերադարձվող արժեքի դիրքը:

Օրինակ, B2-ում արժեքը $150 է: Այս արժեքի համար առաջին 3 պայմանները ճշմարիտ են, իսկ վերջինը (B2 > 150)՝ FALSE: Այսպիսով, index_num հավասար է 3-ի, այսինքն վերադարձվում է 3-րդ արժեքը, որը կազմում է 7%.

Խորհուրդ. Եթե ​​տրամաբանական թեստերից և ոչ մեկը ճշմարիտ չէ, index_num հավասար է 0-ի, և բանաձևը վերադարձնում է #VALUE: սխալ. Հեշտ շտկում է CHOOSE-ը IFERROR ֆունկցիայի մեջ փաթաթելն այսպես.

=IFERROR(CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%), "")

Լրացուցիչ տեղեկությունների համար տե՛ս Excel CHOOSE ֆունկցիան բանաձևերի օրինակներով:

SWITCH ֆունկցիան որպես համառոտ IF-ի համառոտ ձև Excel-ում

Այն իրավիճակներում, երբ գործ ունեք նախապես սահմանված արժեքների ֆիքսված շարքի հետ, այլ ոչ թե մասշտաբների, SWITCH ֆունկցիան կարող է կոմպակտ այլընտրանք լինել բարդին: Ներդրված IF հայտարարություններ՝

SWITCH ֆունկցիան գնահատում է արտահայտությունը ՝ համեմատելով արժեքների ցանկի հետ և վերադարձնում է արդյունքը , որը համապատասխանում է առաջին հայտնաբերված համընկնումին:

Այն դեպքում, երբ ցանկանում եք հաշվարկել միջնորդավճարը` հիմնվելով հետևյալ գնահատականների վրա, այլ ոչ թե վաճառքի գումարների վրա, կարող եք օգտագործել այս կոմպակտը: Excel-ում տեղադրված IF բանաձևի տարբերակը.

=SWITCH(C2, "A", 10%, "B", 7%, "C", 5%, "D", 3%, "")

Կամ կարող եք կազմել հղման աղյուսակ, ինչպես ցույց է տրված ստորև նշված սքրինշոթում և օգտագործել բջիջների հղումները կոշտ կոդավորված արժեքների փոխարեն.

=SWITCH(C2, $F$2, $G$2, $F$3, $G$3, $F$4, $G$4, $F$5, $G$5, "")

Խնդրում եմՈւշադրություն դարձրեք, որ մենք արգելափակում ենք բոլոր հղումները, բացառությամբ առաջինի, $ նշանով, որպեսզի դրանք չփոխվեն բանաձևը այլ բջիջներում պատճենելիս.

Նշում: SWITCH ֆունկցիան հասանելի է միայն Excel 2016 և ավելի բարձր տարբերակներում:

Լրացուցիչ տեղեկությունների համար տե՛ս SWITCH ֆունկցիան՝ ներդիր IF դրույթի կոմպակտ ձևը:

Մի քանի IF ֆունկցիաների միացում Excel-ում

Ինչպես նշվեց նախորդ օրինակում, SWITCH ֆունկցիան ներդրվել է միայն Excel 2016-ում: Excel-ի հին տարբերակներում նմանատիպ առաջադրանքներ կատարելու համար կարող եք միավորել երկու կամ ավելի IF հայտարարություններ՝ օգտագործելով Concatenate օպերատորը (&) կամ CONCATENATE ֆունկցիան: .

Օրինակ՝

=(IF(C2="a", 10%, "") & IF(C2="b", 7%, "") & IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Կամ

=CONCATENATE(IF(C2="a", 10%, ""), IF(C2="b", 7%, ""), IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Ինչպես կարող եք ունենալ նկատեցի, մենք արդյունքը բազմապատկում ենք 1-ով երկու բանաձևերում: Դա արվում է Concatenate բանաձևով վերադարձված տողը թվի փոխակերպելու համար։ Եթե ​​ձեր ակնկալվող ելքը տեքստ է, ապա բազմապատկման գործողությունն անհրաժեշտ չէ:

Լրացուցիչ տեղեկությունների համար տե՛ս Excel-ում CONCATENATE ֆունկցիան:

Դուք կարող եք տեսնել, որ Microsoft Excel-ը տրամադրում է մի քանի լավ այլընտրանքներ: IF բանաձևերի մեջ, և հուսով ենք, որ այս ձեռնարկը ձեզ որոշ հուշումներ է տվել, թե ինչպես դրանք օգտագործել ձեր աշխատաթերթերում: Այս ձեռնարկում քննարկված օրինակներին ավելի մոտիկից ծանոթանալու համար կարող եք ներբեռնել ստորև բերված մեր օրինակելի աշխատանքային գիրքը: Ես շնորհակալություն եմ հայտնում կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Պրակտիկա