Wildcard စာသားဖြင့် IF ထုတ်ပြန်ချက်ကို တည်ဆောက်ရန် ကြိုးစားနေသော်လည်း အချိန်တိုင်း မအောင်မြင်ပါ။ ပြဿနာသည် သင့်ဖော်မြူလာတွင်မဟုတ်သော်လည်း လုပ်ဆောင်ချက်ကိုယ်တိုင်၌ - Excel IF သည် wildcard စာလုံးများကို မပံ့ပိုးပါ။ သို့သော်၊ တစ်စိတ်တစ်ပိုင်း စာသားကိုက်ညီမှု အတွက် လုပ်ဆောင်ရန် နည်းလမ်းတစ်ခု ရှိပြီး၊ ဤသင်ခန်းစာသည် သင့်အား မည်ကဲ့သို့ သင်ပေးမည်နည်း။

Excel တွင် တစ်စိတ်တစ်ပိုင်း သို့မဟုတ် မပီမသ ကိုက်ညီမှု ပြုလုပ်လိုသည့်အခါတိုင်း၊ အထင်ရှားဆုံး ဖြေရှင်းချက်မှာ၊ သင်္ကေတများကို အသုံးပြုရန်။ သို့သော် သင်အသုံးပြုရန်လိုအပ်သည့် တိကျသောလုပ်ဆောင်ချက်တစ်ခုသည် wildcards အက္ခရာများကို မပံ့ပိုးပါက ဘာဖြစ်မည်နည်း။ ဝမ်းနည်းစရာမှာ Excel IF သည် ထိုကဲ့သို့သောလုပ်ဆောင်ချက်များထဲမှ တစ်ခုဖြစ်သည်။ COUNTIF၊ SUMIF၊ နှင့် AVERAGEIFS ကဲ့သို့သော အခြားသော "အခြေအနေအလိုက်" လုပ်ဆောင်ချက်များသည် wildcards များဖြင့် ကောင်းစွာအလုပ်လုပ်သည်ကို ထည့်သွင်းစဉ်းစားခြင်းသည် အထူးသဖြင့် စိတ်ပျက်စရာကောင်းပါသည်။

ကံကောင်းစွာဖြင့်၊ ၎င်းသည် တီထွင်ဖန်တီးထားသော Excel အသုံးပြုသူတစ်ဦးအား ရပ်တန့်နိုင်သည့် အတားအဆီးမဟုတ်ပါ :) IF ကို ပေါင်းစပ်ခြင်းဖြင့် အခြားလုပ်ဆောင်ချက်များဖြင့်၊ တစ်စိတ်တစ်ပိုင်းကိုက်ညီမှုကို အကဲဖြတ်ရန်နှင့် Excel IF wildcard ဖော်မြူလာအတွက် ကောင်းသောရွေးချယ်မှုတစ်ခုရနိုင်သည်။

အဘယ်ကြောင့် Excel IF လုပ်ဆောင်ချက်သည် wildcard ဖြင့် အလုပ်မလုပ်ရသနည်း

အောက်ပါနမူနာဇယားတွင်၊ ပထမကော်လံရှိ ID များတွင် စာလုံး "A" ပါဝင်ခြင်းရှိမရှိ စစ်ဆေးလိုသည်ဆိုပါစို့။ တွေ့ရှိပါက - ကော်လံ B တွင် "Yes" ကိုပြပါ၊ မဟုတ်ပါက - "No" ကိုပြသပါ။

ယုတ္တိဗေဒစမ်းသပ်မှုတွင် wildcard စာသားထည့်သွင်းခြင်းသည် လွယ်ကူသောဖြေရှင်းချက်ဖြစ်ပုံရသည်-

=IF(A2="*a*","Yes", "No")

ဒါပေမယ့် ဝမ်းနည်းစရာကောင်းတာက အလုပ်မလုပ်ပါဘူး။ ဖော်မြူလာသည် "A" ပါရှိသော ဆဲလ်များအားလုံးအတွက် "No" ကို ပြန်ပေးသည်-

