વાઇલ્ડકાર્ડ ટેક્સ્ટ સાથે IF સ્ટેટમેન્ટ બનાવવાનો પ્રયાસ કરી રહ્યાં છો, પરંતુ તે દર વખતે નિષ્ફળ જાય છે? સમસ્યા તમારા ફોર્મ્યુલામાં નથી પરંતુ ફંક્શનમાં જ છે - એક્સેલ IF વાઇલ્ડકાર્ડ અક્ષરોને સપોર્ટ કરતું નથી. જો કે, આંશિક ટેક્સ્ટ મેચ માટે તેને કામ કરવા માટેની એક રીત છે, અને આ ટ્યુટોરીયલ તમને કેવી રીતે શીખવશે.

જ્યારે પણ તમે Excel માં આંશિક અથવા અસ્પષ્ટ મેચિંગ કરવા માંગતા હો, ત્યારે સૌથી સ્પષ્ટ ઉકેલ છે વાઇલ્ડકાર્ડ વાપરવા માટે. પરંતુ જો કોઈ વિશિષ્ટ કાર્ય કે જેનો તમારે ઉપયોગ કરવાની જરૂર છે તે વાઇલ્ડકાર્ડ અક્ષરોને સપોર્ટ કરતું નથી તો શું? દુર્ભાગ્યે, એક્સેલ IF આવા કાર્યોમાંનું એક છે. આ ખાસ કરીને નિરાશાજનક છે કે અન્ય "શરતી" કાર્યો જેમ કે COUNTIF, SUMIF અને AVERAGEIFS વાઇલ્ડકાર્ડ્સ સાથે સંપૂર્ણ રીતે સારી રીતે કાર્ય કરે છે.

સદભાગ્યે, તે કોઈ અવરોધ નથી જે સર્જનાત્મક એક્સેલ વપરાશકર્તાને રોકી શકે :) IF સંયોજિત કરીને અન્ય કાર્યો સાથે, તમે તેને આંશિક મેચનું મૂલ્યાંકન કરવા દબાણ કરી શકો છો અને Excel IF વાઇલ્ડકાર્ડ ફોર્મ્યુલાનો એક સરસ વિકલ્પ મેળવી શકો છો.

શા માટે વાઇલ્ડકાર્ડ સાથે એક્સેલ IF કાર્ય કામ કરતું નથી

નીચેના નમૂના કોષ્ટકમાં, ધારો કે તમે પ્રથમ કૉલમમાં IDsમાં "A" અક્ષર છે કે કેમ તે તપાસવા માંગો છો. જો મળે તો - કૉલમ B માં "હા" દર્શાવો, જો નહીં - "ના" દર્શાવો.

એવું લાગે છે કે લોજિકલ ટેસ્ટમાં વાઇલ્ડકાર્ડ ટેક્સ્ટનો સમાવેશ કરવો એ એક સરળ ઉકેલ હશે:

=IF(A2="*a*","Yes", "No")

પરંતુ અફસોસ કે તે કામ કરતું નથી. સૂત્ર બધા કોષો માટે "ના" પરત કરે છે, તે પણ જેમાં "A" હોય છે:

શા માટેવાઇલ્ડકાર્ડ IF સ્ટેટમેન્ટ નિષ્ફળ જાય છે? તમામ દેખાવમાંથી, એક્સેલ સમાન ચિહ્ન અથવા અન્ય લોજિકલ ઓપરેટરો સાથે ઉપયોગમાં લેવાતા વાઇલ્ડકાર્ડ્સને ઓળખતું નથી. વાઇલ્ડકાર્ડ્સને સપોર્ટ કરતા કાર્યોની સૂચિ પર નજીકથી નજર નાખતા, તમે જોશો કે તેમની વાક્યરચના વાઇલ્ડકાર્ડ ટેક્સ્ટને આના જેવી દલીલમાં સીધી દેખાડવા માટે ધારે છે:

=COUNTIF(A2:A10, "*a*")

Excel IF આંશિક ટેક્સ્ટ ધરાવે છે

હવે તમે વાઇલ્ડકાર્ડ IF ફોર્મ્યુલા નિષ્ફળ થવાનું કારણ જાણો છો, ચાલો તેને કેવી રીતે કાર્ય કરવું તે શોધવાનો પ્રયાસ કરીએ. આ માટે, અમે ફક્ત એક ફંક્શનને એમ્બેડ કરીશું જે IF ની લોજિકલ ટેસ્ટમાં વાઇલ્ડકાર્ડ્સ સ્વીકારે છે, એટલે કે COUNTIF ફંક્શન:

આ અભિગમ સાથે, IF ને વાઇલ્ડકાર્ડ્સ સમજવામાં કોઈ સમસ્યા નથી અને તે કોષોને દોષરહિત રીતે ઓળખે છે જેમાં "A" અથવા "a" (કારણ કે COUNTIF કેસ-સંવેદનશીલ નથી):

=IF(COUNTIF(A2, "*a*"),"Yes", "No")

=IF(COUNTIF(A2, "??-??"), "Valid", "")

