Lernen Sie Formeln und formelfreie Methoden kennen, um Leerzeichen zu entfernen, Sonderzeichen (sogar die ersten/letzten N-Zeichen) und gleiche Textstrings vor/nach bestimmten Zeichen aus mehreren Zellen auf einmal zu entfernen.

Das Entfernen desselben Textteils aus mehreren Zellen auf einmal kann genauso wichtig und knifflig sein wie das Hinzufügen. Selbst wenn Sie einige der Möglichkeiten kennen, werden Sie im heutigen Blogbeitrag bestimmt neue finden. Ich teile viele Funktionen und ihre vorgefertigten Formeln, und wie immer hebe ich mir die einfachste - formelfreie - für den Schluss auf ;)

Formeln für Google Sheets zum Entfernen von Text aus Zellen

Ich beginne mit den Standardfunktionen für Google Sheets, mit denen Sie Ihre Textzeichenfolgen und Zeichen aus den Zellen entfernen können. Es gibt keine universelle Funktion dafür, daher werde ich verschiedene Formeln und deren Kombinationen für verschiedene Fälle bereitstellen.

Google Sheets: Whitespace entfernen

Leerzeichen können sich nach dem Import leicht in Zellen einschleichen oder wenn mehrere Nutzer das Blatt gleichzeitig bearbeiten. Zusätzliche Leerzeichen sind sogar so häufig, dass Google Sheets ein spezielles Trimm-Tool zum Entfernen aller Leerzeichen hat.

Markieren Sie einfach alle Google Sheets-Zellen, in denen Sie Leerzeichen entfernen möchten, und wählen Sie Daten> Whitespace abschneiden im Tabellenkalkulationsmenü:

Wenn Sie auf die Option klicken, werden alle vor- und nachgestellten Leerzeichen in der Auswahl vollständig entfernt, während alle zusätzlichen Leerzeichen zwischen den Daten auf eins reduziert werden:

Entfernen anderer Sonderzeichen aus Textzeichenfolgen in Google Sheets

Leider bietet Google Sheets kein Werkzeug, um andere Zeichen als Leerzeichen zu "trimmen". Sie müssen hier mit Formeln arbeiten.

Tipp: Oder verwenden Sie stattdessen unser Tool - Power Tools befreit Ihren Bereich mit einem Klick von allen Zeichen, die Sie angeben, einschließlich Leerzeichen.

Hier habe ich mit Hashtags vor den Wohnungsnummern und Telefonnummern mit Bindestrichen und Klammern dazwischen angesprochen:

Ich werde Formeln verwenden, um diese Sonderzeichen zu entfernen.

Normalerweise wird die Funktion SUBSTITUTE verwendet, um ein Zeichen durch ein anderes zu ersetzen, aber Sie können das zu Ihrem Vorteil nutzen und die unerwünschten Zeichen durch... nun, nichts ersetzen :) Mit anderen Worten, sie entfernen.

Schauen wir uns an, welches Argument die Funktion benötigt:

• text_zu_suchen ist entweder der zu verarbeitende Text oder eine Zelle, die diesen Text enthält. erforderlich.
• suchen_nach ist das Zeichen, das Sie suchen und löschen möchten. erforderlich.
• ersetzen_mit - ein Zeichen, das Sie anstelle des unerwünschten Symbols einfügen. Erforderlich.
• ereignis_nummer - wenn es mehrere Instanzen des gesuchten Zeichens gibt, können Sie hier angeben, welches ersetzt werden soll. Es ist völlig optional, und wenn Sie dieses Argument weglassen, werden alle Instanzen durch etwas Neues ersetzt ( ersetzen_für ).

Also los: Ich muss einen Hashtag finden ( # ) in A1 und ersetzen Sie es durch 'nichts', das in Tabellenkalkulationen mit doppelten Anführungszeichen gekennzeichnet ist ( "" Mit all dem im Hinterkopf kann ich die folgende Formel aufstellen:

=SUBSTITUTE(A1, "#","")

Tipp: Der Hashtag steht ebenfalls in doppelten Anführungszeichen, da dies die Art und Weise ist, wie Sie Textstrings in Google Sheets-Formeln erwähnen sollten.

Kopieren Sie diese Formel dann in die Spalte, falls Google Sheets dies nicht automatisch anbietet, und Sie erhalten Ihre Adressen ohne die Hashtags:

Aber was ist mit den Bindestrichen und Klammern? Sollten Sie zusätzliche Formeln erstellen? Keineswegs! Wenn Sie mehrere SUBSTITUTE-Funktionen in einer Google Sheets-Formel verschachteln, entfernen Sie alle diese Zeichen aus jeder Zelle:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1, "#",""),"(",""),")",""),"-","")

