У гэтым кароткім уроку вы даведаецеся, як дынамічна фільтраваць у Excel з дапамогай формул. Прыклады фільтрацыі дублікатаў, ячэек, якія змяшчаюць пэўны тэкст, з некалькімі крытэрыямі і многае іншае.

Як вы звычайна фільтруеце ў Excel? Па большай частцы, з дапамогай аўтаматычнага фільтра, а ў больш складаных сітуацыях з пашыраным фільтрам. З'яўляючыся хуткімі і магутнымі, гэтыя метады маюць адзін істотны недахоп - яны не абнаўляюцца аўтаматычна пры змене вашых даных, што азначае, што вам давядзецца чысціць і фільтраваць зноў. Увядзенне функцыі FILTER у Excel 365 становіцца доўгачаканай альтэрнатывай звычайным функцыям. У адрозненне ад іх, формулы Excel пераразлічваюцца аўтаматычна пры кожнай змене аркуша, таму вам трэба будзе наладзіць фільтр толькі адзін раз!

Функцыя FILTER Excel

Функцыя FILTER у Excel выкарыстоўваецца для фільтрацыі шэрагу даных на аснове ўказаных вамі крытэрыяў.

Функцыя належыць да катэгорыі функцый дынамічных масіваў. У выніку атрымліваецца масіў значэнняў, які аўтаматычна пераходзіць у дыяпазон ячэек, пачынаючы з ячэйкі, у якую вы ўводзіце формулу.

Сінтаксіс функцыі FILTER наступны:

Дзе:

• Масіў (абавязкова) - дыяпазон або масіў значэнняў, якія вы хочаце адфільтраваць.
• Уключаць (абавязкова) - крытэрыі, прадстаўленыя ў выглядзе лагічнага масіва (значэнні TRUE і FALSE).

  Ягонават сотні слупкоў, вы, безумоўна, захочаце абмежаваць вынікі некалькімі найбольш важнымі.

  Прыклад 1. Адфільтруйце некаторыя суседнія слупкі

  У сітуацыі, калі вы хочаце, каб некаторыя суседнія слупкі з'явіліся ў вынік FILTER, уключыце толькі тыя слупкі ў масіў , таму што менавіта гэты аргумент вызначае, якія слупкі вярнуць.

  У прыкладзе базавай формулы FILTER, выкажам здагадку, што вы хочаце вярнуць першыя 2 слупкі ( Імя і Група ). Такім чынам, вы падаеце A2:B13 для аргумента масіў :

  =FILTER(A2:B13, B2:B13=F1, "No results")

  У выніку мы атрымаем спіс удзельнікаў мэтавай групы, вызначанай у F1:

  

  Прыклад 2. Фільтруйце несумежныя слупкі

  Каб прымусіць функцыю FILTER вяртаць несумежныя слупкі, выкарыстоўвайце гэты хітры прыём:

  1. Стварыце формулу FILTER з патрэбнай умовай(-ямі), выкарыстоўваючы ўсю табліцу для масіва .
  2. Укладзіце прыведзеную вышэй формулу ў іншую функцыю FILTER. Каб наладзіць функцыю "абгортка", выкарыстоўвайце канстанту масіва са значэннямі TRUE і FALSE або 1 і 0 для аргумента include , дзе TRUE (1) пазначае слупкі, якія трэба захаваць, а FALSE (0) пазначае слупкі, якія трэба захаваць. слупкі, якія трэба выключыць.

  Напрыклад, каб вярнуць толькі Імёны (1-ы слупок) і Wins (3-ці слупок), мы выкарыстоўваем {1, 0,1} або {TRUE,FALSE,TRUE} для аргумента include вонкавай функцыі FILTER:

  =FILTER(FILTER(A2:C13, B2:B13=F1), {1,0,1})

  Або

  =FILTER(FILTER(A2:C13, B2:B13=F1), {TRUE,FALSE,TRUE})

  

  Як абмежавацьколькасць радкоў, вернутых функцыяй FILTER

  Калі ваша формула FILTER знаходзіць даволі шмат вынікаў, але ваш аркуш мае абмежаваную прастору і вы не можаце выдаліць дадзеныя ніжэй, вы можаце абмежаваць колькасць радкоў, якія вяртае функцыя FILTER .

  Давайце паглядзім, як гэта працуе на прыкладзе простай формулы, якая выцягвае гульцоў з мэтавай групы ў F1:

  =FILTER(A2:C13, B2:B13=F1)

  Прыведзеная вышэй формула выводзіць усе запісы, якія ён знаходзіць, 4 радкі ў нашым выпадку. Але выкажам здагадку, што ў вас ёсць месца толькі для дваіх. Каб вывесці толькі першыя 2 знойдзеныя радкі, вам трэба зрабіць вось што:

  • Устаўце формулу FILTER у аргумент масіў функцыі INDEX.
  • Для аргумента row_num INDEX выкарыстоўвайце канстанту вертыкальнага масіва, напрыклад {1;2}. Ён вызначае, колькі радкоў вярнуць (у нашым выпадку 2).
  • Для аргумента column_num выкарыстоўвайце канстанту гарызантальнага масіва, напрыклад {1,2,3}. Ён вызначае, якія слупкі вярнуць (першыя 3 слупкі ў гэтым прыкладзе).
  • Каб паклапаціцца аб магчымых памылках, калі даныя, якія адпавядаюць вашым крытэрыям, не знойдзены, вы можаце змясціць вашу формулу ў функцыю IFERROR.

