বিষয়বস্তুৰ তালিকা
ৱাইল্ডকাৰ্ড লিখনীৰ সৈতে এটা IF বিবৃতি নিৰ্মাণ কৰিবলৈ চেষ্টা কৰা হৈছে, কিন্তু ই প্ৰতিবাৰেই বিফল হয়? সমস্যাটো আপোনাৰ সূত্ৰত নহয় কিন্তু ফাংচনটোত নিজেই আছে - Excel IF এ ৱাইল্ডকাৰ্ড আখৰ সমৰ্থন নকৰে। কিন্তু, আংশিক লিখনী মিলৰ বাবে ইয়াক কাম কৰাৰ এটা উপায় আছে, আৰু এই টিউটোৰিয়েলে আপোনাক কেনেকৈ শিকাব।
যেতিয়াই আপুনি এক্সেলত আংশিক বা অস্পষ্ট মিলন কৰিব বিচাৰে, আটাইতকৈ স্পষ্ট সমাধান হ'ল ৱাইল্ডকাৰ্ড ব্যৱহাৰ কৰিবলৈ। কিন্তু যদি আপুনি ব্যৱহাৰ কৰিবলগীয়া এটা নিৰ্দিষ্ট ফাংচনে ৱাইল্ডকাৰ্ড আখৰসমূহ সমৰ্থন নকৰে তেন্তে কি হ'ব? দুখৰ বিষয় যে এক্সেল আই এফ এনেকুৱা এটা ফাংচন। এইটো বিশেষকৈ হতাশাজনক যে অন্য "চৰ্তসাপেক্ষ" ফাংচন যেনে COUNTIF, SUMIF, আৰু AVERAGEIFS এ ৱাইল্ডকাৰ্ডৰ সৈতে নিখুঁতভাৱে কাম কৰে।
ভাগ্য ভাল যে, ই এটা সৃষ্টিশীল এক্সেল ব্যৱহাৰকাৰীক ৰখাব পৰা বাধা নহয় :) IF সংযুক্ত কৰি অন্য ফাংচনসমূহৰ সৈতে, আপুনি ইয়াক এটা আংশিক মিল মূল্যায়ন কৰিবলৈ বাধ্য কৰিব পাৰে আৰু এটা Excel IF ৱাইল্ডকাৰ্ড সূত্ৰৰ এটা সুন্দৰ বিকল্প পাব পাৰে।
ৱাইল্ডকাৰ্ডৰ সৈতে Excel IF ফাংচনে কিয় কাম নকৰে
তলৰ নমুনা টেবুলত, ধৰি লওক আপুনি প্ৰথম স্তম্ভৰ আইডিসমূহত "A" আখৰ আছে নে নাই পৰীক্ষা কৰিব বিচাৰে। যদি পোৱা যায় - B স্তম্ভত "হয়" প্ৰদৰ্শন কৰক, যদি নহয় - "নাই" প্ৰদৰ্শন কৰক।
এয়া যেন লাগে যে লজিকেল পৰীক্ষাত ৱাইল্ডকাৰ্ড লিখনী অন্তৰ্ভুক্ত কৰাটো এটা সহজ সমাধান হ'ব:
=IF(A2="*a*","Yes", "No")
কিন্তু দুখৰ বিষয় যে ই কাম নকৰে। সূত্ৰটোৱে সকলো কোষৰ বাবে "নাই" ঘূৰাই দিয়ে, আনকি যিবোৰত "A" থাকে:
কিয় কৰেএটা ৱাইল্ডকাৰ্ড IF বিবৃতি বিফল? সকলো ৰূপৰ পৰা, এক্সেলে সমান চিহ্ন বা অন্য লজিকেল অপাৰেটৰৰ সৈতে ব্যৱহৃত ৱাইল্ডকাৰ্ড চিনি নাপায়। ৱাইল্ডকাৰ্ডসমূহ সমৰ্থন কৰা ফাংচনসমূহৰ তালিকাখন ভালদৰে চালে, আপুনি লক্ষ্য কৰিব যে সিহঁতৰ বাক্যবিন্যাসে এটা ৱাইল্ডকাৰ্ড লিখনীক এই ধৰণৰ এটা যুক্তিত প্ৰত্যক্ষভাৱে উপস্থিত হ'ব বুলি ধৰি লৈছে:
=COUNTIF(A2:A10, "*a*")
Excel IF ত আংশিক লিখনী<আছে 7>
এতিয়া যেতিয়া আপুনি এটা ৱাইল্ডকাৰ্ড IF সূত্ৰ বিফল হোৱাৰ কাৰণ জানে, তেতিয়া ইয়াক কেনেকৈ কামত লগাব পাৰি সেইটো বুজিবলৈ চেষ্টা কৰোঁ আহক। ইয়াৰ বাবে আমি কেৱল এটা ফাংচন এম্বেড কৰিম যিয়ে IF ৰ লজিকেল টেষ্টত ৱাইল্ডকাৰ্ড গ্ৰহণ কৰে, যথা COUNTIF ফাংচন:
IF(COUNTIF( cell , "* text * "), value_if_true, value_if_false)এই পদ্ধতিৰ সৈতে, IF ৰ ৱাইল্ডকাৰ্ডসমূহ বুজিবলৈ কোনো সমস্যা নাই আৰু ত্ৰুটিহীনভাৱে "A" বা "a" ধাৰণ কৰা কোষসমূহ চিনাক্ত কৰে (যিহেতু COUNTIF ডাঙৰ-বৰ-সংবেদনশীল নহয়):
=IF(COUNTIF(A2, "*a*"),"Yes", "No")
এই সূত্ৰটো B2, বা শাৰী 2 ৰ আন যিকোনো কোষলৈ যায়, আৰু তাৰ পিছত আপুনি ইয়াক প্ৰয়োজন অনুসৰি যিমান ঘৰলৈ টানিব পাৰে:
এই সমাধানটো এটা নিৰ্দিষ্ট আৰ্হিৰ স্ট্ৰিংসমূহ বিচাৰি উলিয়াবলৈও ব্যৱহাৰ কৰিব পাৰি । কেৱল হাইফেনেৰে পৃথক কৰা ২টা আখৰৰ ২টা গোটৰে গঠিত আইডিসমূহ বৈধ বুলি ধৰি ল'লে, আপুনি "??-??" ৱাইল্ডকাৰ্ড ষ্ট্ৰিং তেওঁলোকক চিনাক্ত কৰিবলৈ:
=IF(COUNTIF(A2, "??-??"), "Valid", "")
এই সূত্ৰই কেনেকৈ কাম কৰে:
ৰ যুক্তিসংগত পৰীক্ষাৰ বাবে IF, আমি COUNTIF ফাংচন ব্যৱহাৰ কৰো যিয়ে নিৰ্দিষ্ট ৱাইল্ডকাৰ্ডৰ সৈতে মিল থকা কোষৰ সংখ্যা গণনা কৰেতাঁৰ. যিহেতু মাপকাঠীৰ পৰিসৰ এটা একক কোষ (A2), ফলাফল সদায় ১ (মিল পোৱা গৈছে) বা ০ (মিল পোৱা নাযায়)। 1 TRUE আৰু 0 FALSE ৰ সমান বুলি ধৰি ল'লে, সূত্ৰই "Valid" (value_if_true) ঘূৰাই দিয়ে যেতিয়া গণনা 1 হয় আৰু এটা খালী ষ্ট্ৰিং (value_if_false) যেতিয়া গণনা 0 হয়।
IF ISNUMBER SEARCH আংশিকৰ বাবে সূত্ৰ matches
এক্সেল আইএফক আংশিক লিখনী মিলৰ বাবে কাম কৰিবলৈ বাধ্য কৰাৰ আন এটা উপায় হ'ল লজিকেল পৰীক্ষাত FIND বা SEARCH ফাংচন অন্তৰ্ভুক্ত কৰা। পাৰ্থক্যটো হ'ল FIND ডাঙৰ-বৰ-সংবেদনশীল আনহাতে SEARCH নহয়।
গতিকে, আপুনি সৰু আৰু ডাঙৰ আখৰক একে বা বেলেগ আখৰ হিচাপে গণ্য কৰিব বিচাৰে নে নাই তাৰ ওপৰত নিৰ্ভৰ কৰি, এই সূত্ৰসমূহৰ এটাই এটা ট্ৰিট কাম কৰিব:
আংশিক মিলৰ বাবে আখৰ-অসংবেদনশীল সূত্ৰ:
IF(ISNUMBER(SEARCH(" text ", cell )), value_if_true, value_if_false )আংশিক মিলৰ বাবে আখৰ-সংবেদনশীল সূত্ৰ:
IF(ISNUMBER(FIND(" পাঠ ", কোষ )), value_if_true, value_if_false )যিহেতু দুয়োটা ফাংচনক এটা "cell contains" ধৰণৰ মিল সম্পাদন কৰিবলে ডিজাইন কৰা হৈছে, এই ক্ষেত্ৰত ৱাইল্ডকাৰ্ডসমূহৰ প্ৰকৃত প্ৰয়োজন নাই।
উদাহৰণস্বৰূপে, "A" বা "a" ধাৰণ কৰা IDসমূহ ধৰা পেলাবলৈ। , সূত্ৰটো হ'ল:
=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")
কেৱল এটা ডাঙৰ "A" বিচাৰিবলৈ আৰু "a"ক আওকাণ কৰিবলৈ, সূত্ৰটো হ'ল:
=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")
তলৰ স্ক্ৰীণশ্বটত B6 ত, আপুনি ফলাফলৰ পাৰ্থক্য পৰ্যবেক্ষণ কৰিব পাৰে:
এই সূত্ৰটোৱে কেনেকৈ কাম কৰে:
এত... হৃদয়ৰসূত্ৰত, ISNUMBER আৰু SEARCH (বা FIND) ৰ এটা সংমিশ্ৰণ আছে:
ISNUMBER(SEARCH("A", A2))
SEARCH ফাংচনে ধাৰ্য্য কৰা লিখনী বিচাৰে (এই উদাহৰণত "A") আৰু ইয়াৰ ভিতৰত ইয়াৰ অৱস্থান ঘূৰাই দিয়ে A2 ত এটা ষ্ট্ৰিং। যদি লিখনী পোৱা নাযায়, এটা #VALUE ভুল ঘূৰাই দিয়া হয়। যিহেতু SEARCH আৰু FIND দুয়োটা এটা "চেল অন্তৰ্ভুক্ত" ধৰণৰ মিল সম্পাদন কৰিবলে ডিজাইন কৰা হৈছে, এই ক্ষেত্ৰত ৱাইল্ডকাৰ্ডৰ প্ৰকৃত প্ৰয়োজন নাই।
ISNUMBER ফাংচনে এটা সংখ্যাক TRUE লৈ আৰু ভুল অন্তৰ্ভুক্ত কৰি অন্য যিকোনো মানক FALSE লৈ ৰূপান্তৰ কৰে . লজিকেল মানটো পোনপটীয়াকৈ IF ৰ লজিকেল পৰীক্ষালৈ যায়। আমাৰ ক্ষেত্ৰত, A2 ত "A" থাকে, গতিকে ISNUMBER এ TRUE ঘূৰাই দিয়ে:
IF(TRUE, "Yes", "No")
ফলস্বৰূপে, IF এ value_if_true যুক্তিৰ বাবে ছেট কৰা মান ঘূৰাই দিয়ে, যিটো হৈছে "হয়".
ৱাইল্ডকাৰ্ডসমূহৰ সৈতে এক্সেল IF OR বিবৃতি
ৱাইল্ডকাৰ্ড লিখনী ষ্ট্ৰিংসমূহৰ এটা ধাৰণ কৰা কোষসমূহ চিনাক্ত কৰিব লাগিব? এই ক্ষেত্ৰত, আপুনি ওপৰত আলোচনা কৰা COUNTIF বা ISNUMBER SEARCH সূত্ৰৰ সৈতে ক্লাছিক IF OR বিবৃতি সংযুক্ত কৰিব পাৰে।
উদাহৰণস্বৰূপে, A2 ত "aa" বা "bb" সন্ধান কৰিবলৈ আখৰৰ কেছ আওকাণ কৰি আৰু " হয়" যদি যিকোনো এটা পোৱা যায়, এই সূত্ৰসমূহৰ এটা ব্যৱহাৰ কৰক:
=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")
বা
=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")
দুটা COUNTIF ফাংচন যোগ কৰিলেও কাম হ'ব। এই ক্ষেত্ৰত, যোগ চিহ্নে OR অপাৰেটৰৰ দৰে কাম কৰে:
=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")
সূত্ৰত ৱাইল্ডকাৰ্ড ষ্ট্ৰিংসমূহ হাৰ্ডক'ড কৰাৰ পৰিবৰ্তে, আপুনি সিহতক পৃথক কোষত ইনপুট কৰিব পাৰে, ধৰক D2 আৰু F2, দেখুৱাৰ দৰে তলৰ স্ক্ৰীণশ্বটত চাওক। অনুগ্ৰহ কৰি মন কৰক যে এইবোৰকোষ প্ৰসংগসমূহক $ চিহ্নৰ সৈতে লক কৰা হয় যাতে সূত্ৰটোৱে তলৰ কোষসমূহলে সঠিকভাৱে কপি কৰে:
=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")
ওপৰৰ সূত্ৰসমূহে 2 টা আংশিক মিলৰ বাবে ভাল কাম কৰে , কিন্তু যদি আপুনি ৩ বা তাতকৈ অধিক বিচাৰিছে, তেন্তে সেইবোৰ বহুত দীঘল হৈ পৰিব। এই ক্ষেত্ৰত, কাৰ্য্যটোৰ কাষ চাপিবলৈ যুক্তিসংগত:
এটা এৰে ধ্ৰুৱকত SEARCH ফাংচনলৈ একাধিক উপস্ট্ৰিং যোগান ধৰক, ঘূৰাই দিয়া সংখ্যাসমূহ গণনা কৰক, আৰু ফলাফল শূন্যতকৈ বেছি নেকি পৰীক্ষা কৰক (যাৰ অৰ্থ হ'ব যে যদি পোৱা যায় তেন্তে অন্ততঃ এটা উপস্ট্ৰিং):
=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")
এই ধৰণে, আপুনি এটা অধিক কমপেক্ট সূত্ৰৰ সৈতে একে ফলাফল পাব:
ৱাইল্ডকাৰ্ডৰ সৈতে IF AND সূত্ৰ এক্সেল কৰক
যেতিয়া আপুনি এটা কোষত দুটা বা তাতকৈ অধিক ভিন্ন উপস্ট্ৰিং আছে নে নাই পৰীক্ষা কৰিব বিচাৰে, আটাইতকৈ সহজ উপায় হ'ল লজিকেল পৰীক্ষাৰ বাবে ৱাইল্ডকাৰ্ডৰ সৈতে COUNTIFS ফলন ব্যৱহাৰ কৰা।
ধৰি লওক আপুনি A স্তম্ভত এনে কোষ বিচাৰিব বিচাৰে য'ত "b" আৰু "2" দুয়োটা থাকে। ইয়াক কৰিবলৈ, COUNTIFS ৰ মাপকাঠীৰ বাবে "*b*" আৰু "*2*" আৰু মাপকাঠীৰ পৰিসৰৰ বাবে A2 ব্যৱহাৰ কৰক:
=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")
আন এটা উপায় হ'ল IF AND সূত্ৰ একেলগে ব্যৱহাৰ কৰা with ISNUMBER SEARCH:
=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")
যদিও আমি এই সূত্ৰত কোনো ৱাইল্ডকাৰ্ড আখৰ অন্তৰ্ভুক্ত নকৰো, ই দুটা ৱাইল্ডকাৰ্ড ষ্ট্ৰিং ("*b*" আৰু "*2*" সন্ধান কৰাৰ দৰে কাম কৰে। ) একেটা কোষতে।
অৱশ্যেই, আপোনাক পূৰ্বনিৰ্ধাৰিত কোষত সন্ধান মানসমূহ প্ৰৱেশ কৰাত একোৱেই বাধা নিদিয়ে, আমাৰ ক্ষেত্ৰত D2 আৰু F2, আৰু যোগান ধৰাতযদি আপুনি সম্ভৱ হ'লে অধিক কমপেক্ট সূত্ৰ ব্যৱহাৰ কৰাটো পছন্দ কৰে, তেন্তে আপুনি এৰে ধ্ৰুৱক পদ্ধতি ভাল পাব পাৰে। IF COUNT SEARCH সূত্ৰটো পূৰ্বৰ উদাহৰণৰ দৰেই, কিন্তু কাৰণ এইবাৰ দুয়োটা উপষ্ট্ৰিং A2 ত দেখা দিব লাগিব, আমি গণনাটো 2:
=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")
<17 ৰ সমান নেকি পৰীক্ষা কৰোঁ>
এক্সেলত IF ষ্টেটমেন্টত ৱাইল্ডকাৰ্ড ব্যৱহাৰ কৰাৰ এইবোৰেই মূল পদ্ধতি। যদি আপুনি আন কোনো সমাধান জানে, তেন্তে আপুনি আপোনাৰ অভিজ্ঞতা মন্তব্যত শ্বেয়াৰ কৰিলে আন ব্যৱহাৰকাৰীসকলে নিশ্চয় শলাগ ল’ব। মই আপোনাক পঢ়াৰ বাবে ধন্যবাদ জনাইছো আৰু অহা সপ্তাহত আমাৰ ব্লগত আপোনাক লগ পাম বুলি আশা কৰিছো!
ডাউনল'ডৰ বাবে অনুশীলন কাৰ্য্যপুস্তিকা
এক্সেল আইএফ ৱাইল্ডকাৰ্ড সূত্ৰৰ উদাহৰণ (.xlsx ফাইল)
