সুচিপত্র
ওয়াইল্ডকার্ড পাঠ্য সহ একটি IF বিবৃতি তৈরি করার চেষ্টা করছেন, কিন্তু এটি প্রতিবার ব্যর্থ হয়? সমস্যাটি আপনার সূত্রে নয় কিন্তু ফাংশনেই - এক্সেল IF ওয়াইল্ডকার্ড অক্ষর সমর্থন করে না। যাইহোক, আংশিক টেক্সট মিলের জন্য এটি কাজ করার একটি উপায় রয়েছে এবং এই টিউটোরিয়ালটি আপনাকে শেখাবে কিভাবে।
যখনই আপনি Excel এ আংশিক বা অস্পষ্ট ম্যাচিং করতে চান, সবচেয়ে স্পষ্ট সমাধান হল ওয়াইল্ডকার্ড ব্যবহার করতে। কিন্তু যদি একটি নির্দিষ্ট ফাংশন যা আপনাকে ব্যবহার করতে হবে তা ওয়াইল্ডকার্ড অক্ষর সমর্থন করে না? দুঃখের বিষয়, Excel IF এই ধরনের একটি ফাংশন। এটি বিশেষত হতাশাজনক যে অন্যান্য "শর্তাধীন" ফাংশন যেমন COUNTIF, SUMIF, এবং AVERAGEIFS ওয়াইল্ডকার্ডের সাথে পুরোপুরি ভালভাবে কাজ করে৷
সৌভাগ্যক্রমে, এটি এমন বাধা নয় যা একটি সৃজনশীল এক্সেল ব্যবহারকারীকে থামাতে পারে :) IF একত্রিত করে অন্যান্য ফাংশনের সাথে, আপনি এটিকে একটি আংশিক মিল মূল্যায়ন করতে বাধ্য করতে পারেন এবং এক্সেল IF ওয়াইল্ডকার্ড সূত্রের একটি চমৎকার বিকল্প পেতে পারেন।
ওয়াইল্ডকার্ড সহ এক্সেল IF ফাংশন কেন কাজ করছে না
নীচের নমুনা সারণীতে, ধরুন আপনি প্রথম কলামের আইডিগুলিতে "A" অক্ষর রয়েছে কিনা তা পরীক্ষা করতে চান৷ যদি পাওয়া যায় - কলাম B-এ "হ্যাঁ" প্রদর্শন করুন, যদি না হয় - "না" প্রদর্শন করুন।
মনে হচ্ছে লজিক্যাল পরীক্ষায় ওয়াইল্ডকার্ড পাঠ্য অন্তর্ভুক্ত করা একটি সহজ সমাধান হবে:
=IF(A2="*a*","Yes", "No") <3
কিন্তু আফসোস এটা কাজ করে না। সূত্রটি সমস্ত কক্ষের জন্য "না" প্রদান করে, এমনকি যেগুলিতে "A" রয়েছে:
কেনএকটি ওয়াইল্ডকার্ড যদি বিবৃতি ব্যর্থ হয়? সমস্ত উপস্থিতি থেকে, Excel সমান চিহ্ন বা অন্যান্য লজিক্যাল অপারেটর সহ ব্যবহৃত ওয়াইল্ডকার্ডগুলিকে চিনতে পারে না৷ ওয়াইল্ডকার্ড সমর্থনকারী ফাংশনগুলির তালিকাটি ঘনিষ্ঠভাবে পর্যবেক্ষণ করলে, আপনি লক্ষ্য করবেন যে তাদের সিনট্যাক্স একটি ওয়াইল্ডকার্ড টেক্সট অনুমান করে এই মত একটি আর্গুমেন্টে সরাসরি উপস্থিত হতে পারে:
=COUNTIF(A2:A10, "*a*")
Excel IF এ আংশিক পাঠ রয়েছে
এখন যেহেতু আপনি ওয়াইল্ডকার্ড IF সূত্র ব্যর্থ হওয়ার কারণ জানেন, আসুন এটি কীভাবে কাজ করা যায় তা খুঁজে বের করার চেষ্টা করি। এর জন্য, আমরা কেবল একটি ফাংশন এমবেড করব যা IF এর লজিক্যাল পরীক্ষায় ওয়াইল্ডকার্ড গ্রহণ করে, যথা COUNTIF ফাংশন:
IF(COUNTIF( cell , "* text * "), value_if_true, value_if_false)এই পদ্ধতির সাহায্যে, IF-এর ওয়াইল্ডকার্ড বোঝার ক্ষেত্রে কোনো সমস্যা নেই এবং ত্রুটিহীনভাবে "A" বা "a" ধারণ করা ঘরগুলিকে চিহ্নিত করে (যেহেতু COUNTIF কেস-সংবেদনশীল নয়):
=IF(COUNTIF(A2, "*a*"),"Yes", "No")
এই সূত্রটি B2 বা সারি 2-এর অন্য যেকোন ঘরে যায় এবং তারপরে আপনি এটিকে যতগুলি প্রয়োজন ততগুলি কোষে টেনে আনতে পারেন:
এই সমাধানটি একটি নির্দিষ্ট প্যাটার্নের স্ট্রিং সনাক্ত করতেও ব্যবহার করা যেতে পারে। হাইফেন দিয়ে আলাদা করা 2টি অক্ষরের 2টি গ্রুপ নিয়ে গঠিত শুধুমাত্র আইডিই বৈধ বলে ধরে নিলে আপনি "???-???" তাদের সনাক্ত করতে ওয়াইল্ডকার্ড স্ট্রিং:
=IF(COUNTIF(A2, "??-??"), "Valid", "")
এই সূত্রটি কীভাবে কাজ করে:
এর যৌক্তিক পরীক্ষার জন্য IF, আমরা COUNTIF ফাংশন ব্যবহার করি যা নির্দিষ্ট ওয়াইল্ডকার্ডের সাথে মিলে যাওয়া কক্ষের সংখ্যা গণনা করেস্ট্রিং যেহেতু মানদণ্ডের পরিসরটি একটি একক কক্ষ (A2), ফলাফলটি সর্বদা 1 (মিল পাওয়া গেছে) বা 0 (মিল পাওয়া যায়নি)। প্রদত্ত যে 1টি সত্যের সাথে এবং 0টি মিথ্যার সাথে সমান হয়, সূত্রটি "ভাল" (মান_ইফ_সত্য) প্রদান করে যখন গণনা 1 হয় এবং গণনা 0 হলে একটি খালি স্ট্রিং (মান_ইফ_ফলস) প্রদান করে।
আংশিক জন্য যদি নম্বর থাকে তবে অনুসন্ধান সূত্র মিলগুলি
আংশিক টেক্সট মিলের জন্য Excel IF কে কাজ করতে বাধ্য করার আরেকটি উপায় হল লজিক্যাল পরীক্ষায় FIND বা SEARCH ফাংশন অন্তর্ভুক্ত করা। পার্থক্য হল যে FIND কেস-সংবেদনশীল যখন SEARCH হয় না৷
সুতরাং, আপনি ছোট হাতের এবং বড় হাতের অক্ষরকে একই বা ভিন্ন অক্ষর হিসাবে বিবেচনা করতে চান কিনা তার উপর নির্ভর করে, এই সূত্রগুলির মধ্যে একটি একটি ট্রিট কাজ করবে:
কেস-সংবেদনশীল আংশিক মিলের সূত্র:
IF(ISNUMBER(SEARCH(" text ", cell )), value_if_true, value_if_false )কেস-সংবেদনশীল আংশিক মিলের সূত্র:
IF(ISNUMBER(FIND(" text ", cell )), value_if_true, value_if_false )যেহেতু উভয় ফাংশনই একটি "সেলে রয়েছে" ধরণের মিল করার জন্য ডিজাইন করা হয়েছে, তাই এই ক্ষেত্রে ওয়াইল্ডকার্ডের আসলেই প্রয়োজন নেই৷
উদাহরণস্বরূপ, "A" বা "a" যুক্ত আইডি সনাক্ত করতে , সূত্রটি হল:
=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")
শুধুমাত্র একটি মূলধন "A" অনুসন্ধান করতে এবং "a" উপেক্ষা করতে, সূত্রটি হল:
=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")
নীচের স্ক্রিনশটে B6-এ, আপনি ফলাফলের পার্থক্য লক্ষ্য করতে পারেন:
এই সূত্রটি কীভাবে কাজ করে:
এ হৃদয়সূত্রে, ISNUMBER এবং SEARCH (বা FIND) এর সংমিশ্রণ রয়েছে:
ISNUMBER(SEARCH("A", A2))
SEARCH ফাংশনটি নির্দিষ্ট পাঠ্যের সন্ধান করে (এই উদাহরণে "A") এবং এর মধ্যে তার অবস্থান ফিরিয়ে দেয় A2 এ একটি স্ট্রিং। যদি পাঠ্যটি পাওয়া না যায়, একটি #VALUE ত্রুটি ফেরত দেওয়া হয়৷ যেহেতু SEARCH এবং FIND উভয়ই একটি "সেলে রয়েছে" ধরণের মিল করার জন্য ডিজাইন করা হয়েছে, তাই এই ক্ষেত্রে ওয়াইল্ডকার্ডের আসলেই প্রয়োজন নেই৷
ISNUMBER ফাংশনটি একটি সংখ্যাকে সত্যে রূপান্তরিত করে এবং ত্রুটি সহ অন্য যেকোনো মানকে মিথ্যাতে রূপান্তরিত করে৷ . যৌক্তিক মান সরাসরি IF এর লজিক্যাল পরীক্ষায় যায়। আমাদের ক্ষেত্রে, A2-এ "A" থাকে, তাই ISNUMBER TRUE প্রদান করে:
IF(TRUE, "Yes", "No")
ফলাফল হিসেবে, IF value_if_true আর্গুমেন্টের জন্য সেট করা মান প্রদান করে, যা হল "হ্যাঁ"।
ওয়াইল্ডকার্ড সহ এক্সেল IF বা স্টেটমেন্ট
কোন কক্ষ চিহ্নিত করতে হবে যেখানে ওয়াইল্ডকার্ড পাঠ্য স্ট্রিংগুলির একটি রয়েছে? এই ক্ষেত্রে, আপনি উপরে আলোচিত COUNTIF বা ISNUMBER অনুসন্ধান সূত্রের সাথে ক্লাসিক IF OR বিবৃতিটি একত্রিত করতে পারেন।
উদাহরণস্বরূপ, A2 তে "aa" বা "bb" অনুসন্ধান করতে অক্ষরের কেসটি উপেক্ষা করে এবং ফিরে যান " হ্যাঁ" যদি দুটি পাওয়া যায় তবে এই সূত্রগুলির মধ্যে একটি ব্যবহার করুন:
=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")
বা
=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")
দুটি COUNTIF ফাংশন যোগ করাও কাজ করবে৷ এই ক্ষেত্রে, প্লাস চিহ্নটি OR অপারেটরের মতো কাজ করে:
=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")
সূত্রে ওয়াইল্ডকার্ড স্ট্রিংগুলি হার্ডকোড করার পরিবর্তে, আপনি সেগুলিকে আলাদা কক্ষে ইনপুট করতে পারেন, যেমন দেখানো হয়েছে D2 এবং F2 বলুন নিচের স্ক্রিনশটে। এই যে দয়া করে লক্ষ্য করুনসেল রেফারেন্সগুলি $ চিহ্ন দিয়ে লক করা হয়েছে যাতে সূত্রটি নীচের কক্ষগুলিতে সঠিকভাবে অনুলিপি করে:
=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")
উপরের সূত্রগুলি 2টি আংশিক মিলের জন্য ভাল কাজ করে , কিন্তু আপনি যদি 3 বা তার বেশি অনুসন্ধান করেন তবে সেগুলি খুব দীর্ঘ হয়ে যাবে৷ এই ক্ষেত্রে, এটি ভিন্নভাবে কাজটির কাছে যাওয়ার কারণ হিসাবে দাঁড়ায়:
একটি অ্যারের ধ্রুবকটিতে অনুসন্ধান ফাংশনে একাধিক সাবস্ট্রিং সরবরাহ করুন, ফিরে আসা সংখ্যাগুলি গণনা করুন এবং ফলাফলটি শূন্যের চেয়ে বেশি কিনা তা পরীক্ষা করুন (যার অর্থ হবে যে সাবস্ট্রিংগুলির মধ্যে অন্তত একটি পাওয়া গেলে:
=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")
এইভাবে, আপনি আরও কমপ্যাক্ট সূত্রের সাথে ঠিক একই ফলাফল পাবেন:
ওয়াইল্ডকার্ড সহ এক্সেল IF এবং সূত্র
যখন আপনি একটি ঘরে দুটি বা তার বেশি আলাদা সাবস্ট্রিং আছে কিনা তা পরীক্ষা করতে চান, সবচেয়ে সহজ উপায় হল লজিক্যাল পরীক্ষার জন্য ওয়াইল্ডকার্ড সহ COUNTIFS ফাংশন ব্যবহার করা৷<3
ধরুন আপনি কলাম A-তে ঘরগুলি সনাক্ত করতে চান যাতে "b" এবং "2" উভয়ই রয়েছে। এটি সম্পন্ন করতে, COUNTIFS-এর মানদণ্ডের জন্য "*b*" এবং "*2*" এবং মানদণ্ড পরিসরের জন্য A2 ব্যবহার করুন:
=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")
অন্য উপায় হল IF এবং সূত্র একসাথে ব্যবহার করা ISNUMBER এর সাথে অনুসন্ধান করুন:
=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")
যদিও আমরা এই সূত্রে কোনো ওয়াইল্ডকার্ড অক্ষর অন্তর্ভুক্ত করি না, তবে এটি দুটি ওয়াইল্ডকার্ড স্ট্রিং ("*b*" এবং "*2*" অনুসন্ধান করার মতো কাজ করে ) একই কক্ষে।
অবশ্যই, কোনো কিছুই আপনাকে পূর্বনির্ধারিত কক্ষে অনুসন্ধান মান প্রবেশ করতে বাধা দেয় না, আমাদের ক্ষেত্রে D2 এবং F2, এবং সরবরাহ করতেকক্ষ সূত্রের উল্লেখ করে:
=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")
যদি আপনি যেখানেই সম্ভব আরও কমপ্যাক্ট সূত্র ব্যবহার করতে পছন্দ করেন, তাহলে আপনি অ্যারে ধ্রুবক পদ্ধতির পছন্দ করতে পারেন। IF COUNT SEARCH সূত্রটি অনেকটা আগের উদাহরণের মতই, কিন্তু যেহেতু এবার উভয় সাবস্ট্রিংকে A2-তে উপস্থিত হতে হবে, তাই আমরা পরীক্ষা করি যে গণনাটি 2 এর সমান কিনা:
=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")
<17
এগুলি হল এক্সেলের IF স্টেটমেন্টে ওয়াইল্ডকার্ড ব্যবহার করার প্রধান পদ্ধতি। আপনি যদি অন্য কোন সমাধান জানেন, আপনি মন্তব্যে আপনার অভিজ্ঞতা শেয়ার করলে অন্য ব্যবহারকারীরা অবশ্যই প্রশংসা করবে। পড়ার জন্য আমি আপনাকে ধন্যবাদ জানাই এবং আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব বলে আশা করছি!
ডাউনলোডের জন্য অনুশীলন ওয়ার্কবুক
Excel IF ওয়াইল্ডকার্ড সূত্র উদাহরণ (.xlsx ফাইল)