Поўная формула мае наступны выгляд:

=IFERROR(INDEX(FILTER(A2:C13, B2:B13=F1), {1;2}, {1,2,3}), "No result")

Пры працы з вялікімі табліцамі можа быць запіс канстант масіва ўручную даволі грувасткі. Няма праблем, функцыя SEQUENCE можа аўтаматычна ствараць для вас паслядоўныя нумары:

=IFERROR(INDEX(FILTER(A2:C13, B2:B13=F1), SEQUENCE(2), SEQUENCE(1, COLUMNS(A2:C13))), "No result")

Першая SEQUENCE стварае вертыкальны масіўякі змяшчае столькі паслядоўных лікаў, колькі паказана ў першым (і адзіным) аргументе. Другі SEQUENCE выкарыстоўвае функцыю COLUMNS для падліку колькасці слупкоў у наборы даных і стварае эквівалентны гарызантальны масіў.

Падказка. Каб вярнуць даныя з канкрэтных слупкоў , а не з усіх слупкоў, у канстанту гарызантальнага масіва, якую вы выкарыстоўваеце для аргумента column_num для INDEX, уключыце толькі гэтыя канкрэтныя лічбы. Напрыклад, каб атрымаць даныя з 1-га і 3-га слупкоў, выкарыстоўвайце {1,3}.

Функцыя Excel FILTER не працуе

У сітуацыі, калі ваша формула Excel FILTER прыводзіць да памылкі, хутчэй за ўсё, гэта будзе адно з наступнага:

#CALC! памылка

Узнікае, калі неабавязковы аргумент if_empty апушчаны і вынікі, якія адпавядаюць крытэрам, не знойдзены. Прычына ў тым, што ў цяперашні час Excel не падтрымлівае пустыя масівы. Каб прадухіліць такія памылкі, абавязкова вызначайце значэнне if_empty у сваіх формулах.

Памылка #ЗНАЧЭННЕ

Узнікае, калі масіў і <Аргумент 1>include мае несумяшчальныя памеры.

#Н/Д, #ЗНАЧЭННЕ і г.д.

Калі нейкае значэнне ў аргуменце include могуць узнікнуць розныя памылкі з'яўляецца памылкай або не можа быць ператворана ў лагічнае значэнне.

Памылка #NAME

Узнікае пры спробе выкарыстоўваць FILTER у старой версіі Excel. Памятайце, што гэта новая функцыя, якая даступна толькі ў Office 365 і Excel 2021.

