Tutorial ini menjelaskan cara menggunakan fungsi IF bersarang di Excel untuk memeriksa beberapa kondisi. Anda juga akan mempelajari beberapa fungsi lain yang bisa menjadi alternatif yang baik untuk menggunakan rumus bersarang di Excel.

Bagaimana Anda biasanya menerapkan logika pengambilan keputusan di lembar kerja Excel Anda? Dalam kebanyakan kasus, Anda akan menggunakan rumus IF untuk menguji kondisi Anda dan mengembalikan satu nilai jika kondisi terpenuhi, nilai lain jika kondisi tidak terpenuhi. Untuk mengevaluasi lebih dari satu kondisi dan mengembalikan nilai yang berbeda tergantung pada hasilnya, Anda menyarangkan beberapa IF di dalam satu sama lain.

Meskipun sangat populer, pernyataan IF bersarang bukan satu-satunya cara untuk memeriksa beberapa kondisi di Excel. Dalam tutorial ini, Anda akan menemukan beberapa alternatif yang pasti layak untuk dijelajahi.

Pernyataan IF bersarang Excel

Berikut rumus IF bersarang Excel klasik dalam bentuk umum:

Anda bisa melihat bahwa setiap fungsi IF berikutnya disematkan ke dalam fungsi value_if_false Setiap fungsi IF diapit dalam rangkaian tanda kurungnya sendiri, tetapi semua tanda kurung penutup berada di akhir rumus.

Rumus IF bersarang generik kita mengevaluasi 3 kondisi, dan mengembalikan 4 hasil yang berbeda (hasil 4 dikembalikan jika tidak ada kondisi yang TRUE). Diterjemahkan ke dalam bahasa manusia, pernyataan IF bersarang ini memberi tahu Excel untuk melakukan hal berikut:

tes kondisi2 , jika TRUE - kembalikan r esult2 , jika FALSE -

tes kondisi3 , jika TRUE - kembali hasil3 , jika FALSE -

kembali hasil4

Sebagai contoh, mari kita cari tahu komisi untuk sejumlah penjual berdasarkan jumlah penjualan yang telah mereka lakukan:

Dalam matematika, mengubah urutan penjumlahan tidak mengubah jumlah. Di Excel, mengubah urutan fungsi IF mengubah hasilnya. Mengapa? Karena rumus IF bersarang mengembalikan nilai yang sesuai dengan rumus kondisi TRUE pertama Oleh karena itu, dalam pernyataan IF bersarangmu, sangat penting untuk mengatur kondisi-kondisinya ke arah yang benar - tinggi ke rendah atau rendah ke tinggi, tergantung pada logika rumusmu. Dalam kasus kita, kita mengecek kondisi "tertinggi" terlebih dahulu, lalu "tertinggi kedua", dan seterusnya:

=IF(B2>150, 10%, IF(B2>=101, 7%, IF(B2>=51, 5%, IF(B2>=1, 3%, ""))))

Jika kita menempatkan kondisi dalam urutan terbalik, dari bawah ke atas, hasilnya akan salah karena rumus kita akan berhenti setelah tes logika pertama (B2>=1) untuk nilai apa pun yang lebih besar dari 1. Katakanlah, kita memiliki penjualan $100 - lebih besar dari 1, sehingga rumus tidak akan memeriksa kondisi lain dan mengembalikan 3% sebagai hasilnya.

Jika Anda lebih suka mengatur kondisi dari rendah ke tinggi, maka gunakan operator "less than" dan evaluasi kondisi "terendah" terlebih dahulu, kemudian "terendah kedua", dan seterusnya:

=IF($B2<1, 0%, IF($B2<51, 3%, IF($B2<101, 5%, IF($B2<=150, 7%, 10%))))

Seperti yang Anda lihat, dibutuhkan banyak pemikiran untuk membangun logika pernyataan IF bersarang dengan benar sampai akhir. Dan meskipun Microsoft Excel memungkinkan bersarang hingga 64 fungsi IF dalam satu rumus, itu bukanlah sesuatu yang benar-benar ingin Anda lakukan di lembar kerja Anda. Jadi, jika Anda (atau orang lain) menatap rumus IF bersarang Excel Anda mencoba mencari tahu apa yang sebenarnya dilakukannya, inilah saatnya untukpertimbangkan kembali strategi Anda dan mungkin memilih alat lain di gudang senjata Anda.