ဘာကြောင့်ဖြစ်သနည်း။သင်္ကေတတစ်ခု IF ထုတ်ပြန်ချက် ပျက်ကွက်ပါသလား။ အသွင်အပြင်အားလုံးမှ Excel သည် တူညီသောသင်္ကေတ သို့မဟုတ် အခြားယုတ္တိရှိသော အော်ပရေတာများဖြင့် အသုံးပြုထားသော ခရင်မ်ကတ်များကို အသိအမှတ်မပြုပါ။ ခရင်မ်ကတ်များကို ပံ့ပိုးပေးသည့် လုပ်ဆောင်ချက်များစာရင်းကို အနီးကပ်ကြည့်ရှုခြင်းဖြင့်၊ ၎င်းတို့၏ syntax သည် ဤကဲ့သို့သော အငြင်းအခုံတစ်ခုတွင် တိုက်ရိုက်ပေါ်လာစေရန် ၎င်းတို့၏ syntax မှ wildcard စာသားဟု ယူဆသည်-

=COUNTIF(A2:A10, "*a*")

Excel IF တွင် တစ်စိတ်တစ်ပိုင်းစာသားပါရှိသည်

ယခုအခါတွင် wildcard IF ဖော်မြူလာတစ်ခု ပျက်သွားရသည့် အကြောင်းရင်းကို သင်သိပြီဆိုလျှင် ၎င်းကို မည်သို့လုပ်ဆောင်ရမည်ကို အဖြေရှာကြည့်ကြပါစို့။ ၎င်းအတွက်၊ ကျွန်ုပ်တို့သည် IF ၏ ယုတ္တိစမ်းသပ်မှုတွင် သင်္ကေတများကို လက်ခံသည့် လုပ်ဆောင်ချက်တစ်ခုကို ရိုးရှင်းစွာ ထည့်သွင်းထားမည်ဖြစ်ပြီး၊ အတိအကျအားဖြင့် COUNTIF လုပ်ဆောင်ချက်-

ဤချဉ်းကပ်မှုဖြင့်၊ IF သည် wildcards များကို နားလည်ပြီး "A" သို့မဟုတ် "a" ပါရှိသော ဆဲလ်များကို အပြစ်အနာအဆာမရှိဘဲ ခွဲခြားသတ်မှတ်ပေးသည် (COUNTIF သည် စာလုံးအကြီးအသေးမဟုတ်သည့်အတွက်ကြောင့်)

=IF(COUNTIF(A2, "*a*"),"Yes", "No")

ဤဖော်မြူလာသည် B2 သို့မဟုတ် အတန်း 2 ရှိ အခြားဆဲလ်တစ်ခုခုသို့သွားသည်၊ ထို့နောက် ၎င်းကို လိုအပ်သလို ဆဲလ်များစွာသို့ ဆွဲယူနိုင်သည်-

ဤဖြေရှင်းချက်ကို သတ်မှတ်ပုံစံတစ်ခု၏ ကြိုးတန်းများ ကို ရှာဖွေရန်လည်း အသုံးပြုနိုင်သည်။ တုံးတိုဖြင့် ခွဲထားသော စာလုံး 2 လုံးပါသော အုပ်စု 2 ခုပါသော ID များသာ မှန်ကန်သည်ဟု ယူဆပါက သင်သည် "??-???" ကို သုံးနိုင်သည်။ ၎င်းတို့ကို ခွဲခြားသတ်မှတ်ရန် wildcard string-

=IF(COUNTIF(A2, "??-??"), "Valid", "")

ဤဖော်မြူလာအလုပ်လုပ်ပုံ-

ယုတ္တိဗေဒစမ်းသပ်မှုအတွက် IF၊ ကျွန်ုပ်တို့သည် သတ်မှတ်ထားသော သင်္ကေတနှင့် ကိုက်ညီသော ဆဲလ်အရေအတွက်ကို ရေတွက်သည့် COUNTIF လုပ်ဆောင်ချက်ကို အသုံးပြုပါသည်။ကြိုးတစ်ချောင်း။ စံသတ်မှတ်ချက်အပိုင်းအခြားသည် ဆဲလ်တစ်ခုတည်း (A2) ဖြစ်သောကြောင့် ရလဒ်သည် အမြဲတမ်း 1 (ကိုက်ညီသည်ကို တွေ့ရှိသည်) သို့မဟုတ် 0 (ကိုက်ညီမှုမတွေ့ပါ)။ 1 သည် TRUE နှင့် 0 နှင့် FALSE နှင့် ညီမျှသောကြောင့် ဖော်မြူလာသည် 1 နှင့် 0 ဖြစ်သောအခါ count သည် "Valid" (value_if_true) နှင့် string အလွတ်တစ်ခု (value_if_false) ဖြစ်သည်။