Уновы Excel, памылка #NAME ўзнікае, калі вы памылкова памыліліся ў назве функцыі.

Памылка #SPILL

Часцей за ўсё гэтая памылка ўзнікае, калі адна ці некалькі вочак у дыяпазоне разліцця не зусім пустыя . Каб выправіць гэта, проста ачысціце або выдаліце ​​непустыя вочкі. Каб расследаваць і вырашыць іншыя выпадкі, калі ласка, глядзіце #SPILL! памылка ў Excel: што гэта значыць і як выправіць.

#REF! памылка

Узнікае, калі формула FILTER выкарыстоўваецца паміж рознымі кнігамі, а зыходная кніга зачынена.

Гэта тое, як дынамічна захоўваць дадзеныя ў Excel. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Спампаваць практычны сшытак

Фільтр у Excel з формуламі (файл .xlsx)

Функцыя FILTER даступная толькі ў Excel для Microsoft 365 і Excel 2021. У Excel 2019, Excel 2016 і больш ранніх версіях ён не падтрымліваецца.

Базавая формула ФІЛЬТРА Excel

Для пачатку давайце абмяркуем пару вельмі простых выпадкаў, каб атрымаць больш выгады лепш зразумець, як працуе формула Excel для фільтрацыі даных.

З прыведзенага ніжэй набору даных, выкажам здагадку, што вы хочаце атрымаць запісы з пэўным значэннем у слупку Група , скажам, група C. Каб зрабіць гэта, мы падаем выраз B2:B13="C" у аргумент include , які створыць неабходны лагічны масіў, дзе TRUE адпавядае значэнням "C".

=FILTER(A2:C13, B2:B13="C", "No results")

На практыцы зручней уводзіць крытэрыі ў асобную ячэйку, напрыклад. F1 і выкарыстоўвайце спасылку на ячэйку замест жорсткага кадзіравання значэння непасрэдна ў формуле:

=FILTER(A2:C13, B2:B13=F1, "No results")

У адрозненне ад функцыі фільтра Excel, гэтая функцыя не ўносіць ніякіх змяненняў у зыходныя даныя. Ён здабывае адфільтраваныя запісы ў так званы дыяпазон разліву (E4:G7 на скрыншоце ніжэй), пачынаючы з ячэйкі, у якую ўводзіцца формула:

Калі няма запісаў адпавядаюць зададзеным крытэрыям, формула вяртае значэнне, якое вы ўвялі ў if_empty аргумент, «Няма вынікаў» у гэтым прыкладзе:

Калі вы хочаце нічога не вяртаць у гэтым выпадку, то увядзіце пусты радок ("") для апошняга аргумента:

=FILTER(A2:C13, B2:B13=F1, "")

Калі вашы дадзеныя арганізаваны гарызантальна злева направа, як паказана на скрыншоце ніжэй, функцыя FILTER таксама будзе добра працаваць. Проста пераканайцеся, што вы вызначылі адпаведныя дыяпазоны для аргументаў array і include , каб зыходны масіў і лагічны масіў мелі аднолькавую шырыню:

=FILTER(B2:M4, B3:M3= B7, "No results")

Функцыя Excel FILTER - заўвагі па выкарыстанні

Каб эфектыўна фільтраваць у Excel з дапамогай формул, вось некалькі важных момантаў, на якія варта звярнуць увагу:

• Функцыя FILTER аўтаматычна раскладвае вынікі па вертыкалі або гарызанталі на аркушы, у залежнасці ад таго, як арганізаваны вашы зыходныя даныя. Такім чынам, калі ласка, пераканайцеся, што ў вас заўсёды ёсць дастаткова пустых вочак унізе і справа, у адваротным выпадку вы атрымаеце памылку #SPILL.
• Вынікі функцыі FILTER Excel з'яўляюцца дынамічнымі, што азначае, што яны аўтаматычна абнаўляюцца, калі значэнні ў змяненне зыходнага набору дадзеных. Аднак дыяпазон, зададзены для аргумента масіў , не абнаўляецца пры даданні новых запісаў да зыходных дадзеных. Калі вы хочаце, каб памер масіўу змяняўся аўтаматычна, пераўтварыце яго ў табліцу Excel і стварыце формулы са структураванымі спасылкамі або стварыце дынамічны найменны дыяпазон.