Untuk informasi lebih lanjut, silakan lihat pernyataan IF bersarang Excel.

IF bersarang dengan kondisi OR/AND

Jika Anda perlu mengevaluasi beberapa set kondisi yang berbeda, Anda dapat mengekspresikan kondisi tersebut menggunakan fungsi OR serta AND, menyarangkan fungsi-fungsi di dalam pernyataan IF, dan kemudian menyarangkan pernyataan IF satu sama lain.

IF bersarang di Excel dengan pernyataan OR

Dengan menggunakan fungsi OR, Anda dapat memeriksa dua atau lebih kondisi yang berbeda dalam pengujian logis dari setiap fungsi IF dan mengembalikan TRUE jika ada (setidaknya satu) argumen OR yang dievaluasi menjadi TRUE. Untuk melihat bagaimana sebenarnya bekerja, harap pertimbangkan contoh berikut.

Misalkan, Anda memiliki dua kolom penjualan, katakanlah penjualan bulan Januari di kolom B dan penjualan bulan Februari di kolom C. Anda ingin memeriksa angka-angka di kedua kolom tersebut dan menghitung komisi berdasarkan angka yang lebih tinggi. Dengan kata lain, Anda membuat rumus dengan logika berikut: jika penjualan bulan Januari atau Februari lebih besar dari $150, penjual mendapat komisi 10%, jika penjualan bulan Januari atau Februari lebih besar dari atau sama dengan$101, penjual mendapat komisi 7%, dan seterusnya.

Untuk menyelesaikannya, tulis beberapa pernyataan OF seperti OR(B2>150, C2>150) dan sarangkan ke dalam tes logis dari fungsi IF yang dibahas di atas. Hasilnya, Anda mendapatkan rumus ini:

=IF(OR(B2>150, C2>150), 10%, IF(OR(B2>=101, C2>=101), 7%, IF(OR(B2>=51, C2>=51), 5%, IF(OR(B2>=1, C2>=1), 3%, ""))))

Dan menetapkan komisi berdasarkan jumlah penjualan yang lebih tinggi:

Untuk contoh rumus lainnya, silakan lihat pernyataan IF OR Excel.

IF bersarang di Excel dengan pernyataan AND

Jika tes logika Anda mencakup beberapa kondisi, dan semua kondisi tersebut harus dievaluasi menjadi TRUE, ekspresikan dengan menggunakan fungsi AND.

Misalnya, untuk menetapkan komisi berdasarkan jumlah penjualan yang lebih rendah, ambil rumus di atas dan ganti OR dengan pernyataan AND. Dengan kata lain, Anda memberi tahu Excel untuk mengembalikan 10% hanya jika penjualan Jan dan Feb lebih besar dari $150, 7% jika penjualan Jan dan Feb lebih besar dari atau sama dengan $101, dan seterusnya.

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, ""))))

Hasilnya, rumus IF bersarang kita menghitung komisi berdasarkan angka yang lebih rendah di kolom B dan C. Jika salah satu kolom kosong, tidak ada komisi sama sekali karena tidak ada kondisi AND yang terpenuhi:

Jika Anda ingin mengembalikan 0% alih-alih sel kosong, ganti string kosong (''") di argumen terakhir dengan 0%:

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, 0%))))

Informasi lebih lanjut dapat ditemukan di sini: Excel IF dengan beberapa kondisi AND/OR.

VLOOKUP alih-alih IF bersarang di Excel

Ketika Anda berurusan dengan "skala", yaitu rentang nilai numerik kontinu yang bersama-sama mencakup seluruh rentang, dalam banyak kasus Anda dapat menggunakan fungsi VLOOKUP alih-alih IF bersarang.

Sebagai permulaan, buat tabel referensi seperti yang ditunjukkan pada gambar di bawah ini. Dan kemudian, buat rumus Vlookup dengan perkiraan kecocokan , yaitu dengan range_lookup argumen diatur ke TRUE.

