Hvis du ser etter en Excel-funksjon for å få ukedag fra dato, har du havnet på riktig side. Denne opplæringen vil lære deg hvordan du bruker WEEKDAY-formelen i Excel for å konvertere en dato til et ukedagsnavn, filtrere, markere og telle helger eller arbeidsdager og mer.

Det finnes en rekke funksjoner for å arbeid med datoer i Excel. Ukedag-funksjonen (WEEKDAY) er spesielt nyttig for planlegging og planlegging, for eksempel for å bestemme tidsrammen for et prosjekt og automatisk fjerne helger fra totalen. Så la oss gå gjennom eksemplene én om gangen og se hvordan de kan hjelpe deg med å takle ulike daterelaterte oppgaver i Excel.

WEEKDAY - Excel-funksjon for dag av uke

Excel WEEKDAY-funksjonen brukes til å returnere ukedagen fra en gitt dato.

Resultatet er et heltall, fra 1 (søndag) til 7 (lørdag) som standard . Hvis forretningslogikken din krever en annen oppregning, kan du konfigurere formelen til å begynne å telle med en hvilken som helst annen ukedag.

UKEDAG-funksjonen er tilgjengelig i alle versjoner av Excel 365 til og med 2000.

Syntaksen til WEEKDAY-funksjonen er som følger:

Hvor:

Serienummer (obligatorisk) - datoen du vil konvertere til ukedagsnummeret. Den kan leveres som et serienummer som representerer datoen, som en tekststreng i formatetsom Excel forstår, som en referanse til cellen som inneholder datoen, eller ved å bruke DATO-funksjonen.

Return_type (valgfritt) - bestemmer hvilken ukedag som skal brukes som første dag . Hvis den utelates, brukes som standard søndag-lør-uken.

Her er en liste over alle støttede return_type verdier:

Merk. return_type -verdiene 11 til 17 ble introdusert i Excel 2010 og kan derfor ikke brukes i tidligere versjoner.

Grunnleggende UKEDAGS-formel i Excel

For det første, la oss se hvordan for å bruke WEEKDAY-formelen i sin enkleste form for å få dagnummeret fra dato.

For eksempel, for å få ukedagen fra dato i C4 med standard søndag - lørdag uke, er formelen:

=WEEKDAY(C4)

Hvis du har et serienummersom representerer datoen (f.eks. hentet av DATOVERDI-funksjonen), kan du angi dette tallet direkte i formelen:

=WEEKDAY(45658)

Du kan også skrive inn datoen som en tekststreng omgitt av anførselstegn direkte i formelen. Bare pass på å bruke datoformatet som Excel forventer og kan tolke:

=WEEKDAY("1/1/2025")

Eller oppgi kildedatoen på en 100 % pålitelig måte ved å bruke DATE-funksjonen:

=WEEKDAY(DATE(2025, 1,1))

For å bruke annen dagskartlegging enn standard søn-lør, skriv inn et passende tall i det andre argumentet. For eksempel, for å begynne å telle dager fra mandag, er formelen:

=WEEKDAY(C4, 2)

I bildet nedenfor returnerer alle formlene ukedagen som tilsvarer 1. januar 2025, som er lagret som nummer 45658 internt i Excel. Avhengig av verdien satt i det andre argumentet, gir formlene forskjellige resultater.

Ved første øyekast kan det virke som om tallene som returneres av WEEKDAY-funksjonen har svært liten praktisk mening. Men la oss se på det fra en annen vinkel og diskutere noen formler som løser virkelige oppgaver.

Hvordan konvertere Excel-dato til ukedagsnavn

Etter design, Excel WEEKDAY-funksjonen returnerer ukedagen som et tall. For å gjøre ukedagnummeret til dagsnavnet, bruk TEXT-funksjonen.

For å få heldagsnavn , bruk "dddd"-formatkoden:

For å returnere forkortetdagnavn , formatkoden er "ddd":

For eksempel for å konvertere datoen i A3 til ukedagens navn , formelen er:

=TEXT(WEEKDAY(A3), "dddd")

Eller

=TEXT(WEEKDAY(A3), "ddd")

En annen mulig løsning er å bruke WEEKDAY sammen med VELG-funksjonen.

For eksempel, for å få et forkortet ukedagsnavn fra datoen i A3, går formelen som følger:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

Her returnerer WEEKDAY et serienummer fra 1 (søn) til 7 (lør) ) og VELG velger den tilsvarende verdien fra listen. Siden datoen i A3 (onsdag) tilsvarer 4, gir VELG ut "ons", som er den 4. verdien i listen.

Selv om CHOOSE-formelen er litt mer tungvint å konfigurere, gir den mer fleksibilitet slik at du kan skrive ut dagnavnene i hvilket som helst format du ønsker. I eksemplet ovenfor viser vi de forkortede dagnavnene. I stedet kan du levere fulle navn, tilpassede forkortelser eller til og med dagnavn på et annet språk.

Tips. En annen enkel måte å konvertere en dato til ukedagsnavnet er ved å bruke et tilpasset datoformat. For eksempel vil kodeformatet "dddd, mmmm d, åååå" ha datoen vist som " fredag ​​3. januar 2025 " mens "dddd" bare viser " fredag " .

Excel WEEKDAY-formel for å finne og filtrere arbeidsdager og helger

Når du har å gjøre med en lang liste med datoer, kan det være lurt å vite hvilke som er arbeidsdager og hvilke som er helger.

For å identifisere helger og ukedager i Excel, bygg en IF-setning med den nestede WEEKDAY-funksjonen. For eksempel:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