Як фільтраваць у Excel -прыклады формул

Цяпер, калі вы ведаеце, як працуе асноўная формула фільтра Excel, прыйшоў час даведацца, як яе можна пашырыць для вырашэння больш складаных задач.

Фільтр па некалькіх крытэрыях (І логіка)

Каб адфільтраваць даныя па некалькіх крытэрыях, вы ўводзіце два або больш лагічных выразаў для аргумента include :

Аперацыя множання апрацоўвае масівы з дапамогай логікі І , забяспечваючы вяртанне толькі тых запісаў, якія адпавядаюць усім крытэрыям . Тэхнічна гэта працуе наступным чынам:

Вынікам кожнага лагічнага выразу з'яўляецца масіў лагічных значэнняў, дзе TRUE роўна 1, а FALSE - 0. Затым элементы ўсіх масіваў на аднолькавых пазіцыях памнажаюцца . Паколькі множанне на нуль заўсёды дае нуль, толькі тыя элементы, для якіх усе крытэрыі TRUE, трапляюць у выніковы масіў, і, такім чынам, толькі гэтыя элементы будуць здабывацца.

У прыведзеных ніжэй прыкладах паказана, што гэтая агульная формула працуе.

Прыклад 1. Фільтруйце некалькі слупкоў у Excel

Пашыраючы нашу базавую формулу Excel FILTER крыху далей, давайце адфільтруем даныя па двух слупках: Група (слупок B) і Перамогі (слупок C).

Для гэтага мы ўсталявалі наступныя крытэрыі: увядзіце назву мэтавай групы ў F2 ( крытэрый1 ) і мінімальна неабходную колькасцьвыйграе ў F3 ( крытэрый2 ).

Улічваючы, што нашы зыходныя дадзеныя знаходзяцца ў A2:C13 ( масіў ), групы знаходзяцца ў B2:B13 ( дыяпазон1 ) і выйгрышы ў C2:C13 ( дыяпазон2 ), формула прымае наступны выгляд:

=FILTER(A2:C13, (B2:B13=F2) * (C2:C13>=F3), "No results")

У выніку вы атрымаеце спіс гульцоў у групе А, якія забяспечылі 2 або больш перамог:

Прыклад 2. Фільтр даных паміж датамі

Па-першае, варта адзначыць, што гэта немагчыма каб скласці агульную формулу для фільтрацыі па даце ў Excel. У розных сітуацыях вам трэба будзе будаваць крытэрыі па-рознаму, у залежнасці ад таго, хочаце вы фільтраваць па канкрэтнай даце, па месяцы або па годзе. Мэта гэтага прыкладу - прадэманстраваць агульны падыход.

Да нашага ўзору дадзеных мы дадаем яшчэ адзін слупок, які змяшчае даты апошняга выйгрышу (слупок D). А цяпер мы вылучым выйгрышы, якія адбыліся ў пэўны перыяд, скажам, з 17 па 31 мая.

Звярніце ўвагу, што ў гэтым выпадку абодва крытэрыі прымяняюцца да аднаго дыяпазону:

=FILTER(A2:D13, (D2:D13>=G2) * (D2:D13<=G3), "No results")

Дзе G2 і G3 - гэта даты для фільтрацыі.

Фільтр па некалькіх крытэрыях (логіка АБО)

Для здабывання даных заснавана на ўмове множнага АБО, вы таксама выкарыстоўваеце лагічныя выразы, як паказана ў папярэдніх прыкладах, але замест множання вы іх складаеце. Калі лагічныя масівы, вернутыя выразамі, сумуюцца, выніковы масіў будзе мець 0 для запісаў, якія не адпавядаюць ніякім крытэрыям (г.зн. усекрытэрыі FALSE), і такія запісы будуць адфільтраваны. Запісы, для якіх хаця б адзін крытэрый TRUE, будуць выняты.

