వైల్డ్‌కార్డ్ టెక్స్ట్‌తో IF స్టేట్‌మెంట్‌ను రూపొందించడానికి ప్రయత్నిస్తున్నారు, కానీ అది ప్రతిసారీ విఫలమవుతుందా? సమస్య మీ ఫార్ములాలో లేదు కానీ ఫంక్షన్‌లోనే ఉంది - Excel IF వైల్డ్‌కార్డ్ అక్షరాలకు మద్దతు ఇవ్వదు. అయినప్పటికీ, పాక్షిక టెక్స్ట్ సరిపోలిక కోసం ఇది పని చేయడానికి ఒక మార్గం ఉంది మరియు ఈ ట్యుటోరియల్ మీకు ఎలా నేర్పుతుంది.

మీరు ఎక్సెల్‌లో పాక్షిక లేదా మసక సరిపోలికను నిర్వహించాలనుకున్నప్పుడు, అత్యంత స్పష్టమైన పరిష్కారం వైల్డ్‌కార్డ్‌లను ఉపయోగించడానికి. మీరు ఉపయోగించాల్సిన నిర్దిష్ట ఫంక్షన్ వైల్డ్‌కార్డ్ అక్షరాలకు మద్దతు ఇవ్వకపోతే ఏమి చేయాలి? పాపం, Excel IF అటువంటి ఫంక్షన్లలో ఒకటి. COUNTIF, SUMIF మరియు AVERAGEIFS వంటి ఇతర "షరతులతో కూడిన" ఫంక్షన్‌లు వైల్డ్‌కార్డ్‌లతో సంపూర్ణంగా పని చేస్తున్నాయని పరిగణనలోకి తీసుకుంటే ఇది చాలా నిరాశపరిచింది.

అదృష్టవశాత్తూ, సృజనాత్మక Excel వినియోగదారుని ఆపగలిగే అడ్డంకి ఇది కాదు :) IF కలపడం ద్వారా ఇతర ఫంక్షన్‌లతో, మీరు పాక్షిక సరిపోలికను మూల్యాంకనం చేయమని బలవంతం చేయవచ్చు మరియు Excel IF వైల్డ్‌కార్డ్ ఫార్ములాకు చక్కని ప్రత్యామ్నాయాన్ని పొందవచ్చు.

వైల్డ్‌కార్డ్‌తో Excel ఎందుకు పని చేయదు

దిగువ నమూనా పట్టికలో, మీరు మొదటి నిలువు వరుసలోని IDలు "A" అక్షరాన్ని కలిగి ఉన్నాయో లేదో తనిఖీ చేయాలనుకుంటున్నారు. కనుగొనబడితే - నిలువు వరుస Bలో "అవును"ని ప్రదర్శించండి, కాకపోతే - "లేదు"ని ప్రదర్శించండి.

లాజికల్ పరీక్షలో వైల్డ్‌కార్డ్ టెక్స్ట్‌ని చేర్చడం సులువైన పరిష్కారంగా కనిపిస్తుంది:

=IF(A2="*a*","Yes", "No")

కానీ విచారకరంగా అది పని చేయడం లేదు. ఫార్ములా అన్ని సెల్‌లకు "A" కలిగి ఉన్న వాటికి కూడా "లేదు" అని అందిస్తుంది:

ఎందుకు చేస్తుందిప్రకటన విఫలమైతే వైల్డ్‌కార్డ్? అన్ని ప్రదర్శనల నుండి, సమాన గుర్తు లేదా ఇతర లాజికల్ ఆపరేటర్‌లతో ఉపయోగించిన వైల్డ్‌కార్డ్‌లను Excel గుర్తించలేదు. వైల్డ్‌కార్డ్‌లకు మద్దతిచ్చే ఫంక్షన్‌ల జాబితాను నిశితంగా పరిశీలిస్తే, వారి సింటాక్స్ వైల్డ్‌కార్డ్ టెక్స్ట్‌ని నేరుగా ఇలాంటి ఆర్గ్యుమెంట్‌లో కనిపించడాన్ని మీరు గమనించవచ్చు:

=COUNTIF(A2:A10, "*a*")

Excel IF పాక్షిక వచనాన్ని కలిగి ఉంది