Bei dieser Formel werden die Zeichen nacheinander entfernt, und jedes SUBSTITUTE wird, beginnend in der Mitte, zum Bereich, der für das nächste SUBSTITUTE herangezogen wird:

Tipp: Sie können dies auch in eine ArrayFormel verpacken und so die gesamte Spalte auf einmal abdecken. In diesem Fall ändern Sie den Zellbezug ( A1 ) zu Ihren Daten in der Spalte ( A1:A7 ) sowie:

=ArrayFormula(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1:A7, "#",""),"(",""),")",""),"-",""))

Bestimmten Text aus Zellen in Google Sheets entfernen

Obwohl Sie die bereits erwähnte Funktion SUBSTITUTE für Google Sheets verwenden können, um Text aus Zellen zu entfernen, möchte ich noch eine weitere Funktion vorstellen - REGEXREPLACE.

Sein Name ist ein Akronym aus 'regular expression replace' (reguläre Ausdrücke ersetzen). Und ich werde die regulären Ausdrücke verwenden, um nach den zu entfernenden Zeichenfolgen zu suchen und sie zu ersetzen durch ' nichts" ( "" ).

Tipp: Wenn Sie kein Interesse an der Verwendung regulärer Ausdrücke haben, beschreibe ich am Ende dieses Blogbeitrags eine viel einfachere Methode.

Tipp: Wenn Sie nach Möglichkeiten suchen, Duplikate in Google Sheets zu finden und zu entfernen, lesen Sie stattdessen diesen Blogbeitrag. REGEXREPLACE(text, regulärer_Ausdruck, Ersatz)

Wie Sie sehen, gibt es drei Argumente für die Funktion:

• Text - ist die Stelle, an der Sie nach der zu entfernenden Textzeichenfolge suchen. Das kann der Text selbst in Anführungszeichen oder ein Verweis auf eine Zelle/einen Bereich mit Text sein.
• regulärer_Ausdruck - Ihr Suchmuster, das aus verschiedenen Zeichenkombinationen besteht. Sie suchen nach allen Zeichenketten, die mit diesem Muster übereinstimmen. In diesem Argument steckt der ganze Spaß, wenn ich das sagen darf.
• Ersatz - eine neue gewünschte Textzeichenfolge.

Nehmen wir an, meine Zellen mit Daten enthalten auch den Ländernamen ( US ) an verschiedenen Stellen in Zellen:

Wie kann REGEXREPLACE mir bei der Entfernung helfen?

=REGEXREPLACE(A1,"(.*)US(.*)","$1 $2")

So funktioniert die Formel genau:

• Es scannt den Inhalt der Zelle A1
• nach Übereinstimmungen mit dieser Maske: "(.*)US(.*)"

  Diese Maske weist die Funktion an, nach dem US unabhängig davon, wie viele andere Zeichen vorausgehen (.*) oder folgen (.*) den Namen des Landes.

  Und die gesamte Maske wird in doppelte Anführungszeichen gesetzt, wie es die Funktion verlangt :)

• das letzte Argument - "$1 $2" - ist das, was ich stattdessen bekommen möchte. $1 und $2 repräsentieren jeweils eine dieser 2 Gruppen von Zeichen - (.*) - Sie sollten diese Gruppen im dritten Argument erwähnen, damit die Formel alles zurückgeben kann, was möglicherweise vor und nach dem Argument US

  Was die US selbst, erwähne ich es einfach nicht im 3. Argument - das heißt, ich möchte alles von A1 ohne die US .

Tipp: Es gibt eine spezielle Seite, auf die Sie verweisen können, um verschiedene reguläre Ausdrücke zu erstellen und den Text in verschiedenen Positionen der Zellen zu suchen.