Вось агульная формула для фільтрацыі слупкоў з логікай АБО:

У якасці прыкладу давайце выцягнем спіс гульцоў, якія маюць гэта або гэта колькасць перамог.

Калі выказаць здагадку, што зыходныя дадзеныя знаходзяцца ў A2:C13, перамогі знаходзяцца ў C2:C13, а нумары перамог знаходзяцца ў F2 і F3, формула будзе выглядаць наступным чынам:

=FILTER(A2:C13, (C2:C13=F2) + (C2:C13=F3), "No results")

У выніку вы ведаеце, якія гульцы выйгралі ўсе гульні (4), а якія не выйгралі ніводнай (0):

Фільтр на аснове некалькіх крытэрыяў І, а таксама АБО

У сітуацыі, калі вам трэба прымяніць абодва тыпы крытэрыяў, запомніце гэтае простае правіла: аб'яднайце крытэрыі І зорачкай (*) і крытэрыі АБО з плюсам знак (+).

Напрыклад, каб вярнуць спіс гульцоў, якія маюць зададзеную колькасць перамог (F2) І належаць да групы, згаданай у E2 АБО E3, пабудуйце наступны ланцужок лагічных выразы:

=FILTER(A2:C13, (C2:C13=F2) * ((B2:B13=E2) + (B2:B13=E3)), "No results")

І вы атрымаеце наступны вынік:

Як адфільтраваць дублікаты ў Excel

Пры працы з велізарнымі аркушамі або аб'яднанні даных з розных крыніц часта існуе верагоднасць таго, што некаторыя дублікаты пракрадуцца.

Калі вы хочаце адфільтраваць дублікаты і экстрактунікальных элементаў, затым выкарыстоўвайце функцыю UNIQUE, як апісана ў падручніку па спасылцы вышэй.

Калі ваша мэта складаецца ў тым, каб фільтраваць дублікаты , г.зн., выняць запісы, якія сустракаюцца больш за адзін раз, выкарыстоўвайце функцыю FILTER разам з COUNTIFS.

Ідэя заключаецца ў тым, каб атрымаць колькасць ўваходжанняў для ўсіх запісаў і атрымаць тыя, якія больш за 1. Каб атрымаць колькасць, вы задаеце аднолькавы дыяпазон для кожнага criteria_range / крытэрыі пара COUNTIFS, напрыклад:

Напрыклад, каб адфільтраваць паўтаральныя радкі з даных у A2:C20 на аснове значэнняў ва ўсіх 3 слупках, вось формула для выкарыстання:

=FILTER(A2:C20, COUNTIFS(A2:A20, A2:A20, B2:B20, B2:B20, C2:C20, C2:C20)>1, "No results")

Савет. Каб адфільтраваць дублікаты на аснове значэнняў у ключавых слупках , уключыце толькі гэтыя пэўныя слупкі ў функцыю COUNTIFS.

Як адфільтраваць пустыя вочкі ў Excel

Формула для адфільтравання пустых ячэек, па сутнасці, з'яўляецца разнавіднасцю формулы ФІЛЬТРА Excel з некалькімі крытэрамі І. У гэтым выпадку мы правяраем, ці ёсць ва ўсіх (або асобных) слупках якія-небудзь дадзеныя, і выключаем радкі, у якіх хаця б адна ячэйка пустая. Каб вызначыць непустыя ячэйкі, вы выкарыстоўваеце аператар "не роўна" () разам з пустым радком (""), як гэта:

З зыходнымі данымі ў A2:C12, каб адфільтраваць радкіякі змяшчае адну або некалькі пустых вочак, наступная формула ўводзіцца ў E3:

Фільтраваць вочкі, якія змяшчаюць пэўны тэкст