వైల్డ్‌కార్డ్ ఫార్ములా ఎందుకు విఫలమవుతుందో ఇప్పుడు మీకు తెలుసు కాబట్టి, దాన్ని ఎలా పని చేయవచ్చో తెలుసుకోవడానికి ప్రయత్నిద్దాం. దీని కోసం, మేము IF యొక్క లాజికల్ టెస్ట్‌లో వైల్డ్‌కార్డ్‌లను ఆమోదించే ఫంక్షన్‌ను పొందుపరుస్తాము, అవి COUNTIF ఫంక్షన్:

ఈ విధానంతో, వైల్డ్‌కార్డ్‌లను అర్థం చేసుకోవడంలో IFకి ఎలాంటి సమస్య లేదు మరియు "A" లేదా "a" (COUNTIF కేస్-సెన్సిటివ్ కాదు కాబట్టి) ఉన్న సెల్‌లను దోషరహితంగా గుర్తిస్తుంది:

=IF(COUNTIF(A2, "*a*"),"Yes", "No")

ఈ ఫార్ములా B2కి లేదా అడ్డు వరుస 2లోని ఏదైనా ఇతర సెల్‌కి వెళుతుంది, ఆపై మీరు దీన్ని అవసరమైనన్ని సెల్‌లకు క్రిందికి లాగవచ్చు:

ఈ పరిష్కారం నిర్దిష్ట నమూనా యొక్క స్ట్రింగ్‌లను గుర్తించడానికి కూడా ఉపయోగించవచ్చు. హైఫన్‌తో వేరు చేయబడిన 2 అక్షరాల 2 సమూహాలతో కూడిన IDలు మాత్రమే చెల్లుబాటు అయ్యేవిగా భావించి, మీరు "??-???" వాటిని గుర్తించడానికి వైల్డ్‌కార్డ్ స్ట్రింగ్:

=IF(COUNTIF(A2, "??-??"), "Valid", "")

ఈ ఫార్ములా ఎలా పని చేస్తుంది:

లాజికల్ టెస్ట్ కోసం IF, మేము పేర్కొన్న వైల్డ్‌కార్డ్‌కు సరిపోలే సెల్‌ల సంఖ్యను లెక్కించే COUNTIF ఫంక్షన్‌ని ఉపయోగిస్తాముస్ట్రింగ్. ప్రమాణాల పరిధి ఒకే సెల్ (A2) కాబట్టి, ఫలితం ఎల్లప్పుడూ 1 (మ్యాచ్ కనుగొనబడింది) లేదా 0 (మ్యాచ్ కనుగొనబడలేదు). 1 TRUEకి మరియు 0 తప్పుకి సమానం అయినందున, గణన 1 అయినప్పుడు ఫార్ములా "చెల్లుబాటు అవుతుంది" (value_if_true) మరియు కౌంట్ 0 అయినప్పుడు ఖాళీ స్ట్రింగ్ (value_if_false)ని అందిస్తుంది.

పాక్షికంగా ISNUMBER శోధన సూత్రం అయితే మ్యాచ్‌లు

పాక్షిక టెక్స్ట్ సరిపోలిక కోసం Excel IFను బలవంతం చేయడానికి మరొక మార్గం లాజికల్ టెస్ట్‌లో FIND లేదా SEARCH ఫంక్షన్‌ని చేర్చడం. తేడా ఏమిటంటే, SEARCH కానప్పుడు FIND కేస్-సెన్సిటివ్‌గా ఉంటుంది.

కాబట్టి, మీరు చిన్న అక్షరాలు మరియు పెద్ద అక్షరాలను ఒకే లేదా విభిన్న అక్షరాలుగా పరిగణించాలనుకుంటున్నారా అనేదానిపై ఆధారపడి, ఈ ఫార్ములాల్లో ఒకటి ట్రీట్‌గా పని చేస్తుంది:<3 పాక్షిక సరిపోలిక కోసం

కేస్-ఇన్సెన్సిటివ్ సూత్రం:

కేస్-సెన్సిటివ్ పాక్షిక సరిపోలిక కోసం సూత్రం:

రెండు ఫంక్షన్‌లు "సెల్ కలిగి ఉన్న" మ్యాచ్ రకంని నిర్వహించడానికి రూపొందించబడినందున, ఈ సందర్భంలో వైల్డ్‌కార్డ్‌లు నిజంగా అవసరం లేదు.