Tipp: Was die verbleibenden Kommata angeht, so hilft die oben beschriebene Funktion SUBSTITUTE, sie loszuwerden ;) Sie können sogar REGEXREPLACE mit SUBSTITUTE einschließen und alles mit einer Formel lösen:

=SUBSTITUTE(REGEXREPLACE(A1,"(.*)US(.*)","$1 $2"),",","")

Text vor/nach bestimmten Zeichen in allen markierten Zellen entfernen

Beispiel 1: REGEXREPLACE-Funktion für Google Sheets

Wenn es darum geht, alles loszuwerden, was vor und nach bestimmten Zeichen steht, hilft auch REGEXREPLACE. Denken Sie daran, dass die Funktion 3 Argumente benötigt:

Und wie ich bereits bei der Einführung der Funktion erwähnt habe, sollten Sie den zweiten Eintrag korrekt verwenden, damit die Funktion weiß, was sie finden und entfernen soll.

Wie kann ich also die Adressen entfernen und nur die Telefonnummern in den Zellen behalten?

Hier ist die Formel, die ich verwenden werde:

=REGEXREPLACE(A1,".*\n.*(\+.*)","$1")

• Hier ist der reguläre Ausdruck, den ich in diesem Fall verwende: ".*\n.*(\+.*)"

  Im ersten Teil - .*\n.* - Ich benutze Backslash+n Ich möchte also, dass die Funktion alles vor und nach dem Zeilenumbruch (einschließlich der Zeile) entfernt.

  Der zweite Teil, der in Klammern steht (\+.*) besagt, dass ich das Pluszeichen und alles, was darauf folgt, beibehalten möchte. Ich setze diesen Teil in Klammern, um ihn zu gruppieren und für später im Hinterkopf zu behalten.

  Tipp: Der Backslash wird vor dem Pluszeichen verwendet, um es in das gesuchte Zeichen zu verwandeln. Ohne ihn wäre das Pluszeichen nur ein Teil des Ausdrucks, der für ein anderes Zeichen steht (wie zum Beispiel ein Sternchen).

• Was das letzte Argument - $1 - betrifft, so gibt die Funktion nur die Gruppe des zweiten Arguments zurück: das Pluszeichen und alles, was darauf folgt (\+.*) .

In ähnlicher Weise können Sie alle Telefonnummern löschen, aber die Adressen behalten:

=REGEXREPLACE(A1,"(.*\n).*","$1")

Nur dieses Mal weisen Sie die Funktion an, alles vor dem Zeilenumbruch zu gruppieren (und zurückzugeben) und den Rest zu löschen:

Beispiel 2: RIGHT+LEN+FIND

Es gibt noch ein paar weitere Google Sheets-Funktionen, mit denen Sie den Text vor einem bestimmten Zeichen entfernen können: RIGHT, LEN und FIND.

Hinweis: Diese Funktionen sind nur hilfreich, wenn die zu speichernden Datensätze gleich lang sind, wie z. B. Telefonnummern in meinem Fall. Ist dies nicht der Fall, verwenden Sie stattdessen REGEXREPLACE oder, noch besser, das am Ende beschriebene einfachere Tool.

Wenn ich dieses Trio in einer bestimmten Reihenfolge verwende, erhalte ich das gleiche Ergebnis und entferne den gesamten Text vor einem Zeichen - einem Pluszeichen:

=RIGHT(A1,(LEN(A1)-(FIND("+",A1)-1)))

Lassen Sie mich erklären, wie diese Formel funktioniert:

• FIND("+",A1)-1 findet die Positionsnummer des Pluszeichens in A1 ( 24 ) und subtrahiert 1, damit die Summe nicht das Plus selbst enthält: 23 .
• LEN(A1)-(FIND("+",A1)-1) prüft die Gesamtzahl der Zeichen in A1 ( 40 ) und subtrahiert davon 23 (gezählt von FIND): 17 .
• Und dann gibt RIGHT 17 Zeichen ab dem Ende (rechts) von A1 zurück.

Leider hilft diese Methode in meinem Fall nicht viel, um den Text nach dem Zeilenumbruch zu entfernen (Telefonnummern löschen und Adressen beibehalten), da die Adressen unterschiedlich lang sind.