Каб атрымаць вочкі, якія змяшчаюць пэўны тэкст, вы можна выкарыстоўваць функцыю FILTER разам з класічнай ячэйкай If, якая змяшчае формулу:

Вось як гэта працуе:

• Функцыя ПОШУК шукае зададзены тэкставы радок у зададзеным дыяпазоне і вяртае альбо лік (становішча першага сімвала), альбо #ЗНАЧЭННЕ! памылка (тэкст не знойдзены).
• Функцыя ISNUMBER пераўтворыць усе лічбы ў TRUE, а памылкі ў FALSE і перадае атрыманы лагічны масіў у аргумент include функцыі FILTER.

Для гэтага прыкладу мы дадалі Прозвішчы гульцоў у B2:B13, увялі частку імя, якую мы хочам знайсці ў G2, а затым выкарысталі наступную формулу для адфільтраваць дадзеныя:

=FILTER(A2:D13, ISNUMBER(SEARCH(G2, B2:B13)), "No results")

У выніку формула здабывае два прозвішчы, якія змяшчаюць «хан»:

Адфільтраваць і вылічыць (Сума, сярэдняе, мінімальнае, максімальнае і г.д.)

Класная рэч у функцыі ФІЛЬТРА Excel заключаецца ў тым, што яна можа не толькі здабываць значэнні з умовамі, але і абагульняць адфільтраваныя даныя. Для гэтага аб'яднайце FILTER з такімі функцыямі агрэгацыі, як SUM, AVERAGE, COUNT, MAX або MIN.

Напрыклад, каб агрэгаваць дадзеныя для пэўнай групы ў F1, выкарыстоўвайце наступнаеформулы:

Агульная колькасць перамог:

=SUM(FILTER(C2:C13, B2:B13=F1, 0))

Сярэдняя колькасць перамог:

=AVERAGE(FILTER(C2:C13, B2:B13=F1, 0))

Максімальная колькасць перамог:

=MAX(FILTER(C2:C13, B2:B13=F1, 0))

Мінімальныя выйгрышы:

=MIN(FILTER(C2:C13, B2:B13=F1, 0))

Звярніце ўвагу, што ва ўсіх формулах мы выкарыстоўваем нуль для аргумента if_empty , таму формулы будуць вяртае 0, калі не знойдзена значэнняў, якія адпавядаюць крытэрам. Увядзенне любога тэксту накшталт "Няма вынікаў" прывядзе да памылкі #ЗНАЧЭННЕ, а гэта, відавочна, апошняе, што вам трэба :)

Формула ФІЛЬТРА з улікам рэгістра

Стандартная формула ФІЛЬТРА Excel неадчувальная да рэгістра, што азначае, што яна не робіць адрозненняў паміж малымі і вялікімі сімваламі. Каб адрозніваць рэгістр тэксту, укладзеце функцыю EXACT у аргумент include . Гэта прымусіць FILTER выконваць лагічны тэст з улікам рэгістра:

Выкажам здагадку , у вас ёсць абедзве групы A і a і вы жадаеце атрымаць запісы, дзе група з'яўляецца малой літарай "a". Каб зрабіць гэта, выкарыстоўвайце наступную формулу, дзе A2:C13 - зыходныя даныя, а B2:B13 - групы для фільтрацыі:

=FILTER(A2:C13, EXACT(B2:B13, "a"), "No results")

Як звычайна, вы можаце ўвесці мэтавую групу ў загадзя вызначаную ячэйку, скажам, F1, і выкарыстоўвайце гэтую спасылку на ячэйку замест жорстка закадаванага тэксту:

=FILTER(A2:C13, EXACT(B2:B13, F1), "No results")

Як ФІЛЬТРАВАЦЬ даныя і вяртаць толькі пэўныя слупкі

Па большай частцы, карыстальнікі Excel хочуць фільтраваць усе слупкі з дапамогай адной формулы. Але калі ваша зыходная табліца змяшчае дзесяткі або