ఉదాహరణకు, "A" లేదా "a" ఉన్న IDలను గుర్తించడానికి , ఫార్ములా:

=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")

క్యాపిటల్ "A" కోసం మాత్రమే శోధించడానికి మరియు "a"ని విస్మరించడానికి, ఫార్ములా:

=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")

దిగువ స్క్రీన్‌షాట్‌లోని B6లో, మీరు ఫలితంలో వ్యత్యాసాన్ని గమనించవచ్చు:

ఈ సూత్రం ఎలా పని చేస్తుంది:

యొక్క గుండెఫార్ములా, ISNUMBER మరియు SEARCH (లేదా FIND) కలయిక ఉంది:

ISNUMBER(SEARCH("A", A2))

శోధన ఫంక్షన్ పేర్కొన్న టెక్స్ట్ (ఈ ఉదాహరణలో "A") కోసం వెతుకుతుంది మరియు లోపల దాని స్థానాన్ని అందిస్తుంది A2లో ఒక స్ట్రింగ్. వచనం కనుగొనబడకపోతే, #VALUE లోపం తిరిగి వస్తుంది. SEARCH మరియు FIND రెండూ "సెల్ కలిగి ఉన్న" సరిపోలికను నిర్వహించడానికి రూపొందించబడినందున, ఈ సందర్భంలో వైల్డ్‌కార్డ్‌లు నిజంగా అవసరం లేదు.

ISNUMBER ఫంక్షన్ సంఖ్యను TRUEగా మారుస్తుంది మరియు లోపంతో సహా ఏదైనా ఇతర విలువను తప్పుగా మారుస్తుంది . తార్కిక విలువ నేరుగా IF యొక్క తార్కిక పరీక్షకు వెళుతుంది. మా సందర్భంలో, A2 "A"ని కలిగి ఉంది, కాబట్టి ISNUMBER TRUEని అందిస్తుంది:

IF(TRUE, "Yes", "No")

ఫలితంగా, IF value_if_true ఆర్గ్యుమెంట్ కోసం సెట్ చేసిన విలువను అందిస్తుంది, ఇది "అవును".

Excel IF OR వైల్డ్‌కార్డ్‌లతో స్టేట్‌మెంట్

వైల్డ్‌కార్డ్ టెక్స్ట్ స్ట్రింగ్‌లలో ఒకదాన్ని కలిగి ఉన్న సెల్‌లను గుర్తించాలా? ఈ సందర్భంలో, మీరు పైన చర్చించిన COUNTIF లేదా ISNUMBER శోధన ఫార్ములాతో క్లాసిక్ IF OR స్టేట్‌మెంట్‌ను మిళితం చేయవచ్చు.

ఉదాహరణకు, A2లో "aa" లేదా "bb" కోసం శోధించడానికి అక్షరం కేసును విస్మరించి " అవును" ఏదైనా కనుగొనబడితే, ఈ ఫార్ములాల్లో ఒకదాన్ని ఉపయోగించండి:

=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")

లేదా

=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")

రెండు COUNTIF ఫంక్షన్‌లను జోడించడం కూడా పని చేస్తుంది. ఈ సందర్భంలో, ప్లస్ సైన్ OR ఆపరేటర్ లాగా పనిచేస్తుంది:

=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")

ఫార్ములాలో హార్డ్‌కోడింగ్ వైల్డ్‌కార్డ్ స్ట్రింగ్‌లకు బదులుగా, మీరు వాటిని ప్రత్యేక సెల్‌లలో ఇన్‌పుట్ చేయవచ్చు, చూపిన విధంగా D2 మరియు F2 అని చెప్పండి దిగువ స్క్రీన్‌షాట్‌లో. దయచేసి వీటిని గమనించండిసెల్ రిఫరెన్స్‌లు $ గుర్తుతో లాక్ చేయబడతాయి, తద్వారా ఫార్ములా కింది సెల్‌లకు సరిగ్గా కాపీ చేయబడుతుంది:

=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")

పై సూత్రాలు 2 పాక్షిక సరిపోలికలకు బాగా పని చేస్తాయి , కానీ మీరు 3 లేదా అంతకంటే ఎక్కువ శోధిస్తున్నట్లయితే, అవి చాలా పొడవుగా మారతాయి. ఈ సందర్భంలో, టాస్క్‌ను విభిన్నంగా సంప్రదించడానికి ఇది కారణం:

అరే స్థిరాంకంలో SEARCH ఫంక్షన్‌కు బహుళ సబ్‌స్ట్రింగ్‌లను సరఫరా చేయండి, తిరిగి వచ్చిన సంఖ్యలను లెక్కించండి మరియు ఫలితం సున్నా కంటే ఎక్కువగా ఉందో లేదో తనిఖీ చేయండి (దీని అర్థం కనీసం సబ్‌స్ట్రింగ్‌లలో ఒకటి కనుగొనబడితే):

=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")

ఈ విధంగా, మీరు మరింత కాంపాక్ట్ ఫార్ములాతో సరిగ్గా అదే ఫలితాన్ని పొందుతారు:

3>

Excel IF మరియు వైల్డ్‌కార్డ్‌లతో ఫార్ములా

ఒక సెల్‌లో రెండు లేదా అంతకంటే ఎక్కువ విభిన్న సబ్‌స్ట్రింగ్‌లు ఉన్నాయో లేదో తనిఖీ చేయాలనుకున్నప్పుడు, లాజికల్ టెస్ట్ కోసం వైల్డ్‌కార్డ్‌లతో COUNTIFS ఫంక్షన్‌ని ఉపయోగించడం సులభమయిన మార్గం.

మీరు కాలమ్ Aలో "b" మరియు "2" రెండింటినీ కలిగి ఉన్న సెల్‌లను గుర్తించాలనుకుంటున్నారు. దీన్ని పూర్తి చేయడానికి, COUNTIFS ప్రమాణాల కోసం "*b*" మరియు "*2*"ని మరియు ప్రమాణాల పరిధి కోసం A2ని ఉపయోగించండి:

=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")

మరొక మార్గం ఏమిటంటే IF AND ఫార్ములాను కలిపి ఉపయోగించడం ISNUMBER శోధనతో:

=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")

మేము ఈ ఫార్ములాలో వైల్డ్‌కార్డ్ అక్షరాలను చేర్చనప్పటికీ, ఇది రెండు వైల్డ్‌కార్డ్ స్ట్రింగ్‌ల కోసం శోధించడం వంటి పని చేస్తుంది ("*b*" మరియు "*2*" ) అదే సెల్‌లో.

అయితే, ముందుగా నిర్వచించిన సెల్‌లలో శోధన విలువలను నమోదు చేయకుండా, మా విషయంలో D2 మరియు F2 మరియు సరఫరా చేయడం నుండి మిమ్మల్ని ఏదీ నిరోధించదు.ఫార్ములాకు సెల్ సూచనలు:

=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")

మీరు సాధ్యమైన చోట మరిన్ని కాంపాక్ట్ ఫార్ములాలను ఉపయోగించాలనుకుంటే, మీరు శ్రేణి స్థిరమైన విధానాన్ని ఇష్టపడవచ్చు. IF COUNT సెర్చ్ ఫార్ములా మునుపటి ఉదాహరణలో చాలా లాగా ఉంది, కానీ ఈసారి రెండు సబ్‌స్ట్రింగ్‌లు తప్పనిసరిగా A2లో కనిపించాలి కాబట్టి, కౌంట్ 2కి సమానంగా ఉందో లేదో తనిఖీ చేస్తాము:

=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")

<17

Excelలో IF స్టేట్‌మెంట్‌లో వైల్డ్‌కార్డ్‌ని ఉపయోగించే ప్రధాన పద్ధతులు ఇవి. మీకు ఏవైనా ఇతర పరిష్కారాలు తెలిస్తే, మీరు మీ అనుభవాన్ని వ్యాఖ్యలలో పంచుకుంటే ఇతర వినియోగదారులు ఖచ్చితంగా అభినందిస్తారు. చదివినందుకు ధన్యవాదాలు మరియు మిమ్మల్ని వచ్చే వారం మా బ్లాగ్‌లో చూడాలని ఆశిస్తున్నాను!

డౌన్‌లోడ్ కోసం వర్క్‌బుక్‌ను ప్రాక్టీస్ చేయండి

Excel IF వైల్డ్‌కార్డ్ ఫార్ములా ఉదాహరణలు (.xlsx ఫైల్)