આ ફોર્મ્યુલા કેવી રીતે કાર્ય કરે છે:

ની તાર્કિક કસોટી માટે જો, અમે COUNTIF ફંક્શનનો ઉપયોગ કરીએ છીએ જે ઉલ્લેખિત વાઇલ્ડકાર્ડ સાથે મેળ ખાતા કોષોની સંખ્યા ગણે છેતાર. માપદંડ શ્રેણી સિંગલ સેલ (A2) હોવાથી, પરિણામ હંમેશા 1 (મેળ મળ્યો છે) અથવા 0 (મેળ મળ્યો નથી) છે. આપેલ છે કે 1 TRUE અને 0 ની FALSE સમાન છે, જ્યારે ગણતરી 1 હોય ત્યારે સૂત્ર "માન્ય" (મૂલ્ય_જો_સત્ય) અને જ્યારે ગણતરી 0 હોય ત્યારે ખાલી શબ્દમાળા (મૂલ્ય_જો_ખોટી) પરત કરે છે.

જો આંશિક માટે ISNUMBER શોધ સૂત્ર મેચો

આંશિક ટેક્સ્ટ મેચ માટે એક્સેલ IF ને કામ કરવા દબાણ કરવાની બીજી રીત એ છે કે લોજિકલ ટેસ્ટમાં ક્યાં તો FIND અથવા SEARCH ફંક્શનનો સમાવેશ કરવો. તફાવત એ છે કે FIND કેસ-સંવેદનશીલ છે જ્યારે SEARCH નથી.

તેથી, તમે લોઅરકેસ અને અપરકેસને સમાન અથવા અલગ અક્ષરો તરીકે ગણવા માંગો છો તેના આધારે, આ ફોર્મ્યુલામાંથી એક સારવારનું કામ કરશે:

કેસ-સંવેદનશીલ આંશિક મેચ માટે ફોર્મ્યુલા:

કેસ-સંવેદનશીલ આંશિક મેળ માટે ફોર્મ્યુલા:

બંને કાર્યો "સેલ સમાવે છે" પ્રકારનો મેળ કરવા માટે રચાયેલ હોવાથી, આ કિસ્સામાં વાઇલ્ડકાર્ડ્સની ખરેખર જરૂર નથી.

ઉદાહરણ તરીકે, "A" અથવા "a" ધરાવતા ID શોધવા માટે , સૂત્ર છે:

=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")

માત્ર કેપિટલ "A" શોધવા અને "a" ને અવગણવા માટે, સૂત્ર છે:

=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")

નીચેના સ્ક્રીનશોટમાં B6 માં, તમે પરિણામમાં તફાવત જોઈ શકો છો:

આ ફોર્મ્યુલા કેવી રીતે કાર્ય કરે છે:

આ પર નું હૃદયસૂત્રમાં, ISNUMBER અને SEARCH (અથવા FIND) નું સંયોજન છે:

ISNUMBER(SEARCH("A", A2))

SEARCH ફંક્શન સ્પષ્ટ કરેલ ટેક્સ્ટ (આ ઉદાહરણમાં "A") માટે જુએ છે અને તેની અંદર તેની સ્થિતિ પરત કરે છે A2 માં એક શબ્દમાળા. જો ટેક્સ્ટ ન મળે, તો #VALUE ભૂલ પરત કરવામાં આવે છે. SEARCH અને FIND બંને "સેલ સમાવે છે" પ્રકારનો મેળ કરવા માટે રચાયેલ હોવાથી, આ કિસ્સામાં વાઈલ્ડકાર્ડની ખરેખર જરૂર નથી.

ISNUMBER ફંક્શન નંબરને TRUE અને અન્ય કોઈપણ મૂલ્યને FALSE માં ભૂલ સહિત રૂપાંતરિત કરે છે. . તાર્કિક મૂલ્ય સીધું જ IF ના તાર્કિક પરીક્ષણમાં જાય છે. અમારા કિસ્સામાં, A2 માં "A" છે, તેથી ISNUMBER TRUE પરત કરે છે:

IF(TRUE, "Yes", "No")

પરિણામે, IF એ value_if_true દલીલ માટે સેટ કરેલ મૂલ્ય પરત કરે છે, જે છે "હા. આ કિસ્સામાં, તમે ક્લાસિક IF OR સ્ટેટમેન્ટને ઉપર ચર્ચા કરેલ COUNTIF અથવા ISNUMBER SEARCH સૂત્ર સાથે જોડી શકો છો.

ઉદાહરણ તરીકે, A2 માં "aa" અથવા "bb" શોધવા માટે અક્ષરના કેસને અવગણીને અને પાછા " હા" જો બેમાંથી એક મળી આવે, તો આમાંથી એક ફોર્મ્યુલાનો ઉપયોગ કરો:

=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")

અથવા

=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")

બે COUNTIF ફંક્શન્સ ઉમેરવાનું પણ કામ કરશે. આ કિસ્સામાં, વત્તા ચિહ્ન OR ઓપરેટરની જેમ કામ કરે છે:

=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")

