உள்ளடக்க அட்டவணை
வைல்டு கார்டு உரையுடன் IF அறிக்கையை உருவாக்க முயற்சி செய்கிறீர்கள், ஆனால் ஒவ்வொரு முறையும் அது தோல்வியடைகிறதா? சிக்கல் உங்கள் சூத்திரத்தில் இல்லை ஆனால் செயல்பாட்டில் உள்ளது - Excel IF வைல்டு கார்டு எழுத்துக்களை ஆதரிக்காது. இருப்பினும், பகுதியளவு உரைப் பொருத்தத்திற்குச் செயல்படுவதற்கு ஒரு வழி உள்ளது, மேலும் இந்தப் பயிற்சி உங்களுக்கு எப்படிக் கற்றுக்கொடுக்கும்.
எக்செல் இல் பகுதி அல்லது தெளிவற்ற பொருத்தத்தை நீங்கள் செய்ய விரும்பும் போதெல்லாம், மிகத் தெளிவான தீர்வு காட்டு அட்டைகளைப் பயன்படுத்த. ஆனால் நீங்கள் பயன்படுத்த வேண்டிய ஒரு குறிப்பிட்ட செயல்பாடு வைல்டு கார்டு எழுத்துக்களை ஆதரிக்கவில்லை என்றால் என்ன செய்வது? துரதிர்ஷ்டவசமாக, Excel IF அத்தகைய செயல்பாடுகளில் ஒன்றாகும். COUNTIF, SUMIF, மற்றும் AVERAGEIFS போன்ற பிற "நிபந்தனை" செயல்பாடுகள் வைல்டு கார்டுகளுடன் சிறப்பாகச் செயல்படுகின்றன என்பதைக் கருத்தில் கொண்டு இது குறிப்பாக ஏமாற்றமளிக்கிறது.
அதிர்ஷ்டவசமாக, ஒரு ஆக்கப்பூர்வமான Excel பயனரை நிறுத்துவதற்கு இது தடையல்ல :) IF இணைப்பதன் மூலம் மற்ற செயல்பாடுகளுடன், நீங்கள் அதை ஒரு பகுதி பொருத்தத்தை மதிப்பிடும்படி கட்டாயப்படுத்தலாம் மற்றும் எக்செல் IF வைல்டு கார்டு சூத்திரத்திற்கு ஒரு நல்ல மாற்றீட்டைப் பெறலாம்.
ஏன் எக்செல் IF வைல்டு கார்டு வேலை செய்யவில்லை
கீழே உள்ள மாதிரி அட்டவணையில், முதல் நெடுவரிசையில் உள்ள ஐடிகளில் "A" என்ற எழுத்து உள்ளதா என்பதைச் சரிபார்க்க வேண்டும். கண்டறியப்பட்டால் - B நெடுவரிசையில் "ஆம்" என்பதைக் காட்டவும், இல்லையெனில் - "இல்லை" என்பதைக் காட்டவும்.
தர்க்க சோதனையில் வைல்டு கார்டு உரையைச் சேர்ப்பது எளிதான தீர்வாக இருக்கும்:
=IF(A2="*a*","Yes", "No")
ஆனால் வருந்தத்தக்க வகையில் அது செயல்படவில்லை. சூத்திரம் அனைத்து கலங்களுக்கும் "இல்லை" என்பதை வழங்குகிறது, "A" உள்ளவை கூட:
ஏன் செய்கிறதுஅறிக்கை தோல்வியடைந்தால் வைல்டு கார்டு? எல்லா தோற்றங்களிலிருந்தும், சமமான அடையாளம் அல்லது பிற தருக்க ஆபரேட்டர்களுடன் பயன்படுத்தப்படும் வைல்டு கார்டுகளை Excel அங்கீகரிக்கவில்லை. வைல்டு கார்டுகளை ஆதரிக்கும் செயல்பாடுகளின் பட்டியலை உன்னிப்பாகப் பார்த்தால், அவற்றின் தொடரியல் வைல்டு கார்டு உரையை இது போன்ற வாதத்தில் நேரடியாகக் காட்டுவதை நீங்கள் கவனிப்பீர்கள்:
=COUNTIF(A2:A10, "*a*")
Excel IF பகுதி உரையைக் கொண்டுள்ளது
இப்போது வைல்டு கார்டு ஃபார்முலா தோல்வியடைவதற்கான காரணத்தை நீங்கள் அறிந்திருக்கிறீர்கள், அதை எவ்வாறு செயல்பட வைப்பது என்பதைக் கண்டுபிடிக்க முயற்சிப்போம். இதற்காக, IF இன் தருக்க சோதனையில் வைல்டு கார்டுகளை ஏற்றுக்கொள்ளும் செயல்பாட்டை உட்பொதிப்போம், அதாவது COUNTIF செயல்பாடு:
IF(COUNTIF( செல்,"* text* "), value_if_true, value_if_false)இந்த அணுகுமுறையால், வைல்டு கார்டுகளைப் புரிந்துகொள்வதில் IFக்கு எந்தப் பிரச்சனையும் இல்லை, மேலும் "A" அல்லது "a" (COUNTIF ஆனது கேஸ்-சென்சிட்டிவ் அல்ல என்பதால்) உள்ள கலங்களை பிழையின்றி அடையாளம் காட்டுகிறது:
=IF(COUNTIF(A2, "*a*"),"Yes", "No")
இந்த சூத்திரம் B2 அல்லது வரிசை 2 இல் உள்ள வேறு எந்த கலத்திற்கும் செல்கிறது, பின்னர் நீங்கள் அதை தேவையான பல கலங்களுக்கு கீழே இழுக்கலாம்:
=IF(COUNTIF(A2, "??-??"), "Valid", "")
இந்த சூத்திரம் எவ்வாறு செயல்படுகிறது:
தர்க்கரீதியான சோதனைக்கு IF, குறிப்பிட்ட வைல்டு கார்டுடன் பொருந்தக்கூடிய கலங்களின் எண்ணிக்கையைக் கணக்கிடும் COUNTIF செயல்பாட்டைப் பயன்படுத்துகிறோம்லேசான கயிறு. அளவுகோல் வரம்பு ஒற்றை செல் (A2) என்பதால், முடிவு எப்போதும் 1 (பொருத்தம் கண்டறியப்பட்டது) அல்லது 0 (பொருத்தம் காணப்படவில்லை). 1 என்பது TRUE க்கும், 0 என்பது FALSE க்கும் சமமானதாக இருந்தால், எண்ணிக்கை 1 ஆக இருக்கும் போது சூத்திரம் "செல்லுபடியாகும்" (மதிப்பு_if_true) மற்றும் எண்ணிக்கை 0 ஆக இருக்கும் போது ஒரு வெற்று சரம் (மதிப்பு_if_false) ஆகியவற்றை வழங்கும்.
If ISNUMBER SEARCH சூத்திரம் பகுதிக்கு பொருத்தங்கள்
எக்செல் IFஐ பகுதியளவு உரைப் பொருத்தத்திற்கு வேலை செய்யும்படி கட்டாயப்படுத்துவதற்கான மற்றொரு வழி, தருக்க சோதனையில் FIND அல்லது SEARCH செயல்பாட்டைச் சேர்ப்பதாகும். வித்தியாசம் என்னவென்றால், SEARCH இல்லாவிட்டாலும், FIND என்பது கேஸ்-சென்சிட்டிவ் ஆகும்.
எனவே, சிறிய எழுத்துக்களையும் பெரிய எழுத்தையும் ஒரே அல்லது வெவ்வேறு எழுத்துகளாகக் கருத வேண்டுமா என்பதைப் பொறுத்து, இந்த சூத்திரங்களில் ஒன்று விருந்தளிக்கும்:<3 பகுதி பொருத்தத்திற்கான
கேஸ்-சென்சிட்டிவ் சூத்திரம்:
IF(ISNUMBER(SEARCH(" text ", செல் )), value_if_true, value_if_false )Case-sensitive பகுதி பொருத்தத்திற்கான சூத்திரம்:
IF(ISNUMBER(FIND(" text ", cell )), value_if_true, value_if_false )இரண்டு செயல்பாடுகளும் "செல் கொண்டிருக்கும்" வகை பொருத்தத்தை செயல்படுத்த வடிவமைக்கப்பட்டுள்ளதால், இந்த வழக்கில் வைல்டு கார்டுகள் தேவையில்லை.
உதாரணமாக, "A" அல்லது "a" ஐக் கண்டறிய , சூத்திரம்:
=IF(ISNUMBER(SEARCH("A", A2)), "Yes", "No")
மூலதனம் "A" ஐ மட்டும் தேடி "a" ஐ புறக்கணிக்க, சூத்திரம்:
=IF(ISNUMBER(FIND("A", A2)), "Yes", "No")
கீழே உள்ள ஸ்கிரீன்ஷாட்டில் உள்ள B6 இல், முடிவில் உள்ள வேறுபாட்டை நீங்கள் கவனிக்கலாம்:
இந்த சூத்திரம் எவ்வாறு செயல்படுகிறது:
இதயம்சூத்திரத்தில், ISNUMBER மற்றும் SEARCH (அல்லது FIND) ஆகியவற்றின் கலவை உள்ளது:
ISNUMBER(SEARCH("A", A2))
தேடல் செயல்பாடு குறிப்பிட்ட உரையைத் தேடுகிறது ("A" இந்த எடுத்துக்காட்டில்) மற்றும் அதன் நிலையைத் தருகிறது A2 இல் ஒரு சரம். உரை கிடைக்கவில்லை என்றால், #VALUE பிழை திரும்பும். SEARCH மற்றும் FIND ஆகிய இரண்டும் "செல் கொண்டிருக்கும்" வகையான பொருத்தத்தை நிகழ்த்தும் வகையில் வடிவமைக்கப்பட்டுள்ளதால், இந்த விஷயத்தில் வைல்டு கார்டுகள் தேவையில்லை.
ISNUMBER செயல்பாடு ஒரு எண்ணை TRUE ஆகவும், பிழை உட்பட வேறு எந்த மதிப்பையும் FALSE ஆகவும் மாற்றுகிறது. . தருக்க மதிப்பு நேரடியாக IF இன் தருக்க சோதனைக்கு செல்கிறது. எங்கள் விஷயத்தில், A2 இல் "A" உள்ளது, எனவே ISNUMBER TRUE ஐ வழங்குகிறது:
IF(TRUE, "Yes", "No")
இதன் விளைவாக, IF value_if_true வாதத்திற்கு அமைக்கப்பட்ட மதிப்பை வழங்குகிறது. "ஆம்".
Excel IF அல்லது வைல்டு கார்டுகளுடன் அறிக்கை
வைல்டு கார்டு உரை சரங்களில் ஒன்றைக் கொண்ட கலங்களை அடையாளம் காண வேண்டுமா? இந்த நிலையில், மேலே விவாதிக்கப்பட்ட COUNTIF அல்லது ISNUMBER தேடல் சூத்திரத்துடன் கிளாசிக் IF OR அறிக்கையை நீங்கள் இணைக்கலாம்.
உதாரணமாக, A2 இல் "aa" அல்லது "bb" ஐத் தேட, எழுத்துப்பெட்டியைப் புறக்கணித்துவிட்டு " ஆம்" ஒன்று கண்டறியப்பட்டால், இந்த சூத்திரங்களில் ஒன்றைப் பயன்படுத்தவும்:
=IF(OR(ISNUMBER(SEARCH("aa", A2)), ISNUMBER(SEARCH("bb", A2))), "Yes", "")
அல்லது
=IF(OR(COUNTIF(A2, "*aa*"), COUNTIF(A2, "*bb*")), "Yes", "")
இரண்டு COUNTIF செயல்பாடுகளைச் சேர்ப்பதும் வேலை செய்யும். இந்த நிலையில், கூட்டல் குறியானது OR ஆபரேட்டரைப் போன்று செயல்படுகிறது:
=IF(COUNTIF(A3, "*aa*") + COUNTIF(A3, "*bb*"), "Yes", "")
சூத்திரத்தில் வைல்டு கார்டு சரங்களை ஹார்ட்கோடிங் செய்வதற்குப் பதிலாக, காட்டப்பட்டுள்ளபடி D2 மற்றும் F2 என்று தனித்தனி கலங்களில் உள்ளிடலாம். கீழே உள்ள ஸ்கிரீன்ஷாட்டில். இவற்றை கவனிக்கவும்செல் குறிப்புகள் $ அடையாளத்துடன் பூட்டப்பட்டுள்ளன, இதனால் சூத்திரம் கீழே உள்ள கலங்களுக்கு சரியாக நகலெடுக்கப்படும்:
=IF(OR(COUNTIF(A2, "*"&$D$2&"*"), COUNTIF(A2, "*"&$F$2&"*")), "Yes", "")
மேலே உள்ள சூத்திரங்கள் 2 பகுதி பொருத்தங்களுக்கு நன்றாக வேலை செய்யும் , ஆனால் நீங்கள் 3 அல்லது அதற்கு மேற்பட்டவற்றைத் தேடினால், அவை மிக நீளமாகிவிடும். இந்த விஷயத்தில், பணியை வித்தியாசமாக அணுகுவதற்கு இது ஒரு காரணம்:
தேடல் செயல்பாட்டிற்கு பல துணைச்சரங்களை வரிசை மாறிலியில் வழங்கவும், திரும்பிய எண்களை எண்ணி, முடிவு பூஜ்ஜியத்தை விட அதிகமாக உள்ளதா என சரிபார்க்கவும் (அதாவது குறைந்த பட்சம் ஒரு துணைச்சரமாவது கண்டுபிடிக்கப்பட்டால்:
=IF(COUNT(SEARCH({"aa","bb"}, A2))>0, "Yes", "")
இவ்வாறு, மிகச் சிறிய சூத்திரத்துடன் அதே முடிவைப் பெறுவீர்கள்:
3>
எக்செல் IF மற்றும் வைல்டு கார்டுகளுடன் சூத்திரம்
ஒரு கலத்தில் இரண்டு அல்லது அதற்கு மேற்பட்ட வெவ்வேறு துணைச்சரங்கள் உள்ளதா என்பதை நீங்கள் சரிபார்க்க விரும்பினால், லாஜிக்கல் சோதனைக்கு வைல்டு கார்டுகளுடன் COUNTIFS செயல்பாட்டைப் பயன்படுத்துவது எளிதான வழி.
"b" மற்றும் "2" இரண்டையும் கொண்ட நெடுவரிசை A இல் உள்ள கலங்களைக் கண்டறிய வேண்டும் என்று வைத்துக்கொள்வோம். இதைச் செய்ய, COUNTIFS இன் அளவுகோல்களுக்கு "*b*" மற்றும் "*2*" ஐப் பயன்படுத்தவும் மற்றும் அளவுகோல் வரம்பிற்கு A2 ஐப் பயன்படுத்தவும்:
=IF(COUNTIFS(A2, "*b*", A2, "*2*"), "Yes", "")
மற்றொரு வழி IF மற்றும் சூத்திரத்தை ஒன்றாகப் பயன்படுத்துவதாகும். ISNUMBER தேடலுடன்:
=IF(AND(ISNUMBER(SEARCH("b", A2)), ISNUMBER(SEARCH("2", A2))), "Yes", "")
இந்த சூத்திரத்தில் எந்த வைல்டு கார்டு எழுத்துக்களையும் நாங்கள் சேர்க்கவில்லை என்றாலும், இது இரண்டு வைல்டு கார்டு சரங்களை ("*b*" மற்றும் "*2*" தேடுவது போல் வேலை செய்கிறது ) அதே கலத்தில்.
நிச்சயமாக, முன் வரையறுக்கப்பட்ட கலங்களில் தேடல் மதிப்புகளை உள்ளிடுவதில் இருந்து எதுவும் உங்களைத் தடுக்காது, எங்கள் விஷயத்தில் D2 மற்றும் F2, மற்றும் வழங்குதல்செல் சூத்திரத்தைக் குறிப்பிடுகிறது:
=IF(AND(ISNUMBER(SEARCH($D$2, A2)), ISNUMBER(SEARCH($F$2, A2))), "Yes", "")
முடிந்த இடங்களில் அதிகச் சுருக்கமான சூத்திரங்களைப் பயன்படுத்த விரும்பினால், வரிசை நிலையான அணுகுமுறையை நீங்கள் விரும்பலாம். IF COUNT SEARCH சூத்திரம் முந்தைய உதாரணத்தைப் போலவே உள்ளது, ஆனால் இந்த முறை இரண்டு துணைச்சரங்களும் A2 இல் தோன்ற வேண்டும் என்பதால், எண்ணிக்கை 2:
=IF(COUNT(SEARCH({"b","2"}, A2))=2, "Yes", "")
<17 க்கு சமமாக உள்ளதா என்பதைச் சரிபார்க்கிறோம்.
இவை எக்செல் இல் IF அறிக்கையில் வைல்டு கார்டைப் பயன்படுத்துவதற்கான முக்கிய முறைகள். வேறு ஏதேனும் தீர்வுகள் உங்களுக்குத் தெரிந்தால், கருத்துகளில் உங்கள் அனுபவத்தைப் பகிர்ந்து கொண்டால், பிற பயனர்கள் நிச்சயமாகப் பாராட்டுவார்கள். படித்ததற்கு நன்றி, அடுத்த வாரம் எங்கள் வலைப்பதிவில் உங்களைப் பார்ப்பேன் என்று நம்புகிறேன்!
பதிவிறக்கப் பயிற்சிப் புத்தகம்
Excel IF வைல்டு கார்டு ஃபார்முலா உதாரணங்கள் (.xlsx கோப்பு)
