विषयसूची
वाइल्डकार्ड टेक्स्ट के साथ IF स्टेटमेंट बनाने की कोशिश कर रहे हैं, लेकिन यह हर बार विफल हो जाता है? समस्या आपके सूत्र में नहीं बल्कि फ़ंक्शन में ही है - Excel IF वाइल्डकार्ड वर्णों का समर्थन नहीं करता है। हालांकि, आंशिक पाठ मिलान के लिए इसे काम में लाने का एक तरीका है, और यह ट्यूटोरियल आपको सिखाएगा कि कैसे।
जब भी आप एक्सेल में आंशिक या अस्पष्ट मिलान करना चाहते हैं, तो सबसे स्पष्ट समाधान है वाइल्डकार्ड का उपयोग करने के लिए। लेकिन क्या होगा यदि कोई विशिष्ट फ़ंक्शन जिसे आपको उपयोग करने की आवश्यकता है, वाइल्डकार्ड वर्णों का समर्थन नहीं करता है? अफसोस की बात है कि एक्सेल IF ऐसे कार्यों में से एक है। यह विचार करते हुए विशेष रूप से निराशाजनक है कि अन्य "सशर्त" फ़ंक्शन जैसे कि COUNTIF, SUMIF, और AVERAGEIFS वाइल्डकार्ड के साथ पूरी तरह से अच्छी तरह से काम करते हैं। अन्य कार्यों के साथ, आप इसे एक आंशिक मिलान का मूल्यांकन करने के लिए बाध्य कर सकते हैं और एक्सेल IF वाइल्डकार्ड सूत्र का एक अच्छा विकल्प प्राप्त कर सकते हैं।> नीचे दी गई नमूना तालिका में, मान लीजिए कि आप यह जांचना चाहते हैं कि पहले कॉलम की आईडी में "ए" अक्षर है या नहीं। यदि मिला - कॉलम बी में "हां" प्रदर्शित करें, यदि नहीं - "नहीं" प्रदर्शित करें।
ऐसा लगता है कि तार्किक परीक्षण में वाइल्डकार्ड पाठ शामिल करना एक आसान समाधान होगा:
=IF(A2="*a*","Yes", "No") <3
लेकिन अफसोस की बात है कि यह काम नहीं करता। सूत्र सभी कक्षों के लिए "नहीं" लौटाता है, यहां तक कि उनमें भी जिनमें "A" है:
ऐसा क्यों होता हैएक वाइल्डकार्ड IF कथन विफल? सभी दिखावे से, एक्सेल एक समान चिह्न या अन्य तार्किक ऑपरेटरों के साथ उपयोग किए जाने वाले वाइल्डकार्ड को नहीं पहचानता है। वाइल्डकार्ड का समर्थन करने वाले कार्यों की सूची पर करीब से नजर डालने पर, आप देखेंगे कि उनका सिंटैक्स वाइल्डकार्ड टेक्स्ट को सीधे तर्क में प्रकट होने के लिए मानता है:
=COUNTIF(A2:A10, "*a*")
Excel IF में आंशिक टेक्स्ट है
अब जबकि आप जानते हैं कि वाइल्डकार्ड IF फ़ॉर्मूला के विफल होने का कारण क्या है, तो आइए यह पता लगाने का प्रयास करें कि इसे कैसे काम में लाया जाए। इसके लिए, हम केवल एक फ़ंक्शन एम्बेड करेंगे जो IF के तार्किक परीक्षण में वाइल्डकार्ड स्वीकार करता है, अर्थात् COUNTIF फ़ंक्शन:
IF(COUNTIF( cell , "* text * "), value_if_true, value_if_false)इस दृष्टिकोण के साथ, IF को वाइल्डकार्ड को समझने में कोई समस्या नहीं है और त्रुटिपूर्ण रूप से उन सेल की पहचान करता है जिनमें "A" या "a" होता है (चूंकि COUNTIF केस-संवेदी नहीं है):
=IF(COUNTIF(A2, "*a*"),"Yes", "No")
यह सूत्र B2, या पंक्ति 2 में किसी अन्य सेल में जाता है, और फिर आप इसे आवश्यकतानुसार कई सेल तक नीचे खींच सकते हैं:
इस समाधान का उपयोग विशिष्ट पैटर्न के स्ट्रिंग्स का पता लगाने के लिए भी किया जा सकता है। यह मानते हुए कि एक हाइफ़न से अलग किए गए 2 वर्णों के 2 समूहों वाली आईडी ही मान्य हैं, आप "??-??" का उपयोग कर सकते हैं। उनकी पहचान करने के लिए वाइल्डकार्ड स्ट्रिंग:
=IF(COUNTIF(A2, "??-??"), "Valid", "")
यह सूत्र कैसे काम करता है:
तार्किक परीक्षण के लिए IF, हम COUNTIF फ़ंक्शन का उपयोग करते हैं जो निर्दिष्ट वाइल्डकार्ड से मेल खाने वाली कोशिकाओं की संख्या की गणना करता हैडोरी। चूँकि मानदंड श्रेणी एक एकल कक्ष (A2) है, परिणाम हमेशा 1 (मिलान पाया जाता है) या 0 (मिलान नहीं मिलता) होता है। यह देखते हुए कि 1 TRUE के बराबर है और 0 FALSE के बराबर है, गणना 1 होने पर सूत्र "मान्य" (value_if_true) लौटाता है और जब गिनती 0 होती है तो एक खाली स्ट्रिंग (value_if_false) देता है।
IF ISNUMBER आंशिक के लिए खोज सूत्र मिलान
Excel IF को आंशिक पाठ मिलान के लिए कार्य करने के लिए बाध्य करने का दूसरा तरीका तार्किक परीक्षण में FIND या SEARCH फ़ंक्शन को शामिल करना है। अंतर यह है कि FIND केस-संवेदी है जबकि SEARCH नहीं है।
इसलिए, इस पर निर्भर करते हुए कि क्या आप लोअरकेस और अपरकेस को समान या भिन्न वर्णों के रूप में मानना चाहते हैं, इनमें से कोई एक फ़ॉर्मूला आपके लिए उपयोगी होगा:<3
आंशिक मिलान के लिए केस-इनसेंसिटिव फॉर्मूला:
IF(ISNUMBER(SEARCH(" text ", cell )), value_if_true, value_if_false )आंशिक मिलान के लिए केस-संवेदी सूत्र:
IF(ISNUMBER(FIND(" text ", cell )), value_if_true, value_if_false )चूंकि दोनों कार्यों को "सेल में शामिल" प्रकार के मिलान के लिए डिज़ाइन किया गया है, इस मामले में वास्तव में वाइल्डकार्ड की आवश्यकता नहीं है।
उदाहरण के लिए, "ए" या "ए" वाली आईडी का पता लगाने के लिए , सूत्र है:
=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")
केवल एक बड़े "A" की खोज करने और "a" को अनदेखा करने के लिए, सूत्र है:
=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")
नीचे दिए गए स्क्रीनशॉट में B6 में, आप परिणाम में अंतर देख सकते हैं:
यह सूत्र कैसे काम करता है:
पर इसका दिलसूत्र, ISNUMBER और SEARCH (या FIND) का एक संयोजन है:
ISNUMBER(SEARCH("A", A2))
SEARCH फ़ंक्शन निर्दिष्ट पाठ (इस उदाहरण में "A") की तलाश करता है और इसके भीतर अपनी स्थिति लौटाता है A2 में एक स्ट्रिंग। यदि पाठ नहीं मिलता है, तो एक #VALUE त्रुटि दी जाती है। जैसा कि SEARCH और FIND दोनों को "सेल में शामिल" प्रकार के मिलान के लिए डिज़ाइन किया गया है, इस मामले में वाइल्डकार्ड की वास्तव में आवश्यकता नहीं है।
ISNUMBER फ़ंक्शन किसी संख्या को TRUE और त्रुटि सहित किसी भी अन्य मान को FALSE में बदल देता है . तार्किक मान सीधे IF के तार्किक परीक्षण में जाता है। हमारे मामले में, A2 में "A" शामिल है, इसलिए ISNUMBER रिटर्न TRUE:
IF(TRUE, "Yes", "No")
परिणामस्वरूप, IF value_if_true तर्क के लिए निर्धारित मान लौटाता है, जो है "हाँ"।
वाइल्डकार्ड के साथ एक्सेल IF OR स्टेटमेंट
ऐसे सेल की पहचान करने की आवश्यकता है जिनमें वाइल्डकार्ड टेक्स्ट स्ट्रिंग्स में से एक हो? इस मामले में, आप क्लासिक IF OR स्टेटमेंट को ऊपर बताए गए COUNTIF या ISNUMBER SEARCH फॉर्मूला के साथ जोड़ सकते हैं। हाँ" यदि कोई मिलता है, तो इनमें से किसी एक सूत्र का उपयोग करें:
=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")
या
=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")
दो COUNTIF फ़ंक्शन जोड़ने से भी काम चल जाएगा। इस मामले में, धन चिह्न OR ऑपरेटर की तरह काम करता है:
=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")
फ़ॉर्मूला में वाइल्डकार्ड स्ट्रिंग को हार्डकोड करने के बजाय, आप उन्हें अलग-अलग सेल में इनपुट कर सकते हैं, जैसे कि D2 और F2, जैसा कि दिखाया गया है नीचे स्क्रीनशॉट में। कृपया ध्यान दें कि येसेल संदर्भों को $ चिन्ह के साथ बंद कर दिया जाता है ताकि सूत्र नीचे के कक्षों में सही ढंग से कॉपी हो जाए:
=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")
उपरोक्त सूत्र 2 आंशिक मिलानों के लिए अच्छी तरह से काम करते हैं , लेकिन यदि आप 3 या अधिक खोज रहे हैं, तो वे बहुत लंबे हो जाएंगे। इस मामले में, कार्य को अलग तरीके से करने का कारण बनता है:
एक सरणी स्थिरांक में SEARCH फ़ंक्शन के लिए एकाधिक सबस्ट्रिंग्स की आपूर्ति करें, लौटाए गए नंबरों की गणना करें, और जांचें कि क्या परिणाम शून्य से अधिक है (जिसका अर्थ होगा कि कम से कम एक सबस्ट्रिंग मिल जाए तो):
=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")
इस तरह, आपको एक अधिक कॉम्पैक्ट सूत्र के साथ ठीक वही परिणाम मिलेगा:
वाइल्डकार्ड के साथ एक्सेल IF AND फॉर्मूला
जब आप यह जांचना चाहते हैं कि किसी सेल में दो या दो से अधिक अलग-अलग सबस्ट्रिंग हैं, तो तार्किक परीक्षण के लिए वाइल्डकार्ड के साथ COUNTIFS फ़ंक्शन का उपयोग करना सबसे आसान तरीका है।<3
मान लीजिए कि आप कॉलम A में उन सेल का पता लगाना चाहते हैं जिनमें "b" और "2" दोनों हैं। इसे पूरा करने के लिए, COUNTIFS के मानदंड के लिए "*b*" और "*2*" का उपयोग करें और मानदंड श्रेणी के लिए A2 का उपयोग करें:
=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")
एक और तरीका यह है कि IF AND सूत्र का एक साथ उपयोग किया जाए ISNUMBER खोज के साथ:
=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")
हालांकि हम इस सूत्र में कोई भी वाइल्डकार्ड वर्ण शामिल नहीं करते हैं, यह दो वाइल्डकार्ड स्ट्रिंग्स ("*b*" और "*2*" की तरह काम करता है ) एक ही सेल में।
बेशक, कुछ भी आपको हमारे मामले में पूर्वनिर्धारित सेल, D2 और F2 में खोज मान दर्ज करने और आपूर्ति करने से नहीं रोकता हैसूत्र के लिए सेल संदर्भ:
=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")
यदि आप जहां भी संभव हो, अधिक कॉम्पैक्ट सूत्रों का उपयोग करना पसंद करते हैं, तो आप सरणी स्थिर दृष्टिकोण को बेहतर ढंग से पसंद कर सकते हैं। IF COUNT SEARCH फॉर्मूला पिछले उदाहरण की तरह ही है, लेकिन क्योंकि इस बार दोनों सबस्ट्रिंग A2 में दिखाई देने चाहिए, हम जांचते हैं कि क्या गिनती 2 के बराबर है:
=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")
<17
एक्सेल में IF स्टेटमेंट में वाइल्डकार्ड का उपयोग करने के ये मुख्य तरीके हैं। यदि आप कोई अन्य समाधान जानते हैं, तो यदि आप टिप्पणियों में अपना अनुभव साझा करते हैं तो अन्य उपयोगकर्ता निश्चित रूप से सराहना करेंगे। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और उम्मीद करता हूं कि अगले सप्ताह हमारे ब्लॉग पर आपसे मुलाकात होगी!
डाउनलोड के लिए प्रैक्टिस वर्कबुक
Excel IF वाइल्डकार्ड फॉर्मूला उदाहरण (.xlsx फ़ाइल)