ફોર્મ્યુલામાં હાર્ડકોડ વાઇલ્ડકાર્ડ સ્ટ્રિંગ્સને બદલે, તમે તેને અલગ કોષોમાં ઇનપુટ કરી શકો છો, બતાવ્યા પ્રમાણે D2 અને F2 કહો. નીચેના સ્ક્રીનશોટમાં. મહેરબાની કરીને નોંધ કરો કે આસેલ સંદર્ભો $ ચિન્હ સાથે લૉક કરવામાં આવે છે જેથી ફોર્મ્યુલા નીચે આપેલા કોષો પર યોગ્ય રીતે નકલ કરે:

=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")

ઉપરોક્ત સૂત્રો 2 આંશિક મેળ માટે સારી રીતે કાર્ય કરે છે , પરંતુ જો તમે 3 કે તેથી વધુ માટે શોધી રહ્યાં છો, તો તે ખૂબ લાંબી થઈ જશે. આ કિસ્સામાં, તે કાર્યને અલગ રીતે સંપર્ક કરવા માટેનું કારણ છે:

એરે કોન્સ્ટન્ટમાં SEARCH ફંક્શનમાં બહુવિધ સબસ્ટ્રિંગ સપ્લાય કરો, પરત કરેલ સંખ્યાઓ ગણો અને તપાસો કે શું પરિણામ શૂન્ય કરતા વધારે છે (જેનો અર્થ થશે જો મળે તો સબસ્ટ્રિંગમાંથી ઓછામાં ઓછું એક:

=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")

આ રીતે, તમને વધુ કોમ્પેક્ટ ફોર્મ્યુલા સાથે બરાબર એ જ પરિણામ મળશે:

વાઇલ્ડકાર્ડ્સ સાથે એક્સેલ IF અને ફોર્મ્યુલા

જ્યારે તમે કોષમાં બે કે તેથી વધુ અલગ-અલગ સબસ્ટ્રિંગ છે કે કેમ તે તપાસવા માંગતા હો, તો લોજિકલ ટેસ્ટ માટે વાઇલ્ડકાર્ડ્સ સાથે COUNTIFS ફંક્શનનો ઉપયોગ કરવાનો સૌથી સરળ રસ્તો છે.

ધારો કે તમે કૉલમ Aમાં કોષો શોધવા માંગો છો જેમાં "b" અને "2" બંને હોય. તે પૂર્ણ કરવા માટે, COUNTIFS ના માપદંડ માટે "*b*" અને "*2*" નો ઉપયોગ કરો અને માપદંડ શ્રેણી માટે A2 નો ઉપયોગ કરો:

=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")

બીજી રીત એ છે કે IF અને ફોર્મ્યુલાનો એકસાથે ઉપયોગ કરવો. ISNUMBER શોધ સાથે:

=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")

જો કે અમે આ ફોર્મ્યુલામાં કોઈપણ વાઈલ્ડકાર્ડ અક્ષરોનો સમાવેશ કરતા નથી, તે બે વાઈલ્ડકાર્ડ શબ્દમાળાઓ ("*b*" અને "*2*" શોધવા જેવું કામ કરે છે. ) એ જ કોષમાં.

અલબત્ત, તમને પૂર્વવ્યાખ્યાયિત કોષોમાં શોધ મૂલ્યો દાખલ કરવાથી, અમારા કિસ્સામાં D2 અને F2, અને સપ્લાય કરવાથી કંઈપણ અટકાવતું નથી.કોષ સૂત્રનો સંદર્ભ આપે છે:

=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")

જો તમે શક્ય હોય ત્યાં વધુ કોમ્પેક્ટ ફોર્મ્યુલાનો ઉપયોગ કરવાનું પસંદ કરો છો, તો તમને એરે કોન્સ્ટન્ટ અભિગમ વધુ સારી રીતે ગમશે. IF COUNT SEARCH ફોર્મ્યુલા અગાઉના ઉદાહરણ જેવું જ છે, પરંતુ કારણ કે આ વખતે બંને સબસ્ટ્રિંગ A2 માં દેખાવા જોઈએ, અમે તપાસ કરીએ છીએ કે ગણતરી 2 ની બરાબર છે કે કેમ:

=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")

<17

આ એક્સેલમાં IF સ્ટેટમેન્ટમાં વાઇલ્ડકાર્ડનો ઉપયોગ કરવાની મુખ્ય પદ્ધતિઓ છે. જો તમે અન્ય કોઈ ઉકેલો જાણો છો, તો અન્ય વપરાશકર્તાઓ ચોક્કસપણે પ્રશંસા કરશે જો તમે ટિપ્પણીઓમાં તમારો અનુભવ શેર કરો છો. હું વાંચવા બદલ તમારો આભાર માનું છું અને આગામી અઠવાડિયે તમને અમારા બ્લોગ પર મળવાની આશા રાખું છું!

ડાઉનલોડ માટે પ્રેક્ટિસ વર્કબુક

Excel IF વાઇલ્ડકાર્ડ ફોર્મ્યુલા ઉદાહરણો (.xlsx ફાઇલ)