Nun, das ist in Ordnung. Das Werkzeug am Ende erledigt diese Aufgabe sowieso besser ;)

Entfernen der ersten/letzten N Zeichen aus Zeichenketten in Google Sheets

Wenn Sie eine bestimmte Anzahl verschiedener Zeichen vom Anfang oder Ende einer Zelle entfernen müssen, helfen Ihnen auch REGEXREPLACE und RIGHT/LEFT+LEN.

Hinweis: Da ich diese Funktionen bereits oben vorgestellt habe, werde ich mich an dieser Stelle kurz fassen und einige fertige Formeln bereitstellen. Sie können aber auch auf die einfachste Lösung zurückgreifen, die ganz am Ende beschrieben wird.

Wie kann ich also die Codes aus diesen Telefonnummern löschen, oder anders gesagt, die ersten 9 Zeichen aus den Zellen entfernen?

• Verwenden Sie REGEXREPLACE: Erstellen Sie einen regulären Ausdruck, der alles bis zum 9. Zeichen (einschließlich dieses 9. Zeichens) findet und löscht:

  =REGEXREPLACE(A1,"(.{9})(.*)","$2")

  .

  Tipp: Um die letzten N Zeichen zu entfernen, vertauschen Sie einfach die Gruppen im regulären Ausdruck:

  =REGEXREPLACE(A1,"(.*)(.{9})","$1")

• RIGHT/LEFT+LEN zählt auch die Anzahl der zu löschenden Zeichen und gibt den verbleibenden Teil vom Ende bzw. Anfang einer Zelle zurück:

  =RECHTS(A1,LEN(A1)-9)

  

  Tipp: Um die letzten 9 Zeichen aus den Zellen zu entfernen, ersetzen Sie RECHTS durch LINKS:

  =LINKS(A1,LEN(A1)-9)

• Zu guter Letzt gibt es noch die Funktion REPLACE, mit der Sie die 9 Zeichen von links beginnend durch nichts ersetzen können ( "" ):

  =REPLACE(A1,1,9,"")

  

  Hinweis: Da REPLACE eine Startposition benötigt, um den Text zu verarbeiten, reicht es nicht aus, wenn Sie N Zeichen vom Ende einer Zelle löschen müssen.

Formelfreie Methode zum Entfernen von bestimmtem Text in Google Sheets - Power Tools Add-on

Funktionen und so weiter sind immer gut, wenn man die Zeit totschlagen muss. Aber wussten Sie, dass es ein spezielles Tool gibt, das alle oben genannten Möglichkeiten umfasst und bei dem Sie nur das gewünschte Optionsfeld auswählen müssen? :) Keine Formeln, keine zusätzlichen Spalten - einen besseren Helfer kann man sich nicht wünschen ;D

Sie müssen sich nicht auf mein Wort verlassen, installieren Sie einfach Power Tools und überzeugen Sie sich selbst davon:

1. Mit der ersten Gruppe können Sie mehrere Teilstrings oder einzelne Zeichen entfernen von einer beliebigen Position in allen markierten Zellen auf einmal:

Ein weiteres Tool von Power Tools entfernt Zeit- und Datumseinheiten aus Zeitstempeln: Split Date & Time:

Was hat das Aufteilungswerkzeug mit dem Entfernen von Zeit- und Datumseinheiten zu tun? Nun, um die Zeit aus Zeitstempeln zu entfernen, wählen Sie Datum da es sich um ein Teil handelt, das Sie behalten und auch abhaken wollen Ersetzen von Quelldaten genau wie auf dem Screenshot oben.

Das Tool extrahiert die Datumseinheit und ersetzt den gesamten Zeitstempel damit, oder anders ausgedrückt: Dieses Add-on für Google Sheets entfernt die Zeiteinheit aus dem Zeitstempel:

Sie können all diese und über 30 weitere Zeitersparnisse für Tabellenkalkulationen nutzen, indem Sie das Add-on aus dem Google Store installieren. Die ersten 30 Tage sind völlig kostenlos und voll funktionsfähig, so dass Sie Zeit haben zu entscheiden, ob sich die Investition lohnt.

Wenn Sie Fragen zu irgendeinem Teil dieses Blogbeitrags haben, können Sie sich gerne unten in den Kommentaren melden!