IF ISNUMBER SEARCH ဖော်မြူလာသည် တစ်စိတ်တစ်ပိုင်းဖြစ်သည် ကိုက်ညီမှုများ

တစ်စိတ်တစ်ပိုင်း စာသားကိုက်ညီမှုအတွက် Excel IF အား အလုပ်လုပ်ရန် အခြားနည်းလမ်းမှာ ယုတ္တိဗေဒစမ်းသပ်မှုတွင် FIND သို့မဟုတ် SEARCH လုပ်ဆောင်ချက်ကို ထည့်သွင်းရန်ဖြစ်သည်။ ခြားနားချက်မှာ FIND သည် SEARCH မဟုတ်သော်လည်း စာလုံးအသေးအလိုက် အကဲဆတ်သည်။

ထို့ကြောင့် သင်သည် စာလုံးသေးနှင့် စာလုံးကြီးများကို တူညီသော သို့မဟုတ် ကွဲပြားသော ဇာတ်ကောင်အဖြစ် ဆက်ဆံလိုခြင်းအပေါ် မူတည်၍ ဤဖော်မြူလာများထဲမှ တစ်ခုသည် ကုသပေးလိမ့်မည်-

တစ်စိတ်တစ်ပိုင်းကိုက်ညီမှုအတွက် စာလုံးအသေးမပါသော ဖော်မြူလာ-

တစ်စိတ်တစ်ပိုင်းကိုက်ညီမှုအတွက် စာလုံးအသေး-အထိခိုက်မခံ ဖော်မြူလာ-

လုပ်ဆောင်ချက်နှစ်ခုလုံးသည် "ဆဲလ်ပါရှိသော" ကိုက်ညီမှုအမျိုးအစားကိုလုပ်ဆောင်ရန် ဒီဇိုင်းထုတ်ထားသောကြောင့်၊ ဤကိစ္စတွင် သင်္ကေတများသည် အမှန်တကယ်မလိုအပ်ပါ။

ဥပမာ၊ "A" သို့မဟုတ် "a" ပါရှိသော ID များကို ရှာဖွေရန်၊ ဖော်မြူလာမှာ-

=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")

မြို့တော် "A" ကိုရှာဖွေပြီး "a ကိုလျစ်လျူရှုရန်" ဖော်မြူလာမှာ-

=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")

အောက်ဖော်ပြပါ ဖန်သားပြင်ဓာတ်ပုံရှိ B6 တွင်၊ ရလဒ်၏ကွာခြားချက်ကို သင်ကြည့်ရှုနိုင်သည်-

ဤဖော်မြူလာအလုပ်လုပ်ပုံ-

တွင်၊ နှလုံးဖော်မြူလာ၊ ISNUMBER နှင့် SEARCH (သို့မဟုတ် FIND) ပေါင်းစပ်ပါ၀င်သည်-

ISNUMBER(SEARCH("A", A2))

ရှာဖွေမှုလုပ်ဆောင်ချက်သည် သတ်မှတ်ထားသောစာသား ("A" ကို ဤဥပမာရှိ) ရှာဖွေပြီး အတွင်းတွင် ၎င်း၏အနေအထားကို ပြန်ပေးသည်။ A2 တွင် ကြိုးတစ်ချောင်း။ စာသားကို ရှာမတွေ့ပါက၊ #VALUE အမှားတစ်ခု ပြန်ပေါ်လာသည်။ SEARCH နှင့် FIND နှစ်ခုစလုံးသည် "ဆဲလ်ပါရှိသော" ကိုက်ညီမှုအမျိုးအစားကိုလုပ်ဆောင်ရန် ဒီဇိုင်းထုတ်ထားသောကြောင့် ဤကိစ္စတွင် သင်္ကေတများသည် အမှန်တကယ်မလိုအပ်ပါ။

