ਵਿਸ਼ਾ - ਸੂਚੀ
ਵਾਈਲਡਕਾਰਡ ਟੈਕਸਟ ਨਾਲ ਇੱਕ IF ਸਟੇਟਮੈਂਟ ਬਣਾਉਣ ਦੀ ਕੋਸ਼ਿਸ਼ ਕਰ ਰਹੇ ਹੋ, ਪਰ ਇਹ ਹਰ ਵਾਰ ਅਸਫਲ ਹੁੰਦਾ ਹੈ? ਸਮੱਸਿਆ ਤੁਹਾਡੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਨਹੀਂ ਹੈ ਬਲਕਿ ਫੰਕਸ਼ਨ ਵਿੱਚ ਹੈ - ਐਕਸਲ IF ਵਾਈਲਡਕਾਰਡ ਅੱਖਰਾਂ ਦਾ ਸਮਰਥਨ ਨਹੀਂ ਕਰਦਾ ਹੈ। ਹਾਲਾਂਕਿ, ਅੰਸ਼ਕ ਪਾਠ ਮੇਲ ਲਈ ਇਸਨੂੰ ਕੰਮ ਕਰਨ ਦਾ ਇੱਕ ਤਰੀਕਾ ਹੈ, ਅਤੇ ਇਹ ਟਿਊਟੋਰਿਅਲ ਤੁਹਾਨੂੰ ਸਿਖਾਏਗਾ ਕਿ ਕਿਵੇਂ।
ਜਦੋਂ ਵੀ ਤੁਸੀਂ ਐਕਸਲ ਵਿੱਚ ਅੰਸ਼ਕ ਜਾਂ ਫਜ਼ੀ ਮੈਚਿੰਗ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ ਸਭ ਤੋਂ ਸਪੱਸ਼ਟ ਹੱਲ ਹੈ ਵਾਈਲਡਕਾਰਡ ਵਰਤਣ ਲਈ. ਪਰ ਉਦੋਂ ਕੀ ਜੇ ਇੱਕ ਖਾਸ ਫੰਕਸ਼ਨ ਜਿਸਦੀ ਤੁਹਾਨੂੰ ਵਰਤੋਂ ਕਰਨ ਦੀ ਲੋੜ ਹੈ ਵਾਈਲਡਕਾਰਡ ਅੱਖਰਾਂ ਦਾ ਸਮਰਥਨ ਨਹੀਂ ਕਰਦਾ ਹੈ? ਅਫ਼ਸੋਸ ਦੀ ਗੱਲ ਹੈ ਕਿ, ਐਕਸਲ ਆਈਐਫ ਅਜਿਹੇ ਫੰਕਸ਼ਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਹੈ। ਇਹ ਖਾਸ ਤੌਰ 'ਤੇ ਨਿਰਾਸ਼ਾਜਨਕ ਹੈ ਕਿਉਂਕਿ ਹੋਰ "ਸ਼ਰਤ" ਫੰਕਸ਼ਨ ਜਿਵੇਂ ਕਿ COUNTIF, SUMIF, ਅਤੇ AVERAGEIFS ਵਾਈਲਡਕਾਰਡਾਂ ਨਾਲ ਪੂਰੀ ਤਰ੍ਹਾਂ ਨਾਲ ਕੰਮ ਕਰਦੇ ਹਨ।
ਖੁਸ਼ਕਿਸਮਤੀ ਨਾਲ, ਇਹ ਕੋਈ ਰੁਕਾਵਟ ਨਹੀਂ ਹੈ ਜੋ ਇੱਕ ਰਚਨਾਤਮਕ ਐਕਸਲ ਉਪਭੋਗਤਾ ਨੂੰ ਰੋਕ ਸਕਦੀ ਹੈ :) IF ਨੂੰ ਜੋੜ ਕੇ ਹੋਰ ਫੰਕਸ਼ਨਾਂ ਦੇ ਨਾਲ, ਤੁਸੀਂ ਇਸਨੂੰ ਅੰਸ਼ਕ ਮੈਚ ਦਾ ਮੁਲਾਂਕਣ ਕਰਨ ਲਈ ਮਜਬੂਰ ਕਰ ਸਕਦੇ ਹੋ ਅਤੇ ਇੱਕ ਐਕਸਲ IF ਵਾਈਲਡਕਾਰਡ ਫਾਰਮੂਲੇ ਦਾ ਇੱਕ ਵਧੀਆ ਵਿਕਲਪ ਪ੍ਰਾਪਤ ਕਰ ਸਕਦੇ ਹੋ।
ਵਾਈਲਡਕਾਰਡ ਦੇ ਨਾਲ ਐਕਸਲ IF ਫੰਕਸ਼ਨ ਕੰਮ ਕਿਉਂ ਨਹੀਂ ਕਰ ਰਿਹਾ
ਹੇਠਾਂ ਦਿੱਤੀ ਨਮੂਨਾ ਸਾਰਣੀ ਵਿੱਚ, ਮੰਨ ਲਓ ਕਿ ਤੁਸੀਂ ਇਹ ਜਾਂਚ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ ਕਿ ਕੀ ਪਹਿਲੇ ਕਾਲਮ ਵਿੱਚ ਆਈਡੀ ਵਿੱਚ "A" ਅੱਖਰ ਹੈ। ਜੇਕਰ ਮਿਲਦਾ ਹੈ - ਕਾਲਮ B ਵਿੱਚ "ਹਾਂ" ਪ੍ਰਦਰਸ਼ਿਤ ਕਰੋ, ਜੇਕਰ ਨਹੀਂ - "ਨਹੀਂ" ਪ੍ਰਦਰਸ਼ਿਤ ਕਰੋ।
ਇੰਝ ਲੱਗਦਾ ਹੈ ਕਿ ਲਾਜ਼ੀਕਲ ਟੈਸਟ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡ ਟੈਕਸਟ ਸ਼ਾਮਲ ਕਰਨਾ ਇੱਕ ਆਸਾਨ ਹੱਲ ਹੋਵੇਗਾ:
=IF(A2="*a*","Yes", "No")
ਪਰ ਅਫਸੋਸ ਕਿ ਇਹ ਕੰਮ ਨਹੀਂ ਕਰਦਾ। ਫਾਰਮੂਲਾ ਸਾਰੇ ਸੈੱਲਾਂ ਲਈ "ਨਹੀਂ" ਵਾਪਸ ਕਰਦਾ ਹੈ, ਇੱਥੋਂ ਤੱਕ ਕਿ ਉਹਨਾਂ ਵਿੱਚ ਵੀ "A":
ਕਿਉਂਇੱਕ ਵਾਈਲਡਕਾਰਡ IF ਸਟੇਟਮੈਂਟ ਫੇਲ ਹੈ? ਸਾਰੀਆਂ ਦਿੱਖਾਂ ਤੋਂ, ਐਕਸਲ ਬਰਾਬਰ ਚਿੰਨ੍ਹ ਜਾਂ ਹੋਰ ਲਾਜ਼ੀਕਲ ਓਪਰੇਟਰਾਂ ਨਾਲ ਵਰਤੇ ਗਏ ਵਾਈਲਡਕਾਰਡਾਂ ਦੀ ਪਛਾਣ ਨਹੀਂ ਕਰਦਾ ਹੈ। ਵਾਈਲਡਕਾਰਡਾਂ ਦਾ ਸਮਰਥਨ ਕਰਨ ਵਾਲੇ ਫੰਕਸ਼ਨਾਂ ਦੀ ਸੂਚੀ 'ਤੇ ਇੱਕ ਡੂੰਘਾਈ ਨਾਲ ਨਜ਼ਰ ਮਾਰਦੇ ਹੋਏ, ਤੁਸੀਂ ਵੇਖੋਗੇ ਕਿ ਉਹਨਾਂ ਦਾ ਸੰਟੈਕਸ ਇੱਕ ਵਾਈਲਡਕਾਰਡ ਟੈਕਸਟ ਨੂੰ ਇਸ ਤਰ੍ਹਾਂ ਇੱਕ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਸਿੱਧੇ ਦਿਖਾਈ ਦੇਣ ਲਈ ਮੰਨਦਾ ਹੈ:
=COUNTIF(A2:A10, "*a*")
Excel IF ਵਿੱਚ ਅੰਸ਼ਕ ਟੈਕਸਟ ਹੈ
ਹੁਣ ਜਦੋਂ ਤੁਸੀਂ ਵਾਈਲਡਕਾਰਡ IF ਫਾਰਮੂਲਾ ਫੇਲ ਹੋਣ ਦਾ ਕਾਰਨ ਜਾਣਦੇ ਹੋ, ਆਓ ਇਹ ਜਾਣਨ ਦੀ ਕੋਸ਼ਿਸ਼ ਕਰੀਏ ਕਿ ਇਸਨੂੰ ਕਿਵੇਂ ਕੰਮ ਕਰਨਾ ਹੈ। ਇਸਦੇ ਲਈ, ਅਸੀਂ ਸਿਰਫ਼ ਇੱਕ ਫੰਕਸ਼ਨ ਨੂੰ ਏਮਬੇਡ ਕਰਾਂਗੇ ਜੋ IF ਦੇ ਲਾਜ਼ੀਕਲ ਟੈਸਟ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡਾਂ ਨੂੰ ਸਵੀਕਾਰ ਕਰਦਾ ਹੈ, ਅਰਥਾਤ COUNTIF ਫੰਕਸ਼ਨ:
IF(COUNTIF( cell, "* text* "), value_if_true, value_if_false)ਇਸ ਪਹੁੰਚ ਨਾਲ, IF ਨੂੰ ਵਾਈਲਡਕਾਰਡਾਂ ਨੂੰ ਸਮਝਣ ਵਿੱਚ ਕੋਈ ਸਮੱਸਿਆ ਨਹੀਂ ਹੈ ਅਤੇ ਉਹ ਸੈੱਲਾਂ ਦੀ ਨਿਰਵਿਘਨ ਪਛਾਣ ਕਰਦਾ ਹੈ ਜਿਨ੍ਹਾਂ ਵਿੱਚ "A" ਜਾਂ "a" ਹੁੰਦਾ ਹੈ (ਕਿਉਂਕਿ COUNTIF ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਨਹੀਂ ਹੈ):
=IF(COUNTIF(A2, "*a*"),"Yes", "No")
ਇਹ ਫਾਰਮੂਲਾ B2, ਜਾਂ ਕਤਾਰ 2 ਦੇ ਕਿਸੇ ਹੋਰ ਸੈੱਲ 'ਤੇ ਜਾਂਦਾ ਹੈ, ਅਤੇ ਫਿਰ ਤੁਸੀਂ ਇਸ ਨੂੰ ਲੋੜ ਅਨੁਸਾਰ ਬਹੁਤ ਸਾਰੇ ਸੈੱਲਾਂ ਤੱਕ ਹੇਠਾਂ ਖਿੱਚ ਸਕਦੇ ਹੋ:
ਇਸ ਹੱਲ ਦੀ ਵਰਤੋਂ ਕਿਸੇ ਖਾਸ ਪੈਟਰਨ ਦੀਆਂ ਤਾਰਾਂ ਨੂੰ ਲੱਭਣ ਲਈ ਵੀ ਕੀਤੀ ਜਾ ਸਕਦੀ ਹੈ। ਇਹ ਮੰਨਦੇ ਹੋਏ ਕਿ ਸਿਰਫ਼ ਹਾਈਫ਼ਨ ਨਾਲ ਵੱਖ ਕੀਤੇ 2 ਅੱਖਰਾਂ ਦੇ 2 ਸਮੂਹਾਂ ਵਾਲੀ ID ਵੈਧ ਹੈ, ਤੁਸੀਂ "???-???" ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ। ਉਹਨਾਂ ਦੀ ਪਛਾਣ ਕਰਨ ਲਈ ਵਾਈਲਡਕਾਰਡ ਸਤਰ:
=IF(COUNTIF(A2, "??-??"), "Valid", "")
ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:
ਦੇ ਲਾਜ਼ੀਕਲ ਟੈਸਟ ਲਈ IF, ਅਸੀਂ COUNTIF ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ ਜੋ ਨਿਰਧਾਰਤ ਵਾਈਲਡਕਾਰਡ ਨਾਲ ਮੇਲ ਖਾਂਦੇ ਸੈੱਲਾਂ ਦੀ ਗਿਣਤੀ ਗਿਣਦਾ ਹੈਸਤਰ ਕਿਉਂਕਿ ਮਾਪਦੰਡ ਰੇਂਜ ਇੱਕ ਸਿੰਗਲ ਸੈੱਲ (A2) ਹੈ, ਨਤੀਜਾ ਹਮੇਸ਼ਾ 1 ਹੁੰਦਾ ਹੈ (ਮੇਲ ਲੱਭਿਆ) ਜਾਂ 0 (ਮੇਲ ਨਹੀਂ ਮਿਲਿਆ)। ਇਹ ਧਿਆਨ ਵਿੱਚ ਰੱਖਦੇ ਹੋਏ ਕਿ 1 ਦਾ ਸਹੀ ਅਤੇ 0 ਦਾ ਗਲਤ ਹੈ, ਜਦੋਂ ਗਿਣਤੀ 1 ਹੁੰਦੀ ਹੈ ਤਾਂ ਫਾਰਮੂਲਾ "ਵੈਧ" (ਮੁੱਲ_ਇਫ_ਸੱਚਾ) ਅਤੇ ਜਦੋਂ ਗਿਣਤੀ 0 ਹੁੰਦੀ ਹੈ ਤਾਂ ਇੱਕ ਖਾਲੀ ਸਤਰ (ਮੁੱਲ_ਫਲਸੇ) ਵਾਪਸ ਕਰਦਾ ਹੈ।
ਅੰਸ਼ਕ ਲਈ ISNUMBER ਖੋਜ ਫਾਰਮੂਲਾ matches
ਐਕਸਲ IF ਨੂੰ ਅੰਸ਼ਕ ਪਾਠ ਮੈਚ ਲਈ ਕੰਮ ਕਰਨ ਲਈ ਮਜਬੂਰ ਕਰਨ ਦਾ ਇੱਕ ਹੋਰ ਤਰੀਕਾ ਹੈ ਲਾਜ਼ੀਕਲ ਟੈਸਟ ਵਿੱਚ FIND ਜਾਂ SEARCH ਫੰਕਸ਼ਨ ਨੂੰ ਸ਼ਾਮਲ ਕਰਨਾ। ਫਰਕ ਇਹ ਹੈ ਕਿ FIND ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਹੈ ਜਦੋਂ ਕਿ SEARCH ਨਹੀਂ ਹੈ।
ਇਸ ਲਈ, ਇਸ ਗੱਲ 'ਤੇ ਨਿਰਭਰ ਕਰਦਾ ਹੈ ਕਿ ਕੀ ਤੁਸੀਂ ਛੋਟੇ ਅੱਖਰਾਂ ਅਤੇ ਵੱਡੇ ਅੱਖਰਾਂ ਨੂੰ ਇੱਕੋ ਜਿਹੇ ਜਾਂ ਵੱਖਰੇ ਅੱਖਰਾਂ ਦੇ ਰੂਪ ਵਿੱਚ ਮੰਨਣਾ ਚਾਹੁੰਦੇ ਹੋ, ਇਹਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਫਾਰਮੂਲਾ ਇੱਕ ਟ੍ਰੀਟ ਕੰਮ ਕਰੇਗਾ:
ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਅੰਸ਼ਕ ਮਿਲਾਨ ਲਈ ਫਾਰਮੂਲਾ:
IF(ISNUMBER(SEARCH(" text", cell)), value_if_true, value_if_false )ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਅੰਸ਼ਕ ਮਿਲਾਨ ਲਈ ਫਾਰਮੂਲਾ:
IF(ISNUMBER(FIND(" text", cell)), value_if_true, value_if_false )ਕਿਉਂਕਿ ਦੋਵੇਂ ਫੰਕਸ਼ਨ ਇੱਕ "ਸੈੱਲ ਰੱਖਦਾ ਹੈ" ਕਿਸਮ ਦੇ ਮੇਲ ਨੂੰ ਕਰਨ ਲਈ ਤਿਆਰ ਕੀਤੇ ਗਏ ਹਨ, ਇਸ ਕੇਸ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡਾਂ ਦੀ ਅਸਲ ਵਿੱਚ ਲੋੜ ਨਹੀਂ ਹੈ।
ਉਦਾਹਰਣ ਲਈ, "A" ਜਾਂ "a" ਵਾਲੀ ID ਖੋਜਣ ਲਈ , ਫ਼ਾਰਮੂਲਾ ਹੈ:
=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")
ਸਿਰਫ਼ ਕੈਪੀਟਲ "A" ਦੀ ਖੋਜ ਕਰਨ ਅਤੇ "a" ਨੂੰ ਅਣਡਿੱਠ ਕਰਨ ਲਈ, ਫਾਰਮੂਲਾ ਹੈ:
=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")
ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ B6 ਵਿੱਚ, ਤੁਸੀਂ ਨਤੀਜੇ ਵਿੱਚ ਅੰਤਰ ਦੇਖ ਸਕਦੇ ਹੋ:
ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:
ਤੇ ਦਾ ਦਿਲਫਾਰਮੂਲਾ, ਇੱਥੇ ISNUMBER ਅਤੇ SEARCH (ਜਾਂ FIND) ਦਾ ਸੁਮੇਲ ਹੈ:
ISNUMBER(SEARCH("A", A2))
SEARCH ਫੰਕਸ਼ਨ ਨਿਰਧਾਰਿਤ ਟੈਕਸਟ (ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ "A") ਦੀ ਖੋਜ ਕਰਦਾ ਹੈ ਅਤੇ ਅੰਦਰ ਇਸਦੀ ਸਥਿਤੀ ਵਾਪਸ ਕਰਦਾ ਹੈ A2 ਵਿੱਚ ਇੱਕ ਸਤਰ। ਜੇਕਰ ਟੈਕਸਟ ਨਹੀਂ ਮਿਲਦਾ ਹੈ, ਤਾਂ ਇੱਕ #VALUE ਗਲਤੀ ਵਾਪਸ ਕੀਤੀ ਜਾਂਦੀ ਹੈ। ਕਿਉਂਕਿ SEARCH ਅਤੇ FIND ਦੋਵੇਂ "ਸੈੱਲ ਰੱਖਦਾ ਹੈ" ਕਿਸਮ ਦੇ ਮੇਲ ਨੂੰ ਕਰਨ ਲਈ ਤਿਆਰ ਕੀਤੇ ਗਏ ਹਨ, ਇਸ ਕੇਸ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡਾਂ ਦੀ ਅਸਲ ਵਿੱਚ ਲੋੜ ਨਹੀਂ ਹੈ।
ISNUMBER ਫੰਕਸ਼ਨ ਇੱਕ ਨੰਬਰ ਨੂੰ TRUE ਵਿੱਚ ਬਦਲਦਾ ਹੈ ਅਤੇ ਗਲਤੀ ਸਮੇਤ ਕਿਸੇ ਹੋਰ ਮੁੱਲ ਨੂੰ FALSE ਵਿੱਚ ਬਦਲਦਾ ਹੈ। . ਲਾਜ਼ੀਕਲ ਮੁੱਲ ਸਿੱਧਾ IF ਦੇ ਲਾਜ਼ੀਕਲ ਟੈਸਟ 'ਤੇ ਜਾਂਦਾ ਹੈ। ਸਾਡੇ ਕੇਸ ਵਿੱਚ, A2 ਵਿੱਚ "A" ਹੈ, ਇਸਲਈ ISNUMBER TRUE ਵਾਪਸ ਕਰਦਾ ਹੈ:
IF(TRUE, "Yes", "No")
ਨਤੀਜੇ ਵਜੋਂ, IF value_if_true ਆਰਗੂਮੈਂਟ ਲਈ ਸੈੱਟ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਜੋ ਕਿ ਹੈ "ਹਾਂ"।
ਵਾਈਲਡਕਾਰਡਾਂ ਦੇ ਨਾਲ ਐਕਸਲ IF ਜਾਂ ਸਟੇਟਮੈਂਟ
ਉਨ੍ਹਾਂ ਸੈੱਲਾਂ ਦੀ ਪਛਾਣ ਕਰਨ ਦੀ ਲੋੜ ਹੈ ਜਿਨ੍ਹਾਂ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡ ਟੈਕਸਟ ਸਤਰਾਂ ਵਿੱਚੋਂ ਇੱਕ ਹੈ? ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਤੁਸੀਂ ਉੱਪਰ ਦੱਸੇ ਗਏ COUNTIF ਜਾਂ ISNUMBER ਖੋਜ ਫਾਰਮੂਲੇ ਦੇ ਨਾਲ ਕਲਾਸਿਕ IF OR ਸਟੇਟਮੈਂਟ ਨੂੰ ਜੋੜ ਸਕਦੇ ਹੋ।
ਉਦਾਹਰਨ ਲਈ, ਅੱਖਰ ਕੇਸ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਦੇ ਹੋਏ A2 ਵਿੱਚ "aa" ਜਾਂ "bb" ਖੋਜਣ ਲਈ ਅਤੇ ਵਾਪਸ " ਹਾਂ" ਜੇਕਰ ਕੋਈ ਲੱਭਦਾ ਹੈ, ਤਾਂ ਇਹਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰੋ:
=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")
ਜਾਂ
=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")
ਦੋ COUNTIF ਫੰਕਸ਼ਨਾਂ ਨੂੰ ਜੋੜਨਾ ਵੀ ਕੰਮ ਕਰੇਗਾ। ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਪਲੱਸ ਚਿੰਨ੍ਹ OR ਓਪਰੇਟਰ ਵਾਂਗ ਕੰਮ ਕਰਦਾ ਹੈ:
=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")
ਫਾਰਮੂਲੇ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡ ਸਤਰ ਨੂੰ ਹਾਰਡਕੋਡ ਕਰਨ ਦੀ ਬਜਾਏ, ਤੁਸੀਂ ਉਹਨਾਂ ਨੂੰ ਵੱਖਰੇ ਸੈੱਲਾਂ ਵਿੱਚ ਇਨਪੁਟ ਕਰ ਸਕਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ ਦਿਖਾਇਆ ਗਿਆ ਹੈ, D2 ਅਤੇ F2 ਕਹੋ। ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ. ਕਿਰਪਾ ਕਰਕੇ ਧਿਆਨ ਦਿਓ ਕਿ ਇਹਸੈੱਲ ਸੰਦਰਭਾਂ ਨੂੰ $ ਚਿੰਨ੍ਹ ਨਾਲ ਲਾਕ ਕੀਤਾ ਜਾਂਦਾ ਹੈ ਤਾਂ ਜੋ ਫਾਰਮੂਲਾ ਹੇਠਾਂ ਦਿੱਤੇ ਸੈੱਲਾਂ ਵਿੱਚ ਸਹੀ ਢੰਗ ਨਾਲ ਨਕਲ ਕਰ ਸਕੇ:
=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")
ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ 2 ਅੰਸ਼ਕ ਮੈਚਾਂ ਲਈ ਵਧੀਆ ਕੰਮ ਕਰਦੇ ਹਨ , ਪਰ ਜੇਕਰ ਤੁਸੀਂ 3 ਜਾਂ ਵੱਧ ਦੀ ਖੋਜ ਕਰ ਰਹੇ ਹੋ, ਤਾਂ ਉਹ ਬਹੁਤ ਲੰਬੇ ਹੋ ਜਾਣਗੇ। ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਇਹ ਕੰਮ ਨੂੰ ਵੱਖਰੇ ਤੌਰ 'ਤੇ ਪਹੁੰਚ ਕਰਨ ਦਾ ਕਾਰਨ ਹੈ:
ਇੱਕ ਐਰੇ ਸਥਿਰਾਂਕ ਵਿੱਚ ਖੋਜ ਫੰਕਸ਼ਨ ਲਈ ਕਈ ਸਬਸਟਰਿੰਗਾਂ ਦੀ ਸਪਲਾਈ ਕਰੋ, ਵਾਪਸ ਕੀਤੇ ਨੰਬਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ, ਅਤੇ ਜਾਂਚ ਕਰੋ ਕਿ ਕੀ ਨਤੀਜਾ ਜ਼ੀਰੋ ਤੋਂ ਵੱਧ ਹੈ (ਜਿਸਦਾ ਮਤਲਬ ਹੋਵੇਗਾ ਜੇਕਰ ਸਬਸਟਰਿੰਗਾਂ ਵਿੱਚੋਂ ਘੱਟੋ-ਘੱਟ ਇੱਕ ਪਾਈ ਜਾਂਦੀ ਹੈ:
=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")
ਇਸ ਤਰ੍ਹਾਂ, ਤੁਸੀਂ ਇੱਕ ਵਧੇਰੇ ਸੰਖੇਪ ਫਾਰਮੂਲੇ ਨਾਲ ਬਿਲਕੁਲ ਉਹੀ ਨਤੀਜਾ ਪ੍ਰਾਪਤ ਕਰੋਗੇ:
ਵਾਈਲਡਕਾਰਡਾਂ ਨਾਲ ਐਕਸਲ IF ਅਤੇ ਫਾਰਮੂਲਾ
ਜਦੋਂ ਤੁਸੀਂ ਇਹ ਦੇਖਣਾ ਚਾਹੁੰਦੇ ਹੋ ਕਿ ਕੀ ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਦੋ ਜਾਂ ਦੋ ਤੋਂ ਵੱਧ ਵੱਖ-ਵੱਖ ਸਬਸਟਰਿੰਗ ਹਨ, ਤਾਂ ਸਭ ਤੋਂ ਆਸਾਨ ਤਰੀਕਾ ਹੈ ਲਾਜ਼ੀਕਲ ਟੈਸਟ ਲਈ ਵਾਈਲਡਕਾਰਡਾਂ ਦੇ ਨਾਲ COUNTIFS ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਨਾ।
ਮੰਨ ਲਓ ਕਿ ਤੁਸੀਂ ਕਾਲਮ A ਵਿੱਚ ਸੈੱਲਾਂ ਨੂੰ ਲੱਭਣਾ ਚਾਹੁੰਦੇ ਹੋ ਜਿਸ ਵਿੱਚ "b" ਅਤੇ "2" ਦੋਵੇਂ ਸ਼ਾਮਲ ਹਨ। ਇਸਨੂੰ ਪੂਰਾ ਕਰਨ ਲਈ, COUNTIFS ਦੇ ਮਾਪਦੰਡ ਲਈ "*b*" ਅਤੇ "*2*" ਅਤੇ ਮਾਪਦੰਡ ਰੇਂਜ ਲਈ A2 ਦੀ ਵਰਤੋਂ ਕਰੋ:
=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")
ਇੱਕ ਹੋਰ ਤਰੀਕਾ ਹੈ IF ਅਤੇ ਫਾਰਮੂਲੇ ਨੂੰ ਇਕੱਠੇ ਵਰਤਣਾ। ISNUMBER ਖੋਜ ਦੇ ਨਾਲ:
=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")
ਹਾਲਾਂਕਿ ਅਸੀਂ ਇਸ ਫਾਰਮੂਲੇ ਵਿੱਚ ਕੋਈ ਵਾਈਲਡਕਾਰਡ ਅੱਖਰ ਸ਼ਾਮਲ ਨਹੀਂ ਕਰਦੇ, ਇਹ ਦੋ ਵਾਈਲਡਕਾਰਡ ਸਤਰ ("*b*" ਅਤੇ "*2*" ਦੀ ਖੋਜ ਕਰਨ ਵਾਂਗ ਕੰਮ ਕਰਦਾ ਹੈ। ) ਉਸੇ ਸੈੱਲ ਵਿੱਚ।
ਬੇਸ਼ੱਕ, ਕੁਝ ਵੀ ਤੁਹਾਨੂੰ ਪੂਰਵ-ਪ੍ਰਭਾਸ਼ਿਤ ਸੈੱਲਾਂ ਵਿੱਚ ਖੋਜ ਮੁੱਲ ਦਾਖਲ ਕਰਨ ਤੋਂ ਨਹੀਂ ਰੋਕਦਾ, ਸਾਡੇ ਕੇਸ ਵਿੱਚ D2 ਅਤੇ F2, ਅਤੇ ਸਪਲਾਈ ਕਰਨ ਤੋਂਸੈੱਲ ਫਾਰਮੂਲੇ ਦਾ ਹਵਾਲਾ ਦਿੰਦਾ ਹੈ:
=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")
ਜੇਕਰ ਤੁਸੀਂ ਜਿੱਥੇ ਵੀ ਸੰਭਵ ਹੋਵੇ ਵਧੇਰੇ ਸੰਖੇਪ ਫਾਰਮੂਲੇ ਵਰਤਣਾ ਪਸੰਦ ਕਰਦੇ ਹੋ, ਤਾਂ ਤੁਸੀਂ ਐਰੇ ਸਥਿਰ ਪਹੁੰਚ ਨੂੰ ਬਿਹਤਰ ਪਸੰਦ ਕਰ ਸਕਦੇ ਹੋ। IF COUNT SEARCH ਫਾਰਮੂਲਾ ਪਿਛਲੀ ਉਦਾਹਰਨ ਦੀ ਤਰ੍ਹਾਂ ਹੀ ਹੈ, ਪਰ ਕਿਉਂਕਿ ਇਸ ਵਾਰ ਦੋਵੇਂ ਸਬਸਟਰਿੰਗਾਂ A2 ਵਿੱਚ ਦਿਖਾਈ ਦੇਣੀਆਂ ਚਾਹੀਦੀਆਂ ਹਨ, ਅਸੀਂ ਜਾਂਚ ਕਰਦੇ ਹਾਂ ਕਿ ਕੀ ਗਿਣਤੀ 2 ਦੇ ਬਰਾਬਰ ਹੈ:
=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")
<17
ਇਹ ਐਕਸਲ ਵਿੱਚ IF ਸਟੇਟਮੈਂਟ ਵਿੱਚ ਵਾਈਲਡਕਾਰਡ ਦੀ ਵਰਤੋਂ ਕਰਨ ਦੇ ਮੁੱਖ ਤਰੀਕੇ ਹਨ। ਜੇ ਤੁਸੀਂ ਕੋਈ ਹੋਰ ਹੱਲ ਜਾਣਦੇ ਹੋ, ਤਾਂ ਦੂਜੇ ਉਪਭੋਗਤਾ ਜ਼ਰੂਰ ਪ੍ਰਸ਼ੰਸਾ ਕਰਨਗੇ ਜੇਕਰ ਤੁਸੀਂ ਟਿੱਪਣੀਆਂ ਵਿੱਚ ਆਪਣਾ ਅਨੁਭਵ ਸਾਂਝਾ ਕਰਦੇ ਹੋ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਸਾਡੇ ਬਲੌਗ 'ਤੇ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ!
ਡਾਊਨਲੋਡ ਲਈ ਅਭਿਆਸ ਵਰਕਬੁੱਕ
Excel IF ਵਾਈਲਡਕਾਰਡ ਫਾਰਮੂਲਾ ਉਦਾਹਰਣਾਂ (.xlsx ਫਾਈਲ)