Dengan mengasumsikan nilai pencarian berada di B2 dan tabel referensinya adalah F2:G5, rumusnya adalah sebagai berikut:

=VLOOKUP(B2,$F$2:$G$5,2,TRUE)

Harap perhatikan bahwa kami memperbaiki table_array dengan referensi absolut ($ F $ 2: $ G $ 5) agar rumus dapat disalin dengan benar ke sel lain:

Dengan mengatur argumen terakhir dari rumus Vlookup Anda ke TRUE, Anda memberi tahu Excel untuk mencari paling cocok - jika kecocokan persis tidak ditemukan, kembalikan nilai terbesar berikutnya yang lebih kecil dari nilai pencarian. Hasilnya, rumusmu akan cocok dengan tidak hanya nilai persis dalam tabel pencarian, tetapi juga nilai apa pun yang berada di antaranya.

Misalnya, nilai pencarian di B3 adalah $ 95. Angka ini tidak ada dalam tabel pencarian, dan Vlookup dengan pencocokan tepat akan mengembalikan kesalahan # N / A dalam kasus ini. Tetapi Vlookup dengan perkiraan kecocokan terus mencari sampai menemukan nilai terdekat yang kurang dari nilai pencarian (yaitu $ 50 dalam contoh kita) dan mengembalikan nilai dari kolom kedua di baris yang sama (yaitu 5%).

Tetapi bagaimana jika nilai pencarian kurang dari angka terkecil dalam tabel pencarian atau sel pencarian kosong? Dalam kasus ini, rumus Vlookup akan mengembalikan kesalahan #N/A. Jika bukan itu yang sebenarnya Anda inginkan, sarangkan VLOOKUP di dalam IFERROR dan berikan nilai untuk output ketika nilai pencarian tidak ditemukan. Sebagai contoh:

=IFERROR(VLOOKUP(B2, $F$2:$G$5, 2, TRUE), "Di luar jangkauan")

Catatan penting! Agar rumus Vlookup dengan perkiraan kecocokan berfungsi dengan benar, kolom pertama dalam tabel pencarian harus diurutkan dalam urutan menaik dari yang terkecil hingga yang terbesar.

Untuk informasi lebih lanjut, lihat VLOOKUP pencocokan persis vs. VLOOKUP pencocokan perkiraan.

Pernyataan IFS sebagai alternatif untuk fungsi IF bersarang

Di Excel 2016 dan versi yang lebih baru, Microsoft memperkenalkan fungsi khusus untuk mengevaluasi beberapa kondisi - fungsi IFS.

Formula IFS bisa menangani hingga 127 logical_test / value_if_true pasangan, dan tes logika pertama yang mengevaluasi TRUE "menang":

Sesuai dengan sintaks di atas, rumus IF bertingkat kita dapat direkonstruksi dengan cara ini:

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%)

Harap perhatikan bahwa fungsi IFS mengembalikan kesalahan #N/A jika tidak ada kondisi yang ditentukan yang terpenuhi. Untuk menghindari hal ini, Anda dapat menambahkan satu lagi logical_test / value_if_true ke akhir rumusmu yang akan mengembalikan 0 atau string kosong ("") atau nilai apa pun yang kamu inginkan jika tidak ada tes logika sebelumnya yang TRUE:

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%, TRUE, "")

Hasilnya, rumus kita akan mengembalikan string kosong (sel kosong) alih-alih kesalahan # N / A jika sel yang sesuai di kolom B kosong atau berisi teks atau angka negatif.

Catatan Seperti IF bersarang, fungsi IFS Excel mengembalikan nilai yang sesuai dengan kondisi pertama yang dievaluasi ke TRUE, itulah sebabnya urutan tes logis dalam rumus IFS penting.

Untuk informasi lebih lanjut, silakan lihat fungsi IFS Excel alih-alih IF bersarang.

PILIH alih-alih rumus IF bersarang di Excel

Cara lain untuk menguji beberapa kondisi dalam satu rumus di Excel menggunakan fungsi CHOOSE, yang dirancang untuk mengembalikan nilai dari daftar berdasarkan posisi nilai tersebut.