ISNUMBER လုပ်ဆောင်ချက်သည် နံပါတ်တစ်ခုအား TRUE အဖြစ်သို့ပြောင်းလဲပေးပြီး အမှားအယွင်းအပါအဝင် အခြားတန်ဖိုးများကို FALSE သို့ပြောင်းပေးသည် . ယုတ္တိတန်ဖိုးသည် IF ၏ ယုတ္တိစမ်းသပ်မှုသို့ တိုက်ရိုက်သွားပါသည်။ ကျွန်ုပ်တို့၏အခြေအနေတွင်၊ A2 တွင် "A" ပါဝင်သောကြောင့် ISNUMBER သည် TRUE ဖြစ်သည်-

IF(TRUE, "Yes", "No")

ရလဒ်အနေဖြင့် IF သည် value_if_true အငြင်းအခုံအတွက် သတ်မှတ်ထားသောတန်ဖိုးကို ပြန်ပေးသည်၊၊ "Yes"။

Excel IF OR ကြေငြာချက်တွင် သင်္ကေတများပါသည့်

Wildcard စာတန်းများထဲမှ တစ်ခုပါရှိသော ဆဲလ်များကို ခွဲခြားသတ်မှတ်ရန် လိုအပ်ပါသလား။ ဤကိစ္စတွင်၊ သင်သည် အထက်တွင်ဖော်ပြထားသော ဆွေးနွေးထားသော COUNTIF သို့မဟုတ် ISNUMBER SEARCH ဖော်မြူလာနှင့် မူရင်း IF OR ကြေညာချက်ကို ပေါင်းစပ်နိုင်သည်။

ဥပမာ၊ A2 ရှိ "aa" OR "bb" ကိုရှာဖွေရန် စာလုံးအသေးကို လျစ်လျူရှုပြီး ပြန်ပို့ရန် " ဟုတ်သည်" တစ်ခုခုကို တွေ့ရှိပါက၊ ဤဖော်မြူလာများထဲမှ တစ်ခုကို အသုံးပြုပါ-

=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")

သို့မဟုတ်

=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")

COUNTIF လုပ်ဆောင်ချက်နှစ်ခုကို ပေါင်းထည့်ခြင်းသည်လည်း အလုပ်ဖြစ်ပါမည်။ ဤကိစ္စတွင်၊ အပေါင်းလက္ခဏာသည် OR အော်ပရေတာကဲ့သို့ အလုပ်လုပ်သည်-

=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")

ဖော်မြူလာတွင် hardcoding wildcard strings များအစား၊ ၎င်းတို့ကို သီးခြားဆဲလ်များတွင် ထည့်သွင်းနိုင်သည်၊ ပြထားသည့်အတိုင်း D2 နှင့် F2 ဟုပြောပါ။ အောက်ပါ screenshot တွင်။ ဒါတွေကို သတိပြုပါ။ဆဲလ်ကိုးကားချက်များကို $ သင်္ကေတဖြင့် လော့ခ်ချထားသောကြောင့် ဖော်မြူလာကို အောက်ဖော်ပြပါဆဲလ်များသို့ မှန်ကန်စွာကူးယူနိုင်စေရန်-

=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")

အထက်ပါဖော်မြူလာများသည် တစ်စိတ်တစ်ပိုင်းကိုက်ညီမှု 2 ခုအတွက် ကောင်းစွာအလုပ်လုပ်သည် 3 သို့မဟုတ် ထို့ထက်ပို၍ ရှာဖွေနေပါက ၎င်းတို့သည် ရှည်လျားလွန်းလှသည်။ ဤကိစ္စတွင်၊ ၎င်းသည် အလုပ်အား ကွဲပြားစွာချဉ်းကပ်ရန် အကြောင်းပြချက်ဖြစ်သည်-