Denne formelen går til celle A3 og kopieres ned på tvers av så mange celler som nødvendig.

I WEEKDAY-formelen angir du return_type til 2, som tilsvarer man-søn-uken der mandag er dag 1. Så hvis ukedagtallet er mindre enn 6 (mandag til fredag), returnerer formelen "Workday", ellers - "Helg".

For å filtrere helger eller arbeidsdager , bruk Excel-filter på datasettet ( Data -fanen > Filter ) og velg enten "Helg" eller "Workday".

I skjermbildet nedenfor har vi filtrert ut ukedager, så bare helger er synlige:

Hvis et regionkontor i organisasjonen din jobber etter en annen tidsplan der hviledagene er andre enn lørdag og søndag, kan du enkelt justere WEEKDAY-formelen til dine behov ved å spesifisere en annen return_type .

For eksempel for å behandle lørdag og Mandag som helger, sett return_type til 12, slik at du får uketypen "tirsdag (1) til mandag (7)":

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

Hvordan fremheve helgers arbeidsdager og i Excel

For å se helger og arbeidsdager i regnearket ditt på et øyeblikk, kan du få dem skyggelagt automatisk i forskjellige farger. For dette, bruk ukedag/helg-formelen diskutert i forrige eksempel medExcel betinget formatering. Som betingelsen er underforstått, trenger vi bare WEEKDAY-funksjonen uten IF-omslaget.

For å fremheve helger (lørdag og søndag):

=WEEKDAY($A2, 2)<6

For å utheve arbeidsdager (mandag – fredag):

=WEEKDAY($A2, 2)>5

Der A2 er cellen øverst til venstre i det valgte området.

sett opp regelen for betinget formatering, trinnene er:

1. Velg listen over datoer (A2:A15 i vårt tilfelle).
2. På Hjem -fanen , i Stiler -gruppen, klikk Betinget formatering > Ny regel .
3. I dialogboksen Ny formateringsregel Velg Bruk en formel for å bestemme hvilke celler som skal formateres .
4. I boksen Formatverdier der denne formelen er sann, skriv inn formelen ovenfor for helger eller ukedager.
5. Klikk Format -knappen og velg ønsket format.
6. Klikk OK to ganger for å lagre endringene og lukke dialogvinduene.

For detaljert informasjon om hvert trinn, se Hvordan sette opp betinget formatering med formel.

Resultatet ser ganske bra ut, gjør det ikke?

Hvordan telle ukedager og helger i Excel

For å få antall ukedager eller helger i datolisten kan du bruke UKEDAG-funksjonen i kombinasjon med SUM. For eksempel:

For å telle helger , er formelen i D3:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

For å telle ukedager ,formelen i D4 har denne formen:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

I Excel 365 og Excel 2021 som håndterer arrays naturlig, fungerer dette som en vanlig formel som vist i skjermbildet nedenfor. I Excel 2019 og tidligere, trykk Ctrl + Shift + Enter for å gjøre det til en matriseformel.

Slik fungerer disse formlene:

WEEKDAY-funksjonen med returtype satt til 2 returnerer et dagnummer fra 1 (man) til 7 (søn) ) for hver dato i området A3:A20. Det logiske uttrykket sjekker om de returnerte tallene er større enn 5 (for helger) eller mindre enn 6 (for ukedager). Resultatet av denne operasjonen er en matrise med TRUE og FALSE-verdier.

Den doble negasjonen (--) tvinger de logiske verdiene til 1-er og 0-er. Og SUM-funksjonen legger dem sammen. Gitt at 1 (SANN) representerer dagene som skal telles og 0 (USANN) dagene som skal ignoreres, får du ønsket resultat.

Tips. For å beregne ukedager mellom to datoer , bruk funksjonen NETWORKDAYS eller NETWORKDAYS.INTL.

Hvis ukedag da, hvis lørdag eller søndag så

Til slutt, la oss diskutere litt mer spesifikt tilfelle som viser hvordan du bestemmer ukedagen, og hvis det er lørdag eller søndag så gjør noe, hvis en ukedag så gjør noe annet.

Tenk deg at du beregner betalinger for ansatte som har gjort litt ekstraarbeid på fridagene, så du trengerå bruke ulike betalingssatser for arbeidsdager og helger. Dette kan gjøres ved å bruke følgende IF-setning:

• I argumentet logical_test , nest WEEKDAY-funksjonen som sjekker om en gitt dag er en arbeidsdag eller helg.
• I verdi_hvis_sann -argumentet multipliserer du antall arbeidstimer med helgesatsen (G4).
• I argumentet verdi_hvis_falsk , multipliser antall arbeidstimer etter arbeidsdagssatsen (G3).

Den fullstendige formelen i D3 har denne formen:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

For at formelen skal kopieres riktig til cellene nedenfor, pass på å låse ratecelleadressene med $-tegnet (som $G$4).

WEEKDAY-funksjonen fungerer ikke

Vanligvis er det to vanlige feil som en WEEKDAY-formel kan returnere:

#VALUE! feil oppstår hvis enten:

• Serial_number eller return_type er ikke-numerisk.
• Serial_number er ute av støttet datoperiode (1900 til 9999).

#NUM! feil oppstår når returtype er utenfor det tillatte området (1-3 eller 11-17).

Dette er hvordan du bruker WEEKDAY-funksjonen i Excel for å manipulere ukedager. I den neste artikkelen vil vi utforske Excel-funksjoner for å operere på større tidsenheter som uker, måneder og år. Følg med og takk for at du leser!

Øvningsarbeidsbok for nedlasting

WEEKDAY-formel i Excel - eksempler (.xlsxfil)