Diterapkan pada set data sampel kami, rumus tersebut mengambil bentuk berikut ini:

=CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%)

Pada argumen pertama ( index_num ), Anda mengevaluasi semua kondisi dan menjumlahkan hasilnya. Mengingat bahwa TRUE setara dengan 1 dan FALSE dengan 0, dengan cara ini Anda menghitung posisi nilai yang akan dikembalikan.

Misalnya, nilai di B2 adalah $150. Untuk nilai ini, 3 kondisi pertama adalah TRUE dan yang terakhir (B2> 150) adalah FALSE. Jadi, index_num sama dengan 3, yang berarti nilai ke-3 dikembalikan, yaitu 7%.

Tip. Jika tidak ada tes logis yang BENAR, index_num sama dengan 0, dan rumusnya mengembalikan #VALUE! kesalahan. Perbaikan yang mudah adalah membungkus CHOOSE dalam fungsi IFERROR seperti ini:

=IFERROR(CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%), "")

Untuk informasi lebih lanjut, silakan lihat Excel CHOOSE berfungsi dengan contoh rumus.

Fungsi SWITCH sebagai bentuk ringkas dari IF bersarang di Excel

Dalam situasi ketika Anda berurusan dengan sekumpulan nilai tetap yang sudah ditentukan sebelumnya, bukan skala, fungsi SWITCH bisa menjadi alternatif ringkas untuk pernyataan IF bersarang yang kompleks:

Fungsi SWITCH mengevaluasi ekspresi terhadap daftar nilai dan mengembalikan hasil sesuai dengan kecocokan pertama yang ditemukan.

Jika, Anda ingin menghitung komisi berdasarkan nilai berikut, daripada jumlah penjualan, Anda dapat menggunakan versi ringkas rumus IF bersarang ini di Excel:

=SWITCH(C2, "A", 10%, "B", 7%, "C", 5%, "D", 3%, "")

Atau, Anda bisa membuat tabel referensi seperti yang ditunjukkan pada gambar di bawah ini dan menggunakan referensi sel alih-alih nilai yang dikodekan dengan keras:

=SWITCH(C2, $F$2, $G$2, $F$3, $G$3, $F$4, $G$4, $F$5, $G$5, "")

Harap perhatikan bahwa kami mengunci semua referensi kecuali yang pertama dengan tanda $ untuk mencegahnya berubah saat menyalin rumus ke sel lain:

Catatan. Fungsi SWITCH hanya tersedia di Excel 2016 dan yang lebih tinggi.

Untuk informasi lebih lanjut, lihat fungsi SWITCH - bentuk ringkas dari pernyataan IF bersarang.

Menggabungkan beberapa fungsi IF di Excel

Seperti disebutkan dalam contoh sebelumnya, fungsi SWITCH hanya diperkenalkan di Excel 2016. Untuk menangani tugas serupa di versi Excel yang lebih lama, Anda dapat menggabungkan dua atau lebih pernyataan IF dengan menggunakan operator Concatenate (&) atau fungsi CONCATENATE.

Contohnya:

=(IF(C2="a", 10%, "") & IF(C2="b", 7%, "") & IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Atau

=CONCATENATE(IF(C2="a", 10%, ""), IF(C2="b", 7%, ""), IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Seperti yang mungkin telah Anda perhatikan, kami mengalikan hasilnya dengan 1 di kedua rumus. Ini dilakukan untuk mengubah string yang dikembalikan oleh rumus Concatenate menjadi angka. Jika output yang Anda harapkan adalah teks, maka operasi perkalian tidak diperlukan.

Untuk informasi lebih lanjut, silakan lihat fungsi CONCATENATE di Excel.

Anda dapat melihat bahwa Microsoft Excel menyediakan beberapa alternatif yang baik untuk rumus IF bersarang, dan semoga tutorial ini telah memberi Anda beberapa petunjuk tentang cara memanfaatkannya di lembar kerja Anda. Untuk melihat lebih dekat contoh-contoh yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh buku kerja sampel kami di bawah ini. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

Excel bersarang Jika pernyataan - contoh (.xlsx file)