SEARCH လုပ်ဆောင်ချက်ကို အဆက်မပြတ်တစ်ခုအတွင်း အပိုင်းခွဲများစွာကို ပံ့ပိုးပေးခြင်း၊ ပြန်ပေးထားသော နံပါတ်များကို ရေတွက်ပြီး ရလဒ်သည် သုညထက် ကြီးခြင်းရှိမရှိ စစ်ဆေးပါ ( ဆိုလိုသည်မှာ ဆိုလိုသည်မှာ၊ အနည်းဆုံး စာကြောင်းခွဲများထဲမှ တစ်ခုကို တွေ့ရှိပါက--

=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")

ဤနည်းဖြင့် သင်သည် ပိုမိုကျစ်လစ်သော ဖော်မြူလာဖြင့် တူညီသောရလဒ်ကို ရရှိလိမ့်မည်-

သင်္ကေတများဖြင့် Excel IF AND ဖော်မြူလာ

ဆဲလ်တစ်ခုတွင် မတူညီသောစာကြောင်းခွဲနှစ်ခု သို့မဟုတ် ထို့ထက်မက ပါဝင်ခြင်းရှိ၊>

"b" နှင့် "2" နှစ်ခုလုံးပါရှိသော ကော်လံ A တွင် ဆဲလ်များကို သင်ရှာဖွေလိုသည်ဆိုပါစို့။ ၎င်းကိုလုပ်ဆောင်ရန်၊ COUNTIFS ၏စံသတ်မှတ်ချက်များနှင့် A2 အတွက် စံသတ်မှတ်ချက်အပိုင်းအခြားအတွက် "*b*" နှင့် "*2*" ကိုသုံးပါ-

=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")

နောက်တနည်းမှာ IF AND ဖော်မြူလာကို အတူတကွအသုံးပြုရန်ဖြစ်သည်။ ISNUMBER ဖြင့်ရှာဖွေခြင်း-

=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")

ကျွန်ုပ်တို့သည် ဤဖော်မြူလာတွင် မည်သည့် သင်္ကေတစာလုံးမျှ မပါဝင်သော်လည်း၊ ၎င်းသည် သင်္ကေတစာကြောင်းနှစ်ခုကို ရှာဖွေခြင်းကဲ့သို့ လုပ်ဆောင်သည် ("*b*" နှင့် "*2*" တူညီသောဆဲလ်တွင် )။

ဟုတ်ပါသည်၊ ကျွန်ုပ်တို့၏ကိစ္စတွင် ကြိုတင်သတ်မှတ်ထားသောဆဲလ်များ၊ D2 နှင့် F2 တို့တွင် ရှာဖွေမှုတန်ဖိုးများကို ဝင်ရောက်ခြင်းမှ မည်သည့်အရာကမှ သင့်ကို တားဆီးထားခြင်းမရှိပါ။ဖော်မြူလာကို ဆဲလ်မှ ရည်ညွှန်းသည်-

=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")

ပို၍ ကျစ်ကျစ်လျစ်လျစ်သော ဖော်မြူလာများကို ဖြစ်နိုင်သမျှ နေရာတိုင်းတွင် အသုံးပြုလိုပါက၊ array စဉ်ဆက်မပြတ်ချဉ်းကပ်မှုကို ပိုနှစ်သက်နိုင်ပါသည်။ IF COUNT SEARCH ဖော်မြူလာသည် ယခင်နမူနာတွင် အလွန်တူပါသည်၊ သို့သော် ယခုတစ်ကြိမ်တွင် စာတန်းခွဲနှစ်ခုစလုံးသည် A2 တွင် ပေါ်နေရမည်ဖြစ်သောကြောင့် အရေအတွက်သည် 2 နှင့် ညီမျှခြင်းရှိမရှိ စစ်ဆေးကြည့်ပါ-

=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")

ဤအရာများသည် Excel ရှိ IF ထုတ်ပြန်ချက်တွင် wildcard အသုံးပြုခြင်း၏ အဓိကနည်းလမ်းများဖြစ်သည်။ အခြားဖြေရှင်းနည်းများကို သင်သိပါက၊ သင့်အတွေ့အကြုံကို မှတ်ချက်များတွင် မျှဝေပါက အခြားအသုံးပြုသူများသည် သဘောကျကြမည်ဖြစ်သည်။ ကျွန်ုပ်တို့၏ဘလော့ဂ်တွင် ဖတ်ရှုပြီး နောက်အပတ်တွင် ဆုံတွေ့ခွင့်ရရန် မျှော်လင့်သည့်အတွက် ကျေးဇူးတင်ပါသည်။

ဒေါင်းလုဒ်လုပ်ရန်အတွက် လေ့ကျင့်ခန်းစာအုပ်

Excel IF သင်္ကေတပုံသေနည်းနမူနာများ (.xlsx ဖိုင်)