Mundarija
O'quv qo'llanma tasodifiy raqamlarni yaratish, ro'yxatni tasodifiy tartiblash, tasodifiy tanlash va ma'lumotlarni guruhlarga tasodifiy belgilashni ko'rsatadi. Hammasi yangi dinamik massiv funksiyasiga ega - RANDARRAY.
Sizga ma'lumki, Microsoft Excelda allaqachon bir nechta tasodifiy funksiyalar mavjud - RAND va RANDBETWEEN. Boshqasini kiritishning ma'nosi nima? Xulosa qilib aytganda, u ancha kuchliroq va ikkala eski funksiyani almashtira oladi. O'zingizning maksimal va minimal qiymatlaringizni o'rnatishdan tashqari, u sizga qancha satr va ustunlarni to'ldirishni va tasodifiy o'nli yoki butun sonlarni chiqarishni belgilash imkonini beradi. Boshqa funksiyalar bilan birgalikda foydalanilganda, RANDARRAY hatto ma'lumotlarni aralashtirib yuborishi va tasodifiy namunani tanlashi mumkin.
Excel RANDARRAY funksiyasi
Excel'dagi RANDARRAY funksiyasi o'rtasida tasodifiy sonlar qatorini qaytaradi. siz ko'rsatgan har qanday ikkita raqam.
Bu Microsoft Excel 365 da kiritilgan oltita yangi dinamik massiv funksiyalaridan biridir. Natijada belgilangan qator va ustunlar soniga avtomatik ravishda tushadigan dinamik massiv hosil bo'ladi.
Funktsiya quyidagi sintaksisga ega. Eʼtibor bering, barcha argumentlar ixtiyoriy:
RANDARRAY([satrlar], [ustunlar], [min], [maks.], [butun_raqam])Bu yerda:
Qatorlar (ixtiyoriy) - nechta qatorni to'ldirishni belgilaydi. Agar o'tkazib yuborilsa, sukut bo'yicha 1 satr.
Ustunlar (ixtiyoriy) - nechta ustunni to'ldirish kerakligini belgilaydi. Agar o'tkazib yuborilsa, birlamchi qiymat 1 bo'ladiishtirokchilarni tasodifiy guruhlarga tayinlang, yuqoridagi formula mos kelmasligi mumkin, chunki u berilgan guruh necha marta tanlanganligini nazorat qilmaydi. Masalan, A guruhiga 5 kishi, C guruhiga esa atigi 2 kishi tayinlanishi mumkin. Tasodifiy topshiriqni teng bajarish uchun, har bir guruhda ishtirokchilar soni bir xil bo'lishi uchun sizga boshqa yechim kerak bo'ladi.
Birinchi, siz quyidagi formuladan foydalanib tasodifiy sonlar roʻyxatini yaratasiz:
=RANDARRAY(ROWS(A2:A13))
Bu yerda A2:A13 manba maʼlumotlaringiz.
Keyin, siz ushbu umumiy formuladan foydalanib guruhlarni (yoki boshqa biror narsani) tayinlaysiz:
INDEX( tayinlash uchun_qiymatlar, ROUNDUP(RANK( birinchi_tasodifiy_raqam, ). tasodifiy_raqamlar_diapazoni)/ n, 0))Bu erda n - guruh hajmi, ya'ni har bir qiymat necha marta tayinlanishi kerak.
Masalan, odamlarni E2:E5 da sanab o‘tilgan guruhlarga tasodifiy belgilash uchun har bir guruhda 3 ta ishtirokchi bo‘lishi uchun quyidagi formuladan foydalaning:
=INDEX($E$2:$E$5, ROUNDUP(RANK(B2,$B$2:$B$13)/3,0))
Iltimos, bu oddiy formula (emas) dinamik massiv formulasi!), shuning uchun yuqoridagi formuladagi kabi mutlaq havolalar bilan diapazonlarni bloklashingiz kerak.
Formulangizni yuqori katakchaga kiriting (bizning holatda C2) va n uni kerak bo'lganda ko'p katakka torting. Natija shunga o'xshash bo'ladi:
RANDARRAY funksiyasi o'zgaruvchan ekanligini unutmang. Ish varag'idagi biror narsani har o'zgartirganingizda yangi tasodifiy qiymatlar paydo bo'lishining oldini olish uchun almashtiringformulalar qiymatlari bilan Maxsus joylashtirish funksiyasidan foydalangan holda.
Ushbu formula qanday ishlaydi:
Yordamchi ustundagi RANDARRAY formulasi juda oddiy va tushuntirishni talab qilmaydi, shuning uchun C ustunidagi formulaga e'tibor qaratamiz.
=INDEX($E$2:$E$5, ROUNDUP(RANK(B2,$B$2:$B$13)/3,0))
RANK funksiyasi B2 dagi qiymatni B2:B13 dagi tasodifiy sonlar massiviga nisbatan tartiblaydi. Natijada 1 va jami ishtirokchilar soni (bizning holimizda 12) o'rtasidagi raqam bo'ladi.
Manba guruh hajmiga bo'linadi (bizning misolimizda 3) va ROUNDUP funksiyasi uni yaxlitlaydi. eng yaqin butun son. Bu amalning natijasi 1 va jami guruhlar soni (bu misolda 4) oʻrtasidagi sondir.
Butun son INDEX funksiyasining satr_num argumentiga oʻtadi va uni majbur qiladi. tayinlangan guruhni ifodalovchi E2:E5 diapazonidagi tegishli qatordan qiymatni qaytaring.
Excel RANDARRAY funksiyasi ishlamayapti
RANDARRAY formulasi xatoni qaytarsa, bular eng aniq ko‘rinib turadi. tekshirish uchun sabablar:
#SPILL xatosi
Boshqa dinamik massiv funksiyalarida bo'lgani kabi, #SPILL! xato ko'pincha barcha natijalarni ko'rsatish uchun mo'ljallangan to'kish oralig'ida etarli joy yo'qligini anglatadi. Shu oraliqdagi barcha katakchalarni tozalang va formulangiz avtomatik ravishda qayta hisoblab chiqiladi. Qo'shimcha ma'lumot olish uchun Excel #SPILL xatosi - sabablari va tuzatishlariga qarang.
#VALUE xatosi
A #VALUE! bularda xatolik yuz berishi mumkinholatlar:
- Agar max qiymati min qiymatidan kichik boʻlsa.
- Agar argumentlardan birortasi raqamli boʻlmasa.
#NAME xatosi
Ko'p hollarda #NAME! xato quyidagilardan birini bildiradi:
- Funktsiya nomi noto'g'ri yozilgan.
- Funktsiya Excel versiyangizda mavjud emas.
#CALC! xato
A #CALC! Agar satr yoki ustun argumenti 1 dan kichik bo'lsa yoki bo'sh katakka ishora qilsa, xatolik yuzaga keladi.
Mana shunday yangi bilan Excelda tasodifiy sonlar generatorini qurish mumkin. RANDARRAY funktsiyasi. O'qiganingiz uchun rahmat va keyingi haftada blogimizda ko'rishga umid qilaman!
Yuklab olish uchun mashq kitobi
RANDARRAY formula misollari (.xlsx fayli)
Min (ixtiyoriy) - ishlab chiqarish uchun eng kichik tasodifiy son. Agar ko'rsatilmagan bo'lsa, standart 0 qiymati ishlatiladi.
Maks (ixtiyoriy) - yaratish uchun eng katta tasodifiy son. Agar ko'rsatilmagan bo'lsa, birlamchi 1 qiymati ishlatiladi.
To'liq_raqam (ixtiyoriy) - qanday qiymatlarni qaytarish kerakligini aniqlaydi:
- TRUE - butun sonlar
- YOLG'ON yoki o'tkazib yuborilgan (standart) - o'nlik sonlar
RANDARRAY funktsiyasi - eslash kerak bo'lgan narsalar
Excel ish varaqlarida tasodifiy sonlarni samarali yaratish uchun 6 ta muhim nuqta mavjud. e'tibor bering:
- RANDARRAY funksiyasi faqat Microsoft 365 va Excel 2021 uchun Excelda mavjud. Excel 2019, Excel 2016 va oldingi versiyalarida RANDARRAY funksiyasi mavjud emas.
- Agar RANDARRAY tomonidan qaytarilgan massiv yakuniy natija bo'lsa (hujayradagi chiqish va boshqa funktsiyaga o'tkazilmasa), Excel avtomatik ravishda dinamik to'kish oralig'ini yaratadi va uni tasodifiy raqamlar bilan to'ldiradi. Shunday qilib, formulani kiritayotgan katakning pastida va/yoki o‘ng tomonida yetarlicha bo‘sh katakchalar mavjudligiga ishonch hosil qiling, aks holda #SPILL xatosi yuzaga keladi.
- Agar argumentlarning hech biri ko‘rsatilmagan bo‘lsa, RANDARRAY( ) formula 0 dan 1 gacha boʻlgan bitta oʻnlik sonni qaytaradi.
- Agar satr yoki/va ustun argumentlari oʻnlik sonlar bilan ifodalangan boʻlsa, ular oʻnlik sonlarga qisqartiriladi. Kasrdan oldingi butun son (masalan, 5,9 hisobga olinadisifatida 5).
- Agar min yoki max argumenti aniqlanmagan bo'lsa, RANDARRAY mos ravishda 0 va 1 ga o'rnatiladi.
- Boshqa tasodifiy kabi funktsiyalari uchun Excel RANDARRAY uchuvchan , ya'ni har safar ish varag'i hisoblanganda tasodifiy qiymatlarning yangi ro'yxatini yaratadi. Buning oldini olish uchun Excelning Maxsus joylashtirish > Qiymatlar funksiyasidan foydalanib, formulalarni qiymatlar bilan almashtirishingiz mumkin.
Asosiy Excel RANDARRAY formulasi
Va endi men sizga tasodifiy Excel formulasini eng oddiy ko'rinishida ko'rsataman.
Aytaylik, siz 5 qator va 3 ustundan iborat diapazonni istalgan tasodifiy raqamlar bilan to'ldirmoqchisiz. Buni amalga oshirish uchun dastlabki ikkita argumentni quyidagi tarzda o'rnating:
- Qatorlar 5, chunki biz natijalarni 5 qatorda olishni xohlaymiz.
- Ustunlar 3 ta, chunki biz natijalarni 3 ta ustunda olishimiz kerak.
Boshqa barcha argumentlarni standart qiymatlariga qoldirib, quyidagi formulani olamiz:
=RANDARRAY(5, 3)
Uni belgilangan diapazonning yuqori chap katakchasiga kiriting (bizning holimizda A2), Enter tugmasini bosing va natijalar belgilangan qator va ustunlar soniga to'g'ri keladi.
Yuqoridagi skrinshotda koʻrib turganingizdek, bu asosiy RANDARRAY formulasi diapazonni 0 dan 1 gacha boʻlgan tasodifiy oʻnlik sonlar bilan toʻldiradi. Agar maʼlum diapazonda butun sonlarni olishni maʼqul koʻrsangiz, oxirgisini sozlang. Keyingi misollarda ko'rsatilgan uchta argument.
Qanday qilib randomizatsiya qilish kerakExcel - RANDARRAY formula misollari
Quyida siz Excelda odatiy tasodifiy stsenariylarni qamrab oluvchi bir necha ilg'or formulalarni topasiz.
Ikki raqam o'rtasida tasodifiy sonlarni yarating
Ro'yxatini yaratish uchun ma'lum bir diapazondagi tasodifiy sonlar, 3-argumentdagi minimal qiymatni va 4-argumentdagi maksimal sonni taqdim eting. Butun yoki oʻnli sonlar kerakligiga qarab, 5-argumentni mos ravishda TRUE yoki FALSE ga oʻrnating.
Masalan, 6 qator va 4 ta ustun oraligʻini 1 dan 100 gacha tasodifiy butun sonlar bilan toʻldiramiz. Buning uchun , biz RANDARRAY funksiyasining quyidagi argumentlarini o'rnatamiz:
- Qatorlar 6, chunki biz natijalarni 6 qatorda olishni xohlaymiz.
- Ustunlar - 4, chunki biz 4 ta ustunda natijalarni olishni xohlaymiz.
- Min - 1, bu biz ega bo'lishni istagan minimal qiymatdir.
- Maks - 100, ya'ni hosil qilinadigan maksimal qiymat.
- To'liq_raqam TO'G'ri, chunki bizga butun sonlar kerak.
Argumentlarni bir joyga qo'yib, biz hosil bo'lamiz. bu formula:
=RANDARRAY(6, 4, 1, 100, TRUE)
Va u quyidagi natijani beradi:
Ikki sana orasida tasodifiy sanani yarating
Excelda tasodifiy sana generatorini qidiryapsizmi? RANDARRAY funksiyasi oson yechim! Oldindan belgilangan yacheykalarga oldingi sanani (1-sana) va keyingi sanani (2-sana) kiritib, formulangizdagi oʻsha kataklarga havola qilish kifoya:
RANDARRAY(satrlar, ustunlar, sana1, date2, TRUE)Ushbu misol uchun biz D1 va D2 sanalari orasidagi tasodifiy sanalar ro'yxatini quyidagi formula bilan yaratdik:
=RANDARRAY(10, 1, D1, D2, TRUE)
Albatta, agar xohlasangiz, to'g'ridan-to'g'ri formulada minimal va maksimal sanalarni kiritishingizga hech narsa to'sqinlik qilmaydi. Ularni Excel tushunadigan formatda kiritganingizga ishonch hosil qiling:
=RANDARRAY(10, 1, "1/1/2020", "12/31/2020", TRUE)
Xatolarning oldini olish uchun sanalarni kiritish uchun DATE funksiyasidan foydalanishingiz mumkin:
=RANDARRAY(10, 1, DATE(2020,1,1), DATE(2020,12,31), TRUE)
Eslatma. Ichki Excel sanalarni seriya raqamlari sifatida saqlaydi, shuning uchun formula natijalari katta ehtimollik bilan raqamlar sifatida ko'rsatiladi. Natijalarni to'g'ri ko'rsatish uchun Sana formatini to'kilish oralig'idagi barcha hujayralarga qo'llang.
Excelda tasodifiy ish kunlarini yarating
Tasodifiy ish kunlarini yaratish uchun RANDARRAY funksiyasini WORKDAY ning birinchi argumentiga quyidagicha kiriting:
WORKDAY(RANDARRAY(satrlar, ustunlar, date1<2)>, date2 , TRUE), 1)RANDARRAY tasodifiy boshlanish sanalari qatorini yaratadi, unga WORKDAY funksiyasi 1 ish kuni qo‘shadi va barcha qaytarilgan sanalar ish kuni ekanligini ta’minlaydi.
D1-da 1-sana va D2-da 2-sana bilan 10 ish kuni roʻyxatini yaratish formulasi quyidagicha:
=WORKDAY(RANDARRAY(10, 1, D1, D2, TRUE), 1)
Kubi oldingi misolda, natijalar to'g'ri ko'rsatilishi uchun to'kilish diapazonini Sana sifatida formatlashni unutmang.
Tasodifiy raqamlarni dublikatsiz qanday yaratish mumkin
Garchi zamonaviy Excel 6 tani taklif qiladi. yangi dinamik massivafsuski, tasodifiy sonlarni dublikatsiz qaytarish uchun hali ham oʻrnatilgan funksiya mavjud emas.
Excelda oʻzingizning noyob tasodifiy sonlar generatorini yaratish uchun koʻrsatilganidek, bir nechta funksiyalarni bir-biriga bogʻlashingiz kerak boʻladi. quyida.
Tasodifiy butun sonlar :
INDEX(UNIQUE(RANDARRAY( n *2, 1, min , maks. , TRUE)), SEQUENCE( n ))Tasodifiy oʻnli kasrlar :
INDEX(UNIQUE(RANDARRAY( n *2,) 1, min , maks , FALSE)), SEQUENCE( n ))Bu yerda:
- N siz yaratmoqchi bo'lgan qancha qiymat.
- Min eng past qiymat.
- Maks eng yuqori qiymat.
Masalan, dublikatsiz 10 ta tasodifiy butun son hosil qilish uchun quyidagi formuladan foydalaning:
=INDEX(UNIQUE(RANDARRAY(20, 1, 1, 100, TRUE)), SEQUENCE(10))
Yaratish uchun 10 ta noyob tasodifiy oʻnlik sonlar roʻyxati, RANDARRAY funksiyasining oxirgi argumentida TRUE ni FALSE ga oʻzgartiring yoki shunchaki ushbu argumentni oʻtkazib yuboring:
=INDEX(UNIQUE(RANDARRAY(20, 1, 1, 100, FALSE)), SEQUENCE(10))
Maslahatlar va eslatmalar:
- Formulaning batafsil tushuntirishi f bo'lishi mumkin ound bo'limida Excelda tasodifiy sonlarni dublikatsiz qanday yaratish mumkin.
- Excel 2019 va undan oldingi versiyalarida RANDARRAY funksiyasi mavjud emas. Buning o'rniga, iltimos, ushbu yechimni ko'rib chiqing.
Excelda tasodifiy tartiblash qanday
Excelda ma'lumotlarni aralashtirib yuborish uchun RANDARRAY-dan "tartiblash bo'yicha" massividan foydalaning ( bo'yicha_massiv argumenti) SORTBY funksiyasining. ROWS funksiyasi sizdagi qatorlar sonini hisoblab chiqadiQancha tasodifiy son hosil qilish kerakligini ko'rsatadigan ma'lumotlar to'plami:
SORTBY( ma'lumotlar , RANDARRAY(ROWS( ma'lumotlar )))Ushbu yondashuv bilan siz Excelda ro'yxatni tasodifiy tartiblash , unda raqamlar, sanalar yoki matnli yozuvlar mavjud:
=SORTBY(A2:A13, RANDARRAY(ROWS(A2:A13)))
Shuningdek, siz ma'lumotlaringizni aralashtirmasdan qatorlarni aralashtiring :
=SORTBY(A2:B10, RANDARRAY(ROWS(A2:B10)))
Excelda tasodifiy tanlovni qanday olish mumkin
Tasodifiyni ajratib olish uchun roʻyxatdagi namuna, bu yerda foydalanish uchun umumiy formula:
INDEX( maʼlumotlar , RANDARRAY( n , 1, 1, ROWS( maʼlumotlar ), TRUE))Bu yerda n siz chiqarmoqchi boʻlgan tasodifiy yozuvlar soni.
Masalan, A2:A10 roʻyxatidan 3 ta nomni tasodifiy tanlash uchun ushbu formuladan foydalaning. :
=INDEX(A2:A10, RANDARRAY(3, 1, 1, ROWS(A2:A10), TRUE))
Yoki ba'zi katakchaga kerakli namuna hajmini kiriting, C2 deb ayting va o'sha katakka murojaat qiling:
=INDEX(A2:A10, RANDARRAY(C2, 1, 1, ROWS(A2:A10), TRUE))
Ushbu formula qanday ishlaydi:
Ushbu formulaning o'zagida tasodifiy butun sonlar massivini yaratuvchi RANDARRAY funksiyasi joylashgan bo'lib, C2 dagi qiymat qancha qiymat hosil qilish kerakligini aniqlaydi. . Minimal raqam qattiq kodlangan (1) va maksimal raqam ROWS funksiyasi tomonidan qaytariladigan maʼlumotlar toʻplamidagi qatorlar soniga mos keladi.
Tasodifiy butun sonlar toʻgʻridan-toʻgʻri satr_numiga oʻtadi. INDEX funktsiyasining argumenti, qaytariladigan elementlarning o'rnini belgilab beradi. Yuqoridagi skrinshotdagi namuna uchun u:
=INDEX(A2:A10, {8;7;4})
Maslahat. Katta namunani tanlayotgandakichik ma'lumotlar to'plami, tasodifiy tanlovingiz bir xil yozuvning bir nechta takrorlanishini o'z ichiga olishi ehtimoli bor, chunki RANDARRAY faqat noyob raqamlarni ishlab chiqarishiga kafolat yo'q. Buning oldini olish uchun ushbu formulaning dublikatsiz versiyasidan foydalaning.
Excelda tasodifiy qatorlarni qanday tanlash mumkin
Agar ma'lumotlar to'plamida bir nechta ustunlar mavjud bo'lsa, namunaga qaysi ustunlarni kiritish kerakligini belgilang. Buning uchun INDEX funksiyasining oxirgi argumenti ( ustun_num ) uchun massiv konstantasini keltiring, masalan:
=INDEX(A2:B10, RANDARRAY(D2, 1, 1, ROWS(A2:A10), TRUE), {1,2})
Bu erda A2:B10 manba ma'lumoti va D2 - namuna hajmi.
Natijada tasodifiy tanlovimiz ikkita ma'lumot ustunini o'z ichiga oladi:
Maslahat. Oldingi misolda bo'lgani kabi, bu formula takroriy yozuvlarni qaytarishi mumkin. Namunangiz takrorlanmasligiga ishonch hosil qilish uchun tasodifiy qatorlarni dublikatsiz tanlash bo'limida tasvirlangan biroz boshqacha yondashuvdan foydalaning.
Excelda raqamlar va matnlarni tasodifiy belgilash usullari
Excelda tasodifiy belgilashni amalga oshirish uchun RANDBETWEEN-dan CHOOSE funksiyasi bilan birga quyidagi tarzda foydalaning:
CHOOSE(RANDARRAY(ROWS( ma'lumotlar<) 2>), 1, 1, n , TRUE), qiymat1 , qiymat2 ,…)Bu yerda:
- Ma'lumotlar - bu tasodifiy qiymatlarni tayinlamoqchi bo'lgan manba ma'lumotlaringiz diapazoni.
- N - tayinlanadigan qiymatlarning umumiy soni.
- Qiymat1 , qiymat2 , qiymat3 va hokazo.tasodifiy tayinlangan.
Masalan, A2:A13 ishtirokchilariga 1 dan 3 gacha raqamlarni belgilash uchun quyidagi formuladan foydalaning:
=CHOOSE(RANDARRAY(ROWS(A2:A13), 1, 1, 3, TRUE), 1, 2, 3)
Qulaylik uchun siz alohida katakchalarga belgilash uchun qiymatlarni kiritishingiz mumkin, masalan, D2 dan D4 gacha va formulangizdagi ushbu kataklarga murojaat qiling (diapazon sifatida emas, alohida):
=CHOOSE(RANDARRAY(ROWS(A2:A13), 1, 1, 3, TRUE), D2, D3, D4)
Natijada siz tasodifiy ravishda istalgan raqamlar, harflar, matn, sana va vaqtlarni bir xil formula bilan belgilashingiz mumkin bo'ladi:
Eslatma. RANDARRAY funktsiyasi ish varag'idagi har bir o'zgarish bilan yangi tasodifiy qiymatlarni yaratishda davom etadi, chunki natijada har safar yangi qiymatlar tayinlanadi. Belgilangan qiymatlarni "tuzatish" uchun Paste Special > Formulalarni hisoblangan qiymatlari bilan almashtirish uchun xususiyatlarni baholaydi.
Ushbu formula qanday ishlaydi
Ushbu yechimning markazida yana siz ko'rsatgan minimal va maksimal raqamlar (1 dan boshlab) asosida tasodifiy butun sonlar massivini hosil qiluvchi RANDARRAY funksiyasi mavjud. bizning holatlarimizda 3 ga). ROWS funksiyasi RANDARRAY ga nechta tasodifiy sonlarni yaratish kerakligini aytadi. Bu massiv CHOOSE funksiyasining indeks_num argumentiga boradi. Masalan:
=CHOOSE({1;2;1;2;3;2;3;3;1;3;1;2}, D2, D3, D4)
Index_num - qaytariladigan qiymatlarning o'rinlarini belgilovchi argument. Va pozitsiyalar tasodifiy bo'lgani uchun D2: D4 qiymatlari tasodifiy tartibda tanlanadi. Ha, bu juda oddiy :)
Qanday qilib ma'lumotlarni guruhlarga tasodifiy belgilash mumkin
Sizning vazifangiz qachon
